git.sesse.net Git - nageru/blob - densify.vert

   1 #version 450 core
   2
   3 in vec2 position;
   4 out vec2 image_pos;
   5 flat out vec2 flow_du;
   6 flat out float mean_diff;
   7
   8 uniform vec2 patch_size;  // In 0..1 coordinates.
   9 uniform sampler2D flow_tex;
  10
  11 void main()
  12 {
  13         int patch_x = gl_InstanceID % textureSize(flow_tex, 0).x;
  14         int patch_y = gl_InstanceID / textureSize(flow_tex, 0).x;
  15
  16         // Convert the patch index to being the full 0..1 range, to match where
  17         // the motion search puts the patches. We don't bother with the locking
  18         // to texel centers, though.
  19         vec2 patch_center = ivec2(patch_x, patch_y) / (textureSize(flow_tex, 0) - 1.0);
  20
  21         // Increase the patch size a bit; since patch spacing is not necessarily
  22         // an integer number of pixels, and we don't use conservative rasterization,
  23         // we could be missing the outer edges of the patch. And it seemingly helps
  24         // a little bit in general to have some more candidates as well -- although
  25         // this is measured without variational refinement, so it might be moot
  26         // with it.
  27         //
  28         // This maps [0.0,1.0] to [-0.25,1.25], ie. extends the patch by 25% in
  29         // all directions.
  30         vec2 grown_pos = (position * 1.5) - 0.25;
  31
  32         image_pos = patch_center + patch_size * (grown_pos - 0.5f);
  33
  34         // Find the flow value for this patch, and send it on to the fragment shader.
  35         vec3 flow_du_and_mean_diff = texelFetch(flow_tex, ivec2(patch_x, patch_y), 0).xyz;
  36         flow_du = flow_du_and_mean_diff.xy;
  37         mean_diff = flow_du_and_mean_diff.z;
  38
  39         // The result of glOrtho(0.0, 1.0, 0.0, 1.0, 0.0, 1.0) is:
  40         //
  41         //   2.000  0.000  0.000 -1.000
  42         //   0.000  2.000  0.000 -1.000
  43         //   0.000  0.000 -2.000 -1.000
  44         //   0.000  0.000  0.000  1.000
  45         gl_Position = vec4(2.0 * image_pos.x - 1.0, 2.0 * image_pos.y - 1.0, -1.0, 1.0);
  46 }