git.sesse.net Git - foosball/blob - recalc-single-result.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 use DBI;
   5 use CGI;
   6 use CGI::Carp qw(fatalsToBrowser);
   7 require 'foosball.pm';
   8 use foosrank;
   9 no warnings 'once';
  10
  11 my $dryrun = 0;
  12 if (defined($ARGV[0])) {
  13         $dryrun = 1;
  14         $foosball::initial_rd = $ARGV[0];
  15         $foosball::c = $ARGV[1];
  16 }
  17
  18 my $dbh = foosball::db_connect();
  19 $dbh->{AutoCommit} = 0;
  20
  21 $dbh->do('delete from single_rating') unless $dryrun;
  22
  23 my %ratings = ();
  24 my $q = $dbh->prepare('select *,extract(epoch from gametime) as eptime from single_results order by gametime');
  25 $q->execute;
  26
  27 # Combined log-likelihood
  28 my $cll = 0.0;
  29
  30 while (my $ref = $q->fetchrow_hashref) {
  31         for my $user (($ref->{'username1'}, $ref->{'username2'})) {
  32                 if (!exists($ratings{$user})) {
  33                         $ratings{$user} = [ $foosball::initial_rating, $foosball::initial_rd, 0 ];
  34                 }
  35         }
  36
  37         my $rating1 = $ratings{$ref->{'username1'}}->[0];
  38         my $rd1 = $ratings{$ref->{'username1'}}->[1];
  39         my $age1 = $ref->{'eptime'} - $ratings{$ref->{'username1'}}->[2];
  40
  41         my $rating2 = $ratings{$ref->{'username2'}}->[0];
  42         my $rd2 = $ratings{$ref->{'username2'}}->[1];
  43         my $age2 = $ref->{'eptime'} - $ratings{$ref->{'username2'}}->[2];
  44
  45         my $score1 = $ref->{'score1'};
  46         my $score2 = $ref->{'score2'};
  47
  48         $rd1 = foosball::apply_aging($rd1, $age1 / 86400.0);
  49         $rd2 = foosball::apply_aging($rd2, $age2 / 86400.0);
  50
  51         my ($newr1, $newrd1, $likelihood) = foosrank::compute_new_rating($rating1, $rd1, $rating2, $rd2, $score1, $score2);
  52         my ($newr2, $newrd2) = foosrank::compute_new_rating($rating2, $rd2, $rating1, $rd1, $score2, $score1);
  53
  54         $cll += log($likelihood);
  55
  56         unless ($dryrun) {
  57                 printf("%-10s - %-10s: %u - %u, new ratings %u/%u %u/%u [$likelihood]\n",
  58                         $ref->{'username1'}, $ref->{'username2'}, $ref->{'score1'},
  59                         $ref->{'score2'}, $newr1, $newrd1, $newr2, $newrd2);
  60                 $dbh->do('insert into single_rating values (?,?,?,?,?)', undef,
  61                         $ref->{'username1'}, $ref->{'gametime'}, $newr1, $newrd1, $newr1-$rating1);
  62                 $dbh->do('insert into single_rating values (?,?,?,?,?)', undef,
  63                         $ref->{'username2'}, $ref->{'gametime'}, $newr2, $newrd2, $newr2-$rating2);
  64         }
  65
  66         $ratings{$ref->{'username1'}} = [ $newr1, $newrd1, $ref->{'eptime'} ];
  67         $ratings{$ref->{'username2'}} = [ $newr2, $newrd2, $ref->{'eptime'} ];
  68 }
  69
  70 $dbh->commit unless $dryrun;
  71 $dbh->disconnect;
  72
  73 printf "\nCombined negative log-likelihood (smaller value means a better model): %f\n",
  74         -$cll;