Added MBD as a part of NMS.

[nms] / mbd / mbd.pl

diff --git a/mbd/mbd.pl b/mbd/mbd.pl
new file mode 100644 (file)
index 0000000..90ee4d6
--- /dev/null
+++ b/mbd/mbd.pl
@@ -0,0 +1,122 @@
+#! /usr/bin/perl
+use strict;
+use warnings;
+use Socket;
+use Net::CIDR;
+use Net::RawIP;
+require './access_list.pl';
+require './nets.pl';
+
+sub expand_range {
+       my $range = shift;
+
+       if ($range =~ /^(\d+)\.\.(\d+)$/) {
+               return $1..$2;
+       } else {
+               return $range;
+       }
+}
+
+sub match_ranges {
+       my ($elem, $ranges) = @_;
+       
+       for my $range (@$ranges) {
+               if ($range =~ /^(\d+)\.\.(\d+)$/) {
+                       return 1 if ($elem >= $1 && $elem <= $2);
+               } else {
+                       return 1 if ($elem == $range);
+               }
+       }
+
+       return 0;
+}
+
+sub fhbits {
+       my $bits = 0;
+       for my $fh (@_) {
+               vec($bits, fileno($fh), 1) = 1;
+       }
+       return $bits;
+}
+
+# Find what ports we need to listen on
+my %port_hash = ();
+for my $e (@Config::access_list) {
+       for my $r (@{$e->{'ports'}}) {
+               for my $p (expand_range($r)) {
+                       $port_hash{$p} = 1;
+               }
+       }
+}
+my @ports = sort { $a <=> $b } keys %port_hash;
+
+# Open a socket for each port
+my @socks = ();
+my $udp = getprotobyname("udp");
+for my $p (@ports) {
+       my $sock;
+       socket($sock, PF_INET, SOCK_DGRAM, $udp);
+       bind($sock, sockaddr_in($p, INADDR_ANY));
+       push @socks, $sock;
+}
+
+my $sendsock = Net::RawIP->new({udp => {}});
+
+print "Listening on " . scalar @ports . " ports.\n";
+
+# Main loop
+while (1) {
+       my $rin = fhbits(@socks);
+       my $rout;
+
+       my $nfound = select($rout=$rin, undef, undef, undef);
+       for my $sock (@socks) {
+               next unless (vec($rout, fileno($sock), 1) == 1);
+
+               my $data;
+               my $addr = recv($sock, $data, 8192, 0);   # jumbo broadcast! :-P
+               my ($sport, $saddr) = sockaddr_in($addr);
+               my ($dport, $daddr) = sockaddr_in(getsockname($sock));
+               my $size = length($data);
+
+               # We don't get the packet's destination address, but I guess this should do...
+               # Check against the ACL.
+               my $pass = 0;
+               for my $rule (@Config::access_list) {
+                       if (match_ranges($dport, $rule->{'ports'}) &&
+                           match_ranges($size, $rule->{'sizes'})) {
+                               $pass = 1;
+                       }
+               }
+
+               if (!$pass) {
+                       print "$dport, $size bytes => filtered\n";
+               }
+
+               next unless $pass;
+
+               for my $net (@Config::networks) {
+                       next if (Net::CIDR::cidrlookup(inet_ntoa($saddr), $net));
+
+                       my ($range) = Net::CIDR::cidr2range($net);
+                       $range =~ /-(.*?)$/;
+                       my $broadcast = $1;
+
+                       print inet_ntoa($saddr), ", $dport, $size bytes => $broadcast\n";
+
+                       $sendsock->set({
+                               ip => {
+                                       saddr => inet_ntoa($saddr),
+                                       daddr => $broadcast
+                               },
+                               udp => {
+                                       source => $sport,
+                                       dest => $dport,
+                                       data => $data
+                               }
+                       });
+                       $sendsock->send;
+               }
+       }
+}
+