git.sesse.net Git - ffmpeg/blob - libswscale/x86/input.asm

   1 ;******************************************************************************
   2 ;* x86-optimized input routines; does shuffling of packed
   3 ;* YUV formats into individual planes, and converts RGB
   4 ;* into YUV planes also.
   5 ;* Copyright (c) 2012 Ronald S. Bultje <rsbultje@gmail.com>
   6 ;*
   7 ;* This file is part of Libav.
   8 ;*
   9 ;* Libav is free software; you can redistribute it and/or
  10 ;* modify it under the terms of the GNU Lesser General Public
  11 ;* License as published by the Free Software Foundation; either
  12 ;* version 2.1 of the License, or (at your option) any later version.
  13 ;*
  14 ;* Libav is distributed in the hope that it will be useful,
  15 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;* Lesser General Public License for more details.
  18 ;*
  19 ;* You should have received a copy of the GNU Lesser General Public
  20 ;* License along with Libav; if not, write to the Free Software
  21 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  22 ;******************************************************************************
  23
  24 %include "libavutil/x86/x86util.asm"
  25
  26 SECTION_RODATA
  27
  28 %define RY 0x20DE
  29 %define GY 0x4087
  30 %define BY 0x0C88
  31 %define RU 0xECFF
  32 %define GU 0xDAC8
  33 %define BU 0x3838
  34 %define RV 0x3838
  35 %define GV 0xD0E3
  36 %define BV 0xF6E4
  37
  38 rgb_Yrnd:        times 4 dd 0x84000        ;  16.5 << 15
  39 rgb_UVrnd:       times 4 dd 0x404000       ; 128.5 << 15
  40 bgr_Ycoeff_12x4: times 2 dw BY, GY, 0, BY
  41 bgr_Ycoeff_3x56: times 2 dw RY, 0, GY, RY
  42 rgb_Ycoeff_12x4: times 2 dw RY, GY, 0, RY
  43 rgb_Ycoeff_3x56: times 2 dw BY, 0, GY, BY
  44 bgr_Ucoeff_12x4: times 2 dw BU, GU, 0, BU
  45 bgr_Ucoeff_3x56: times 2 dw RU, 0, GU, RU
  46 rgb_Ucoeff_12x4: times 2 dw RU, GU, 0, RU
  47 rgb_Ucoeff_3x56: times 2 dw BU, 0, GU, BU
  48 bgr_Vcoeff_12x4: times 2 dw BV, GV, 0, BV
  49 bgr_Vcoeff_3x56: times 2 dw RV, 0, GV, RV
  50 rgb_Vcoeff_12x4: times 2 dw RV, GV, 0, RV
  51 rgb_Vcoeff_3x56: times 2 dw BV, 0, GV, BV
  52
  53 rgba_Ycoeff_rb:  times 4 dw RY, BY
  54 rgba_Ycoeff_br:  times 4 dw BY, RY
  55 rgba_Ycoeff_ga:  times 4 dw GY, 0
  56 rgba_Ycoeff_ag:  times 4 dw 0,  GY
  57 rgba_Ucoeff_rb:  times 4 dw RU, BU
  58 rgba_Ucoeff_br:  times 4 dw BU, RU
  59 rgba_Ucoeff_ga:  times 4 dw GU, 0
  60 rgba_Ucoeff_ag:  times 4 dw 0,  GU
  61 rgba_Vcoeff_rb:  times 4 dw RV, BV
  62 rgba_Vcoeff_br:  times 4 dw BV, RV
  63 rgba_Vcoeff_ga:  times 4 dw GV, 0
  64 rgba_Vcoeff_ag:  times 4 dw 0,  GV
  65
  66 shuf_rgb_12x4:   db 0, 0x80, 1, 0x80,  2, 0x80,  3, 0x80, \
  67                     6, 0x80, 7, 0x80,  8, 0x80,  9, 0x80
  68 shuf_rgb_3x56:   db 2, 0x80, 3, 0x80,  4, 0x80,  5, 0x80, \
  69                     8, 0x80, 9, 0x80, 10, 0x80, 11, 0x80
  70
  71 SECTION .text
  72
  73 ;-----------------------------------------------------------------------------
  74 ; RGB to Y/UV.
  75 ;
  76 ; void <fmt>ToY_<opt>(uint8_t *dst, const uint8_t *src, int w);
  77 ; and
  78 ; void <fmt>toUV_<opt>(uint8_t *dstU, uint8_t *dstV, const uint8_t *src,
  79 ;                      const uint8_t *unused, int w);
  80 ;-----------------------------------------------------------------------------
  81
  82 ; %1 = nr. of XMM registers
  83 ; %2 = rgb or bgr
  84 %macro RGB24_TO_Y_FN 2-3
  85 cglobal %2 %+ 24ToY, 3, 3, %1, dst, src, w
  86 %if mmsize == 8
  87     mova           m5, [%2_Ycoeff_12x4]
  88     mova           m6, [%2_Ycoeff_3x56]
  89 %define coeff1 m5
  90 %define coeff2 m6
  91 %elif ARCH_X86_64
  92     mova           m8, [%2_Ycoeff_12x4]
  93     mova           m9, [%2_Ycoeff_3x56]
  94 %define coeff1 m8
  95 %define coeff2 m9
  96 %else ; x86-32 && mmsize == 16
  97 %define coeff1 [%2_Ycoeff_12x4]
  98 %define coeff2 [%2_Ycoeff_3x56]
  99 %endif ; x86-32/64 && mmsize == 8/16
 100 %if (ARCH_X86_64 || mmsize == 8) && %0 == 3
 101     jmp mangle(private_prefix %+ _ %+ %3 %+ 24ToY %+ SUFFIX).body
 102 %else ; (ARCH_X86_64 && %0 == 3) || mmsize == 8
 103 .body:
 104 %if cpuflag(ssse3)
 105     mova           m7, [shuf_rgb_12x4]
 106 %define shuf_rgb1 m7
 107 %if ARCH_X86_64
 108     mova          m10, [shuf_rgb_3x56]
 109 %define shuf_rgb2 m10
 110 %else ; x86-32
 111 %define shuf_rgb2 [shuf_rgb_3x56]
 112 %endif ; x86-32/64
 113 %endif ; cpuflag(ssse3)
 114 %if ARCH_X86_64
 115     movsxd         wq, wd
 116 %endif
 117     add          dstq, wq
 118     neg            wq
 119 %if notcpuflag(ssse3)
 120     pxor           m7, m7
 121 %endif ; !cpuflag(ssse3)
 122     mova           m4, [rgb_Yrnd]
 123 .loop:
 124 %if cpuflag(ssse3)
 125     movu           m0, [srcq+0]           ; (byte) { Bx, Gx, Rx }[0-3]
 126     movu           m2, [srcq+12]          ; (byte) { Bx, Gx, Rx }[4-7]
 127     pshufb         m1, m0, shuf_rgb2      ; (word) { R0, B1, G1, R1, R2, B3, G3, R3 }
 128     pshufb         m0, shuf_rgb1          ; (word) { B0, G0, R0, B1, B2, G2, R2, B3 }
 129     pshufb         m3, m2, shuf_rgb2      ; (word) { R4, B5, G5, R5, R6, B7, G7, R7 }
 130     pshufb         m2, shuf_rgb1          ; (word) { B4, G4, R4, B5, B6, G6, R6, B7 }
 131 %else ; !cpuflag(ssse3)
 132     movd           m0, [srcq+0]           ; (byte) { B0, G0, R0, B1 }
 133     movd           m1, [srcq+2]           ; (byte) { R0, B1, G1, R1 }
 134     movd           m2, [srcq+6]           ; (byte) { B2, G2, R2, B3 }
 135     movd           m3, [srcq+8]           ; (byte) { R2, B3, G3, R3 }
 136 %if mmsize == 16 ; i.e. sse2
 137     punpckldq      m0, m2                 ; (byte) { B0, G0, R0, B1, B2, G2, R2, B3 }
 138     punpckldq      m1, m3                 ; (byte) { R0, B1, G1, R1, R2, B3, G3, R3 }
 139     movd           m2, [srcq+12]          ; (byte) { B4, G4, R4, B5 }
 140     movd           m3, [srcq+14]          ; (byte) { R4, B5, G5, R5 }
 141     movd           m5, [srcq+18]          ; (byte) { B6, G6, R6, B7 }
 142     movd           m6, [srcq+20]          ; (byte) { R6, B7, G7, R7 }
 143     punpckldq      m2, m5                 ; (byte) { B4, G4, R4, B5, B6, G6, R6, B7 }
 144     punpckldq      m3, m6                 ; (byte) { R4, B5, G5, R5, R6, B7, G7, R7 }
 145 %endif ; mmsize == 16
 146     punpcklbw      m0, m7                 ; (word) { B0, G0, R0, B1, B2, G2, R2, B3 }
 147     punpcklbw      m1, m7                 ; (word) { R0, B1, G1, R1, R2, B3, G3, R3 }
 148     punpcklbw      m2, m7                 ; (word) { B4, G4, R4, B5, B6, G6, R6, B7 }
 149     punpcklbw      m3, m7                 ; (word) { R4, B5, G5, R5, R6, B7, G7, R7 }
 150 %endif ; cpuflag(ssse3)
 151     add          srcq, 3 * mmsize / 2
 152     pmaddwd        m0, coeff1             ; (dword) { B0*BY + G0*GY, B1*BY, B2*BY + G2*GY, B3*BY }
 153     pmaddwd        m1, coeff2             ; (dword) { R0*RY, G1+GY + R1*RY, R2*RY, G3+GY + R3*RY }
 154     pmaddwd        m2, coeff1             ; (dword) { B4*BY + G4*GY, B5*BY, B6*BY + G6*GY, B7*BY }
 155     pmaddwd        m3, coeff2             ; (dword) { R4*RY, G5+GY + R5*RY, R6*RY, G7+GY + R7*RY }
 156     paddd          m0, m1                 ; (dword) { Bx*BY + Gx*GY + Rx*RY }[0-3]
 157     paddd          m2, m3                 ; (dword) { Bx*BY + Gx*GY + Rx*RY }[4-7]
 158     paddd          m0, m4                 ; += rgb_Yrnd, i.e. (dword) { Y[0-3] }
 159     paddd          m2, m4                 ; += rgb_Yrnd, i.e. (dword) { Y[4-7] }
 160     psrad          m0, 15
 161     psrad          m2, 15
 162     packssdw       m0, m2                 ; (word) { Y[0-7] }
 163     packuswb       m0, m0                 ; (byte) { Y[0-7] }
 164     movh    [dstq+wq], m0
 165     add            wq, mmsize / 2
 166     jl .loop
 167     REP_RET
 168 %endif ; (ARCH_X86_64 && %0 == 3) || mmsize == 8
 169 %endmacro
 170
 171 ; %1 = nr. of XMM registers
 172 ; %2 = rgb or bgr
 173 %macro RGB24_TO_UV_FN 2-3
 174 cglobal %2 %+ 24ToUV, 3, 4, %1, dstU, dstV, src, w
 175 %if ARCH_X86_64
 176     mova           m8, [%2_Ucoeff_12x4]
 177     mova           m9, [%2_Ucoeff_3x56]
 178     mova          m10, [%2_Vcoeff_12x4]
 179     mova          m11, [%2_Vcoeff_3x56]
 180 %define coeffU1 m8
 181 %define coeffU2 m9
 182 %define coeffV1 m10
 183 %define coeffV2 m11
 184 %else ; x86-32
 185 %define coeffU1 [%2_Ucoeff_12x4]
 186 %define coeffU2 [%2_Ucoeff_3x56]
 187 %define coeffV1 [%2_Vcoeff_12x4]
 188 %define coeffV2 [%2_Vcoeff_3x56]
 189 %endif ; x86-32/64
 190 %if ARCH_X86_64 && %0 == 3
 191     jmp mangle(private_prefix %+ _ %+ %3 %+ 24ToUV %+ SUFFIX).body
 192 %else ; ARCH_X86_64 && %0 == 3
 193 .body:
 194 %if cpuflag(ssse3)
 195     mova           m7, [shuf_rgb_12x4]
 196 %define shuf_rgb1 m7
 197 %if ARCH_X86_64
 198     mova          m12, [shuf_rgb_3x56]
 199 %define shuf_rgb2 m12
 200 %else ; x86-32
 201 %define shuf_rgb2 [shuf_rgb_3x56]
 202 %endif ; x86-32/64
 203 %endif ; cpuflag(ssse3)
 204 %if ARCH_X86_64
 205     movsxd         wq, dword r4m
 206 %else ; x86-32
 207     mov            wq, r4m
 208 %endif
 209     add         dstUq, wq
 210     add         dstVq, wq
 211     neg            wq
 212     mova           m6, [rgb_UVrnd]
 213 %if notcpuflag(ssse3)
 214     pxor           m7, m7
 215 %endif
 216 .loop:
 217 %if cpuflag(ssse3)
 218     movu           m0, [srcq+0]           ; (byte) { Bx, Gx, Rx }[0-3]
 219     movu           m4, [srcq+12]          ; (byte) { Bx, Gx, Rx }[4-7]
 220     pshufb         m1, m0, shuf_rgb2      ; (word) { R0, B1, G1, R1, R2, B3, G3, R3 }
 221     pshufb         m0, shuf_rgb1          ; (word) { B0, G0, R0, B1, B2, G2, R2, B3 }
 222 %else ; !cpuflag(ssse3)
 223     movd           m0, [srcq+0]           ; (byte) { B0, G0, R0, B1 }
 224     movd           m1, [srcq+2]           ; (byte) { R0, B1, G1, R1 }
 225     movd           m4, [srcq+6]           ; (byte) { B2, G2, R2, B3 }
 226     movd           m5, [srcq+8]           ; (byte) { R2, B3, G3, R3 }
 227 %if mmsize == 16
 228     punpckldq      m0, m4                 ; (byte) { B0, G0, R0, B1, B2, G2, R2, B3 }
 229     punpckldq      m1, m5                 ; (byte) { R0, B1, G1, R1, R2, B3, G3, R3 }
 230     movd           m4, [srcq+12]          ; (byte) { B4, G4, R4, B5 }
 231     movd           m5, [srcq+14]          ; (byte) { R4, B5, G5, R5 }
 232 %endif ; mmsize == 16
 233     punpcklbw      m0, m7                 ; (word) { B0, G0, R0, B1, B2, G2, R2, B3 }
 234     punpcklbw      m1, m7                 ; (word) { R0, B1, G1, R1, R2, B3, G3, R3 }
 235 %endif ; cpuflag(ssse3)
 236     pmaddwd        m2, m0, coeffV1        ; (dword) { B0*BV + G0*GV, B1*BV, B2*BV + G2*GV, B3*BV }
 237     pmaddwd        m3, m1, coeffV2        ; (dword) { R0*BV, G1*GV + R1*BV, R2*BV, G3*GV + R3*BV }
 238     pmaddwd        m0, coeffU1            ; (dword) { B0*BU + G0*GU, B1*BU, B2*BU + G2*GU, B3*BU }
 239     pmaddwd        m1, coeffU2            ; (dword) { R0*BU, G1*GU + R1*BU, R2*BU, G3*GU + R3*BU }
 240     paddd          m0, m1                 ; (dword) { Bx*BU + Gx*GU + Rx*RU }[0-3]
 241     paddd          m2, m3                 ; (dword) { Bx*BV + Gx*GV + Rx*RV }[0-3]
 242 %if cpuflag(ssse3)
 243     pshufb         m5, m4, shuf_rgb2      ; (word) { R4, B5, G5, R5, R6, B7, G7, R7 }
 244     pshufb         m4, shuf_rgb1          ; (word) { B4, G4, R4, B5, B6, G6, R6, B7 }
 245 %else ; !cpuflag(ssse3)
 246 %if mmsize == 16
 247     movd           m1, [srcq+18]          ; (byte) { B6, G6, R6, B7 }
 248     movd           m3, [srcq+20]          ; (byte) { R6, B7, G7, R7 }
 249     punpckldq      m4, m1                 ; (byte) { B4, G4, R4, B5, B6, G6, R6, B7 }
 250     punpckldq      m5, m3                 ; (byte) { R4, B5, G5, R5, R6, B7, G7, R7 }
 251 %endif ; mmsize == 16 && !cpuflag(ssse3)
 252     punpcklbw      m4, m7                 ; (word) { B4, G4, R4, B5, B6, G6, R6, B7 }
 253     punpcklbw      m5, m7                 ; (word) { R4, B5, G5, R5, R6, B7, G7, R7 }
 254 %endif ; cpuflag(ssse3)
 255     add          srcq, 3 * mmsize / 2
 256     pmaddwd        m1, m4, coeffU1        ; (dword) { B4*BU + G4*GU, B5*BU, B6*BU + G6*GU, B7*BU }
 257     pmaddwd        m3, m5, coeffU2        ; (dword) { R4*BU, G5*GU + R5*BU, R6*BU, G7*GU + R7*BU }
 258     pmaddwd        m4, coeffV1            ; (dword) { B4*BV + G4*GV, B5*BV, B6*BV + G6*GV, B7*BV }
 259     pmaddwd        m5, coeffV2            ; (dword) { R4*BV, G5*GV + R5*BV, R6*BV, G7*GV + R7*BV }
 260     paddd          m1, m3                 ; (dword) { Bx*BU + Gx*GU + Rx*RU }[4-7]
 261     paddd          m4, m5                 ; (dword) { Bx*BV + Gx*GV + Rx*RV }[4-7]
 262     paddd          m0, m6                 ; += rgb_UVrnd, i.e. (dword) { U[0-3] }
 263     paddd          m2, m6                 ; += rgb_UVrnd, i.e. (dword) { V[0-3] }
 264     paddd          m1, m6                 ; += rgb_UVrnd, i.e. (dword) { U[4-7] }
 265     paddd          m4, m6                 ; += rgb_UVrnd, i.e. (dword) { V[4-7] }
 266     psrad          m0, 15
 267     psrad          m2, 15
 268     psrad          m1, 15
 269     psrad          m4, 15
 270     packssdw       m0, m1                 ; (word) { U[0-7] }
 271     packssdw       m2, m4                 ; (word) { V[0-7] }
 272 %if mmsize == 8
 273     packuswb       m0, m0                 ; (byte) { U[0-3] }
 274     packuswb       m2, m2                 ; (byte) { V[0-3] }
 275     movh   [dstUq+wq], m0
 276     movh   [dstVq+wq], m2
 277 %else ; mmsize == 16
 278     packuswb       m0, m2                 ; (byte) { U[0-7], V[0-7] }
 279     movh   [dstUq+wq], m0
 280     movhps [dstVq+wq], m0
 281 %endif ; mmsize == 8/16
 282     add            wq, mmsize / 2
 283     jl .loop
 284     REP_RET
 285 %endif ; ARCH_X86_64 && %0 == 3
 286 %endmacro
 287
 288 ; %1 = nr. of XMM registers for rgb-to-Y func
 289 ; %2 = nr. of XMM registers for rgb-to-UV func
 290 %macro RGB24_FUNCS 2
 291 RGB24_TO_Y_FN %1, rgb
 292 RGB24_TO_Y_FN %1, bgr, rgb
 293 RGB24_TO_UV_FN %2, rgb
 294 RGB24_TO_UV_FN %2, bgr, rgb
 295 %endmacro
 296
 297 %if ARCH_X86_32
 298 INIT_MMX mmx
 299 RGB24_FUNCS 0, 0
 300 %endif
 301
 302 INIT_XMM sse2
 303 RGB24_FUNCS 10, 12
 304
 305 INIT_XMM ssse3
 306 RGB24_FUNCS 11, 13
 307
 308 INIT_XMM avx
 309 RGB24_FUNCS 11, 13
 310
 311 ; %1 = nr. of XMM registers
 312 ; %2-5 = rgba, bgra, argb or abgr (in individual characters)
 313 %macro RGB32_TO_Y_FN 5-6
 314 cglobal %2%3%4%5 %+ ToY, 3, 3, %1, dst, src, w
 315     mova           m5, [rgba_Ycoeff_%2%4]
 316     mova           m6, [rgba_Ycoeff_%3%5]
 317 %if %0 == 6
 318     jmp mangle(private_prefix %+ _ %+ %6 %+ ToY %+ SUFFIX).body
 319 %else ; %0 == 6
 320 .body:
 321 %if ARCH_X86_64
 322     movsxd         wq, wd
 323 %endif
 324     lea          srcq, [srcq+wq*4]
 325     add          dstq, wq
 326     neg            wq
 327     mova           m4, [rgb_Yrnd]
 328     pcmpeqb        m7, m7
 329     psrlw          m7, 8                  ; (word) { 0x00ff } x4
 330 .loop:
 331     ; FIXME check alignment and use mova
 332     movu           m0, [srcq+wq*4+0]      ; (byte) { Bx, Gx, Rx, xx }[0-3]
 333     movu           m2, [srcq+wq*4+mmsize] ; (byte) { Bx, Gx, Rx, xx }[4-7]
 334     DEINTB          1,  0,  3,  2,  7     ; (word) { Gx, xx (m0/m2) or Bx, Rx (m1/m3) }[0-3]/[4-7]
 335     pmaddwd        m1, m5                 ; (dword) { Bx*BY + Rx*RY }[0-3]
 336     pmaddwd        m0, m6                 ; (dword) { Gx*GY }[0-3]
 337     pmaddwd        m3, m5                 ; (dword) { Bx*BY + Rx*RY }[4-7]
 338     pmaddwd        m2, m6                 ; (dword) { Gx*GY }[4-7]
 339     paddd          m0, m4                 ; += rgb_Yrnd
 340     paddd          m2, m4                 ; += rgb_Yrnd
 341     paddd          m0, m1                 ; (dword) { Y[0-3] }
 342     paddd          m2, m3                 ; (dword) { Y[4-7] }
 343     psrad          m0, 15
 344     psrad          m2, 15
 345     packssdw       m0, m2                 ; (word) { Y[0-7] }
 346     packuswb       m0, m0                 ; (byte) { Y[0-7] }
 347     movh    [dstq+wq], m0
 348     add            wq, mmsize / 2
 349     jl .loop
 350     REP_RET
 351 %endif ; %0 == 3
 352 %endmacro
 353
 354 ; %1 = nr. of XMM registers
 355 ; %2-5 = rgba, bgra, argb or abgr (in individual characters)
 356 %macro RGB32_TO_UV_FN 5-6
 357 cglobal %2%3%4%5 %+ ToUV, 3, 4, %1, dstU, dstV, src, w
 358 %if ARCH_X86_64
 359     mova           m8, [rgba_Ucoeff_%2%4]
 360     mova           m9, [rgba_Ucoeff_%3%5]
 361     mova          m10, [rgba_Vcoeff_%2%4]
 362     mova          m11, [rgba_Vcoeff_%3%5]
 363 %define coeffU1 m8
 364 %define coeffU2 m9
 365 %define coeffV1 m10
 366 %define coeffV2 m11
 367 %else ; x86-32
 368 %define coeffU1 [rgba_Ucoeff_%2%4]
 369 %define coeffU2 [rgba_Ucoeff_%3%5]
 370 %define coeffV1 [rgba_Vcoeff_%2%4]
 371 %define coeffV2 [rgba_Vcoeff_%3%5]
 372 %endif ; x86-64/32
 373 %if ARCH_X86_64 && %0 == 6
 374     jmp mangle(private_prefix %+ _ %+ %6 %+ ToUV %+ SUFFIX).body
 375 %else ; ARCH_X86_64 && %0 == 6
 376 .body:
 377 %if ARCH_X86_64
 378     movsxd         wq, dword r4m
 379 %else ; x86-32
 380     mov            wq, r4m
 381 %endif
 382     add         dstUq, wq
 383     add         dstVq, wq
 384     lea          srcq, [srcq+wq*4]
 385     neg            wq
 386     pcmpeqb        m7, m7
 387     psrlw          m7, 8                  ; (word) { 0x00ff } x4
 388     mova           m6, [rgb_UVrnd]
 389 .loop:
 390     ; FIXME check alignment and use mova
 391     movu           m0, [srcq+wq*4+0]      ; (byte) { Bx, Gx, Rx, xx }[0-3]
 392     movu           m4, [srcq+wq*4+mmsize] ; (byte) { Bx, Gx, Rx, xx }[4-7]
 393     DEINTB          1,  0,  5,  4,  7     ; (word) { Gx, xx (m0/m4) or Bx, Rx (m1/m5) }[0-3]/[4-7]
 394     pmaddwd        m3, m1, coeffV1        ; (dword) { Bx*BV + Rx*RV }[0-3]
 395     pmaddwd        m2, m0, coeffV2        ; (dword) { Gx*GV }[0-3]
 396     pmaddwd        m1, coeffU1            ; (dword) { Bx*BU + Rx*RU }[0-3]
 397     pmaddwd        m0, coeffU2            ; (dword) { Gx*GU }[0-3]
 398     paddd          m3, m6                 ; += rgb_UVrnd
 399     paddd          m1, m6                 ; += rgb_UVrnd
 400     paddd          m2, m3                 ; (dword) { V[0-3] }
 401     paddd          m0, m1                 ; (dword) { U[0-3] }
 402     pmaddwd        m3, m5, coeffV1        ; (dword) { Bx*BV + Rx*RV }[4-7]
 403     pmaddwd        m1, m4, coeffV2        ; (dword) { Gx*GV }[4-7]
 404     pmaddwd        m5, coeffU1            ; (dword) { Bx*BU + Rx*RU }[4-7]
 405     pmaddwd        m4, coeffU2            ; (dword) { Gx*GU }[4-7]
 406     paddd          m3, m6                 ; += rgb_UVrnd
 407     paddd          m5, m6                 ; += rgb_UVrnd
 408     psrad          m0, 15
 409     paddd          m1, m3                 ; (dword) { V[4-7] }
 410     paddd          m4, m5                 ; (dword) { U[4-7] }
 411     psrad          m2, 15
 412     psrad          m4, 15
 413     psrad          m1, 15
 414     packssdw       m0, m4                 ; (word) { U[0-7] }
 415     packssdw       m2, m1                 ; (word) { V[0-7] }
 416 %if mmsize == 8
 417     packuswb       m0, m0                 ; (byte) { U[0-7] }
 418     packuswb       m2, m2                 ; (byte) { V[0-7] }
 419     movh   [dstUq+wq], m0
 420     movh   [dstVq+wq], m2
 421 %else ; mmsize == 16
 422     packuswb       m0, m2                 ; (byte) { U[0-7], V[0-7] }
 423     movh   [dstUq+wq], m0
 424     movhps [dstVq+wq], m0
 425 %endif ; mmsize == 8/16
 426     add            wq, mmsize / 2
 427     jl .loop
 428     REP_RET
 429 %endif ; ARCH_X86_64 && %0 == 3
 430 %endmacro
 431
 432 ; %1 = nr. of XMM registers for rgb-to-Y func
 433 ; %2 = nr. of XMM registers for rgb-to-UV func
 434 %macro RGB32_FUNCS 2
 435 RGB32_TO_Y_FN %1, r, g, b, a
 436 RGB32_TO_Y_FN %1, b, g, r, a, rgba
 437 RGB32_TO_Y_FN %1, a, r, g, b, rgba
 438 RGB32_TO_Y_FN %1, a, b, g, r, rgba
 439
 440 RGB32_TO_UV_FN %2, r, g, b, a
 441 RGB32_TO_UV_FN %2, b, g, r, a, rgba
 442 RGB32_TO_UV_FN %2, a, r, g, b, rgba
 443 RGB32_TO_UV_FN %2, a, b, g, r, rgba
 444 %endmacro
 445
 446 %if ARCH_X86_32
 447 INIT_MMX mmx
 448 RGB32_FUNCS 0, 0
 449 %endif
 450
 451 INIT_XMM sse2
 452 RGB32_FUNCS 8, 12
 453
 454 INIT_XMM avx
 455 RGB32_FUNCS 8, 12
 456
 457 ;-----------------------------------------------------------------------------
 458 ; YUYV/UYVY/NV12/NV21 packed pixel shuffling.
 459 ;
 460 ; void <fmt>ToY_<opt>(uint8_t *dst, const uint8_t *src, int w);
 461 ; and
 462 ; void <fmt>toUV_<opt>(uint8_t *dstU, uint8_t *dstV, const uint8_t *src,
 463 ;                      const uint8_t *unused, int w);
 464 ;-----------------------------------------------------------------------------
 465
 466 ; %1 = a (aligned) or u (unaligned)
 467 ; %2 = yuyv or uyvy
 468 %macro LOOP_YUYV_TO_Y 2
 469 .loop_%1:
 470     mov%1          m0, [srcq+wq*2]        ; (byte) { Y0, U0, Y1, V0, ... }
 471     mov%1          m1, [srcq+wq*2+mmsize] ; (byte) { Y8, U4, Y9, V4, ... }
 472 %ifidn %2, yuyv
 473     pand           m0, m2                 ; (word) { Y0, Y1, ..., Y7 }
 474     pand           m1, m2                 ; (word) { Y8, Y9, ..., Y15 }
 475 %else ; uyvy
 476     psrlw          m0, 8                  ; (word) { Y0, Y1, ..., Y7 }
 477     psrlw          m1, 8                  ; (word) { Y8, Y9, ..., Y15 }
 478 %endif ; yuyv/uyvy
 479     packuswb       m0, m1                 ; (byte) { Y0, ..., Y15 }
 480     mova    [dstq+wq], m0
 481     add            wq, mmsize
 482     jl .loop_%1
 483     REP_RET
 484 %endmacro
 485
 486 ; %1 = nr. of XMM registers
 487 ; %2 = yuyv or uyvy
 488 ; %3 = if specified, it means that unaligned and aligned code in loop
 489 ;      will be the same (i.e. YUYV+AVX), and thus we don't need to
 490 ;      split the loop in an aligned and unaligned case
 491 %macro YUYV_TO_Y_FN 2-3
 492 cglobal %2ToY, 3, 3, %1, dst, src, w
 493 %if ARCH_X86_64
 494     movsxd         wq, wd
 495 %endif
 496     add          dstq, wq
 497 %if mmsize == 16
 498     test         srcq, 15
 499 %endif
 500     lea          srcq, [srcq+wq*2]
 501 %ifidn %2, yuyv
 502     pcmpeqb        m2, m2                 ; (byte) { 0xff } x 16
 503     psrlw          m2, 8                  ; (word) { 0x00ff } x 8
 504 %endif ; yuyv
 505 %if mmsize == 16
 506     jnz .loop_u_start
 507     neg            wq
 508     LOOP_YUYV_TO_Y  a, %2
 509 .loop_u_start:
 510     neg            wq
 511     LOOP_YUYV_TO_Y  u, %2
 512 %else ; mmsize == 8
 513     neg            wq
 514     LOOP_YUYV_TO_Y  a, %2
 515 %endif ; mmsize == 8/16
 516 %endmacro
 517
 518 ; %1 = a (aligned) or u (unaligned)
 519 ; %2 = yuyv or uyvy
 520 %macro LOOP_YUYV_TO_UV 2
 521 .loop_%1:
 522 %ifidn %2, yuyv
 523     mov%1          m0, [srcq+wq*4]        ; (byte) { Y0, U0, Y1, V0, ... }
 524     mov%1          m1, [srcq+wq*4+mmsize] ; (byte) { Y8, U4, Y9, V4, ... }
 525     psrlw          m0, 8                  ; (word) { U0, V0, ..., U3, V3 }
 526     psrlw          m1, 8                  ; (word) { U4, V4, ..., U7, V7 }
 527 %else ; uyvy
 528 %if cpuflag(avx)
 529     vpand          m0, m2, [srcq+wq*4]        ; (word) { U0, V0, ..., U3, V3 }
 530     vpand          m1, m2, [srcq+wq*4+mmsize] ; (word) { U4, V4, ..., U7, V7 }
 531 %else
 532     mov%1          m0, [srcq+wq*4]        ; (byte) { Y0, U0, Y1, V0, ... }
 533     mov%1          m1, [srcq+wq*4+mmsize] ; (byte) { Y8, U4, Y9, V4, ... }
 534     pand           m0, m2                 ; (word) { U0, V0, ..., U3, V3 }
 535     pand           m1, m2                 ; (word) { U4, V4, ..., U7, V7 }
 536 %endif
 537 %endif ; yuyv/uyvy
 538     packuswb       m0, m1                 ; (byte) { U0, V0, ..., U7, V7 }
 539     pand           m1, m0, m2             ; (word) { U0, U1, ..., U7 }
 540     psrlw          m0, 8                  ; (word) { V0, V1, ..., V7 }
 541 %if mmsize == 16
 542     packuswb       m1, m0                 ; (byte) { U0, ... U7, V1, ... V7 }
 543     movh   [dstUq+wq], m1
 544     movhps [dstVq+wq], m1
 545 %else ; mmsize == 8
 546     packuswb       m1, m1                 ; (byte) { U0, ... U3 }
 547     packuswb       m0, m0                 ; (byte) { V0, ... V3 }
 548     movh   [dstUq+wq], m1
 549     movh   [dstVq+wq], m0
 550 %endif ; mmsize == 8/16
 551     add            wq, mmsize / 2
 552     jl .loop_%1
 553     REP_RET
 554 %endmacro
 555
 556 ; %1 = nr. of XMM registers
 557 ; %2 = yuyv or uyvy
 558 ; %3 = if specified, it means that unaligned and aligned code in loop
 559 ;      will be the same (i.e. UYVY+AVX), and thus we don't need to
 560 ;      split the loop in an aligned and unaligned case
 561 %macro YUYV_TO_UV_FN 2-3
 562 cglobal %2ToUV, 3, 4, %1, dstU, dstV, src, w
 563 %if ARCH_X86_64
 564     movsxd         wq, dword r4m
 565 %else ; x86-32
 566     mov            wq, r4m
 567 %endif
 568     add         dstUq, wq
 569     add         dstVq, wq
 570 %if mmsize == 16 && %0 == 2
 571     test         srcq, 15
 572 %endif
 573     lea          srcq, [srcq+wq*4]
 574     pcmpeqb        m2, m2                 ; (byte) { 0xff } x 16
 575     psrlw          m2, 8                  ; (word) { 0x00ff } x 8
 576     ; NOTE: if uyvy+avx, u/a are identical
 577 %if mmsize == 16 && %0 == 2
 578     jnz .loop_u_start
 579     neg            wq
 580     LOOP_YUYV_TO_UV a, %2
 581 .loop_u_start:
 582     neg            wq
 583     LOOP_YUYV_TO_UV u, %2
 584 %else ; mmsize == 8
 585     neg            wq
 586     LOOP_YUYV_TO_UV a, %2
 587 %endif ; mmsize == 8/16
 588 %endmacro
 589
 590 ; %1 = a (aligned) or u (unaligned)
 591 ; %2 = nv12 or nv21
 592 %macro LOOP_NVXX_TO_UV 2
 593 .loop_%1:
 594     mov%1          m0, [srcq+wq*2]        ; (byte) { U0, V0, U1, V1, ... }
 595     mov%1          m1, [srcq+wq*2+mmsize] ; (byte) { U8, V8, U9, V9, ... }
 596     pand           m2, m0, m4             ; (word) { U0, U1, ..., U7 }
 597     pand           m3, m1, m4             ; (word) { U8, U9, ..., U15 }
 598     psrlw          m0, 8                  ; (word) { V0, V1, ..., V7 }
 599     psrlw          m1, 8                  ; (word) { V8, V9, ..., V15 }
 600     packuswb       m2, m3                 ; (byte) { U0, ..., U15 }
 601     packuswb       m0, m1                 ; (byte) { V0, ..., V15 }
 602 %ifidn %2, nv12
 603     mova   [dstUq+wq], m2
 604     mova   [dstVq+wq], m0
 605 %else ; nv21
 606     mova   [dstVq+wq], m2
 607     mova   [dstUq+wq], m0
 608 %endif ; nv12/21
 609     add            wq, mmsize
 610     jl .loop_%1
 611     REP_RET
 612 %endmacro
 613
 614 ; %1 = nr. of XMM registers
 615 ; %2 = nv12 or nv21
 616 %macro NVXX_TO_UV_FN 2
 617 cglobal %2ToUV, 3, 4, %1, dstU, dstV, src, w
 618 %if ARCH_X86_64
 619     movsxd         wq, dword r4m
 620 %else ; x86-32
 621     mov            wq, r4m
 622 %endif
 623     add         dstUq, wq
 624     add         dstVq, wq
 625 %if mmsize == 16
 626     test         srcq, 15
 627 %endif
 628     lea          srcq, [srcq+wq*2]
 629     pcmpeqb        m4, m4                 ; (byte) { 0xff } x 16
 630     psrlw          m4, 8                  ; (word) { 0x00ff } x 8
 631 %if mmsize == 16
 632     jnz .loop_u_start
 633     neg            wq
 634     LOOP_NVXX_TO_UV a, %2
 635 .loop_u_start:
 636     neg            wq
 637     LOOP_NVXX_TO_UV u, %2
 638 %else ; mmsize == 8
 639     neg            wq
 640     LOOP_NVXX_TO_UV a, %2
 641 %endif ; mmsize == 8/16
 642 %endmacro
 643
 644 %if ARCH_X86_32
 645 INIT_MMX mmx
 646 YUYV_TO_Y_FN  0, yuyv
 647 YUYV_TO_Y_FN  0, uyvy
 648 YUYV_TO_UV_FN 0, yuyv
 649 YUYV_TO_UV_FN 0, uyvy
 650 NVXX_TO_UV_FN 0, nv12
 651 NVXX_TO_UV_FN 0, nv21
 652 %endif
 653
 654 INIT_XMM sse2
 655 YUYV_TO_Y_FN  3, yuyv
 656 YUYV_TO_Y_FN  2, uyvy
 657 YUYV_TO_UV_FN 3, yuyv
 658 YUYV_TO_UV_FN 3, uyvy
 659 NVXX_TO_UV_FN 5, nv12
 660 NVXX_TO_UV_FN 5, nv21
 661
 662 INIT_XMM avx
 663 ; in theory, we could write a yuy2-to-y using vpand (i.e. AVX), but
 664 ; that's not faster in practice
 665 YUYV_TO_UV_FN 3, yuyv
 666 YUYV_TO_UV_FN 3, uyvy, 1
 667 NVXX_TO_UV_FN 5, nv12
 668 NVXX_TO_UV_FN 5, nv21