git.sesse.net Git - nageru/blob - meson.build

   1 project('nageru', 'cpp', default_options: ['buildtype=debugoptimized'], version: '2.0.1')
   2
   3 cxx = meson.get_compiler('cpp')
   4 qt5 = import('qt5')
   5 protoc = find_program('protoc')
   6
   7 embedded_bmusb = get_option('embedded_bmusb')
   8
   9 alsadep = dependency('alsa')
  10 bmusbdep = dependency('bmusb', required: not embedded_bmusb)
  11 dldep = cxx.find_library('dl')
  12 eigendep = dependency('eigen3')
  13 epoxydep = dependency('epoxy')
  14 libavcodecdep = dependency('libavcodec')
  15 libavformatdep = dependency('libavformat')
  16 libswresampledep = dependency('libswresample')
  17 libavutildep = dependency('libavutil')
  18 libjpegdep = dependency('libjpeg')
  19 libswscaledep = dependency('libswscale')
  20 libusbdep = dependency('libusb-1.0')
  21 luajitdep = dependency('luajit')
  22 movitdep = dependency('movit')
  23 protobufdep = dependency('protobuf')
  24 qcustomplotdep = cxx.find_library('qcustomplot')
  25 qt5deps = dependency('qt5', modules: ['Core', 'Gui', 'Widgets', 'OpenGLExtensions', 'OpenGL', 'Network'])
  26 sdl2_imagedep = dependency('SDL2_image', required: false)
  27 sdl2dep = dependency('sdl2', required: false)
  28 srtdep = dependency('srt', required: false)
  29 sqlite3dep = dependency('sqlite3')
  30 threaddep = dependency('threads')
  31 vadrmdep = dependency('libva-drm')
  32 vax11dep = dependency('libva-x11')
  33 x11dep = dependency('x11')
  34 x264dep = dependency('x264')
  35 zitaresamplerdep = cxx.find_library('zita-resampler')
  36
  37 # Use lld if we can; it links a lot faster than ld.bfd or gold.
  38 code = '''#include <stdio.h>
  39 int main() { printf("Hello, world!\n"); return 0; }
  40 '''
  41 if cxx.links(code, args: '-fuse-ld=lld', name: 'check for LLD')
  42         add_project_link_arguments('-fuse-ld=lld', language: 'cpp')
  43 endif
  44
  45 # Add the right MOVIT_SHADER_DIR definition.
  46 movit_shader_dir = movitdep.get_pkgconfig_variable('shaderdir')
  47 add_project_arguments('-DMOVIT_SHADER_DIR="' + movit_shader_dir + '"', language: 'cpp')
  48
  49 # Make the Nageru version available as a #define.
  50 add_project_arguments('-DNAGERU_VERSION="' + meson.project_version() + '"', language: 'cpp')
  51
  52 # Make the prefix (e.g. /usr/local) available as a #define.
  53 add_project_arguments('-DPREFIX="' + get_option('prefix') + '"', language: 'cpp')
  54
  55 # This needs to be done before declaring any build targets.
  56 if get_option('cef_dir') != ''
  57         add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  58 endif
  59
  60 if srtdep.found()
  61         # NOTE: Seemingly there's no way to figure out if we have OpenSSL libsrt
  62         # or gnutls libsrt, so we cannot check license compatibility here.
  63         add_project_arguments('-DHAVE_SRT=1', language: 'cpp')
  64 endif
  65
  66 top_include = include_directories('.')
  67
  68 subdir('shared')
  69
  70 # Nageru. (Not a subdir() because we don't want the output in nageru/nageru.)
  71
  72 nageru_srcs = []
  73 nageru_deps = [shareddep, qt5deps, libjpegdep, movitdep, protobufdep,
  74         vax11dep, vadrmdep, x11dep, libavformatdep, libswresampledep, libavcodecdep, libavutildep,
  75         libswscaledep, libusbdep, luajitdep, dldep, x264dep, alsadep, zitaresamplerdep,
  76         qcustomplotdep, threaddep, eigendep, srtdep]
  77 nageru_include_dirs = [include_directories('nageru')]
  78 nageru_link_with = []
  79 nageru_build_rpath = ''
  80 nageru_install_rpath = ''
  81
  82 kaeru_link_with = []
  83 kaeru_extra_deps = []
  84
  85 # CEF.
  86 exe_dir = join_paths(get_option('prefix'), 'lib/nageru')
  87 cef_dir = get_option('cef_dir')
  88 cef_build_type = get_option('cef_build_type')
  89 have_cef = (cef_dir != '')
  90 if have_cef
  91         # This is done in the top-level file; just kept here for reference.
  92         # add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  93
  94         system_cef = (cef_build_type == 'system')
  95         if system_cef
  96                 cef_lib_dir = cef_dir
  97                 cef_resource_dir = cef_dir
  98         else
  99                 cef_lib_dir = join_paths(cef_dir, cef_build_type)
 100                 cef_resource_dir = join_paths(cef_dir, 'Resources')
 101
 102                 nageru_include_dirs += include_directories(cef_dir)
 103                 nageru_include_dirs += include_directories(join_paths(cef_dir, 'include'))
 104                 nageru_build_rpath = cef_lib_dir
 105                 nageru_install_rpath = '$ORIGIN/'
 106         endif
 107
 108         # CEF wrapper library; not built as part of the CEF binary distribution,
 109         # but should be if CEF is installed as a system library.
 110         if system_cef
 111                 cefdlldep = cxx.find_library('cef_dll_wrapper')
 112                 nageru_deps += cefdlldep
 113         else
 114                 cmake = find_program('cmake')
 115                 cef_compile_script = find_program('nageru/scripts/compile_cef_dll_wrapper.sh')
 116
 117                 cef_dll_target = custom_target('libcef_dll_wrapper',
 118                         input: join_paths(cef_dir, 'libcef_dll/CMakeLists.txt'),
 119                         output: ['libcef_dll_wrapper.a', 'cef-stamp'],
 120                         command: [cef_compile_script, '@BUILD_DIR@', cef_dir, cmake, '@OUTPUT@'])
 121
 122                 # Putting the .a in sources seemingly hits a bug where the .a files get sorted
 123                 # in the wrong order. This is a workaround; see
 124                 # https://github.com/mesonbuild/meson/issues/3613#issuecomment-408276296 .
 125                 cefdlldep = declare_dependency(sources: cef_dll_target[1], link_args: cef_dll_target.full_path())
 126                 nageru_deps += cefdlldep
 127         endif
 128
 129         cef_libs = ['libEGL.so', 'libGLESv2.so', 'snapshot_blob.bin', 'v8_context_snapshot.bin']
 130         cef_resources = ['cef.pak', 'cef_100_percent.pak', 'cef_200_percent.pak', 'cef_extensions.pak', 'devtools_resources.pak']
 131         if not get_option('cef_no_icudtl')
 132                 cef_resources += ['icudtl.dat']
 133         endif
 134         if cef_build_type != 'system'
 135                 cef_libs += ['libcef.so']
 136         endif
 137
 138         # Symlink the files into the build directory, so that running nageru without ninja install works.
 139         run_command('mkdir', join_paths(meson.current_build_dir(), 'locales/'))
 140         foreach file : cef_libs
 141                 run_command('ln', '-s', join_paths(cef_lib_dir, file), meson.current_build_dir())
 142                 install_data(join_paths(cef_lib_dir, file), install_dir: exe_dir)
 143         endforeach
 144         foreach file : cef_resources
 145                 run_command('ln', '-s', join_paths(cef_resource_dir, file), meson.current_build_dir())
 146                 install_data(join_paths(cef_resource_dir, file), install_dir: exe_dir)
 147         endforeach
 148         run_command('ln', '-s', join_paths(cef_resource_dir, 'locales/en-US.pak'), join_paths(meson.current_build_dir(), 'locales/'))
 149         install_data(join_paths(cef_resource_dir, 'locales/en-US.pak'), install_dir: join_paths(exe_dir, 'locales'))
 150
 151         # NOTE: We link against libcef.so in the local directory, _not_ in the CEF directory,
 152         # since upstream CEF searches for icudtl.dat in whatever path dladdr() says libcef.so
 153         # comes from, and the upstream CEF tarballs have libcef.so and icudtl.dat in different
 154         # directories. Thus, get both from the local symlinks we just created.
 155         cefdep = cxx.find_library('cef', dirs: meson.current_build_dir())
 156         nageru_deps += cefdep
 157 endif
 158
 159 # bmusb.
 160 if embedded_bmusb
 161         bmusb_dir = include_directories('nageru/bmusb')
 162         nageru_include_dirs += bmusb_dir
 163
 164         bmusb = static_library('bmusb', 'nageru/bmusb/bmusb.cpp', 'nageru/bmusb/fake_capture.cpp',
 165                 dependencies: [libusbdep],
 166                 include_directories: [bmusb_dir])
 167         nageru_link_with += bmusb
 168         kaeru_link_with += bmusb
 169 else
 170         nageru_deps += bmusbdep
 171         kaeru_extra_deps += bmusbdep
 172 endif
 173
 174 # Protobuf compilation.
 175 gen = generator(protoc, \
 176         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 177         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/nageru', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 178 proto_generated = gen.process(['nageru/state.proto', 'nageru/json.proto', 'nageru/nageru_midi_mapping.proto'])
 179 protobuf_lib = static_library('nageru_protobufs', proto_generated, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 180 protobuf_hdrs = declare_dependency(sources: proto_generated)
 181 nageru_link_with += protobuf_lib
 182
 183 # Preprocess Qt as needed.
 184 qt_files = qt5.preprocess(
 185         moc_headers: ['nageru/analyzer.h', 'nageru/clickable_label.h', 'nageru/compression_reduction_meter.h', 'nageru/correlation_meter.h',
 186                 'nageru/ellipsis_label.h', 'nageru/glwidget.h', 'nageru/input_mapping_dialog.h', 'nageru/lrameter.h', 'nageru/mainwindow.h', 'nageru/midi_mapping_dialog.h',
 187                 'nageru/nonlinear_fader.h', 'nageru/vumeter.h'],
 188         ui_files: ['nageru/analyzer.ui', 'nageru/audio_expanded_view.ui', 'nageru/audio_miniview.ui', 'nageru/display.ui',
 189                 'nageru/input_mapping.ui', 'nageru/mainwindow.ui', 'nageru/midi_mapping.ui'],
 190         dependencies: qt5deps)
 191
 192 # Qt objects.
 193 nageru_srcs += ['nageru/glwidget.cpp', 'nageru/mainwindow.cpp', 'nageru/vumeter.cpp', 'nageru/lrameter.cpp', 'nageru/compression_reduction_meter.cpp',
 194         'nageru/correlation_meter.cpp', 'nageru/analyzer.cpp', 'nageru/input_mapping_dialog.cpp', 'nageru/midi_mapping_dialog.cpp',
 195         'nageru/nonlinear_fader.cpp', 'nageru/context_menus.cpp', 'nageru/vu_common.cpp', 'nageru/piecewise_interpolator.cpp', 'nageru/midi_mapper.cpp']
 196
 197 # Auxiliary objects used for nearly everything.
 198 aux_srcs = ['nageru/flags.cpp']
 199 aux = static_library('aux', aux_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 200 nageru_link_with += aux
 201
 202 # Audio objects.
 203 audio_mixer_srcs = ['nageru/audio_mixer.cpp', 'nageru/alsa_input.cpp', 'nageru/alsa_pool.cpp', 'nageru/ebu_r128_proc.cc', 'nageru/stereocompressor.cpp',
 204         'nageru/resampling_queue.cpp', 'nageru/flags.cpp', 'nageru/correlation_measurer.cpp', 'nageru/filter.cpp', 'nageru/input_mapping.cpp']
 205 audio = static_library('audio', audio_mixer_srcs, dependencies: [nageru_deps, protobuf_hdrs], include_directories: nageru_include_dirs)
 206 nageru_link_with += audio
 207
 208 # Mixer objects.
 209 nageru_srcs += ['nageru/chroma_subsampler.cpp', 'nageru/v210_converter.cpp', 'nageru/mixer.cpp', 'nageru/pbo_frame_allocator.cpp',
 210         'nageru/theme.cpp', 'nageru/scene.cpp', 'nageru/image_input.cpp', 'nageru/alsa_output.cpp',
 211         'nageru/timecode_renderer.cpp', 'nageru/tweaked_inputs.cpp', 'nageru/mjpeg_encoder.cpp']
 212
 213 # Streaming and encoding objects (largely the set that is shared between Nageru and Kaeru).
 214 stream_srcs = ['nageru/quicksync_encoder.cpp', 'nageru/x264_encoder.cpp', 'nageru/x264_dynamic.cpp', 'nageru/x264_speed_control.cpp', 'nageru/video_encoder.cpp',
 215         'nageru/audio_encoder.cpp', 'nageru/ffmpeg_util.cpp', 'nageru/ffmpeg_capture.cpp',
 216         'nageru/print_latency.cpp', 'nageru/basic_stats.cpp', 'nageru/ref_counted_frame.cpp',
 217         'nageru/v4l_output.cpp']
 218 stream = static_library('stream', stream_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 219 nageru_link_with += stream
 220
 221 # DeckLink.
 222 decklink_dir = include_directories('nageru/decklink', is_system: true)
 223 decklink_lib = static_library('decklink', 'nageru/decklink/DeckLinkAPIDispatch.cpp', include_directories: decklink_dir, cpp_args: '-w')
 224 nageru_link_with += decklink_lib
 225
 226 nageru_srcs += ['nageru/decklink_capture.cpp', 'nageru/decklink_util.cpp', 'nageru/decklink_output.cpp']
 227 nageru_include_dirs += decklink_dir
 228
 229 # CEF input.
 230 if have_cef
 231         nageru_srcs += ['nageru/nageru_cef_app.cpp', 'nageru/cef_capture.cpp']
 232 endif
 233
 234 nageru_srcs += qt_files
 235 nageru_srcs += proto_generated
 236
 237 # Shaders needed at runtime.
 238 shaders = ['nageru/cbcr_subsample.vert', 'nageru/cbcr_subsample.frag', 'nageru/uyvy_subsample.vert', 'nageru/uyvy_subsample.frag', 'nageru/v210_subsample.comp', 'nageru/timecode.vert', 'nageru/timecode.frag', 'nageru/timecode_10bit.frag']
 239 foreach shader : shaders
 240         run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 241 endforeach
 242
 243 nageru_shader_srcs = bin2h_gen.process(shaders)
 244 nageru_srcs += nageru_shader_srcs
 245
 246 # Everything except main.cpp. (We do this because if you specify a .cpp file in
 247 # both Nageru and Kaeru, it gets compiled twice. In the older Makefiles, Kaeru
 248 # depended on a smaller set of objects.)
 249 core = static_library('core', nageru_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 250 nageru_link_with += core
 251
 252 # Nageru executable; it goes into /usr/lib/nageru since CEF files go there, too
 253 # (we can't put them straight into /usr/bin).
 254 executable('nageru', 'nageru/main.cpp',
 255         dependencies: nageru_deps,
 256         include_directories: nageru_include_dirs,
 257         link_with: nageru_link_with,
 258         build_rpath: nageru_build_rpath,
 259         install_rpath: nageru_install_rpath,
 260         install: true,
 261         install_dir: exe_dir
 262 )
 263 meson.add_install_script('nageru/scripts/setup_nageru_symlink.sh')
 264
 265 # Kaeru executable.
 266 executable('kaeru', 'nageru/kaeru.cpp',
 267         dependencies: [nageru_deps, kaeru_extra_deps],
 268         include_directories: nageru_include_dirs,
 269         link_with: [stream, aux, kaeru_link_with],
 270         install: true)
 271
 272 # Audio mixer microbenchmark.
 273 executable('benchmark_audio_mixer', 'nageru/benchmark_audio_mixer.cpp', dependencies: nageru_deps, include_directories: nageru_include_dirs, link_with: [audio, aux])
 274
 275 # These are needed for a default run.
 276 data_files = ['nageru/theme.lua', 'nageru/simple.lua', 'nageru/bg.jpeg', 'nageru/akai_midimix.midimapping', 'futatabi/behringer_cmd_pl1.midimapping']
 277 install_data(data_files, install_dir: join_paths(get_option('prefix'), 'share/nageru'))
 278 foreach file : data_files
 279         run_command('ln', '-s', join_paths(meson.current_source_dir(), file), meson.current_build_dir())
 280 endforeach
 281
 282 # Futatabi. (Not a subdir() because we don't want the output in nageru/nageru.)
 283
 284 # Protobuf compilation.
 285 gen = generator(protoc, \
 286         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 287         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/futatabi', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 288 proto_generated = gen.process('futatabi/state.proto', 'futatabi/frame.proto', 'futatabi/futatabi_midi_mapping.proto')
 289
 290 # Preprocess Qt as needed.
 291 moc_files = qt5.preprocess(
 292         moc_headers: ['futatabi/mainwindow.h', 'futatabi/jpeg_frame_view.h', 'futatabi/clip_list.h', 'futatabi/midi_mapping_dialog.h'],
 293         ui_files: ['futatabi/mainwindow.ui', 'futatabi/midi_mapping.ui'],
 294         qresources: ['futatabi/mainwindow.qrc'],
 295         dependencies: qt5deps)
 296
 297 # Flow objects.
 298 futatabi_srcs = ['futatabi/flow.cpp', 'futatabi/gpu_timers.cpp']
 299
 300 # All the other files.
 301 futatabi_srcs += ['futatabi/main.cpp', 'futatabi/player.cpp', 'futatabi/video_stream.cpp', 'futatabi/chroma_subsampler.cpp']
 302 futatabi_srcs += ['futatabi/vaapi_jpeg_decoder.cpp', 'futatabi/db.cpp', 'futatabi/ycbcr_converter.cpp', 'futatabi/flags.cpp']
 303 futatabi_srcs += ['futatabi/mainwindow.cpp', 'futatabi/jpeg_frame_view.cpp', 'futatabi/clip_list.cpp', 'futatabi/frame_on_disk.cpp']
 304 futatabi_srcs += ['futatabi/export.cpp', 'futatabi/midi_mapper.cpp', 'futatabi/midi_mapping_dialog.cpp']
 305 futatabi_srcs += ['futatabi/exif_parser.cpp', 'futatabi/pbo_pool.cpp']
 306 futatabi_srcs += moc_files
 307 futatabi_srcs += proto_generated
 308
 309 # Shaders needed at runtime.
 310 shaders = ['futatabi/chroma_subsample.vert', 'futatabi/densify.vert', 'futatabi/equations.vert', 'futatabi/hole_fill.vert', 'futatabi/motion_search.vert', 'futatabi/sor.vert', 'futatabi/splat.vert', 'futatabi/vs.vert']
 311 shaders += ['futatabi/add_base_flow.frag', 'futatabi/blend.frag', 'futatabi/chroma_subsample.frag', 'futatabi/densify.frag', 'futatabi/derivatives.frag', 'futatabi/diffusivity.frag',
 312         'futatabi/equations.frag', 'futatabi/gray.frag', 'futatabi/hole_blend.frag', 'futatabi/hole_fill.frag', 'futatabi/motion_search.frag', 'futatabi/prewarp.frag', 'futatabi/resize_flow.frag',
 313         'futatabi/sobel.frag', 'futatabi/sor.frag', 'futatabi/splat.frag']
 314
 315 foreach shader : shaders
 316         run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 317 endforeach
 318
 319 futatabi_shader_srcs = bin2h_gen.process(shaders)
 320 futatabi_srcs += futatabi_shader_srcs
 321
 322 executable('futatabi', futatabi_srcs,
 323         dependencies: [shareddep, qt5deps, libjpegdep, movitdep, libmicrohttpddep, protobufdep, sqlite3dep, vax11dep, vadrmdep, x11dep, threaddep, libavformatdep, libavcodecdep, libavutildep, libswscaledep, eigendep],
 324         link_with: shared,
 325         include_directories: [include_directories('futatabi')],
 326         install: true)
 327
 328 # Test binaries for the optical flow code.
 329 if sdl2dep.found() and sdl2_imagedep.found()
 330         executable('flow', 'futatabi/flow_main.cpp', 'futatabi/flow.cpp', 'futatabi/gpu_timers.cpp', futatabi_shader_srcs, dependencies: [shareddep, epoxydep, sdl2dep, sdl2_imagedep])
 331 endif
 332 executable('eval', 'futatabi/eval.cpp', 'futatabi/util.cpp')
 333 executable('vis', 'futatabi/vis.cpp', 'futatabi/util.cpp')