git.sesse.net Git - ffmpeg/blob - libavutil/x86/x86inc.asm

   1 ;*****************************************************************************
   2 ;* x86inc.asm: x264asm abstraction layer
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2005-2012 x264 project
   5 ;*
   6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
   7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
   8 ;*          Jason Garrett-Glaser <darkshikari@gmail.com>
   9 ;*          Henrik Gramner <hengar-6@student.ltu.se>
  10 ;*
  11 ;* Permission to use, copy, modify, and/or distribute this software for any
  12 ;* purpose with or without fee is hereby granted, provided that the above
  13 ;* copyright notice and this permission notice appear in all copies.
  14 ;*
  15 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  16 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  17 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  18 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  19 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  20 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  21 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  22 ;*****************************************************************************
  23
  24 ; This is a header file for the x264ASM assembly language, which uses
  25 ; NASM/YASM syntax combined with a large number of macros to provide easy
  26 ; abstraction between different calling conventions (x86_32, win64, linux64).
  27 ; It also has various other useful features to simplify writing the kind of
  28 ; DSP functions that are most often used in x264.
  29
  30 ; Unlike the rest of x264, this file is available under an ISC license, as it
  31 ; has significant usefulness outside of x264 and we want it to be available
  32 ; to the largest audience possible.  Of course, if you modify it for your own
  33 ; purposes to add a new feature, we strongly encourage contributing a patch
  34 ; as this feature might be useful for others as well.  Send patches or ideas
  35 ; to x264-devel@videolan.org .
  36
  37 %ifndef program_name
  38     %define program_name x264
  39 %endif
  40
  41 %define WIN64  0
  42 %define UNIX64 0
  43 %if ARCH_X86_64
  44     %ifidn __OUTPUT_FORMAT__,win32
  45         %define WIN64  1
  46     %elifidn __OUTPUT_FORMAT__,win64
  47         %define WIN64  1
  48     %else
  49         %define UNIX64 1
  50     %endif
  51 %endif
  52
  53 %ifdef PREFIX
  54     %define mangle(x) _ %+ x
  55 %else
  56     %define mangle(x) x
  57 %endif
  58
  59 ; Name of the .rodata section.
  60 %macro SECTION_RODATA 0-1 16
  61     ; Kludge: Something on OS X fails to align .rodata even given an align
  62     ; attribute, so use a different read-only section. This has been fixed in
  63     ; yasm 0.8.0 and nasm 2.6.
  64     %ifdef __YASM_VERSION_ID__
  65         %if __YASM_VERSION_ID__ < 00080000h
  66             %define NEED_MACHO_RODATA_KLUDGE
  67         %endif
  68     %elifdef __NASM_VERSION_ID__
  69         %if __NASM_VERSION_ID__ < 02060000h
  70             %define NEED_MACHO_RODATA_KLUDGE
  71         %endif
  72     %endif
  73
  74     %ifidn __OUTPUT_FORMAT__,aout
  75         section .text
  76     %else
  77         %ifndef NEED_MACHO_RODATA_KLUDGE
  78             SECTION .rodata align=%1
  79         %else
  80             %ifidn __OUTPUT_FORMAT__,macho64
  81                 SECTION .text align=%1
  82             %elifidn __OUTPUT_FORMAT__,macho
  83                 SECTION .text align=%1
  84                 fakegot:
  85             %else
  86                 SECTION .rodata align=%1
  87             %endif
  88         %endif
  89     %endif
  90
  91     %undef NEED_MACHO_RODATA_KLUDGE
  92 %endmacro
  93
  94 ; aout does not support align=
  95 %macro SECTION_TEXT 0-1 16
  96     %ifidn __OUTPUT_FORMAT__,aout
  97         SECTION .text
  98     %else
  99         SECTION .text align=%1
 100     %endif
 101 %endmacro
 102
 103 %if WIN64
 104     %define PIC
 105 %elif ARCH_X86_64 == 0
 106 ; x86_32 doesn't require PIC.
 107 ; Some distros prefer shared objects to be PIC, but nothing breaks if
 108 ; the code contains a few textrels, so we'll skip that complexity.
 109     %undef PIC
 110 %endif
 111 %ifdef PIC
 112     default rel
 113 %endif
 114
 115 %macro CPUNOP 1
 116     %if HAVE_CPUNOP
 117         CPU %1
 118     %endif
 119 %endmacro
 120
 121 ; Always use long nops (reduces 0x90 spam in disassembly on x86_32)
 122 CPUNOP amdnop
 123
 124 ; Macros to eliminate most code duplication between x86_32 and x86_64:
 125 ; Currently this works only for leaf functions which load all their arguments
 126 ; into registers at the start, and make no other use of the stack. Luckily that
 127 ; covers most of x264's asm.
 128
 129 ; PROLOGUE:
 130 ; %1 = number of arguments. loads them from stack if needed.
 131 ; %2 = number of registers used. pushes callee-saved regs if needed.
 132 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
 133 ; %4 = (optional) stack size to be allocated. If not aligned (x86-32 ICC 10.x,
 134 ;      MSVC or YMM), the stack will be manually aligned (to 16 or 32 bytes),
 135 ;      and an extra register will be allocated to hold the original stack
 136 ;      pointer (to not invalidate r0m etc.). To prevent the use of an extra
 137 ;      register as stack pointer, request a negative stack size.
 138 ; %4+/%5+ = list of names to define to registers
 139 ; PROLOGUE can also be invoked by adding the same options to cglobal
 140
 141 ; e.g.
 142 ; cglobal foo, 2,3,0, dst, src, tmp
 143 ; declares a function (foo), taking two args (dst and src) and one local variable (tmp)
 144
 145 ; TODO Some functions can use some args directly from the stack. If they're the
 146 ; last args then you can just not declare them, but if they're in the middle
 147 ; we need more flexible macro.
 148
 149 ; RET:
 150 ; Pops anything that was pushed by PROLOGUE, and returns.
 151
 152 ; REP_RET:
 153 ; Same, but if it doesn't pop anything it becomes a 2-byte ret, for athlons
 154 ; which are slow when a normal ret follows a branch.
 155
 156 ; registers:
 157 ; rN and rNq are the native-size register holding function argument N
 158 ; rNd, rNw, rNb are dword, word, and byte size
 159 ; rNh is the high 8 bits of the word size
 160 ; rNm is the original location of arg N (a register or on the stack), dword
 161 ; rNmp is native size
 162
 163 %macro DECLARE_REG 2-3
 164     %define r%1q %2
 165     %define r%1d %2d
 166     %define r%1w %2w
 167     %define r%1b %2b
 168     %define r%1h %2h
 169     %define %2q %2
 170     %if %0 == 2
 171         %define r%1m  %2d
 172         %define r%1mp %2
 173     %elif ARCH_X86_64 ; memory
 174         %define r%1m [rstk + stack_offset + %3]
 175         %define r%1mp qword r %+ %1m
 176     %else
 177         %define r%1m [rstk + stack_offset + %3]
 178         %define r%1mp dword r %+ %1m
 179     %endif
 180     %define r%1  %2
 181 %endmacro
 182
 183 %macro DECLARE_REG_SIZE 3
 184     %define r%1q r%1
 185     %define e%1q r%1
 186     %define r%1d e%1
 187     %define e%1d e%1
 188     %define r%1w %1
 189     %define e%1w %1
 190     %define r%1h %3
 191     %define e%1h %3
 192     %define r%1b %2
 193     %define e%1b %2
 194 %if ARCH_X86_64 == 0
 195     %define r%1  e%1
 196 %endif
 197 %endmacro
 198
 199 DECLARE_REG_SIZE ax, al, ah
 200 DECLARE_REG_SIZE bx, bl, bh
 201 DECLARE_REG_SIZE cx, cl, ch
 202 DECLARE_REG_SIZE dx, dl, dh
 203 DECLARE_REG_SIZE si, sil, null
 204 DECLARE_REG_SIZE di, dil, null
 205 DECLARE_REG_SIZE bp, bpl, null
 206
 207 ; t# defines for when per-arch register allocation is more complex than just function arguments
 208
 209 %macro DECLARE_REG_TMP 1-*
 210     %assign %%i 0
 211     %rep %0
 212         CAT_XDEFINE t, %%i, r%1
 213         %assign %%i %%i+1
 214         %rotate 1
 215     %endrep
 216 %endmacro
 217
 218 %macro DECLARE_REG_TMP_SIZE 0-*
 219     %rep %0
 220         %define t%1q t%1 %+ q
 221         %define t%1d t%1 %+ d
 222         %define t%1w t%1 %+ w
 223         %define t%1h t%1 %+ h
 224         %define t%1b t%1 %+ b
 225         %rotate 1
 226     %endrep
 227 %endmacro
 228
 229 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14
 230
 231 %if ARCH_X86_64
 232     %define gprsize 8
 233 %else
 234     %define gprsize 4
 235 %endif
 236
 237 %macro PUSH 1
 238     push %1
 239     %ifidn rstk, rsp
 240         %assign stack_offset stack_offset+gprsize
 241     %endif
 242 %endmacro
 243
 244 %macro POP 1
 245     pop %1
 246     %ifidn rstk, rsp
 247         %assign stack_offset stack_offset-gprsize
 248     %endif
 249 %endmacro
 250
 251 %macro PUSH_IF_USED 1-*
 252     %rep %0
 253         %if %1 < regs_used
 254             PUSH r%1
 255         %endif
 256         %rotate 1
 257     %endrep
 258 %endmacro
 259
 260 %macro POP_IF_USED 1-*
 261     %rep %0
 262         %if %1 < regs_used
 263             pop r%1
 264         %endif
 265         %rotate 1
 266     %endrep
 267 %endmacro
 268
 269 %macro LOAD_IF_USED 1-*
 270     %rep %0
 271         %if %1 < num_args
 272             mov r%1, r %+ %1 %+ mp
 273         %endif
 274         %rotate 1
 275     %endrep
 276 %endmacro
 277
 278 %macro SUB 2
 279     sub %1, %2
 280     %ifidn %1, rstk
 281         %assign stack_offset stack_offset+(%2)
 282     %endif
 283 %endmacro
 284
 285 %macro ADD 2
 286     add %1, %2
 287     %ifidn %1, rstk
 288         %assign stack_offset stack_offset-(%2)
 289     %endif
 290 %endmacro
 291
 292 %macro movifnidn 2
 293     %ifnidn %1, %2
 294         mov %1, %2
 295     %endif
 296 %endmacro
 297
 298 %macro movsxdifnidn 2
 299     %ifnidn %1, %2
 300         movsxd %1, %2
 301     %endif
 302 %endmacro
 303
 304 %macro ASSERT 1
 305     %if (%1) == 0
 306         %error assert failed
 307     %endif
 308 %endmacro
 309
 310 %macro DEFINE_ARGS 0-*
 311     %ifdef n_arg_names
 312         %assign %%i 0
 313         %rep n_arg_names
 314             CAT_UNDEF arg_name %+ %%i, q
 315             CAT_UNDEF arg_name %+ %%i, d
 316             CAT_UNDEF arg_name %+ %%i, w
 317             CAT_UNDEF arg_name %+ %%i, h
 318             CAT_UNDEF arg_name %+ %%i, b
 319             CAT_UNDEF arg_name %+ %%i, m
 320             CAT_UNDEF arg_name %+ %%i, mp
 321             CAT_UNDEF arg_name, %%i
 322             %assign %%i %%i+1
 323         %endrep
 324     %endif
 325
 326     %xdefine %%stack_offset stack_offset
 327     %undef stack_offset ; so that the current value of stack_offset doesn't get baked in by xdefine
 328     %assign %%i 0
 329     %rep %0
 330         %xdefine %1q r %+ %%i %+ q
 331         %xdefine %1d r %+ %%i %+ d
 332         %xdefine %1w r %+ %%i %+ w
 333         %xdefine %1h r %+ %%i %+ h
 334         %xdefine %1b r %+ %%i %+ b
 335         %xdefine %1m r %+ %%i %+ m
 336         %xdefine %1mp r %+ %%i %+ mp
 337         CAT_XDEFINE arg_name, %%i, %1
 338         %assign %%i %%i+1
 339         %rotate 1
 340     %endrep
 341     %xdefine stack_offset %%stack_offset
 342     %assign n_arg_names %0
 343 %endmacro
 344
 345 %macro ALLOC_STACK 1-2 0 ; stack_size, n_xmm_regs (for win64 only)
 346     %ifnum %1
 347         %if %1 != 0
 348             %assign %%stack_alignment ((mmsize + 15) & ~15)
 349             %assign stack_size %1
 350             %if stack_size < 0
 351                 %assign stack_size -stack_size
 352             %endif
 353             %assign xmm_regs_used %2
 354             %if mmsize <= 16 && HAVE_ALIGNED_STACK
 355                 %assign stack_size_padded stack_size + %%stack_alignment - gprsize - (stack_offset & (%%stack_alignment - 1))
 356                 %if xmm_regs_used > 6
 357                     %assign stack_size_padded stack_size_padded + (xmm_regs_used - 6) * 16
 358                 %endif
 359                 SUB rsp, stack_size_padded
 360             %else
 361                 %assign reg_num (regs_used - 1)
 362                 %xdefine rstk r %+ reg_num
 363                 ; align stack, and save original stack location directly above
 364                 ; it, i.e. in [rsp+stack_size_padded], so we can restore the
 365                 ; stack in a single instruction (i.e. mov rsp, rstk or mov
 366                 ; rsp, [rsp+stack_size_padded])
 367                 mov  rstk, rsp
 368                 %assign stack_size_padded stack_size
 369                 %if xmm_regs_used > 6
 370                     %assign stack_size_padded stack_size_padded + (xmm_regs_used - 6) * 16
 371                 %endif
 372                 %if %1 < 0 ; need to store rsp on stack
 373                     sub  rsp, gprsize+stack_size_padded
 374                     and  rsp, ~(%%stack_alignment-1)
 375                     %xdefine rstkm [rsp+stack_size_padded]
 376                     mov rstkm, rstk
 377                 %else ; can keep rsp in rstk during whole function
 378                     sub  rsp, stack_size_padded
 379                     and  rsp, ~(%%stack_alignment-1)
 380                     %xdefine rstkm rstk
 381                 %endif
 382             %endif
 383             %if xmm_regs_used > 6
 384                 WIN64_PUSH_XMM
 385             %endif
 386         %endif
 387     %endif
 388 %endmacro
 389
 390 %macro SETUP_STACK_POINTER 1
 391     %ifnum %1
 392         %if %1 != 0 && (HAVE_ALIGNED_STACK == 0 || mmsize == 32)
 393             %if %1 > 0
 394                 %assign regs_used (regs_used + 1)
 395             %elif ARCH_X86_64 && regs_used == num_args && num_args <= 4 + UNIX64 * 2
 396                 %warning "Stack pointer will overwrite register argument"
 397             %endif
 398         %endif
 399     %endif
 400 %endmacro
 401
 402 %macro DEFINE_ARGS_INTERNAL 3+
 403     %ifnum %2
 404         DEFINE_ARGS %3
 405     %elif %1 == 4
 406         DEFINE_ARGS %2
 407     %elif %1 > 4
 408         DEFINE_ARGS %2, %3
 409     %endif
 410 %endmacro
 411
 412 %if WIN64 ; Windows x64 ;=================================================
 413
 414 DECLARE_REG 0,  rcx
 415 DECLARE_REG 1,  rdx
 416 DECLARE_REG 2,  R8
 417 DECLARE_REG 3,  R9
 418 DECLARE_REG 4,  R10, 40
 419 DECLARE_REG 5,  R11, 48
 420 DECLARE_REG 6,  rax, 56
 421 DECLARE_REG 7,  rdi, 64
 422 DECLARE_REG 8,  rsi, 72
 423 DECLARE_REG 9,  rbx, 80
 424 DECLARE_REG 10, rbp, 88
 425 DECLARE_REG 11, R12, 96
 426 DECLARE_REG 12, R13, 104
 427 DECLARE_REG 13, R14, 112
 428 DECLARE_REG 14, R15, 120
 429
 430 %macro PROLOGUE 2-5+ 0 ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
 431     %assign num_args %1
 432     %assign regs_used %2
 433     SETUP_STACK_POINTER %4
 434     ASSERT regs_used >= num_args
 435     ASSERT regs_used <= 15
 436     PUSH_IF_USED 7, 8, 9, 10, 11, 12, 13, 14
 437     %assign xmm_regs_used 0
 438     ALLOC_STACK %4, %3
 439     %if mmsize != 8 && stack_size == 0
 440         WIN64_SPILL_XMM %3
 441     %endif
 442     LOAD_IF_USED 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14
 443     DEFINE_ARGS_INTERNAL %0, %4, %5
 444 %endmacro
 445
 446 %macro WIN64_PUSH_XMM 0
 447     %assign %%i xmm_regs_used
 448     %rep (xmm_regs_used-6)
 449         %assign %%i %%i-1
 450         movdqa [rsp + (%%i-6)*16 + stack_size + (~stack_offset&8)], xmm %+ %%i
 451     %endrep
 452 %endmacro
 453
 454 %macro WIN64_SPILL_XMM 1
 455     %assign xmm_regs_used %1
 456     ASSERT xmm_regs_used <= 16
 457     %if xmm_regs_used > 6
 458         SUB rsp, (xmm_regs_used-6)*16+16
 459         WIN64_PUSH_XMM
 460     %endif
 461 %endmacro
 462
 463 %macro WIN64_RESTORE_XMM_INTERNAL 1
 464     %if xmm_regs_used > 6
 465         %assign %%i xmm_regs_used
 466         %rep (xmm_regs_used-6)
 467             %assign %%i %%i-1
 468             movdqa xmm %+ %%i, [%1 + (%%i-6)*16+stack_size+(~stack_offset&8)]
 469         %endrep
 470         %if stack_size_padded == 0
 471             add %1, (xmm_regs_used-6)*16+16
 472         %endif
 473     %endif
 474     %if stack_size_padded > 0
 475         %if stack_size > 0 && (mmsize == 32 || HAVE_ALIGNED_STACK == 0)
 476             mov rsp, rstkm
 477         %else
 478             add %1, stack_size_padded
 479         %endif
 480     %endif
 481 %endmacro
 482
 483 %macro WIN64_RESTORE_XMM 1
 484     WIN64_RESTORE_XMM_INTERNAL %1
 485     %assign stack_offset (stack_offset-stack_size_padded)
 486     %assign xmm_regs_used 0
 487 %endmacro
 488
 489 %define has_epilogue regs_used > 7 || xmm_regs_used > 6 || mmsize == 32 || stack_size > 0
 490
 491 %macro RET 0
 492     WIN64_RESTORE_XMM_INTERNAL rsp
 493     POP_IF_USED 14, 13, 12, 11, 10, 9, 8, 7
 494 %if mmsize == 32
 495     vzeroupper
 496 %endif
 497     ret
 498 %endmacro
 499
 500 %elif ARCH_X86_64 ; *nix x64 ;=============================================
 501
 502 DECLARE_REG 0,  rdi
 503 DECLARE_REG 1,  rsi
 504 DECLARE_REG 2,  rdx
 505 DECLARE_REG 3,  rcx
 506 DECLARE_REG 4,  R8
 507 DECLARE_REG 5,  R9
 508 DECLARE_REG 6,  rax, 8
 509 DECLARE_REG 7,  R10, 16
 510 DECLARE_REG 8,  R11, 24
 511 DECLARE_REG 9,  rbx, 32
 512 DECLARE_REG 10, rbp, 40
 513 DECLARE_REG 11, R12, 48
 514 DECLARE_REG 12, R13, 56
 515 DECLARE_REG 13, R14, 64
 516 DECLARE_REG 14, R15, 72
 517
 518 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
 519     %assign num_args %1
 520     %assign regs_used %2
 521     SETUP_STACK_POINTER %4
 522     ASSERT regs_used >= num_args
 523     ASSERT regs_used <= 15
 524     PUSH_IF_USED 9, 10, 11, 12, 13, 14
 525     ALLOC_STACK %4
 526     LOAD_IF_USED 6, 7, 8, 9, 10, 11, 12, 13, 14
 527     DEFINE_ARGS_INTERNAL %0, %4, %5
 528 %endmacro
 529
 530 %define has_epilogue regs_used > 9 || mmsize == 32 || stack_size > 0
 531
 532 %macro RET 0
 533 %if stack_size_padded > 0
 534 %if mmsize == 32 || HAVE_ALIGNED_STACK == 0
 535     mov rsp, rstkm
 536 %else
 537     add rsp, stack_size_padded
 538 %endif
 539 %endif
 540     POP_IF_USED 14, 13, 12, 11, 10, 9
 541 %if mmsize == 32
 542     vzeroupper
 543 %endif
 544     ret
 545 %endmacro
 546
 547 %else ; X86_32 ;==============================================================
 548
 549 DECLARE_REG 0, eax, 4
 550 DECLARE_REG 1, ecx, 8
 551 DECLARE_REG 2, edx, 12
 552 DECLARE_REG 3, ebx, 16
 553 DECLARE_REG 4, esi, 20
 554 DECLARE_REG 5, edi, 24
 555 DECLARE_REG 6, ebp, 28
 556 %define rsp esp
 557
 558 %macro DECLARE_ARG 1-*
 559     %rep %0
 560         %define r%1m [rstk + stack_offset + 4*%1 + 4]
 561         %define r%1mp dword r%1m
 562         %rotate 1
 563     %endrep
 564 %endmacro
 565
 566 DECLARE_ARG 7, 8, 9, 10, 11, 12, 13, 14
 567
 568 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
 569     %assign num_args %1
 570     %assign regs_used %2
 571     %if regs_used > 7
 572         %assign regs_used 7
 573     %endif
 574     SETUP_STACK_POINTER %4
 575     ASSERT regs_used <= 7
 576     ASSERT regs_used >= num_args
 577     PUSH_IF_USED 3, 4, 5, 6
 578     ALLOC_STACK %4
 579     LOAD_IF_USED 0, 1, 2, 3, 4, 5, 6
 580     DEFINE_ARGS_INTERNAL %0, %4, %5
 581 %endmacro
 582
 583 %define has_epilogue regs_used > 3 || mmsize == 32 || stack_size > 0
 584
 585 %macro RET 0
 586 %if stack_size_padded > 0
 587 %if mmsize == 32 || HAVE_ALIGNED_STACK == 0
 588     mov rsp, rstkm
 589 %else
 590     add rsp, stack_size_padded
 591 %endif
 592 %endif
 593     POP_IF_USED 6, 5, 4, 3
 594 %if mmsize == 32
 595     vzeroupper
 596 %endif
 597     ret
 598 %endmacro
 599
 600 %endif ;======================================================================
 601
 602 %if WIN64 == 0
 603 %macro WIN64_SPILL_XMM 1
 604 %endmacro
 605 %macro WIN64_RESTORE_XMM 1
 606 %endmacro
 607 %macro WIN64_PUSH_XMM 0
 608 %endmacro
 609 %endif
 610
 611 %macro REP_RET 0
 612     %if has_epilogue
 613         RET
 614     %else
 615         rep ret
 616     %endif
 617 %endmacro
 618
 619 %macro TAIL_CALL 2 ; callee, is_nonadjacent
 620     %if has_epilogue
 621         call %1
 622         RET
 623     %elif %2
 624         jmp %1
 625     %endif
 626 %endmacro
 627
 628 ;=============================================================================
 629 ; arch-independent part
 630 ;=============================================================================
 631
 632 %assign function_align 16
 633
 634 ; Begin a function.
 635 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
 636 ; subsequent uses of the function name automatically refer to the mangled version.
 637 ; Appends cpuflags to the function name if cpuflags has been specified.
 638 %macro cglobal 1-2+ ; name, [PROLOGUE args]
 639 %if %0 == 1
 640     cglobal_internal %1 %+ SUFFIX
 641 %else
 642     cglobal_internal %1 %+ SUFFIX, %2
 643 %endif
 644 %endmacro
 645 %macro cglobal_internal 1-2+
 646     %ifndef cglobaled_%1
 647         %xdefine %1 mangle(program_name %+ _ %+ %1)
 648         %xdefine %1.skip_prologue %1 %+ .skip_prologue
 649         CAT_XDEFINE cglobaled_, %1, 1
 650     %endif
 651     %xdefine current_function %1
 652     %ifidn __OUTPUT_FORMAT__,elf
 653         global %1:function hidden
 654     %else
 655         global %1
 656     %endif
 657     align function_align
 658     %1:
 659     RESET_MM_PERMUTATION ; not really needed, but makes disassembly somewhat nicer
 660     %xdefine rstk rsp
 661     %assign stack_offset 0
 662     %assign stack_size 0
 663     %assign stack_size_padded 0
 664     %if %0 > 1
 665         PROLOGUE %2
 666     %endif
 667 %endmacro
 668
 669 %macro cextern 1
 670     %xdefine %1 mangle(program_name %+ _ %+ %1)
 671     CAT_XDEFINE cglobaled_, %1, 1
 672     extern %1
 673 %endmacro
 674
 675 ; like cextern, but without the prefix
 676 %macro cextern_naked 1
 677     %xdefine %1 mangle(%1)
 678     CAT_XDEFINE cglobaled_, %1, 1
 679     extern %1
 680 %endmacro
 681
 682 %macro const 2+
 683     %xdefine %1 mangle(program_name %+ _ %+ %1)
 684     global %1
 685     %1: %2
 686 %endmacro
 687
 688 ; This is needed for ELF, otherwise the GNU linker assumes the stack is
 689 ; executable by default.
 690 %ifidn __OUTPUT_FORMAT__,elf
 691 SECTION .note.GNU-stack noalloc noexec nowrite progbits
 692 %endif
 693
 694 ; cpuflags
 695
 696 %assign cpuflags_mmx      (1<<0)
 697 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
 698 %assign cpuflags_3dnow    (1<<2) | cpuflags_mmx
 699 %assign cpuflags_3dnowext (1<<3) | cpuflags_3dnow
 700 %assign cpuflags_sse      (1<<4) | cpuflags_mmx2
 701 %assign cpuflags_sse2     (1<<5) | cpuflags_sse
 702 %assign cpuflags_sse2slow (1<<6) | cpuflags_sse2
 703 %assign cpuflags_sse3     (1<<7) | cpuflags_sse2
 704 %assign cpuflags_ssse3    (1<<8) | cpuflags_sse3
 705 %assign cpuflags_sse4     (1<<9) | cpuflags_ssse3
 706 %assign cpuflags_sse42    (1<<10)| cpuflags_sse4
 707 %assign cpuflags_avx      (1<<11)| cpuflags_sse42
 708 %assign cpuflags_xop      (1<<12)| cpuflags_avx
 709 %assign cpuflags_fma4     (1<<13)| cpuflags_avx
 710 %assign cpuflags_avx2     (1<<14)| cpuflags_avx
 711 %assign cpuflags_fma3     (1<<15)| cpuflags_avx
 712
 713 %assign cpuflags_cache32  (1<<16)
 714 %assign cpuflags_cache64  (1<<17)
 715 %assign cpuflags_slowctz  (1<<18)
 716 %assign cpuflags_lzcnt    (1<<19)
 717 %assign cpuflags_misalign (1<<20)
 718 %assign cpuflags_aligned  (1<<21) ; not a cpu feature, but a function variant
 719 %assign cpuflags_atom     (1<<22)
 720 %assign cpuflags_bmi1     (1<<23)
 721 %assign cpuflags_bmi2     (1<<24)|cpuflags_bmi1
 722 %assign cpuflags_tbm      (1<<25)|cpuflags_bmi1
 723
 724 %define    cpuflag(x) ((cpuflags & (cpuflags_ %+ x)) == (cpuflags_ %+ x))
 725 %define notcpuflag(x) ((cpuflags & (cpuflags_ %+ x)) != (cpuflags_ %+ x))
 726
 727 ; Takes up to 2 cpuflags from the above list.
 728 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
 729 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
 730 %macro INIT_CPUFLAGS 0-2
 731     CPUNOP amdnop
 732     %if %0 >= 1
 733         %xdefine cpuname %1
 734         %assign cpuflags cpuflags_%1
 735         %if %0 >= 2
 736             %xdefine cpuname %1_%2
 737             %assign cpuflags cpuflags | cpuflags_%2
 738         %endif
 739         %xdefine SUFFIX _ %+ cpuname
 740         %if cpuflag(avx)
 741             %assign avx_enabled 1
 742         %endif
 743         %if mmsize == 16 && notcpuflag(sse2)
 744             %define mova movaps
 745             %define movu movups
 746             %define movnta movntps
 747         %endif
 748         %if cpuflag(aligned)
 749             %define movu mova
 750         %elifidn %1, sse3
 751             %define movu lddqu
 752         %endif
 753         %if notcpuflag(mmx2)
 754             CPUNOP basicnop
 755         %endif
 756     %else
 757         %xdefine SUFFIX
 758         %undef cpuname
 759         %undef cpuflags
 760     %endif
 761 %endmacro
 762
 763 ; merge mmx and sse*
 764
 765 %macro CAT_XDEFINE 3
 766     %xdefine %1%2 %3
 767 %endmacro
 768
 769 %macro CAT_UNDEF 2
 770     %undef %1%2
 771 %endmacro
 772
 773 %macro INIT_MMX 0-1+
 774     %assign avx_enabled 0
 775     %define RESET_MM_PERMUTATION INIT_MMX %1
 776     %define mmsize 8
 777     %define num_mmregs 8
 778     %define mova movq
 779     %define movu movq
 780     %define movh movd
 781     %define movnta movntq
 782     %assign %%i 0
 783     %rep 8
 784     CAT_XDEFINE m, %%i, mm %+ %%i
 785     CAT_XDEFINE nmm, %%i, %%i
 786     %assign %%i %%i+1
 787     %endrep
 788     %rep 8
 789     CAT_UNDEF m, %%i
 790     CAT_UNDEF nmm, %%i
 791     %assign %%i %%i+1
 792     %endrep
 793     INIT_CPUFLAGS %1
 794 %endmacro
 795
 796 %macro INIT_XMM 0-1+
 797     %assign avx_enabled 0
 798     %define RESET_MM_PERMUTATION INIT_XMM %1
 799     %define mmsize 16
 800     %define num_mmregs 8
 801     %if ARCH_X86_64
 802     %define num_mmregs 16
 803     %endif
 804     %define mova movdqa
 805     %define movu movdqu
 806     %define movh movq
 807     %define movnta movntdq
 808     %assign %%i 0
 809     %rep num_mmregs
 810     CAT_XDEFINE m, %%i, xmm %+ %%i
 811     CAT_XDEFINE nxmm, %%i, %%i
 812     %assign %%i %%i+1
 813     %endrep
 814     INIT_CPUFLAGS %1
 815 %endmacro
 816
 817 ; FIXME: INIT_AVX can be replaced by INIT_XMM avx
 818 %macro INIT_AVX 0
 819     INIT_XMM
 820     %assign avx_enabled 1
 821     %define PALIGNR PALIGNR_SSSE3
 822     %define RESET_MM_PERMUTATION INIT_AVX
 823 %endmacro
 824
 825 %macro INIT_YMM 0-1+
 826     %assign avx_enabled 1
 827     %define RESET_MM_PERMUTATION INIT_YMM %1
 828     %define mmsize 32
 829     %define num_mmregs 8
 830     %if ARCH_X86_64
 831     %define num_mmregs 16
 832     %endif
 833     %define mova vmovaps
 834     %define movu vmovups
 835     %undef movh
 836     %define movnta vmovntps
 837     %assign %%i 0
 838     %rep num_mmregs
 839     CAT_XDEFINE m, %%i, ymm %+ %%i
 840     CAT_XDEFINE nymm, %%i, %%i
 841     %assign %%i %%i+1
 842     %endrep
 843     INIT_CPUFLAGS %1
 844 %endmacro
 845
 846 INIT_XMM
 847
 848 ; I often want to use macros that permute their arguments. e.g. there's no
 849 ; efficient way to implement butterfly or transpose or dct without swapping some
 850 ; arguments.
 851 ;
 852 ; I would like to not have to manually keep track of the permutations:
 853 ; If I insert a permutation in the middle of a function, it should automatically
 854 ; change everything that follows. For more complex macros I may also have multiple
 855 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
 856 ;
 857 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
 858 ; permutes its arguments. It's equivalent to exchanging the contents of the
 859 ; registers, except that this way you exchange the register names instead, so it
 860 ; doesn't cost any cycles.
 861
 862 %macro PERMUTE 2-* ; takes a list of pairs to swap
 863 %rep %0/2
 864     %xdefine tmp%2 m%2
 865     %xdefine ntmp%2 nm%2
 866     %rotate 2
 867 %endrep
 868 %rep %0/2
 869     %xdefine m%1 tmp%2
 870     %xdefine nm%1 ntmp%2
 871     %undef tmp%2
 872     %undef ntmp%2
 873     %rotate 2
 874 %endrep
 875 %endmacro
 876
 877 %macro SWAP 2-* ; swaps a single chain (sometimes more concise than pairs)
 878 %rep %0-1
 879 %ifdef m%1
 880     %xdefine tmp m%1
 881     %xdefine m%1 m%2
 882     %xdefine m%2 tmp
 883     CAT_XDEFINE n, m%1, %1
 884     CAT_XDEFINE n, m%2, %2
 885 %else
 886     ; If we were called as "SWAP m0,m1" rather than "SWAP 0,1" infer the original numbers here.
 887     ; Be careful using this mode in nested macros though, as in some cases there may be
 888     ; other copies of m# that have already been dereferenced and don't get updated correctly.
 889     %xdefine %%n1 n %+ %1
 890     %xdefine %%n2 n %+ %2
 891     %xdefine tmp m %+ %%n1
 892     CAT_XDEFINE m, %%n1, m %+ %%n2
 893     CAT_XDEFINE m, %%n2, tmp
 894     CAT_XDEFINE n, m %+ %%n1, %%n1
 895     CAT_XDEFINE n, m %+ %%n2, %%n2
 896 %endif
 897     %undef tmp
 898     %rotate 1
 899 %endrep
 900 %endmacro
 901
 902 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
 903 ; calls to that function will automatically load the permutation, so values can
 904 ; be returned in mmregs.
 905 %macro SAVE_MM_PERMUTATION 0-1
 906     %if %0
 907         %xdefine %%f %1_m
 908     %else
 909         %xdefine %%f current_function %+ _m
 910     %endif
 911     %assign %%i 0
 912     %rep num_mmregs
 913         CAT_XDEFINE %%f, %%i, m %+ %%i
 914     %assign %%i %%i+1
 915     %endrep
 916 %endmacro
 917
 918 %macro LOAD_MM_PERMUTATION 1 ; name to load from
 919     %ifdef %1_m0
 920         %assign %%i 0
 921         %rep num_mmregs
 922             CAT_XDEFINE m, %%i, %1_m %+ %%i
 923             CAT_XDEFINE n, m %+ %%i, %%i
 924         %assign %%i %%i+1
 925         %endrep
 926     %endif
 927 %endmacro
 928
 929 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
 930 %macro call 1
 931     call_internal %1 %+ SUFFIX, %1
 932 %endmacro
 933 %macro call_internal 2
 934     %xdefine %%i %2
 935     %ifndef cglobaled_%2
 936         %ifdef cglobaled_%1
 937             %xdefine %%i %1
 938         %endif
 939     %endif
 940     call %%i
 941     LOAD_MM_PERMUTATION %%i
 942 %endmacro
 943
 944 ; Substitutions that reduce instruction size but are functionally equivalent
 945 %macro add 2
 946     %ifnum %2
 947         %if %2==128
 948             sub %1, -128
 949         %else
 950             add %1, %2
 951         %endif
 952     %else
 953         add %1, %2
 954     %endif
 955 %endmacro
 956
 957 %macro sub 2
 958     %ifnum %2
 959         %if %2==128
 960             add %1, -128
 961         %else
 962             sub %1, %2
 963         %endif
 964     %else
 965         sub %1, %2
 966     %endif
 967 %endmacro
 968
 969 ;=============================================================================
 970 ; AVX abstraction layer
 971 ;=============================================================================
 972
 973 %assign i 0
 974 %rep 16
 975     %if i < 8
 976         CAT_XDEFINE sizeofmm, i, 8
 977     %endif
 978     CAT_XDEFINE sizeofxmm, i, 16
 979     CAT_XDEFINE sizeofymm, i, 32
 980 %assign i i+1
 981 %endrep
 982 %undef i
 983
 984 %macro CHECK_AVX_INSTR_EMU 3-*
 985     %xdefine %%opcode %1
 986     %xdefine %%dst %2
 987     %rep %0-2
 988         %ifidn %%dst, %3
 989             %error non-avx emulation of ``%%opcode'' is not supported
 990         %endif
 991         %rotate 1
 992     %endrep
 993 %endmacro
 994
 995 ;%1 == instruction
 996 ;%2 == 1 if float, 0 if int
 997 ;%3 == 1 if 4-operand (xmm, xmm, xmm, imm), 0 if 2- or 3-operand (xmm, xmm, xmm)
 998 ;%4 == number of operands given
 999 ;%5+: operands
