git.sesse.net Git - nageru/blob - equations.frag

   1 #version 450 core
   2
   3 in vec2 tc;
   4 out uvec4 equation;
   5
   6 uniform sampler2D I_x_y_tex, I_t_tex;
   7 uniform sampler2D diff_flow_tex, base_flow_tex;
   8 uniform sampler2D beta_0_tex;
   9 uniform sampler2D smoothness_x_tex, smoothness_y_tex;
  10
  11 // Relative weighting of intensity term.
  12 uniform float delta;
  13
  14 // Relative weighting of gradient term.
  15 uniform float gamma;
  16
  17 // Similar to packHalf2x16, but the two values share exponent, and are stored
  18 // as 12-bit fixed point numbers multiplied by that exponent (the leading one
  19 // can't be implicit in this kind of format). This allows us to store a much
  20 // greater range of numbers (8-bit, ie., full fp32 range), and also gives us an
  21 // extra mantissa bit. (Well, ostensibly two, but because the numbers have to
  22 // be stored denormalized, we only really gain one.)
  23 //
  24 // The price we pay is that if the numbers are of very different magnitudes,
  25 // the smaller number gets less precision.
  26 uint pack_floats_shared(float a, float b)
  27 {
  28         float greatest = max(abs(a), abs(b));
  29
  30         // Find the exponent, increase it by one, and negate it.
  31         // E.g., if the nonbiased exponent is 3, the number is between
  32         // 2^3 and 2^4, so our normalization factor to get within -1..1
  33         // is going to be 2^-4.
  34         //
  35         // exponent -= 127;
  36         // exponent = -(exponent + 1);
  37         // exponent += 127;
  38         //
  39         // is the same as
  40         //
  41         // exponent = 252 - exponent;
  42         uint e = floatBitsToUint(greatest) & 0x7f800000u;
  43         float normalizer = uintBitsToFloat((252 << 23) - e);
  44
  45         // The exponent is the same range as fp32, so just copy it
  46         // verbatim, shifted up to where the sign bit used to be.
  47         e <<= 1;
  48
  49         // Quantize to 12 bits.
  50         uint qa = uint(int(round(a * (normalizer * 2047.0))));
  51         uint qb = uint(int(round(b * (normalizer * 2047.0))));
  52
  53         return (qa & 0xfffu) | ((qb & 0xfffu) << 12) | e;
  54 }
  55
  56 void main()
  57 {
  58         // Read the flow (on top of the u0/v0 flow).
  59         vec2 diff_flow = texture(diff_flow_tex, tc).xy;
  60         float du = diff_flow.x;
  61         float dv = diff_flow.y;
  62
  63         // Read the first derivatives.
  64         vec2 I_x_y = texture(I_x_y_tex, tc).xy;
  65         float I_x = I_x_y.x;
  66         float I_y = I_x_y.y;
  67         float I_t = texture(I_t_tex, tc).x;
  68
  69         // E_I term. Note that we don't square β_0, in line with DeepFlow;
  70         // it's probably an error (see variational_refinement.txt),
  71         // but squaring it seems to give worse results.
  72         //
  73         // FIXME: Should the penalizer be adjusted for 0..1 intensity range instead of 0..255?
  74         float beta_0 = texture(beta_0_tex, tc).x;
  75         float k1 = delta * beta_0 * inversesqrt(beta_0 * (I_x * du + I_y * dv + I_t) * (I_x * du + I_y * dv + I_t) + 1e-6);
  76         float A11 = k1 * I_x * I_x;
  77         float A12 = k1 * I_x * I_y;
  78         float A22 = k1 * I_y * I_y;
  79         float b1 = -k1 * I_t * I_x;
  80         float b2 = -k1 * I_t * I_y;
  81
  82         // Compute the second derivatives. First I_xx and I_xy.
  83         vec2 I_x_y_m2 = textureOffset(I_x_y_tex, tc, ivec2(-2,  0)).xy;
  84         vec2 I_x_y_m1 = textureOffset(I_x_y_tex, tc, ivec2(-1,  0)).xy;
  85         vec2 I_x_y_p1 = textureOffset(I_x_y_tex, tc, ivec2( 1,  0)).xy;
  86         vec2 I_x_y_p2 = textureOffset(I_x_y_tex, tc, ivec2( 2,  0)).xy;
  87         vec2 I_xx_yx = (I_x_y_p1 - I_x_y_m1) * (2.0/3.0) + (I_x_y_m2 - I_x_y_p2) * (1.0/12.0);
  88         float I_xx = I_xx_yx.x;
  89         float I_xy = I_xx_yx.y;
  90
  91         // And now I_yy; I_yx = I_xy, bar rounding differences, so we don't
  92         // bother computing it. We still have to sample the x component,
  93         // though, but we can throw it away immediately.
  94         float I_y_m2 = textureOffset(I_x_y_tex, tc, ivec2(0, -2)).y;
  95         float I_y_m1 = textureOffset(I_x_y_tex, tc, ivec2(0, -1)).y;
  96         float I_y_p1 = textureOffset(I_x_y_tex, tc, ivec2(0,  1)).y;
  97         float I_y_p2 = textureOffset(I_x_y_tex, tc, ivec2(0,  2)).y;
  98         float I_yy = (I_y_p1 - I_y_m1) * (2.0/3.0) + (I_y_m2 - I_y_p2) * (1.0/12.0);
  99
 100         // Finally I_xt and I_yt. (We compute these as I_tx and I_yt.)
 101         vec2 I_t_m2 = textureOffset(I_t_tex, tc, ivec2(-2,  0)).xy;
 102         vec2 I_t_m1 = textureOffset(I_t_tex, tc, ivec2(-1,  0)).xy;
 103         vec2 I_t_p1 = textureOffset(I_t_tex, tc, ivec2( 1,  0)).xy;
 104         vec2 I_t_p2 = textureOffset(I_t_tex, tc, ivec2( 2,  0)).xy;
 105         vec2 I_tx_ty = (I_t_p1 - I_t_m1) * (2.0/3.0) + (I_t_m2 - I_t_p2) * (1.0/12.0);
 106         float I_xt = I_tx_ty.x;
 107         float I_yt = I_tx_ty.y;
 108
 109         // E_G term. Same TODOs as E_I. Same normalization as beta_0
 110         // (see derivatives.frag).
 111         float beta_x = 1.0 / (I_xx * I_xx + I_xy * I_xy + 1e-7);
 112         float beta_y = 1.0 / (I_xy * I_xy + I_yy * I_yy + 1e-7);
 113         float k2 = gamma * inversesqrt(
 114                 beta_x * (I_xx * du + I_xy * dv + I_xt) * (I_xx * du + I_xy * dv + I_xt) +
 115                 beta_y * (I_xy * du + I_yy * dv + I_yt) * (I_xy * du + I_yy * dv + I_yt) +
 116                 1e-6);
 117         float k_x = k2 * beta_x;
 118         float k_y = k2 * beta_y;
 119         A11 += k_x * I_xx * I_xx + k_y * I_xy * I_xy;
 120         A12 += k_x * I_xx * I_xy + k_y * I_xy * I_yy;
 121         A22 += k_x * I_xy * I_xy + k_y * I_yy * I_yy;
 122         b1 -= k_x * I_xx * I_xt + k_y * I_xy * I_yt;
 123         b2 -= k_x * I_xy * I_xt + k_y * I_yy * I_yt;
 124
 125         // E_S term, sans the part on the right-hand side that deals with
 126         // the neighboring pixels. The gamma is multiplied in in smoothness.frag.
 127         float smooth_l = textureOffset(smoothness_x_tex, tc, ivec2(-1,  0)).x;
 128         float smooth_r = texture(smoothness_x_tex, tc).x;
 129         float smooth_d = textureOffset(smoothness_y_tex, tc, ivec2( 0, -1)).x;
 130         float smooth_u = texture(smoothness_y_tex, tc).x;
 131         A11 += smooth_l + smooth_r + smooth_d + smooth_u;
 132         A22 += smooth_l + smooth_r + smooth_d + smooth_u;
 133
 134         // Laplacian of (u0, v0).
 135         vec2 laplacian =
 136                 smooth_l * textureOffset(base_flow_tex, tc, ivec2(-1,  0)).xy +
 137                 smooth_r * textureOffset(base_flow_tex, tc, ivec2( 1,  0)).xy +
 138                 smooth_d * textureOffset(base_flow_tex, tc, ivec2( 0, -1)).xy +
 139                 smooth_u * textureOffset(base_flow_tex, tc, ivec2( 0,  1)).xy -
 140                 (smooth_l + smooth_r + smooth_d + smooth_u) * texture(base_flow_tex, tc).xy;
 141         b1 += laplacian.x;
 142         b2 += laplacian.y;
 143
 144         // Encode the equation down into four uint32s.
 145         equation.x = floatBitsToUint(1.0 / A11);
 146         equation.y = floatBitsToUint(A12);
 147         equation.z = floatBitsToUint(1.0 / A22);
 148         equation.w = pack_floats_shared(b1, b2);
 149 }