git.sesse.net Git - ffmpeg/blob - libavutil/x86/x86util.asm

   1 ;*****************************************************************************
   2 ;* x86util.asm
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2008-2010 x264 project
   5 ;*
   6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
   7 ;*          Holger Lubitz <holger@lubitz.org>
   8 ;*
   9 ;* This file is part of FFmpeg.
  10 ;*
  11 ;* FFmpeg is free software; you can redistribute it and/or
  12 ;* modify it under the terms of the GNU Lesser General Public
  13 ;* License as published by the Free Software Foundation; either
  14 ;* version 2.1 of the License, or (at your option) any later version.
  15 ;*
  16 ;* FFmpeg is distributed in the hope that it will be useful,
  17 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;* Lesser General Public License for more details.
  20 ;*
  21 ;* You should have received a copy of the GNU Lesser General Public
  22 ;* License along with FFmpeg; if not, write to the Free Software
  23 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  24 ;******************************************************************************
  25
  26 %macro SBUTTERFLY 4
  27 %if avx_enabled == 0
  28     mova      m%4, m%2
  29     punpckl%1 m%2, m%3
  30     punpckh%1 m%4, m%3
  31 %else
  32     punpckh%1 m%4, m%2, m%3
  33     punpckl%1 m%2, m%3
  34 %endif
  35     SWAP %3, %4
  36 %endmacro
  37
  38 %macro SBUTTERFLY2 4
  39     punpckl%1 m%4, m%2, m%3
  40     punpckh%1 m%2, m%2, m%3
  41     SWAP %2, %4, %3
  42 %endmacro
  43
  44 %macro SBUTTERFLYPS 3
  45     unpcklps m%3, m%1, m%2
  46     unpckhps m%1, m%1, m%2
  47     SWAP %1, %3, %2
  48 %endmacro
  49
  50 %macro TRANSPOSE4x4B 5
  51     SBUTTERFLY bw, %1, %2, %5
  52     SBUTTERFLY bw, %3, %4, %5
  53     SBUTTERFLY wd, %1, %3, %5
  54     SBUTTERFLY wd, %2, %4, %5
  55     SWAP %2, %3
  56 %endmacro
  57
  58 %macro TRANSPOSE4x4W 5
  59     SBUTTERFLY wd, %1, %2, %5
  60     SBUTTERFLY wd, %3, %4, %5
  61     SBUTTERFLY dq, %1, %3, %5
  62     SBUTTERFLY dq, %2, %4, %5
  63     SWAP %2, %3
  64 %endmacro
  65
  66 %macro TRANSPOSE2x4x4W 5
  67     SBUTTERFLY wd,  %1, %2, %5
  68     SBUTTERFLY wd,  %3, %4, %5
  69     SBUTTERFLY dq,  %1, %3, %5
  70     SBUTTERFLY dq,  %2, %4, %5
  71     SBUTTERFLY qdq, %1, %2, %5
  72     SBUTTERFLY qdq, %3, %4, %5
  73 %endmacro
  74
  75 %macro TRANSPOSE4x4D 5
  76     SBUTTERFLY dq,  %1, %2, %5
  77     SBUTTERFLY dq,  %3, %4, %5
  78     SBUTTERFLY qdq, %1, %3, %5
  79     SBUTTERFLY qdq, %2, %4, %5
  80     SWAP %2, %3
  81 %endmacro
  82
  83 ; identical behavior to TRANSPOSE4x4D, but using SSE1 float ops
  84 %macro TRANSPOSE4x4PS 5
  85     SBUTTERFLYPS %1, %2, %5
  86     SBUTTERFLYPS %3, %4, %5
  87     movlhps m%5, m%1, m%3
  88     movhlps m%3, m%1
  89     SWAP %5, %1
  90     movlhps m%5, m%2, m%4
  91     movhlps m%4, m%2
  92     SWAP %5, %2, %3
  93 %endmacro
  94
  95 %macro TRANSPOSE8x8W 9-11
  96 %if ARCH_X86_64
  97     SBUTTERFLY wd,  %1, %2, %9
  98     SBUTTERFLY wd,  %3, %4, %9
  99     SBUTTERFLY wd,  %5, %6, %9
 100     SBUTTERFLY wd,  %7, %8, %9
 101     SBUTTERFLY dq,  %1, %3, %9
 102     SBUTTERFLY dq,  %2, %4, %9
 103     SBUTTERFLY dq,  %5, %7, %9
 104     SBUTTERFLY dq,  %6, %8, %9
 105     SBUTTERFLY qdq, %1, %5, %9
 106     SBUTTERFLY qdq, %2, %6, %9
 107     SBUTTERFLY qdq, %3, %7, %9
 108     SBUTTERFLY qdq, %4, %8, %9
 109     SWAP %2, %5
 110     SWAP %4, %7
 111 %else
 112 ; in:  m0..m7, unless %11 in which case m6 is in %9
 113 ; out: m0..m7, unless %11 in which case m4 is in %10
 114 ; spills into %9 and %10
 115 %if %0<11
 116     movdqa %9, m%7
 117 %endif
 118     SBUTTERFLY wd,  %1, %2, %7
 119     movdqa %10, m%2
 120     movdqa m%7, %9
 121     SBUTTERFLY wd,  %3, %4, %2
 122     SBUTTERFLY wd,  %5, %6, %2
 123     SBUTTERFLY wd,  %7, %8, %2
 124     SBUTTERFLY dq,  %1, %3, %2
 125     movdqa %9, m%3
 126     movdqa m%2, %10
 127     SBUTTERFLY dq,  %2, %4, %3
 128     SBUTTERFLY dq,  %5, %7, %3
 129     SBUTTERFLY dq,  %6, %8, %3
 130     SBUTTERFLY qdq, %1, %5, %3
 131     SBUTTERFLY qdq, %2, %6, %3
 132     movdqa %10, m%2
 133     movdqa m%3, %9
 134     SBUTTERFLY qdq, %3, %7, %2
 135     SBUTTERFLY qdq, %4, %8, %2
 136     SWAP %2, %5
 137     SWAP %4, %7
 138 %if %0<11
 139     movdqa m%5, %10
 140 %endif
 141 %endif
 142 %endmacro
 143
 144 ; PABSW macros assume %1 != %2, while ABS1/2 macros work in-place
 145 %macro PABSW_MMX 2
 146     pxor       %1, %1
 147     pcmpgtw    %1, %2
 148     pxor       %2, %1
 149     psubw      %2, %1
 150     SWAP       %1, %2
 151 %endmacro
 152
 153 %macro PSIGNW_MMX 2
 154     pxor       %1, %2
 155     psubw      %1, %2
 156 %endmacro
 157
 158 %macro PABSW_MMX2 2
 159     pxor    %1, %1
 160     psubw   %1, %2
 161     pmaxsw  %1, %2
 162 %endmacro
 163
 164 %macro PABSW_SSSE3 2
 165     pabsw      %1, %2
 166 %endmacro
 167
 168 %macro PSIGNW_SSSE3 2
 169     psignw     %1, %2
 170 %endmacro
 171
 172 %macro ABS1_MMX 2    ; a, tmp
 173     pxor       %2, %2
 174     pcmpgtw    %2, %1
 175     pxor       %1, %2
 176     psubw      %1, %2
 177 %endmacro
 178
 179 %macro ABS2_MMX 4    ; a, b, tmp0, tmp1
 180     pxor       %3, %3
 181     pxor       %4, %4
 182     pcmpgtw    %3, %1
 183     pcmpgtw    %4, %2
 184     pxor       %1, %3
 185     pxor       %2, %4
 186     psubw      %1, %3
 187     psubw      %2, %4
 188 %endmacro
 189
 190 %macro ABS1_MMX2 2   ; a, tmp
 191     pxor    %2, %2
 192     psubw   %2, %1
 193     pmaxsw  %1, %2
 194 %endmacro
 195
 196 %macro ABS2_MMX2 4   ; a, b, tmp0, tmp1
 197     pxor    %3, %3
 198     pxor    %4, %4
 199     psubw   %3, %1
 200     psubw   %4, %2
 201     pmaxsw  %1, %3
 202     pmaxsw  %2, %4
 203 %endmacro
 204
 205 %macro ABS1_SSSE3 2
 206     pabsw   %1, %1
 207 %endmacro
 208
 209 %macro ABS2_SSSE3 4
 210     pabsw   %1, %1
 211     pabsw   %2, %2
 212 %endmacro
 213
 214 %macro ABSB_MMX 2
 215     pxor    %2, %2
 216     psubb   %2, %1
 217     pminub  %1, %2
 218 %endmacro
 219
 220 %macro ABSB2_MMX 4
 221     pxor    %3, %3
 222     pxor    %4, %4
 223     psubb   %3, %1
 224     psubb   %4, %2
 225     pminub  %1, %3
 226     pminub  %2, %4
 227 %endmacro
 228
 229 %macro ABSD2_MMX 4
 230     pxor    %3, %3
 231     pxor    %4, %4
 232     pcmpgtd %3, %1
 233     pcmpgtd %4, %2
 234     pxor    %1, %3
 235     pxor    %2, %4
 236     psubd   %1, %3
 237     psubd   %2, %4
 238 %endmacro
 239
 240 %macro ABSB_SSSE3 2
 241     pabsb   %1, %1
 242 %endmacro
 243
 244 %macro ABSB2_SSSE3 4
 245     pabsb   %1, %1
 246     pabsb   %2, %2
 247 %endmacro
 248
 249 %macro ABS4 6
 250     ABS2 %1, %2, %5, %6
 251     ABS2 %3, %4, %5, %6
 252 %endmacro
 253
 254 %define ABS1 ABS1_MMX
 255 %define ABS2 ABS2_MMX
 256 %define ABSB ABSB_MMX
 257 %define ABSB2 ABSB2_MMX
 258
 259 %macro SPLATB_MMX 3
 260     movd      %1, [%2-3] ;to avoid crossing a cacheline
 261     punpcklbw %1, %1
 262     SPLATW    %1, %1, 3
 263 %endmacro
 264
 265 %macro SPLATB_SSSE3 3
 266     movd      %1, [%2-3]
 267     pshufb    %1, %3
 268 %endmacro
 269
 270 %macro PALIGNR_MMX 4-5 ; [dst,] src1, src2, imm, tmp
 271     %define %%dst %1
 272 %if %0==5
 273 %ifnidn %1, %2
 274     mova    %%dst, %2
 275 %endif
 276     %rotate 1
 277 %endif
 278 %ifnidn %4, %2
 279     mova    %4, %2
 280 %endif
 281 %if mmsize==8
 282     psllq   %%dst, (8-%3)*8
 283     psrlq   %4, %3*8
 284 %else
 285     pslldq  %%dst, 16-%3
 286     psrldq  %4, %3
 287 %endif
 288     por     %%dst, %4
 289 %endmacro
 290
 291 %macro PALIGNR_SSSE3 4-5
 292 %if %0==5
 293     palignr %1, %2, %3, %4
 294 %else
 295     palignr %1, %2, %3
 296 %endif
 297 %endmacro
 298
 299 %macro DEINTB 5 ; mask, reg1, mask, reg2, optional src to fill masks from
 300 %ifnum %5
 301     pand   m%3, m%5, m%4 ; src .. y6 .. y4
 302     pand   m%1, m%5, m%2 ; dst .. y6 .. y4
 303 %else
 304     mova   m%1, %5
 305     pand   m%3, m%1, m%4 ; src .. y6 .. y4
 306     pand   m%1, m%1, m%2 ; dst .. y6 .. y4
 307 %endif
 308     psrlw  m%2, 8        ; dst .. y7 .. y5
 309     psrlw  m%4, 8        ; src .. y7 .. y5
 310 %endmacro
 311
 312 %macro SUMSUB_BA 3-4
 313 %if %0==3
 314     padd%1  m%2, m%3
 315     padd%1  m%3, m%3
 316     psub%1  m%3, m%2
 317 %else
 318 %if avx_enabled == 0
 319     mova    m%4, m%2
 320     padd%1  m%2, m%3
 321     psub%1  m%3, m%4
 322 %else
 323     padd%1  m%4, m%2, m%3
 324     psub%1  m%3, m%2
 325     SWAP    %2, %4
 326 %endif
 327 %endif
 328 %endmacro
 329
 330 %macro SUMSUB_BADC 5-6
 331 %if %0==6
 332     SUMSUB_BA %1, %2, %3, %6
 333     SUMSUB_BA %1, %4, %5, %6
 334 %else
 335     padd%1  m%2, m%3
 336     padd%1  m%4, m%5
 337     padd%1  m%3, m%3
 338     padd%1  m%5, m%5
 339     psub%1  m%3, m%2
 340     psub%1  m%5, m%4
 341 %endif
 342 %endmacro
 343
 344 %macro SUMSUB2_AB 4
 345 %ifnum %3
 346     psub%1  m%4, m%2, m%3
 347     psub%1  m%4, m%3
 348     padd%1  m%2, m%2
 349     padd%1  m%2, m%3
 350 %else
 351     mova    m%4, m%2
 352     padd%1  m%2, m%2
 353     padd%1  m%2, %3
 354     psub%1  m%4, %3
 355     psub%1  m%4, %3
 356 %endif
 357 %endmacro
 358
 359 %macro SUMSUB2_BA 4
 360 %if avx_enabled == 0
 361     mova    m%4, m%2
 362     padd%1  m%2, m%3
 363     padd%1  m%2, m%3
 364     psub%1  m%3, m%4
 365     psub%1  m%3, m%4
 366 %else
 367     padd%1  m%4, m%2, m%3
 368     padd%1  m%4, m%3
 369     psub%1  m%3, m%2
 370     psub%1  m%3, m%2
 371     SWAP     %2,  %4
 372 %endif
 373 %endmacro
 374
 375 %macro SUMSUBD2_AB 5
 376 %ifnum %4
 377     psra%1  m%5, m%2, 1  ; %3: %3>>1
 378     psra%1  m%4, m%3, 1  ; %2: %2>>1
 379     padd%1  m%4, m%2     ; %3: %3>>1+%2
 380     psub%1  m%5, m%3     ; %2: %2>>1-%3
 381     SWAP     %2, %5
 382     SWAP     %3, %4
 383 %else
 384     mova    %5, m%2
 385     mova    %4, m%3
 386     psra%1  m%3, 1  ; %3: %3>>1
 387     psra%1  m%2, 1  ; %2: %2>>1
 388     padd%1  m%3, %5 ; %3: %3>>1+%2
 389     psub%1  m%2, %4 ; %2: %2>>1-%3
 390 %endif
 391 %endmacro
 392
 393 %macro DCT4_1D 5
 394 %ifnum %5
 395     SUMSUB_BADC w, %4, %1, %3, %2, %5
 396     SUMSUB_BA   w, %3, %4, %5
 397     SUMSUB2_AB  w, %1, %2, %5
 398     SWAP %1, %3, %4, %5, %2
 399 %else
 400     SUMSUB_BADC w, %4, %1, %3, %2
 401     SUMSUB_BA   w, %3, %4
 402     mova     [%5], m%2
 403     SUMSUB2_AB  w, %1, [%5], %2
 404     SWAP %1, %3, %4, %2
 405 %endif
 406 %endmacro
 407
 408 %macro IDCT4_1D 6-7
 409 %ifnum %6
 410     SUMSUBD2_AB %1, %3, %5, %7, %6
 411     ; %3: %3>>1-%5 %5: %3+%5>>1
 412     SUMSUB_BA   %1, %4, %2, %7
 413     ; %4: %2+%4 %2: %2-%4
 414     SUMSUB_BADC %1, %5, %4, %3, %2, %7
 415     ; %5: %2+%4 + (%3+%5>>1)
 416     ; %4: %2+%4 - (%3+%5>>1)
 417     ; %3: %2-%4 + (%3>>1-%5)
 418     ; %2: %2-%4 - (%3>>1-%5)
 419 %else
 420 %ifidn %1, w
 421     SUMSUBD2_AB %1, %3, %5, [%6], [%6+16]
 422 %else
 423     SUMSUBD2_AB %1, %3, %5, [%6], [%6+32]
 424 %endif
 425     SUMSUB_BA   %1, %4, %2
 426     SUMSUB_BADC %1, %5, %4, %3, %2
 427 %endif
 428     SWAP %2, %5, %4
 429     ; %2: %2+%4 + (%3+%5>>1) row0
 430     ; %3: %2-%4 + (%3>>1-%5) row1
 431     ; %4: %2-%4 - (%3>>1-%5) row2
 432     ; %5: %2+%4 - (%3+%5>>1) row3
 433 %endmacro
 434
 435
 436 %macro LOAD_DIFF 5
 437 %ifidn %3, none
 438     movh       %1, %4
 439     movh       %2, %5
 440     punpcklbw  %1, %2
 441     punpcklbw  %2, %2
 442     psubw      %1, %2
 443 %else
 444     movh       %1, %4
 445     punpcklbw  %1, %3
 446     movh       %2, %5
 447     punpcklbw  %2, %3
 448     psubw      %1, %2
 449 %endif
 450 %endmacro
 451
 452 %macro STORE_DCT 6
 453     movq   [%5+%6+ 0], m%1
 454     movq   [%5+%6+ 8], m%2
 455     movq   [%5+%6+16], m%3
 456     movq   [%5+%6+24], m%4
 457     movhps [%5+%6+32], m%1
 458     movhps [%5+%6+40], m%2
 459     movhps [%5+%6+48], m%3
 460     movhps [%5+%6+56], m%4
 461 %endmacro
 462
 463 %macro LOAD_DIFF_8x4P 7-10 r0,r2,0 ; 4x dest, 2x temp, 2x pointer, increment?
 464     LOAD_DIFF m%1, m%5, m%7, [%8],      [%9]
 465     LOAD_DIFF m%2, m%6, m%7, [%8+r1],   [%9+r3]
 466     LOAD_DIFF m%3, m%5, m%7, [%8+2*r1], [%9+2*r3]
 467     LOAD_DIFF m%4, m%6, m%7, [%8+r4],   [%9+r5]
 468 %if %10
 469     lea %8, [%8+4*r1]
 470     lea %9, [%9+4*r3]
 471 %endif
 472 %endmacro
 473
 474 %macro DIFFx2 6-7
 475     movh       %3, %5
 476     punpcklbw  %3, %4
 477     psraw      %1, 6
 478     paddsw     %1, %3
 479     movh       %3, %6
 480     punpcklbw  %3, %4
 481     psraw      %2, 6
 482     paddsw     %2, %3
 483     packuswb   %2, %1
 484 %endmacro
 485
 486 %macro STORE_DIFF 4
 487     movh       %2, %4
 488     punpcklbw  %2, %3
 489     psraw      %1, 6
 490     paddsw     %1, %2
 491     packuswb   %1, %1
 492     movh       %4, %1
 493 %endmacro
 494
 495 %macro STORE_DIFFx2 8 ; add1, add2, reg1, reg2, zero, shift, source, stride
 496     movh       %3, [%7]
 497     movh       %4, [%7+%8]
 498     psraw      %1, %6
 499     psraw      %2, %6
 500     punpcklbw  %3, %5
 501     punpcklbw  %4, %5
 502     paddw      %3, %1
 503     paddw      %4, %2
 504     packuswb   %3, %5
 505     packuswb   %4, %5
 506     movh     [%7], %3
 507     movh  [%7+%8], %4
 508 %endmacro
 509
 510 %macro PMINUB_MMX 3 ; dst, src, tmp
 511     mova     %3, %1
 512     psubusb  %3, %2
 513     psubb    %1, %3
 514 %endmacro
 515
 516 %macro PMINUB_MMXEXT 3 ; dst, src, ignored
 517     pminub   %1, %2
 518 %endmacro
 519
 520 %macro SPLATW 2-3 0
 521 %if mmsize == 16
 522     pshuflw    %1, %2, (%3)*0x55
 523     punpcklqdq %1, %1
 524 %else
 525     pshufw     %1, %2, (%3)*0x55
 526 %endif
 527 %endmacro
 528
 529 %macro SPLATD 2-3 0
 530 %if mmsize == 16
 531     pshufd %1, %2, (%3)*0x55
 532 %else
 533     pshufw %1, %2, (%3)*0x11 + ((%3)+1)*0x44
 534 %endif
 535 %endmacro
 536
 537 %macro SPLATD_MMX 1
 538     punpckldq  %1, %1
 539 %endmacro
 540
 541 %macro SPLATD_SSE 1
 542     shufps  %1, %1, 0
 543 %endmacro
 544
 545 %macro SPLATD_SSE2 1
 546     pshufd  %1, %1, 0
 547 %endmacro
 548
 549 %macro CLIPW 3 ;(dst, min, max)
 550     pmaxsw %1, %2
 551     pminsw %1, %3
 552 %endmacro
 553
 554 %macro PMINSD_MMX 3 ; dst, src, tmp
 555     mova      %3, %2
 556     pcmpgtd   %3, %1
 557     pxor      %1, %2
 558     pand      %1, %3
 559     pxor      %1, %2
 560 %endmacro
 561
 562 %macro PMAXSD_MMX 3 ; dst, src, tmp
 563     mova      %3, %1
 564     pcmpgtd   %3, %2
 565     pand      %1, %3
 566     pandn     %3, %2
 567     por       %1, %3
 568 %endmacro
 569
 570 %macro CLIPD_MMX 3-4 ; src/dst, min, max, tmp
 571     PMINSD_MMX %1, %3, %4
 572     PMAXSD_MMX %1, %2, %4
 573 %endmacro
 574
 575 %macro CLIPD_SSE2 3-4 ; src/dst, min (float), max (float), unused
 576     cvtdq2ps  %1, %1
 577     minps     %1, %3
 578     maxps     %1, %2
 579     cvtps2dq  %1, %1
 580 %endmacro
 581
 582 %macro CLIPD_SSE41 3-4 ;  src/dst, min, max, unused
 583     pminsd  %1, %3
 584     pmaxsd  %1, %2
 585 %endmacro
 586
 587 %macro VBROADCASTSS 2 ; dst xmm/ymm, src m32
 588 %if cpuflag(avx)
 589     vbroadcastss %1, %2
 590 %else ; sse
 591     movss        %1, %2
 592     shufps       %1, %1, 0
 593 %endif
 594 %endmacro