git.sesse.net Git - ffmpeg/blob - libavutil/x86/x86inc.asm

   1 ;*****************************************************************************
   2 ;* x86inc.asm: x264asm abstraction layer
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2005-2012 x264 project
   5 ;*
   6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
   7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
   8 ;*          Jason Garrett-Glaser <darkshikari@gmail.com>
   9 ;*          Henrik Gramner <hengar-6@student.ltu.se>
  10 ;*
  11 ;* Permission to use, copy, modify, and/or distribute this software for any
  12 ;* purpose with or without fee is hereby granted, provided that the above
  13 ;* copyright notice and this permission notice appear in all copies.
  14 ;*
  15 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  16 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  17 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  18 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  19 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  20 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  21 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  22 ;*****************************************************************************
  23
  24 ; This is a header file for the x264ASM assembly language, which uses
  25 ; NASM/YASM syntax combined with a large number of macros to provide easy
  26 ; abstraction between different calling conventions (x86_32, win64, linux64).
  27 ; It also has various other useful features to simplify writing the kind of
  28 ; DSP functions that are most often used in x264.
  29
  30 ; Unlike the rest of x264, this file is available under an ISC license, as it
  31 ; has significant usefulness outside of x264 and we want it to be available
  32 ; to the largest audience possible.  Of course, if you modify it for your own
  33 ; purposes to add a new feature, we strongly encourage contributing a patch
  34 ; as this feature might be useful for others as well.  Send patches or ideas
  35 ; to x264-devel@videolan.org .
  36
  37 %define program_name ff
  38
  39 %define WIN64  0
  40 %define UNIX64 0
  41 %if ARCH_X86_64
  42     %ifidn __OUTPUT_FORMAT__,win32
  43         %define WIN64  1
  44     %elifidn __OUTPUT_FORMAT__,win64
  45         %define WIN64  1
  46     %else
  47         %define UNIX64 1
  48     %endif
  49 %endif
  50
  51 %ifdef PREFIX
  52     %define mangle(x) _ %+ x
  53 %else
  54     %define mangle(x) x
  55 %endif
  56
  57 ; Name of the .rodata section.
  58 %macro SECTION_RODATA 0-1 16
  59     ; Kludge: Something on OS X fails to align .rodata even given an align
  60     ; attribute, so use a different read-only section. This has been fixed in
  61     ; yasm 0.8.0 and nasm 2.6.
  62     %ifdef __YASM_VERSION_ID__
  63         %if __YASM_VERSION_ID__ < 00080000h
  64             %define NEED_MACHO_RODATA_KLUDGE
  65         %endif
  66     %elifdef __NASM_VERSION_ID__
  67         %if __NASM_VERSION_ID__ < 02060000h
  68             %define NEED_MACHO_RODATA_KLUDGE
  69         %endif
  70     %endif
  71
  72     %ifidn __OUTPUT_FORMAT__,aout
  73         section .text
  74     %else
  75         %ifndef NEED_MACHO_RODATA_KLUDGE
  76             SECTION .rodata align=%1
  77         %else
  78             %ifidn __OUTPUT_FORMAT__,macho64
  79                 SECTION .text align=%1
  80             %elifidn __OUTPUT_FORMAT__,macho
  81                 SECTION .text align=%1
  82                 fakegot:
  83             %else
  84                 SECTION .rodata align=%1
  85             %endif
  86         %endif
  87     %endif
  88
  89     %undef NEED_MACHO_RODATA_KLUDGE
  90 %endmacro
  91
  92 ; aout does not support align=
  93 %macro SECTION_TEXT 0-1 16
  94     %ifidn __OUTPUT_FORMAT__,aout
  95         SECTION .text
  96     %else
  97         SECTION .text align=%1
  98     %endif
  99 %endmacro
 100
 101 %if WIN64
 102     %define PIC
 103 %elif ARCH_X86_64 == 0
 104 ; x86_32 doesn't require PIC.
 105 ; Some distros prefer shared objects to be PIC, but nothing breaks if
 106 ; the code contains a few textrels, so we'll skip that complexity.
 107     %undef PIC
 108 %endif
 109 %ifdef PIC
 110     default rel
 111 %endif
 112
 113 %macro CPUNOP 1
 114     %if HAVE_CPUNOP
 115         CPU %1
 116     %endif
 117 %endmacro
 118
 119 ; Always use long nops (reduces 0x90 spam in disassembly on x86_32)
 120 CPUNOP amdnop
 121
 122 ; Macros to eliminate most code duplication between x86_32 and x86_64:
 123 ; Currently this works only for leaf functions which load all their arguments
 124 ; into registers at the start, and make no other use of the stack. Luckily that
 125 ; covers most of x264's asm.
 126
 127 ; PROLOGUE:
 128 ; %1 = number of arguments. loads them from stack if needed.
 129 ; %2 = number of registers used. pushes callee-saved regs if needed.
 130 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
 131 ; %4 = list of names to define to registers
 132 ; PROLOGUE can also be invoked by adding the same options to cglobal
 133
 134 ; e.g.
 135 ; cglobal foo, 2,3,0, dst, src, tmp
 136 ; declares a function (foo), taking two args (dst and src) and one local variable (tmp)
 137
 138 ; TODO Some functions can use some args directly from the stack. If they're the
 139 ; last args then you can just not declare them, but if they're in the middle
 140 ; we need more flexible macro.
 141
 142 ; RET:
 143 ; Pops anything that was pushed by PROLOGUE, and returns.
 144
 145 ; REP_RET:
 146 ; Same, but if it doesn't pop anything it becomes a 2-byte ret, for athlons
 147 ; which are slow when a normal ret follows a branch.
 148
 149 ; registers:
 150 ; rN and rNq are the native-size register holding function argument N
 151 ; rNd, rNw, rNb are dword, word, and byte size
 152 ; rNh is the high 8 bits of the word size
 153 ; rNm is the original location of arg N (a register or on the stack), dword
 154 ; rNmp is native size
 155
 156 %macro DECLARE_REG 2-3
 157     %define r%1q %2
 158     %define r%1d %2d
 159     %define r%1w %2w
 160     %define r%1b %2b
 161     %define r%1h %2h
 162     %define %2q %2
 163     %if %0 == 2
 164         %define r%1m  %2d
 165         %define r%1mp %2
 166     %elif ARCH_X86_64 ; memory
 167         %define r%1m [rsp + stack_offset + %3]
 168         %define r%1mp qword r %+ %1 %+ m
 169     %else
 170         %define r%1m [esp + stack_offset + %3]
 171         %define r%1mp dword r %+ %1 %+ m
 172     %endif
 173     %define r%1  %2
 174 %endmacro
 175
 176 %macro DECLARE_REG_SIZE 3
 177     %define r%1q r%1
 178     %define e%1q r%1
 179     %define r%1d e%1
 180     %define e%1d e%1
 181     %define r%1w %1
 182     %define e%1w %1
 183     %define r%1h %3
 184     %define e%1h %3
 185     %define r%1b %2
 186     %define e%1b %2
 187 %if ARCH_X86_64 == 0
 188     %define r%1  e%1
 189 %endif
 190 %endmacro
 191
 192 DECLARE_REG_SIZE ax, al, ah
 193 DECLARE_REG_SIZE bx, bl, bh
 194 DECLARE_REG_SIZE cx, cl, ch
 195 DECLARE_REG_SIZE dx, dl, dh
 196 DECLARE_REG_SIZE si, sil, null
 197 DECLARE_REG_SIZE di, dil, null
 198 DECLARE_REG_SIZE bp, bpl, null
 199
 200 ; t# defines for when per-arch register allocation is more complex than just function arguments
 201
 202 %macro DECLARE_REG_TMP 1-*
 203     %assign %%i 0
 204     %rep %0
 205         CAT_XDEFINE t, %%i, r%1
 206         %assign %%i %%i+1
 207         %rotate 1
 208     %endrep
 209 %endmacro
 210
 211 %macro DECLARE_REG_TMP_SIZE 0-*
 212     %rep %0
 213         %define t%1q t%1 %+ q
 214         %define t%1d t%1 %+ d
 215         %define t%1w t%1 %+ w
 216         %define t%1h t%1 %+ h
 217         %define t%1b t%1 %+ b
 218         %rotate 1
 219     %endrep
 220 %endmacro
 221
 222 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14
 223
 224 %if ARCH_X86_64
 225     %define gprsize 8
 226 %else
 227     %define gprsize 4
 228 %endif
 229
 230 %macro PUSH 1
 231     push %1
 232     %assign stack_offset stack_offset+gprsize
 233 %endmacro
 234
 235 %macro POP 1
 236     pop %1
 237     %assign stack_offset stack_offset-gprsize
 238 %endmacro
 239
 240 %macro PUSH_IF_USED 1-*
 241     %rep %0
 242         %if %1 < regs_used
 243             PUSH r%1
 244         %endif
 245         %rotate 1
 246     %endrep
 247 %endmacro
 248
 249 %macro POP_IF_USED 1-*
 250     %rep %0
 251         %if %1 < regs_used
 252             pop r%1
 253         %endif
 254         %rotate 1
 255     %endrep
 256 %endmacro
 257
 258 %macro LOAD_IF_USED 1-*
 259     %rep %0
 260         %if %1 < num_args
 261             mov r%1, r %+ %1 %+ mp
 262         %endif
 263         %rotate 1
 264     %endrep
 265 %endmacro
 266
 267 %macro SUB 2
 268     sub %1, %2
 269     %ifidn %1, rsp
 270         %assign stack_offset stack_offset+(%2)
 271     %endif
 272 %endmacro
 273
 274 %macro ADD 2
 275     add %1, %2
 276     %ifidn %1, rsp
 277         %assign stack_offset stack_offset-(%2)
 278     %endif
 279 %endmacro
 280
 281 %macro movifnidn 2
 282     %ifnidn %1, %2
 283         mov %1, %2
 284     %endif
 285 %endmacro
 286
 287 %macro movsxdifnidn 2
 288     %ifnidn %1, %2
 289         movsxd %1, %2
 290     %endif
 291 %endmacro
 292
 293 %macro ASSERT 1
 294     %if (%1) == 0
 295         %error assert failed
 296     %endif
 297 %endmacro
 298
 299 %macro DEFINE_ARGS 0-*
 300     %ifdef n_arg_names
 301         %assign %%i 0
 302         %rep n_arg_names
 303             CAT_UNDEF arg_name %+ %%i, q
 304             CAT_UNDEF arg_name %+ %%i, d
 305             CAT_UNDEF arg_name %+ %%i, w
 306             CAT_UNDEF arg_name %+ %%i, h
 307             CAT_UNDEF arg_name %+ %%i, b
 308             CAT_UNDEF arg_name %+ %%i, m
 309             CAT_UNDEF arg_name %+ %%i, mp
 310             CAT_UNDEF arg_name, %%i
 311             %assign %%i %%i+1
 312         %endrep
 313     %endif
 314
 315     %xdefine %%stack_offset stack_offset
 316     %undef stack_offset ; so that the current value of stack_offset doesn't get baked in by xdefine
 317     %assign %%i 0
 318     %rep %0
 319         %xdefine %1q r %+ %%i %+ q
 320         %xdefine %1d r %+ %%i %+ d
 321         %xdefine %1w r %+ %%i %+ w
 322         %xdefine %1h r %+ %%i %+ h
 323         %xdefine %1b r %+ %%i %+ b
 324         %xdefine %1m r %+ %%i %+ m
 325         %xdefine %1mp r %+ %%i %+ mp
 326         CAT_XDEFINE arg_name, %%i, %1
 327         %assign %%i %%i+1
 328         %rotate 1
 329     %endrep
 330     %xdefine stack_offset %%stack_offset
 331     %assign n_arg_names %0
 332 %endmacro
 333
 334 %if WIN64 ; Windows x64 ;=================================================
 335
 336 DECLARE_REG 0,  rcx
 337 DECLARE_REG 1,  rdx
 338 DECLARE_REG 2,  R8
 339 DECLARE_REG 3,  R9
 340 DECLARE_REG 4,  R10, 40
 341 DECLARE_REG 5,  R11, 48
 342 DECLARE_REG 6,  rax, 56
 343 DECLARE_REG 7,  rdi, 64
 344 DECLARE_REG 8,  rsi, 72
 345 DECLARE_REG 9,  rbx, 80
 346 DECLARE_REG 10, rbp, 88
 347 DECLARE_REG 11, R12, 96
 348 DECLARE_REG 12, R13, 104
 349 DECLARE_REG 13, R14, 112
 350 DECLARE_REG 14, R15, 120
 351
 352 %macro PROLOGUE 2-4+ 0 ; #args, #regs, #xmm_regs, arg_names...
 353     %assign num_args %1
 354     %assign regs_used %2
 355     ASSERT regs_used >= num_args
 356     ASSERT regs_used <= 15
 357     PUSH_IF_USED 7, 8, 9, 10, 11, 12, 13, 14
 358     %if mmsize == 8
 359         %assign xmm_regs_used 0
 360     %else
 361         WIN64_SPILL_XMM %3
 362     %endif
 363     LOAD_IF_USED 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14
 364     DEFINE_ARGS %4
 365 %endmacro
 366
 367 %macro WIN64_SPILL_XMM 1
 368     %assign xmm_regs_used %1
 369     ASSERT xmm_regs_used <= 16
 370     %if xmm_regs_used > 6
 371         SUB rsp, (xmm_regs_used-6)*16+16
 372         %assign %%i xmm_regs_used
 373         %rep (xmm_regs_used-6)
 374             %assign %%i %%i-1
 375             movdqa [rsp + (%%i-6)*16+(~stack_offset&8)], xmm %+ %%i
 376         %endrep
 377     %endif
 378 %endmacro
 379
 380 %macro WIN64_RESTORE_XMM_INTERNAL 1
 381     %if xmm_regs_used > 6
 382         %assign %%i xmm_regs_used
 383         %rep (xmm_regs_used-6)
 384             %assign %%i %%i-1
 385             movdqa xmm %+ %%i, [%1 + (%%i-6)*16+(~stack_offset&8)]
 386         %endrep
 387         add %1, (xmm_regs_used-6)*16+16
 388     %endif
 389 %endmacro
 390
 391 %macro WIN64_RESTORE_XMM 1
 392     WIN64_RESTORE_XMM_INTERNAL %1
 393     %assign stack_offset stack_offset-(xmm_regs_used-6)*16+16
 394     %assign xmm_regs_used 0
 395 %endmacro
 396
 397 %define has_epilogue regs_used > 7 || xmm_regs_used > 6 || mmsize == 32
 398
 399 %macro RET 0
 400     WIN64_RESTORE_XMM_INTERNAL rsp
 401     POP_IF_USED 14, 13, 12, 11, 10, 9, 8, 7
 402 %if mmsize == 32
 403     vzeroupper
 404 %endif
 405     ret
 406 %endmacro
 407
 408 %elif ARCH_X86_64 ; *nix x64 ;=============================================
 409
 410 DECLARE_REG 0,  rdi
 411 DECLARE_REG 1,  rsi
 412 DECLARE_REG 2,  rdx
 413 DECLARE_REG 3,  rcx
 414 DECLARE_REG 4,  R8
 415 DECLARE_REG 5,  R9
 416 DECLARE_REG 6,  rax, 8
 417 DECLARE_REG 7,  R10, 16
 418 DECLARE_REG 8,  R11, 24
 419 DECLARE_REG 9,  rbx, 32
 420 DECLARE_REG 10, rbp, 40
 421 DECLARE_REG 11, R12, 48
 422 DECLARE_REG 12, R13, 56
 423 DECLARE_REG 13, R14, 64
 424 DECLARE_REG 14, R15, 72
 425
 426 %macro PROLOGUE 2-4+ ; #args, #regs, #xmm_regs, arg_names...
 427     %assign num_args %1
 428     %assign regs_used %2
 429     ASSERT regs_used >= num_args
 430     ASSERT regs_used <= 15
 431     PUSH_IF_USED 9, 10, 11, 12, 13, 14
 432     LOAD_IF_USED 6, 7, 8, 9, 10, 11, 12, 13, 14
 433     DEFINE_ARGS %4
 434 %endmacro
 435
 436 %define has_epilogue regs_used > 9 || mmsize == 32
 437
 438 %macro RET 0
 439     POP_IF_USED 14, 13, 12, 11, 10, 9
 440 %if mmsize == 32
 441     vzeroupper
 442 %endif
 443     ret
 444 %endmacro
 445
 446 %else ; X86_32 ;==============================================================
 447
 448 DECLARE_REG 0, eax, 4
 449 DECLARE_REG 1, ecx, 8
 450 DECLARE_REG 2, edx, 12
 451 DECLARE_REG 3, ebx, 16
 452 DECLARE_REG 4, esi, 20
 453 DECLARE_REG 5, edi, 24
 454 DECLARE_REG 6, ebp, 28
 455 %define rsp esp
 456
 457 %macro DECLARE_ARG 1-*
 458     %rep %0
 459         %define r%1m [esp + stack_offset + 4*%1 + 4]
 460         %define r%1mp dword r%1m
 461         %rotate 1
 462     %endrep
 463 %endmacro
 464
 465 DECLARE_ARG 7, 8, 9, 10, 11, 12, 13, 14
 466
 467 %macro PROLOGUE 2-4+ ; #args, #regs, #xmm_regs, arg_names...
 468     %assign num_args %1
 469     %assign regs_used %2
 470     %if num_args > 7
 471         %assign num_args 7
 472     %endif
 473     %if regs_used > 7
 474         %assign regs_used 7
 475     %endif
 476     ASSERT regs_used >= num_args
 477     PUSH_IF_USED 3, 4, 5, 6
 478     LOAD_IF_USED 0, 1, 2, 3, 4, 5, 6
 479     DEFINE_ARGS %4
 480 %endmacro
 481
 482 %define has_epilogue regs_used > 3 || mmsize == 32
 483
 484 %macro RET 0
 485     POP_IF_USED 6, 5, 4, 3
 486 %if mmsize == 32
 487     vzeroupper
 488 %endif
 489     ret
 490 %endmacro
 491
 492 %endif ;======================================================================
 493
 494 %if WIN64 == 0
 495 %macro WIN64_SPILL_XMM 1
 496 %endmacro
 497 %macro WIN64_RESTORE_XMM 1
 498 %endmacro
 499 %endif
 500
 501 %macro REP_RET 0
 502     %if has_epilogue
 503         RET
 504     %else
 505         rep ret
 506     %endif
 507 %endmacro
 508
 509 %macro TAIL_CALL 2 ; callee, is_nonadjacent
 510     %if has_epilogue
 511         call %1
 512         RET
 513     %elif %2
 514         jmp %1
 515     %endif
 516 %endmacro
 517
 518 ;=============================================================================
 519 ; arch-independent part
 520 ;=============================================================================
 521
 522 %assign function_align 16
 523
 524 ; Begin a function.
 525 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
 526 ; subsequent uses of the function name automatically refer to the mangled version.
 527 ; Appends cpuflags to the function name if cpuflags has been specified.
 528 %macro cglobal 1-2+ "" ; name, [PROLOGUE args]
 529     cglobal_internal %1 %+ SUFFIX, %2
 530 %endmacro
 531 %macro cglobal_internal 1-2+
 532     %ifndef cglobaled_%1
 533         %xdefine %1 mangle(program_name %+ _ %+ %1)
 534         %xdefine %1.skip_prologue %1 %+ .skip_prologue
 535         CAT_XDEFINE cglobaled_, %1, 1
 536     %endif
 537     %xdefine current_function %1
 538     %ifidn __OUTPUT_FORMAT__,elf
 539         global %1:function hidden
 540     %else
 541         global %1
 542     %endif
 543     align function_align
 544     %1:
 545     RESET_MM_PERMUTATION ; not really needed, but makes disassembly somewhat nicer
 546     %assign stack_offset 0
 547     %ifnidn %2, ""
 548         PROLOGUE %2
 549     %endif
 550 %endmacro
 551
 552 %macro cextern 1
 553     %xdefine %1 mangle(program_name %+ _ %+ %1)
 554     CAT_XDEFINE cglobaled_, %1, 1
 555     extern %1
 556 %endmacro
 557
 558 ; like cextern, but without the prefix
 559 %macro cextern_naked 1
 560     %xdefine %1 mangle(%1)
 561     CAT_XDEFINE cglobaled_, %1, 1
 562     extern %1
 563 %endmacro
 564
 565 %macro const 2+
 566     %xdefine %1 mangle(program_name %+ _ %+ %1)
 567     global %1
 568     %1: %2
 569 %endmacro
 570
 571 ; This is needed for ELF, otherwise the GNU linker assumes the stack is
 572 ; executable by default.
 573 %ifidn __OUTPUT_FORMAT__,elf
 574 SECTION .note.GNU-stack noalloc noexec nowrite progbits
 575 %endif
 576
 577 ; cpuflags
 578
 579 %assign cpuflags_mmx      (1<<0)
 580 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
 581 %assign cpuflags_3dnow    (1<<2) | cpuflags_mmx
 582 %assign cpuflags_3dnowext (1<<3) | cpuflags_3dnow
 583 %assign cpuflags_sse      (1<<4) | cpuflags_mmx2
 584 %assign cpuflags_sse2     (1<<5) | cpuflags_sse
 585 %assign cpuflags_sse2slow (1<<6) | cpuflags_sse2
 586 %assign cpuflags_sse3     (1<<7) | cpuflags_sse2
 587 %assign cpuflags_ssse3    (1<<8) | cpuflags_sse3
 588 %assign cpuflags_sse4     (1<<9) | cpuflags_ssse3
 589 %assign cpuflags_sse42    (1<<10)| cpuflags_sse4
 590 %assign cpuflags_avx      (1<<11)| cpuflags_sse42
 591 %assign cpuflags_xop      (1<<12)| cpuflags_avx
 592 %assign cpuflags_fma4     (1<<13)| cpuflags_avx
 593 %assign cpuflags_avx2     (1<<14)| cpuflags_avx
 594 %assign cpuflags_fma3     (1<<15)| cpuflags_avx
 595
 596 %assign cpuflags_cache32  (1<<16)
 597 %assign cpuflags_cache64  (1<<17)
 598 %assign cpuflags_slowctz  (1<<18)
 599 %assign cpuflags_lzcnt    (1<<19)
 600 %assign cpuflags_misalign (1<<20)
 601 %assign cpuflags_aligned  (1<<21) ; not a cpu feature, but a function variant
 602 %assign cpuflags_atom     (1<<22)
 603 %assign cpuflags_bmi1     (1<<23)
 604 %assign cpuflags_bmi2     (1<<24)|cpuflags_bmi1
 605 %assign cpuflags_tbm      (1<<25)|cpuflags_bmi1
 606
 607 %define    cpuflag(x) ((cpuflags & (cpuflags_ %+ x)) == (cpuflags_ %+ x))
 608 %define notcpuflag(x) ((cpuflags & (cpuflags_ %+ x)) != (cpuflags_ %+ x))
 609
 610 ; Takes up to 2 cpuflags from the above list.
 611 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
 612 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
 613 %macro INIT_CPUFLAGS 0-2
 614     CPUNOP amdnop
 615     %if %0 >= 1
 616         %xdefine cpuname %1
 617         %assign cpuflags cpuflags_%1
 618         %if %0 >= 2
 619             %xdefine cpuname %1_%2
 620             %assign cpuflags cpuflags | cpuflags_%2
 621         %endif
 622         %xdefine SUFFIX _ %+ cpuname
 623         %if cpuflag(avx)
 624             %assign avx_enabled 1
 625         %endif
 626         %if mmsize == 16 && notcpuflag(sse2)
 627             %define mova movaps
 628             %define movu movups
 629             %define movnta movntps
 630         %endif
 631         %if cpuflag(aligned)
 632             %define movu mova
 633         %elifidn %1, sse3
 634             %define movu lddqu
 635         %endif
 636         %if notcpuflag(mmx2)
 637             CPUNOP basicnop
 638         %endif
 639     %else
 640         %xdefine SUFFIX
 641         %undef cpuname
 642         %undef cpuflags
 643     %endif
 644 %endmacro
 645
 646 ; merge mmx and sse*
 647
 648 %macro CAT_XDEFINE 3
 649     %xdefine %1%2 %3
 650 %endmacro
 651
 652 %macro CAT_UNDEF 2
 653     %undef %1%2
 654 %endmacro
 655
 656 %macro INIT_MMX 0-1+
 657     %assign avx_enabled 0
 658     %define RESET_MM_PERMUTATION INIT_MMX %1
 659     %define mmsize 8
 660     %define num_mmregs 8
 661     %define mova movq
 662     %define movu movq
 663     %define movh movd
 664     %define movnta movntq
 665     %assign %%i 0
 666     %rep 8
 667     CAT_XDEFINE m, %%i, mm %+ %%i
 668     CAT_XDEFINE nmm, %%i, %%i
 669     %assign %%i %%i+1
 670     %endrep
 671     %rep 8
 672     CAT_UNDEF m, %%i
 673     CAT_UNDEF nmm, %%i
 674     %assign %%i %%i+1
 675     %endrep
 676     INIT_CPUFLAGS %1
 677 %endmacro
 678
 679 %macro INIT_XMM 0-1+
 680     %assign avx_enabled 0
 681     %define RESET_MM_PERMUTATION INIT_XMM %1
 682     %define mmsize 16
 683     %define num_mmregs 8
 684     %if ARCH_X86_64
 685     %define num_mmregs 16
 686     %endif
 687     %define mova movdqa
 688     %define movu movdqu
 689     %define movh movq
 690     %define movnta movntdq
 691     %assign %%i 0
 692     %rep num_mmregs
 693     CAT_XDEFINE m, %%i, xmm %+ %%i
 694     CAT_XDEFINE nxmm, %%i, %%i
 695     %assign %%i %%i+1
 696     %endrep
 697     INIT_CPUFLAGS %1
 698 %endmacro
 699
 700 ; FIXME: INIT_AVX can be replaced by INIT_XMM avx
 701 %macro INIT_AVX 0
 702     INIT_XMM
 703     %assign avx_enabled 1
 704     %define PALIGNR PALIGNR_SSSE3
 705     %define RESET_MM_PERMUTATION INIT_AVX
 706 %endmacro
 707
 708 %macro INIT_YMM 0-1+
 709     %assign avx_enabled 1
 710     %define RESET_MM_PERMUTATION INIT_YMM %1
 711     %define mmsize 32
 712     %define num_mmregs 8
 713     %if ARCH_X86_64
 714     %define num_mmregs 16
 715     %endif
 716     %define mova vmovaps
 717     %define movu vmovups
 718     %undef movh
 719     %define movnta vmovntps
 720     %assign %%i 0
 721     %rep num_mmregs
 722     CAT_XDEFINE m, %%i, ymm %+ %%i
 723     CAT_XDEFINE nymm, %%i, %%i
 724     %assign %%i %%i+1
 725     %endrep
 726     INIT_CPUFLAGS %1
 727 %endmacro
 728
 729 INIT_XMM
 730
 731 ; I often want to use macros that permute their arguments. e.g. there's no
 732 ; efficient way to implement butterfly or transpose or dct without swapping some
 733 ; arguments.
 734 ;
 735 ; I would like to not have to manually keep track of the permutations:
 736 ; If I insert a permutation in the middle of a function, it should automatically
 737 ; change everything that follows. For more complex macros I may also have multiple
 738 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
 739 ;
 740 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
 741 ; permutes its arguments. It's equivalent to exchanging the contents of the
 742 ; registers, except that this way you exchange the register names instead, so it
 743 ; doesn't cost any cycles.
 744
 745 %macro PERMUTE 2-* ; takes a list of pairs to swap
 746 %rep %0/2
 747     %xdefine tmp%2 m%2
 748     %xdefine ntmp%2 nm%2
 749     %rotate 2
 750 %endrep
 751 %rep %0/2
 752     %xdefine m%1 tmp%2
 753     %xdefine nm%1 ntmp%2
 754     %undef tmp%2
 755     %undef ntmp%2
 756     %rotate 2
 757 %endrep
 758 %endmacro
 759
 760 %macro SWAP 2-* ; swaps a single chain (sometimes more concise than pairs)
 761 %rep %0-1
 762 %ifdef m%1
 763     %xdefine tmp m%1
 764     %xdefine m%1 m%2
 765     %xdefine m%2 tmp
 766     CAT_XDEFINE n, m%1, %1
 767     CAT_XDEFINE n, m%2, %2
 768 %else
 769     ; If we were called as "SWAP m0,m1" rather than "SWAP 0,1" infer the original numbers here.
 770     ; Be careful using this mode in nested macros though, as in some cases there may be
 771     ; other copies of m# that have already been dereferenced and don't get updated correctly.
 772     %xdefine %%n1 n %+ %1
 773     %xdefine %%n2 n %+ %2
 774     %xdefine tmp m %+ %%n1
 775     CAT_XDEFINE m, %%n1, m %+ %%n2
 776     CAT_XDEFINE m, %%n2, tmp
 777     CAT_XDEFINE n, m %+ %%n1, %%n1
 778     CAT_XDEFINE n, m %+ %%n2, %%n2
 779 %endif
 780     %undef tmp
 781     %rotate 1
 782 %endrep
 783 %endmacro
 784
 785 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
 786 ; calls to that function will automatically load the permutation, so values can
 787 ; be returned in mmregs.
 788 %macro SAVE_MM_PERMUTATION 0-1
 789     %if %0
 790         %xdefine %%f %1_m
 791     %else
 792         %xdefine %%f current_function %+ _m
 793     %endif
 794     %assign %%i 0
 795     %rep num_mmregs
 796         CAT_XDEFINE %%f, %%i, m %+ %%i
 797     %assign %%i %%i+1
 798     %endrep
 799 %endmacro
 800
 801 %macro LOAD_MM_PERMUTATION 1 ; name to load from
 802     %ifdef %1_m0
 803         %assign %%i 0
 804         %rep num_mmregs
 805             CAT_XDEFINE m, %%i, %1_m %+ %%i
 806             CAT_XDEFINE n, m %+ %%i, %%i
 807         %assign %%i %%i+1
 808         %endrep
 809     %endif
 810 %endmacro
 811
 812 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
 813 %macro call 1
 814     call_internal %1 %+ SUFFIX, %1
 815 %endmacro
 816 %macro call_internal 2
 817     %xdefine %%i %2
 818     %ifndef cglobaled_%2
 819         %ifdef cglobaled_%1
 820             %xdefine %%i %1
 821         %endif
 822     %endif
 823     call %%i
 824     LOAD_MM_PERMUTATION %%i
 825 %endmacro
 826
 827 ; Substitutions that reduce instruction size but are functionally equivalent
 828 %macro add 2
 829     %ifnum %2
 830         %if %2==128
 831             sub %1, -128
 832         %else
 833             add %1, %2
 834         %endif
 835     %else
 836         add %1, %2
 837     %endif
 838 %endmacro
 839
 840 %macro sub 2
 841     %ifnum %2
 842         %if %2==128
 843             add %1, -128
 844         %else
 845             sub %1, %2
 846         %endif
 847     %else
 848         sub %1, %2
 849     %endif
 850 %endmacro
 851
 852 ;=============================================================================
 853 ; AVX abstraction layer
 854 ;=============================================================================
 855
 856 %assign i 0
 857 %rep 16
 858     %if i < 8
 859         CAT_XDEFINE sizeofmm, i, 8
 860     %endif
 861     CAT_XDEFINE sizeofxmm, i, 16
 862     CAT_XDEFINE sizeofymm, i, 32
 863 %assign i i+1
 864 %endrep
 865 %undef i
 866
 867 %macro CHECK_AVX_INSTR_EMU 3-*
 868     %xdefine %%opcode %1
 869     %xdefine %%dst %2
 870     %rep %0-2
 871         %ifidn %%dst, %3
 872             %error non-avx emulation of ``%%opcode'' is not supported
 873         %endif
 874         %rotate 1
 875     %endrep
 876 %endmacro
 877
 878 ;%1 == instruction
 879 ;%2 == 1 if float, 0 if int
 880 ;%3 == 1 if 4-operand (xmm, xmm, xmm, imm), 0 if 2- or 3-operand (xmm, xmm, xmm)
 881 ;%4 == number of operands given
 882 ;%5+: operands
 883 %macro RUN_AVX_INSTR 6-7+
 884     %ifid %6
 885         %define %%sizeofreg sizeof%6
 886     %elifid %5
 887         %define %%sizeofreg sizeof%5
 888     %else
 889         %define %%sizeofreg mmsize
 890     %endif
 891     %if %%sizeofreg==32
 892         %if %4>=3
 893             v%1 %5, %6, %7
 894         %else
 895             v%1 %5, %6
 896         %endif
 897     %else
 898         %if %%sizeofreg==8
 899             %define %%regmov movq
 900         %elif %2
 901             %define %%regmov movaps
 902         %else
 903             %define %%regmov movdqa
 904         %endif
 905
 906         %if %4>=3+%3
 907             %ifnidn %5, %6
 908                 %if avx_enabled && %%sizeofreg==16
 909                     v%1 %5, %6, %7
 910                 %else
 911                     CHECK_AVX_INSTR_EMU {%1 %5, %6, %7}, %5, %7
 912                     %%regmov %5, %6
 913                     %1 %5, %7
 914                 %endif
 915             %else
 916                 %1 %5, %7
 917             %endif
 918         %elif %4>=3
 919             %1 %5, %6, %7
 920         %else
 921             %1 %5, %6
 922         %endif
 923     %endif
 924 %endmacro
 925
 926 ; 3arg AVX ops with a memory arg can only have it in src2,
 927 ; whereas SSE emulation of 3arg prefers to have it in src1 (i.e. the mov).
 928 ; So, if the op is symmetric and the wrong one is memory, swap them.
 929 %macro RUN_AVX_INSTR1 8
 930     %assign %%swap 0
 931     %if avx_enabled
 932         %ifnid %6
 933             %assign %%swap 1
 934         %endif
 935     %elifnidn %5, %6
 936         %ifnid %7
 937             %assign %%swap 1
 938         %endif
 939     %endif
 940     %if %%swap && %3 == 0 && %8 == 1
 941         RUN_AVX_INSTR %1, %2, %3, %4, %5, %7, %6
 942     %else
 943         RUN_AVX_INSTR %1, %2, %3, %4, %5, %6, %7
 944     %endif
 945 %endmacro
 946
 947 ;%1 == instruction
 948 ;%2 == 1 if float, 0 if int
 949 ;%3 == 1 if 4-operand (xmm, xmm, xmm, imm), 0 if 2- or 3-operand (xmm, xmm, xmm)
 950 ;%4 == 1 if symmetric (i.e. doesn't matter which src arg is which), 0 if not
 951 %macro AVX_INSTR 4
 952     %macro %1 2-9 fnord, fnord, fnord, %1, %2, %3, %4
 953         %ifidn %3, fnord
 954             RUN_AVX_INSTR %6, %7, %8, 2, %1, %2
 955         %elifidn %4, fnord
 956             RUN_AVX_INSTR1 %6, %7, %8, 3, %1, %2, %3, %9
 957         %elifidn %5, fnord
 958             RUN_AVX_INSTR %6, %7, %8, 4, %1, %2, %3, %4
 959         %else
 960             RUN_AVX_INSTR %6, %7, %8, 5, %1, %2, %3, %4, %5
 961         %endif
 962     %endmacro
 963 %endmacro
 964
 965 AVX_INSTR addpd, 1, 0, 1
 966 AVX_INSTR addps, 1, 0, 1
 967 AVX_INSTR addsd, 1, 0, 1
 968 AVX_INSTR addss, 1, 0, 1
 969 AVX_INSTR addsubpd, 1, 0, 0
 970 AVX_INSTR addsubps, 1, 0, 0
 971 AVX_INSTR andpd, 1, 0, 1
 972 AVX_INSTR andps, 1, 0, 1
 973 AVX_INSTR andnpd, 1, 0, 0
 974 AVX_INSTR andnps, 1, 0, 0
 975 AVX_INSTR blendpd, 1, 0, 0
 976 AVX_INSTR blendps, 1, 0, 0
 977 AVX_INSTR blendvpd, 1, 0, 0
 978 AVX_INSTR blendvps, 1, 0, 0
 979 AVX_INSTR cmppd, 1, 0, 0
 980 AVX_INSTR cmpps, 1, 0, 0
 981 AVX_INSTR cmpsd, 1, 0, 0
 982 AVX_INSTR cmpss, 1, 0, 0
 983 AVX_INSTR cvtdq2ps, 1, 0, 0
 984 AVX_INSTR cvtps2dq, 1, 0, 0
 985 AVX_INSTR divpd, 1, 0, 0
 986 AVX_INSTR divps, 1, 0, 0
 987 AVX_INSTR divsd, 1, 0, 0
 988 AVX_INSTR divss, 1, 0, 0
 989 AVX_INSTR dppd, 1, 1, 0
 990 AVX_INSTR dpps, 1, 1, 0
 991 AVX_INSTR haddpd, 1, 0, 0
 992 AVX_INSTR haddps, 1, 0, 0
 993 AVX_INSTR hsubpd, 1, 0, 0
 994 AVX_INSTR hsubps, 1, 0, 0
 995 AVX_INSTR maxpd, 1, 0, 1
 996 AVX_INSTR maxps, 1, 0, 1
 997 AVX_INSTR maxsd, 1, 0, 1
 998 AVX_INSTR maxss, 1, 0, 1
 999 AVX_INSTR minpd, 1, 0, 1
1000 AVX_INSTR minps, 1, 0, 1
1001 AVX_INSTR minsd, 1, 0, 1
1002 AVX_INSTR minss, 1, 0, 1
1003 AVX_INSTR movhlps, 1, 0, 0
1004 AVX_INSTR movlhps, 1, 0, 0
1005 AVX_INSTR movsd, 1, 0, 0
1006 AVX_INSTR movss, 1, 0, 0
1007 AVX_INSTR mpsadbw, 0, 1, 0
1008 AVX_INSTR mulpd, 1, 0, 1
1009 AVX_INSTR mulps, 1, 0, 1
1010 AVX_INSTR mulsd, 1, 0, 1
1011 AVX_INSTR mulss, 1, 0, 1
1012 AVX_INSTR orpd, 1, 0, 1
1013 AVX_INSTR orps, 1, 0, 1
1014 AVX_INSTR pabsb, 0, 0, 0
1015 AVX_INSTR pabsw, 0, 0, 0
1016 AVX_INSTR pabsd, 0, 0, 0
1017 AVX_INSTR packsswb, 0, 0, 0
1018 AVX_INSTR packssdw, 0, 0, 0
1019 AVX_INSTR packuswb, 0, 0, 0
1020 AVX_INSTR packusdw, 0, 0, 0
1021 AVX_INSTR paddb, 0, 0, 1
1022 AVX_INSTR paddw, 0, 0, 1
1023 AVX_INSTR paddd, 0, 0, 1
1024 AVX_INSTR paddq, 0, 0, 1
1025 AVX_INSTR paddsb, 0, 0, 1
1026 AVX_INSTR paddsw, 0, 0, 1
1027 AVX_INSTR paddusb, 0, 0, 1
1028 AVX_INSTR paddusw, 0, 0, 1
1029 AVX_INSTR palignr, 0, 1, 0
1030 AVX_INSTR pand, 0, 0, 1
1031 AVX_INSTR pandn, 0, 0, 0
1032 AVX_INSTR pavgb, 0, 0, 1
1033 AVX_INSTR pavgw, 0, 0, 1
1034 AVX_INSTR pblendvb, 0, 0, 0
1035 AVX_INSTR pblendw, 0, 1, 0
1036 AVX_INSTR pcmpestri, 0, 0, 0
1037 AVX_INSTR pcmpestrm, 0, 0, 0
1038 AVX_INSTR pcmpistri, 0, 0, 0
1039 AVX_INSTR pcmpistrm, 0, 0, 0
1040 AVX_INSTR pcmpeqb, 0, 0, 1
1041 AVX_INSTR pcmpeqw, 0, 0, 1
1042 AVX_INSTR pcmpeqd, 0, 0, 1
1043 AVX_INSTR pcmpeqq, 0, 0, 1
1044 AVX_INSTR pcmpgtb, 0, 0, 0
1045 AVX_INSTR pcmpgtw, 0, 0, 0
1046 AVX_INSTR pcmpgtd, 0, 0, 0
1047 AVX_INSTR pcmpgtq, 0, 0, 0
1048 AVX_INSTR phaddw, 0, 0, 0
1049 AVX_INSTR phaddd, 0, 0, 0
1050 AVX_INSTR phaddsw, 0, 0, 0
1051 AVX_INSTR phsubw, 0, 0, 0
1052 AVX_INSTR phsubd, 0, 0, 0
1053 AVX_INSTR phsubsw, 0, 0, 0
1054 AVX_INSTR pmaddwd, 0, 0, 1
1055 AVX_INSTR pmaddubsw, 0, 0, 0
1056 AVX_INSTR pmaxsb, 0, 0, 1
1057 AVX_INSTR pmaxsw, 0, 0, 1
1058 AVX_INSTR pmaxsd, 0, 0, 1
1059 AVX_INSTR pmaxub, 0, 0, 1
1060 AVX_INSTR pmaxuw, 0, 0, 1
1061 AVX_INSTR pmaxud, 0, 0, 1
1062 AVX_INSTR pminsb, 0, 0, 1
1063 AVX_INSTR pminsw, 0, 0, 1
1064 AVX_INSTR pminsd, 0, 0, 1
1065 AVX_INSTR pminub, 0, 0, 1
1066 AVX_INSTR pminuw, 0, 0, 1
1067 AVX_INSTR pminud, 0, 0, 1
1068 AVX_INSTR pmovmskb, 0, 0, 0
1069 AVX_INSTR pmulhuw, 0, 0, 1
1070 AVX_INSTR pmulhrsw, 0, 0, 1
1071 AVX_INSTR pmulhw, 0, 0, 1
1072 AVX_INSTR pmullw, 0, 0, 1
1073 AVX_INSTR pmulld, 0, 0, 1
1074 AVX_INSTR pmuludq, 0, 0, 1
1075 AVX_INSTR pmuldq, 0, 0, 1
1076 AVX_INSTR por, 0, 0, 1
1077 AVX_INSTR psadbw, 0, 0, 1
1078 AVX_INSTR pshufb, 0, 0, 0
1079 AVX_INSTR pshufd, 0, 1, 0
1080 AVX_INSTR pshufhw, 0, 1, 0
1081 AVX_INSTR pshuflw, 0, 1, 0
1082 AVX_INSTR psignb, 0, 0, 0
1083 AVX_INSTR psignw, 0, 0, 0
1084 AVX_INSTR psignd, 0, 0, 0
1085 AVX_INSTR psllw, 0, 0, 0
1086 AVX_INSTR pslld, 0, 0, 0
1087 AVX_INSTR psllq, 0, 0, 0
1088 AVX_INSTR pslldq, 0, 0, 0
1089 AVX_INSTR psraw, 0, 0, 0
1090 AVX_INSTR psrad, 0, 0, 0
1091 AVX_INSTR psrlw, 0, 0, 0
1092 AVX_INSTR psrld, 0, 0, 0
1093 AVX_INSTR psrlq, 0, 0, 0
1094 AVX_INSTR psrldq, 0, 0, 0
1095 AVX_INSTR psubb, 0, 0, 0
1096 AVX_INSTR psubw, 0, 0, 0
1097 AVX_INSTR psubd, 0, 0, 0
1098 AVX_INSTR psubq, 0, 0, 0
1099 AVX_INSTR psubsb, 0, 0, 0
1100 AVX_INSTR psubsw, 0, 0, 0
1101 AVX_INSTR psubusb, 0, 0, 0
1102 AVX_INSTR psubusw, 0, 0, 0
1103 AVX_INSTR ptest, 0, 0, 0
1104 AVX_INSTR punpckhbw, 0, 0, 0
1105 AVX_INSTR punpckhwd, 0, 0, 0
1106 AVX_INSTR punpckhdq, 0, 0, 0
1107 AVX_INSTR punpckhqdq, 0, 0, 0
1108 AVX_INSTR punpcklbw, 0, 0, 0
1109 AVX_INSTR punpcklwd, 0, 0, 0
1110 AVX_INSTR punpckldq, 0, 0, 0
1111 AVX_INSTR punpcklqdq, 0, 0, 0
1112 AVX_INSTR pxor, 0, 0, 1
1113 AVX_INSTR shufps, 1, 1, 0
1114 AVX_INSTR subpd, 1, 0, 0
1115 AVX_INSTR subps, 1, 0, 0
1116 AVX_INSTR subsd, 1, 0, 0
1117 AVX_INSTR subss, 1, 0, 0
1118 AVX_INSTR unpckhpd, 1, 0, 0
1119 AVX_INSTR unpckhps, 1, 0, 0
1120 AVX_INSTR unpcklpd, 1, 0, 0
1121 AVX_INSTR unpcklps, 1, 0, 0
1122 AVX_INSTR xorpd, 1, 0, 1
1123 AVX_INSTR xorps, 1, 0, 1
1124
1125 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
1126 AVX_INSTR pfadd, 1, 0, 1
1127 AVX_INSTR pfsub, 1, 0, 0
1128 AVX_INSTR pfmul, 1, 0, 1
1129
1130 ; base-4 constants for shuffles
1131 %assign i 0
1132 %rep 256
1133     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
1134     %if j < 10
1135         CAT_XDEFINE q000, j, i
1136     %elif j < 100
1137         CAT_XDEFINE q00, j, i
1138     %elif j < 1000
1139         CAT_XDEFINE q0, j, i
1140     %else
1141         CAT_XDEFINE q, j, i
1142     %endif
1143 %assign i i+1
1144 %endrep
1145 %undef i
1146 %undef j
1147
1148 %macro FMA_INSTR 3
1149     %macro %1 5-8 %1, %2, %3
1150         %if cpuflag(xop) || cpuflag(fma4)
1151             v%6 %1, %2, %3, %4
1152         %else
1153             %ifidn %1, %4
1154                 %7 %5, %2, %3
1155                 %8 %1, %4, %5
1156             %else
1157                 %7 %1, %2, %3
1158                 %8 %1, %4
1159             %endif
1160         %endif
1161     %endmacro
1162 %endmacro
1163
1164 FMA_INSTR  fmaddps,   mulps, addps
1165 FMA_INSTR  pmacsdd,  pmulld, paddd
1166 FMA_INSTR  pmacsww,  pmullw, paddw
1167 FMA_INSTR pmadcswd, pmaddwd, paddd
1168
1169 ; tzcnt is equivalent to "rep bsf" and is backwards-compatible with bsf.
1170 ; This lets us use tzcnt without bumping the yasm version requirement yet.
1171 %define tzcnt rep bsf