git.sesse.net Git - ffmpeg/blob - libavutil/x86/x86util.asm

   1 ;*****************************************************************************
   2 ;* x86util.asm
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2008-2010 x264 project
   5 ;*
   6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
   7 ;*          Holger Lubitz <holger@lubitz.org>
   8 ;*
   9 ;* This file is part of FFmpeg.
  10 ;*
  11 ;* FFmpeg is free software; you can redistribute it and/or
  12 ;* modify it under the terms of the GNU Lesser General Public
  13 ;* License as published by the Free Software Foundation; either
  14 ;* version 2.1 of the License, or (at your option) any later version.
  15 ;*
  16 ;* FFmpeg is distributed in the hope that it will be useful,
  17 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;* Lesser General Public License for more details.
  20 ;*
  21 ;* You should have received a copy of the GNU Lesser General Public
  22 ;* License along with FFmpeg; if not, write to the Free Software
  23 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  24 ;******************************************************************************
  25
  26 %define program_name ff
  27 %define cpuflags_mmxext cpuflags_mmx2
  28
  29 %include "libavutil/x86/x86inc.asm"
  30
  31 %macro SBUTTERFLY 4
  32 %if avx_enabled == 0
  33     mova      m%4, m%2
  34     punpckl%1 m%2, m%3
  35     punpckh%1 m%4, m%3
  36 %else
  37     punpckh%1 m%4, m%2, m%3
  38     punpckl%1 m%2, m%3
  39 %endif
  40     SWAP %3, %4
  41 %endmacro
  42
  43 %macro SBUTTERFLY2 4
  44     punpckl%1 m%4, m%2, m%3
  45     punpckh%1 m%2, m%2, m%3
  46     SWAP %2, %4, %3
  47 %endmacro
  48
  49 %macro SBUTTERFLYPS 3
  50     unpcklps m%3, m%1, m%2
  51     unpckhps m%1, m%1, m%2
  52     SWAP %1, %3, %2
  53 %endmacro
  54
  55 %macro TRANSPOSE4x4B 5
  56     SBUTTERFLY bw, %1, %2, %5
  57     SBUTTERFLY bw, %3, %4, %5
  58     SBUTTERFLY wd, %1, %3, %5
  59     SBUTTERFLY wd, %2, %4, %5
  60     SWAP %2, %3
  61 %endmacro
  62
  63 %macro TRANSPOSE4x4W 5
  64     SBUTTERFLY wd, %1, %2, %5
  65     SBUTTERFLY wd, %3, %4, %5
  66     SBUTTERFLY dq, %1, %3, %5
  67     SBUTTERFLY dq, %2, %4, %5
  68     SWAP %2, %3
  69 %endmacro
  70
  71 %macro TRANSPOSE2x4x4W 5
  72     SBUTTERFLY wd,  %1, %2, %5
  73     SBUTTERFLY wd,  %3, %4, %5
  74     SBUTTERFLY dq,  %1, %3, %5
  75     SBUTTERFLY dq,  %2, %4, %5
  76     SBUTTERFLY qdq, %1, %2, %5
  77     SBUTTERFLY qdq, %3, %4, %5
  78 %endmacro
  79
  80 %macro TRANSPOSE4x4D 5
  81     SBUTTERFLY dq,  %1, %2, %5
  82     SBUTTERFLY dq,  %3, %4, %5
  83     SBUTTERFLY qdq, %1, %3, %5
  84     SBUTTERFLY qdq, %2, %4, %5
  85     SWAP %2, %3
  86 %endmacro
  87
  88 ; identical behavior to TRANSPOSE4x4D, but using SSE1 float ops
  89 %macro TRANSPOSE4x4PS 5
  90     SBUTTERFLYPS %1, %2, %5
  91     SBUTTERFLYPS %3, %4, %5
  92     movlhps m%5, m%1, m%3
  93     movhlps m%3, m%1
  94     SWAP %5, %1
  95     movlhps m%5, m%2, m%4
  96     movhlps m%4, m%2
  97     SWAP %5, %2, %3
  98 %endmacro
  99
 100 %macro TRANSPOSE8x8W 9-11
 101 %if ARCH_X86_64
 102     SBUTTERFLY wd,  %1, %2, %9
 103     SBUTTERFLY wd,  %3, %4, %9
 104     SBUTTERFLY wd,  %5, %6, %9
 105     SBUTTERFLY wd,  %7, %8, %9
 106     SBUTTERFLY dq,  %1, %3, %9
 107     SBUTTERFLY dq,  %2, %4, %9
 108     SBUTTERFLY dq,  %5, %7, %9
 109     SBUTTERFLY dq,  %6, %8, %9
 110     SBUTTERFLY qdq, %1, %5, %9
 111     SBUTTERFLY qdq, %2, %6, %9
 112     SBUTTERFLY qdq, %3, %7, %9
 113     SBUTTERFLY qdq, %4, %8, %9
 114     SWAP %2, %5
 115     SWAP %4, %7
 116 %else
 117 ; in:  m0..m7, unless %11 in which case m6 is in %9
 118 ; out: m0..m7, unless %11 in which case m4 is in %10
 119 ; spills into %9 and %10
 120 %if %0<11
 121     movdqa %9, m%7
 122 %endif
 123     SBUTTERFLY wd,  %1, %2, %7
 124     movdqa %10, m%2
 125     movdqa m%7, %9
 126     SBUTTERFLY wd,  %3, %4, %2
 127     SBUTTERFLY wd,  %5, %6, %2
 128     SBUTTERFLY wd,  %7, %8, %2
 129     SBUTTERFLY dq,  %1, %3, %2
 130     movdqa %9, m%3
 131     movdqa m%2, %10
 132     SBUTTERFLY dq,  %2, %4, %3
 133     SBUTTERFLY dq,  %5, %7, %3
 134     SBUTTERFLY dq,  %6, %8, %3
 135     SBUTTERFLY qdq, %1, %5, %3
 136     SBUTTERFLY qdq, %2, %6, %3
 137     movdqa %10, m%2
 138     movdqa m%3, %9
 139     SBUTTERFLY qdq, %3, %7, %2
 140     SBUTTERFLY qdq, %4, %8, %2
 141     SWAP %2, %5
 142     SWAP %4, %7
 143 %if %0<11
 144     movdqa m%5, %10
 145 %endif
 146 %endif
 147 %endmacro
 148
 149 ; PABSW macro assumes %1 != %2, while ABS1/2 macros work in-place
 150 %macro PABSW 2
 151 %if cpuflag(ssse3)
 152     pabsw      %1, %2
 153 %elif cpuflag(mmxext)
 154     pxor    %1, %1
 155     psubw   %1, %2
 156     pmaxsw  %1, %2
 157 %else
 158     pxor       %1, %1
 159     pcmpgtw    %1, %2
 160     pxor       %2, %1
 161     psubw      %2, %1
 162     SWAP       %1, %2
 163 %endif
 164 %endmacro
 165
 166 %macro PSIGNW_MMX 2
 167     pxor       %1, %2
 168     psubw      %1, %2
 169 %endmacro
 170
 171 %macro PSIGNW_SSSE3 2
 172     psignw     %1, %2
 173 %endmacro
 174
 175 %macro ABS1_MMX 2    ; a, tmp
 176     pxor       %2, %2
 177     pcmpgtw    %2, %1
 178     pxor       %1, %2
 179     psubw      %1, %2
 180 %endmacro
 181
 182 %macro ABS2_MMX 4    ; a, b, tmp0, tmp1
 183     pxor       %3, %3
 184     pxor       %4, %4
 185     pcmpgtw    %3, %1
 186     pcmpgtw    %4, %2
 187     pxor       %1, %3
 188     pxor       %2, %4
 189     psubw      %1, %3
 190     psubw      %2, %4
 191 %endmacro
 192
 193 %macro ABS1_MMXEXT 2 ; a, tmp
 194     pxor    %2, %2
 195     psubw   %2, %1
 196     pmaxsw  %1, %2
 197 %endmacro
 198
 199 %macro ABS2_MMXEXT 4 ; a, b, tmp0, tmp1
 200     pxor    %3, %3
 201     pxor    %4, %4
 202     psubw   %3, %1
 203     psubw   %4, %2
 204     pmaxsw  %1, %3
 205     pmaxsw  %2, %4
 206 %endmacro
 207
 208 %macro ABS1_SSSE3 2
 209     pabsw   %1, %1
 210 %endmacro
 211
 212 %macro ABS2_SSSE3 4
 213     pabsw   %1, %1
 214     pabsw   %2, %2
 215 %endmacro
 216
 217 %macro ABSB_MMX 2
 218     pxor    %2, %2
 219     psubb   %2, %1
 220     pminub  %1, %2
 221 %endmacro
 222
 223 %macro ABSB2_MMX 4
 224     pxor    %3, %3
 225     pxor    %4, %4
 226     psubb   %3, %1
 227     psubb   %4, %2
 228     pminub  %1, %3
 229     pminub  %2, %4
 230 %endmacro
 231
 232 %macro ABSD2_MMX 4
 233     pxor    %3, %3
 234     pxor    %4, %4
 235     pcmpgtd %3, %1
 236     pcmpgtd %4, %2
 237     pxor    %1, %3
 238     pxor    %2, %4
 239     psubd   %1, %3
 240     psubd   %2, %4
 241 %endmacro
 242
 243 %macro ABSB_SSSE3 2
 244     pabsb   %1, %1
 245 %endmacro
 246
 247 %macro ABSB2_SSSE3 4
 248     pabsb   %1, %1
 249     pabsb   %2, %2
 250 %endmacro
 251
 252 %macro ABS4 6
 253     ABS2 %1, %2, %5, %6
 254     ABS2 %3, %4, %5, %6
 255 %endmacro
 256
 257 %define ABS1 ABS1_MMX
 258 %define ABS2 ABS2_MMX
 259 %define ABSB ABSB_MMX
 260 %define ABSB2 ABSB2_MMX
 261
 262 %macro SPLATB_LOAD 3
 263 %if cpuflag(ssse3)
 264     movd      %1, [%2-3]
 265     pshufb    %1, %3
 266 %else
 267     movd      %1, [%2-3] ;to avoid crossing a cacheline
 268     punpcklbw %1, %1
 269     SPLATW    %1, %1, 3
 270 %endif
 271 %endmacro
 272
 273 %macro SPLATB_REG 3
 274 %if cpuflag(ssse3)
 275     movd      %1, %2d
 276     pshufb    %1, %3
 277 %else
 278     movd      %1, %2d
 279     punpcklbw %1, %1
 280     SPLATW    %1, %1, 0
 281 %endif
 282 %endmacro
 283
 284 %macro PALIGNR 4-5
 285 %if cpuflag(ssse3)
 286 %if %0==5
 287     palignr %1, %2, %3, %4
 288 %else
 289     palignr %1, %2, %3
 290 %endif
 291 %elif cpuflag(mmx) ; [dst,] src1, src2, imm, tmp
 292     %define %%dst %1
 293 %if %0==5
 294 %ifnidn %1, %2
 295     mova    %%dst, %2
 296 %endif
 297     %rotate 1
 298 %endif
 299 %ifnidn %4, %2
 300     mova    %4, %2
 301 %endif
 302 %if mmsize==8
 303     psllq   %%dst, (8-%3)*8
 304     psrlq   %4, %3*8
 305 %else
 306     pslldq  %%dst, 16-%3
 307     psrldq  %4, %3
 308 %endif
 309     por     %%dst, %4
 310 %endif
 311 %endmacro
 312
 313 %macro PSHUFLW 1+
 314     %if mmsize == 8
 315         pshufw %1
 316     %else
 317         pshuflw %1
 318     %endif
 319 %endmacro
 320
 321 %macro PSWAPD 2
 322 %if cpuflag(mmxext)
 323     pshufw    %1, %2, q1032
 324 %elif cpuflag(3dnowext)
 325     pswapd    %1, %2
 326 %elif cpuflag(3dnow)
 327     movq      %1, %2
 328     psrlq     %1, 32
 329     punpckldq %1, %2
 330 %endif
 331 %endmacro
 332
 333 %macro DEINTB 5 ; mask, reg1, mask, reg2, optional src to fill masks from
 334 %ifnum %5
 335     pand   m%3, m%5, m%4 ; src .. y6 .. y4
 336     pand   m%1, m%5, m%2 ; dst .. y6 .. y4
 337 %else
 338     mova   m%1, %5
 339     pand   m%3, m%1, m%4 ; src .. y6 .. y4
 340     pand   m%1, m%1, m%2 ; dst .. y6 .. y4
 341 %endif
 342     psrlw  m%2, 8        ; dst .. y7 .. y5
 343     psrlw  m%4, 8        ; src .. y7 .. y5
 344 %endmacro
 345
 346 %macro SUMSUB_BA 3-4
 347 %if %0==3
 348     padd%1  m%2, m%3
 349     padd%1  m%3, m%3
 350     psub%1  m%3, m%2
 351 %else
 352 %if avx_enabled == 0
 353     mova    m%4, m%2
 354     padd%1  m%2, m%3
 355     psub%1  m%3, m%4
 356 %else
 357     padd%1  m%4, m%2, m%3
 358     psub%1  m%3, m%2
 359     SWAP    %2, %4
 360 %endif
 361 %endif
 362 %endmacro
 363
 364 %macro SUMSUB_BADC 5-6
 365 %if %0==6
 366     SUMSUB_BA %1, %2, %3, %6
 367     SUMSUB_BA %1, %4, %5, %6
 368 %else
 369     padd%1  m%2, m%3
 370     padd%1  m%4, m%5
 371     padd%1  m%3, m%3
 372     padd%1  m%5, m%5
 373     psub%1  m%3, m%2
 374     psub%1  m%5, m%4
 375 %endif
 376 %endmacro
 377
 378 %macro SUMSUB2_AB 4
 379 %ifnum %3
 380     psub%1  m%4, m%2, m%3
 381     psub%1  m%4, m%3
 382     padd%1  m%2, m%2
 383     padd%1  m%2, m%3
 384 %else
 385     mova    m%4, m%2
 386     padd%1  m%2, m%2
 387     padd%1  m%2, %3
 388     psub%1  m%4, %3
 389     psub%1  m%4, %3
 390 %endif
 391 %endmacro
 392
 393 %macro SUMSUB2_BA 4
 394 %if avx_enabled == 0
 395     mova    m%4, m%2
 396     padd%1  m%2, m%3
 397     padd%1  m%2, m%3
 398     psub%1  m%3, m%4
 399     psub%1  m%3, m%4
 400 %else
 401     padd%1  m%4, m%2, m%3
 402     padd%1  m%4, m%3
 403     psub%1  m%3, m%2
 404     psub%1  m%3, m%2
 405     SWAP     %2,  %4
 406 %endif
 407 %endmacro
 408
 409 %macro SUMSUBD2_AB 5
 410 %ifnum %4
 411     psra%1  m%5, m%2, 1  ; %3: %3>>1
 412     psra%1  m%4, m%3, 1  ; %2: %2>>1
 413     padd%1  m%4, m%2     ; %3: %3>>1+%2
 414     psub%1  m%5, m%3     ; %2: %2>>1-%3
 415     SWAP     %2, %5
 416     SWAP     %3, %4
 417 %else
 418     mova    %5, m%2
 419     mova    %4, m%3
 420     psra%1  m%3, 1  ; %3: %3>>1
 421     psra%1  m%2, 1  ; %2: %2>>1
 422     padd%1  m%3, %5 ; %3: %3>>1+%2
 423     psub%1  m%2, %4 ; %2: %2>>1-%3
 424 %endif
 425 %endmacro
 426
 427 %macro DCT4_1D 5
 428 %ifnum %5
 429     SUMSUB_BADC w, %4, %1, %3, %2, %5
 430     SUMSUB_BA   w, %3, %4, %5
 431     SUMSUB2_AB  w, %1, %2, %5
 432     SWAP %1, %3, %4, %5, %2
 433 %else
 434     SUMSUB_BADC w, %4, %1, %3, %2
 435     SUMSUB_BA   w, %3, %4
 436     mova     [%5], m%2
 437     SUMSUB2_AB  w, %1, [%5], %2
 438     SWAP %1, %3, %4, %2
 439 %endif
 440 %endmacro
 441
 442 %macro IDCT4_1D 6-7
 443 %ifnum %6
 444     SUMSUBD2_AB %1, %3, %5, %7, %6
 445     ; %3: %3>>1-%5 %5: %3+%5>>1
 446     SUMSUB_BA   %1, %4, %2, %7
 447     ; %4: %2+%4 %2: %2-%4
 448     SUMSUB_BADC %1, %5, %4, %3, %2, %7
 449     ; %5: %2+%4 + (%3+%5>>1)
 450     ; %4: %2+%4 - (%3+%5>>1)
 451     ; %3: %2-%4 + (%3>>1-%5)
 452     ; %2: %2-%4 - (%3>>1-%5)
 453 %else
 454 %ifidn %1, w
 455     SUMSUBD2_AB %1, %3, %5, [%6], [%6+16]
 456 %else
 457     SUMSUBD2_AB %1, %3, %5, [%6], [%6+32]
 458 %endif
 459     SUMSUB_BA   %1, %4, %2
 460     SUMSUB_BADC %1, %5, %4, %3, %2
 461 %endif
 462     SWAP %2, %5, %4
 463     ; %2: %2+%4 + (%3+%5>>1) row0
 464     ; %3: %2-%4 + (%3>>1-%5) row1
 465     ; %4: %2-%4 - (%3>>1-%5) row2
 466     ; %5: %2+%4 - (%3+%5>>1) row3
 467 %endmacro
 468
 469
 470 %macro LOAD_DIFF 5
 471 %ifidn %3, none
 472     movh       %1, %4
 473     movh       %2, %5
 474     punpcklbw  %1, %2
 475     punpcklbw  %2, %2
 476     psubw      %1, %2
 477 %else
 478     movh       %1, %4
 479     punpcklbw  %1, %3
 480     movh       %2, %5
 481     punpcklbw  %2, %3
 482     psubw      %1, %2
 483 %endif
 484 %endmacro
 485
 486 %macro STORE_DCT 6
 487     movq   [%5+%6+ 0], m%1
 488     movq   [%5+%6+ 8], m%2
 489     movq   [%5+%6+16], m%3
 490     movq   [%5+%6+24], m%4
 491     movhps [%5+%6+32], m%1
 492     movhps [%5+%6+40], m%2
 493     movhps [%5+%6+48], m%3
 494     movhps [%5+%6+56], m%4
 495 %endmacro
 496
 497 %macro LOAD_DIFF_8x4P 7-10 r0,r2,0 ; 4x dest, 2x temp, 2x pointer, increment?
 498     LOAD_DIFF m%1, m%5, m%7, [%8],      [%9]
 499     LOAD_DIFF m%2, m%6, m%7, [%8+r1],   [%9+r3]
 500     LOAD_DIFF m%3, m%5, m%7, [%8+2*r1], [%9+2*r3]
 501     LOAD_DIFF m%4, m%6, m%7, [%8+r4],   [%9+r5]
 502 %if %10
 503     lea %8, [%8+4*r1]
 504     lea %9, [%9+4*r3]
 505 %endif
 506 %endmacro
 507
 508 %macro DIFFx2 6-7
 509     movh       %3, %5
 510     punpcklbw  %3, %4
 511     psraw      %1, 6
 512     paddsw     %1, %3
 513     movh       %3, %6
 514     punpcklbw  %3, %4
 515     psraw      %2, 6
 516     paddsw     %2, %3
 517     packuswb   %2, %1
 518 %endmacro
 519
 520 %macro STORE_DIFF 4
 521     movh       %2, %4
 522     punpcklbw  %2, %3
 523     psraw      %1, 6
 524     paddsw     %1, %2
 525     packuswb   %1, %1
 526     movh       %4, %1
 527 %endmacro
 528
 529 %macro STORE_DIFFx2 8 ; add1, add2, reg1, reg2, zero, shift, source, stride
 530     movh       %3, [%7]
 531     movh       %4, [%7+%8]
 532     psraw      %1, %6
 533     psraw      %2, %6
 534     punpcklbw  %3, %5
 535     punpcklbw  %4, %5
 536     paddw      %3, %1
 537     paddw      %4, %2
 538     packuswb   %3, %5
 539     packuswb   %4, %5
 540     movh     [%7], %3
 541     movh  [%7+%8], %4
 542 %endmacro
 543
 544 %macro PMINUB 3 ; dst, src, ignored
 545 %if cpuflag(mmxext)
 546     pminub   %1, %2
 547 %else ; dst, src, tmp
 548     mova     %3, %1
 549     psubusb  %3, %2
 550     psubb    %1, %3
 551 %endif
 552 %endmacro
 553
 554 %macro SPLATW 2-3 0
 555 %if mmsize == 16
 556     pshuflw    %1, %2, (%3)*0x55
 557     punpcklqdq %1, %1
 558 %elif cpuflag(mmxext)
 559     pshufw     %1, %2, (%3)*0x55
 560 %else
 561     %ifnidn %1, %2
 562         mova       %1, %2
 563     %endif
 564     %if %3 & 2
 565         punpckhwd  %1, %1
 566     %else
 567         punpcklwd  %1, %1
 568     %endif
 569     %if %3 & 1
 570         punpckhwd  %1, %1
 571     %else
 572         punpcklwd  %1, %1
 573     %endif
 574 %endif
 575 %endmacro
 576
 577 %macro SPLATD 1
 578 %if mmsize == 8
 579     punpckldq  %1, %1
 580 %elif cpuflag(sse2)
 581     pshufd  %1, %1, 0
 582 %elif cpuflag(sse)
 583     shufps  %1, %1, 0
 584 %endif
 585 %endmacro
 586
 587 %macro CLIPW 3 ;(dst, min, max)
 588     pmaxsw %1, %2
 589     pminsw %1, %3
 590 %endmacro
 591
 592 %macro PMINSD_MMX 3 ; dst, src, tmp
 593     mova      %3, %2
 594     pcmpgtd   %3, %1
 595     pxor      %1, %2
 596     pand      %1, %3
 597     pxor      %1, %2
 598 %endmacro
 599
 600 %macro PMAXSD_MMX 3 ; dst, src, tmp
 601     mova      %3, %1
 602     pcmpgtd   %3, %2
 603     pand      %1, %3
 604     pandn     %3, %2
 605     por       %1, %3
 606 %endmacro
 607
 608 %macro CLIPD_MMX 3-4 ; src/dst, min, max, tmp
 609     PMINSD_MMX %1, %3, %4
 610     PMAXSD_MMX %1, %2, %4
 611 %endmacro
 612
 613 %macro CLIPD_SSE2 3-4 ; src/dst, min (float), max (float), unused
 614     cvtdq2ps  %1, %1
 615     minps     %1, %3
 616     maxps     %1, %2
 617     cvtps2dq  %1, %1
 618 %endmacro
 619
 620 %macro CLIPD_SSE41 3-4 ;  src/dst, min, max, unused
 621     pminsd  %1, %3
 622     pmaxsd  %1, %2
 623 %endmacro
 624
 625 %macro VBROADCASTSS 2 ; dst xmm/ymm, src m32
 626 %if cpuflag(avx)
 627     vbroadcastss %1, %2
 628 %else ; sse
 629     movss        %1, %2
 630     shufps       %1, %1, 0
 631 %endif
 632 %endmacro
 633
 634 %macro VBROADCASTSD 2 ; dst xmm/ymm, src m64
 635 %if cpuflag(avx) && mmsize == 32
 636     vbroadcastsd %1, %2
 637 %elif cpuflag(sse3)
 638     movddup      %1, %2
 639 %else ; sse2
 640     movsd        %1, %2
 641     movlhps      %1, %1
 642 %endif
 643 %endmacro
 644
 645 %macro SHUFFLE_MASK_W 8
 646     %rep 8
 647         %if %1>=0x80
 648             db %1, %1
 649         %else
 650             db %1*2
 651             db %1*2+1
 652         %endif
 653         %rotate 1
 654     %endrep
 655 %endmacro
 656
 657 %macro PMOVSXWD 2; dst, src
 658 %if cpuflag(sse4)
 659     pmovsxwd     %1, %2
 660 %else
 661     %ifnidn %1, %2
 662     mova         %1, %2
 663     %endif
 664     punpcklwd    %1, %1
 665     psrad        %1, 16
 666 %endif
 667 %endmacro