1000 %macro RUN_AVX_INSTR 6-7+
1001     %ifid %6
1002         %define %%sizeofreg sizeof%6
1003     %elifid %5
1004         %define %%sizeofreg sizeof%5
1005     %else
1006         %define %%sizeofreg mmsize
1007     %endif
1008     %if %%sizeofreg==32
1009         %if %4>=3
1010             v%1 %5, %6, %7
1011         %else
1012             v%1 %5, %6
1013         %endif
1014     %else
1015         %if %%sizeofreg==8
1016             %define %%regmov movq
1017         %elif %2
1018             %define %%regmov movaps
1019         %else
1020             %define %%regmov movdqa
1021         %endif
1022
1023         %if %4>=3+%3
1024             %ifnidn %5, %6
1025                 %if avx_enabled && %%sizeofreg==16
1026                     v%1 %5, %6, %7
1027                 %else
1028                     CHECK_AVX_INSTR_EMU {%1 %5, %6, %7}, %5, %7
1029                     %%regmov %5, %6
1030                     %1 %5, %7
1031                 %endif
1032             %else
1033                 %1 %5, %7
1034             %endif
1035         %elif %4>=3
1036             %1 %5, %6, %7
1037         %else
1038             %1 %5, %6
1039         %endif
1040     %endif
1041 %endmacro
1042
1043 ; 3arg AVX ops with a memory arg can only have it in src2,
1044 ; whereas SSE emulation of 3arg prefers to have it in src1 (i.e. the mov).
1045 ; So, if the op is symmetric and the wrong one is memory, swap them.
1046 %macro RUN_AVX_INSTR1 8
1047     %assign %%swap 0
1048     %if avx_enabled
1049         %ifnid %6
1050             %assign %%swap 1
1051         %endif
1052     %elifnidn %5, %6
1053         %ifnid %7
1054             %assign %%swap 1
1055         %endif
1056     %endif
1057     %if %%swap && %3 == 0 && %8 == 1
1058         RUN_AVX_INSTR %1, %2, %3, %4, %5, %7, %6
1059     %else
1060         RUN_AVX_INSTR %1, %2, %3, %4, %5, %6, %7
1061     %endif
1062 %endmacro
1063
1064 ;%1 == instruction
1065 ;%2 == 1 if float, 0 if int
1066 ;%3 == 1 if 4-operand (xmm, xmm, xmm, imm), 0 if 2- or 3-operand (xmm, xmm, xmm)
1067 ;%4 == 1 if symmetric (i.e. doesn't matter which src arg is which), 0 if not
1068 %macro AVX_INSTR 4
1069     %macro %1 2-9 fnord, fnord, fnord, %1, %2, %3, %4
1070         %ifidn %3, fnord
1071             RUN_AVX_INSTR %6, %7, %8, 2, %1, %2
1072         %elifidn %4, fnord
1073             RUN_AVX_INSTR1 %6, %7, %8, 3, %1, %2, %3, %9
1074         %elifidn %5, fnord
1075             RUN_AVX_INSTR %6, %7, %8, 4, %1, %2, %3, %4
1076         %else
1077             RUN_AVX_INSTR %6, %7, %8, 5, %1, %2, %3, %4, %5
1078         %endif
1079     %endmacro
1080 %endmacro
1081
1082 AVX_INSTR addpd, 1, 0, 1
1083 AVX_INSTR addps, 1, 0, 1
1084 AVX_INSTR addsd, 1, 0, 1
1085 AVX_INSTR addss, 1, 0, 1
1086 AVX_INSTR addsubpd, 1, 0, 0
1087 AVX_INSTR addsubps, 1, 0, 0
1088 AVX_INSTR andpd, 1, 0, 1
1089 AVX_INSTR andps, 1, 0, 1
1090 AVX_INSTR andnpd, 1, 0, 0
1091 AVX_INSTR andnps, 1, 0, 0
1092 AVX_INSTR blendpd, 1, 0, 0
1093 AVX_INSTR blendps, 1, 0, 0
1094 AVX_INSTR blendvpd, 1, 0, 0
1095 AVX_INSTR blendvps, 1, 0, 0
1096 AVX_INSTR cmppd, 1, 0, 0
1097 AVX_INSTR cmpps, 1, 0, 0
1098 AVX_INSTR cmpsd, 1, 0, 0
1099 AVX_INSTR cmpss, 1, 0, 0
1100 AVX_INSTR cvtdq2ps, 1, 0, 0
1101 AVX_INSTR cvtpd2dq, 1, 0, 0
1102 AVX_INSTR cvtps2dq, 1, 0, 0
1103 AVX_INSTR divpd, 1, 0, 0
1104 AVX_INSTR divps, 1, 0, 0
1105 AVX_INSTR divsd, 1, 0, 0
1106 AVX_INSTR divss, 1, 0, 0
1107 AVX_INSTR dppd, 1, 1, 0
1108 AVX_INSTR dpps, 1, 1, 0
1109 AVX_INSTR haddpd, 1, 0, 0
1110 AVX_INSTR haddps, 1, 0, 0
1111 AVX_INSTR hsubpd, 1, 0, 0
1112 AVX_INSTR hsubps, 1, 0, 0
1113 AVX_INSTR maxpd, 1, 0, 1
1114 AVX_INSTR maxps, 1, 0, 1
1115 AVX_INSTR maxsd, 1, 0, 1
1116 AVX_INSTR maxss, 1, 0, 1
1117 AVX_INSTR minpd, 1, 0, 1
1118 AVX_INSTR minps, 1, 0, 1
1119 AVX_INSTR minsd, 1, 0, 1
1120 AVX_INSTR minss, 1, 0, 1
1121 AVX_INSTR movhlps, 1, 0, 0
1122 AVX_INSTR movlhps, 1, 0, 0
1123 AVX_INSTR movsd, 1, 0, 0
1124 AVX_INSTR movss, 1, 0, 0
1125 AVX_INSTR mpsadbw, 0, 1, 0
1126 AVX_INSTR mulpd, 1, 0, 1
1127 AVX_INSTR mulps, 1, 0, 1
1128 AVX_INSTR mulsd, 1, 0, 1
1129 AVX_INSTR mulss, 1, 0, 1
1130 AVX_INSTR orpd, 1, 0, 1
1131 AVX_INSTR orps, 1, 0, 1
1132 AVX_INSTR pabsb, 0, 0, 0
1133 AVX_INSTR pabsw, 0, 0, 0
1134 AVX_INSTR pabsd, 0, 0, 0
1135 AVX_INSTR packsswb, 0, 0, 0
1136 AVX_INSTR packssdw, 0, 0, 0
1137 AVX_INSTR packuswb, 0, 0, 0
1138 AVX_INSTR packusdw, 0, 0, 0
1139 AVX_INSTR paddb, 0, 0, 1
1140 AVX_INSTR paddw, 0, 0, 1
1141 AVX_INSTR paddd, 0, 0, 1
1142 AVX_INSTR paddq, 0, 0, 1
1143 AVX_INSTR paddsb, 0, 0, 1
1144 AVX_INSTR paddsw, 0, 0, 1
1145 AVX_INSTR paddusb, 0, 0, 1
1146 AVX_INSTR paddusw, 0, 0, 1
1147 AVX_INSTR palignr, 0, 1, 0
1148 AVX_INSTR pand, 0, 0, 1
1149 AVX_INSTR pandn, 0, 0, 0
1150 AVX_INSTR pavgb, 0, 0, 1
1151 AVX_INSTR pavgw, 0, 0, 1
1152 AVX_INSTR pblendvb, 0, 0, 0
1153 AVX_INSTR pblendw, 0, 1, 0
1154 AVX_INSTR pcmpestri, 0, 0, 0
1155 AVX_INSTR pcmpestrm, 0, 0, 0
1156 AVX_INSTR pcmpistri, 0, 0, 0
1157 AVX_INSTR pcmpistrm, 0, 0, 0
1158 AVX_INSTR pcmpeqb, 0, 0, 1
1159 AVX_INSTR pcmpeqw, 0, 0, 1
1160 AVX_INSTR pcmpeqd, 0, 0, 1
1161 AVX_INSTR pcmpeqq, 0, 0, 1
1162 AVX_INSTR pcmpgtb, 0, 0, 0
1163 AVX_INSTR pcmpgtw, 0, 0, 0
1164 AVX_INSTR pcmpgtd, 0, 0, 0
1165 AVX_INSTR pcmpgtq, 0, 0, 0
1166 AVX_INSTR phaddw, 0, 0, 0
1167 AVX_INSTR phaddd, 0, 0, 0
1168 AVX_INSTR phaddsw, 0, 0, 0
1169 AVX_INSTR phsubw, 0, 0, 0
1170 AVX_INSTR phsubd, 0, 0, 0
1171 AVX_INSTR phsubsw, 0, 0, 0
1172 AVX_INSTR pmaddwd, 0, 0, 1
1173 AVX_INSTR pmaddubsw, 0, 0, 0
1174 AVX_INSTR pmaxsb, 0, 0, 1
1175 AVX_INSTR pmaxsw, 0, 0, 1
1176 AVX_INSTR pmaxsd, 0, 0, 1
1177 AVX_INSTR pmaxub, 0, 0, 1
1178 AVX_INSTR pmaxuw, 0, 0, 1
1179 AVX_INSTR pmaxud, 0, 0, 1
1180 AVX_INSTR pminsb, 0, 0, 1
1181 AVX_INSTR pminsw, 0, 0, 1
1182 AVX_INSTR pminsd, 0, 0, 1
1183 AVX_INSTR pminub, 0, 0, 1
1184 AVX_INSTR pminuw, 0, 0, 1
1185 AVX_INSTR pminud, 0, 0, 1
1186 AVX_INSTR pmovmskb, 0, 0, 0
1187 AVX_INSTR pmulhuw, 0, 0, 1
1188 AVX_INSTR pmulhrsw, 0, 0, 1
1189 AVX_INSTR pmulhw, 0, 0, 1
1190 AVX_INSTR pmullw, 0, 0, 1
1191 AVX_INSTR pmulld, 0, 0, 1
1192 AVX_INSTR pmuludq, 0, 0, 1
1193 AVX_INSTR pmuldq, 0, 0, 1
1194 AVX_INSTR por, 0, 0, 1
1195 AVX_INSTR psadbw, 0, 0, 1
1196 AVX_INSTR pshufb, 0, 0, 0
1197 AVX_INSTR pshufd, 0, 1, 0
1198 AVX_INSTR pshufhw, 0, 1, 0
1199 AVX_INSTR pshuflw, 0, 1, 0
1200 AVX_INSTR psignb, 0, 0, 0
1201 AVX_INSTR psignw, 0, 0, 0
1202 AVX_INSTR psignd, 0, 0, 0
1203 AVX_INSTR psllw, 0, 0, 0
1204 AVX_INSTR pslld, 0, 0, 0
1205 AVX_INSTR psllq, 0, 0, 0
1206 AVX_INSTR pslldq, 0, 0, 0
1207 AVX_INSTR psraw, 0, 0, 0
1208 AVX_INSTR psrad, 0, 0, 0
1209 AVX_INSTR psrlw, 0, 0, 0
1210 AVX_INSTR psrld, 0, 0, 0
1211 AVX_INSTR psrlq, 0, 0, 0
1212 AVX_INSTR psrldq, 0, 0, 0
1213 AVX_INSTR psubb, 0, 0, 0
1214 AVX_INSTR psubw, 0, 0, 0
1215 AVX_INSTR psubd, 0, 0, 0
1216 AVX_INSTR psubq, 0, 0, 0
1217 AVX_INSTR psubsb, 0, 0, 0
1218 AVX_INSTR psubsw, 0, 0, 0
1219 AVX_INSTR psubusb, 0, 0, 0
1220 AVX_INSTR psubusw, 0, 0, 0
1221 AVX_INSTR ptest, 0, 0, 0
1222 AVX_INSTR punpckhbw, 0, 0, 0
1223 AVX_INSTR punpckhwd, 0, 0, 0
1224 AVX_INSTR punpckhdq, 0, 0, 0
1225 AVX_INSTR punpckhqdq, 0, 0, 0
1226 AVX_INSTR punpcklbw, 0, 0, 0
1227 AVX_INSTR punpcklwd, 0, 0, 0
1228 AVX_INSTR punpckldq, 0, 0, 0
1229 AVX_INSTR punpcklqdq, 0, 0, 0
1230 AVX_INSTR pxor, 0, 0, 1
1231 AVX_INSTR shufps, 1, 1, 0
1232 AVX_INSTR subpd, 1, 0, 0
1233 AVX_INSTR subps, 1, 0, 0
1234 AVX_INSTR subsd, 1, 0, 0
1235 AVX_INSTR subss, 1, 0, 0
1236 AVX_INSTR unpckhpd, 1, 0, 0
1237 AVX_INSTR unpckhps, 1, 0, 0
1238 AVX_INSTR unpcklpd, 1, 0, 0
1239 AVX_INSTR unpcklps, 1, 0, 0
1240 AVX_INSTR xorpd, 1, 0, 1
1241 AVX_INSTR xorps, 1, 0, 1
1242
1243 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
1244 AVX_INSTR pfadd, 1, 0, 1
1245 AVX_INSTR pfsub, 1, 0, 0
1246 AVX_INSTR pfmul, 1, 0, 1
1247
1248 ; base-4 constants for shuffles
1249 %assign i 0
1250 %rep 256
1251     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
1252     %if j < 10
1253         CAT_XDEFINE q000, j, i
1254     %elif j < 100
1255         CAT_XDEFINE q00, j, i
1256     %elif j < 1000
1257         CAT_XDEFINE q0, j, i
1258     %else
1259         CAT_XDEFINE q, j, i
1260     %endif
1261 %assign i i+1
1262 %endrep
1263 %undef i
1264 %undef j
1265
1266 %macro FMA_INSTR 3
1267     %macro %1 5-8 %1, %2, %3
1268         %if cpuflag(xop) || cpuflag(fma4)
1269             v%6 %1, %2, %3, %4
1270         %else
1271             %ifidn %1, %4
1272                 %7 %5, %2, %3
1273                 %8 %1, %4, %5
1274             %else
1275                 %7 %1, %2, %3
1276                 %8 %1, %4
1277             %endif
1278         %endif
1279     %endmacro
1280 %endmacro
1281
1282 FMA_INSTR  fmaddps,   mulps, addps
1283 FMA_INSTR  pmacsdd,  pmulld, paddd
1284 FMA_INSTR  pmacsww,  pmullw, paddw
1285 FMA_INSTR pmadcswd, pmaddwd, paddd
1286
1287 ; tzcnt is equivalent to "rep bsf" and is backwards-compatible with bsf.
1288 ; This lets us use tzcnt without bumping the yasm version requirement yet.
1289 %define tzcnt rep bsf