git.sesse.net Git - nageru/blob - meson.build

   1 project('nageru', 'cpp', default_options: ['buildtype=debugoptimized'], version: '2.3.1-pre')
   2
   3 add_project_arguments('-Wno-unqualified-std-cast-call', language: 'cpp')
   4
   5 cxx = meson.get_compiler('cpp')
   6 qt5 = import('qt5')
   7 protoc = find_program('protoc')
   8
   9 embedded_bmusb = get_option('embedded_bmusb')
  10
  11 alsadep = dependency('alsa')
  12 bmusbdep = dependency('bmusb', required: not embedded_bmusb)
  13 dldep = cxx.find_library('dl')
  14 eigendep = dependency('eigen3')
  15 epoxydep = dependency('epoxy')
  16 libavcodecdep = dependency('libavcodec')
  17 libavformatdep = dependency('libavformat')
  18 libswresampledep = dependency('libswresample')
  19 libavutildep = dependency('libavutil')
  20 libdrmdep = dependency('libdrm')
  21 libjpegdep = dependency('libjpeg')
  22 libswscaledep = dependency('libswscale')
  23 libusbdep = dependency('libusb-1.0')
  24 luajitdep = dependency('luajit')
  25 movitdep = dependency('movit')
  26 protobufdep = dependency('protobuf')
  27 qt5deps = dependency('qt5', modules: ['Core', 'Gui', 'Widgets', 'OpenGLExtensions', 'OpenGL', 'Network'])
  28 sdl2_imagedep = dependency('SDL2_image', required: false)
  29 sdl2dep = dependency('sdl2', required: false)
  30 srtdep = dependency('srt', required: false)
  31 svtav1dep = dependency('SvtAv1Enc', required: false, version: '>=1.5.0')
  32 sqlite3dep = dependency('sqlite3')
  33 threaddep = dependency('threads')
  34 vadrmdep = dependency('libva-drm')
  35 vax11dep = dependency('libva-x11')
  36 x11dep = dependency('x11')
  37 x264dep = dependency('x264')
  38 zitaresamplerdep = cxx.find_library('zita-resampler')
  39
  40 # Use lld if we can; it links a lot faster than ld.bfd or gold.
  41 code = '''#include <stdio.h>
  42 int main() { printf("Hello, world!\n"); return 0; }
  43 '''
  44 if cxx.links(code, args: '-fuse-ld=lld', name: 'check for LLD')
  45         add_project_link_arguments('-fuse-ld=lld', language: 'cpp')
  46 endif
  47
  48 # Add the right MOVIT_SHADER_DIR definition.
  49 movit_shader_dir = movitdep.get_pkgconfig_variable('shaderdir')
  50 add_project_arguments('-DMOVIT_SHADER_DIR="' + movit_shader_dir + '"', language: 'cpp')
  51
  52 # Make the Nageru version available as a #define.
  53 add_project_arguments('-DNAGERU_VERSION="' + meson.project_version() + '"', language: 'cpp')
  54
  55 # Make the prefix (e.g. /usr/local) available as a #define.
  56 add_project_arguments('-DPREFIX="' + get_option('prefix') + '"', language: 'cpp')
  57
  58 # This needs to be done before declaring any build targets.
  59 if get_option('cef_dir') != ''
  60         add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  61 endif
  62
  63 if srtdep.found()
  64         # NOTE: Seemingly there's no way to figure out if we have OpenSSL libsrt
  65         # or gnutls libsrt, so we cannot check license compatibility here.
  66         add_project_arguments('-DHAVE_SRT=1', language: 'cpp')
  67 endif
  68 if svtav1dep.found()
  69         add_project_arguments('-DHAVE_AV1=1', language: 'cpp')
  70 endif
  71
  72 top_include = include_directories('.')
  73
  74 subdir('shared')
  75
  76 # Nageru. (Not a subdir() because we don't want the output in nageru/nageru.)
  77
  78 nageru_srcs = []
  79 nageru_deps = [shareddep, qt5deps, libjpegdep, movitdep, protobufdep,
  80         vax11dep, vadrmdep, x11dep, libavformatdep, libswresampledep, libavcodecdep, libavutildep,
  81         libswscaledep, libusbdep, luajitdep, dldep, x264dep, svtav1dep, alsadep, zitaresamplerdep,
  82         threaddep, eigendep, srtdep, libdrmdep]
  83 nageru_include_dirs = [include_directories('nageru')]
  84 nageru_link_with = []
  85 nageru_build_rpath = ''
  86 nageru_install_rpath = ''
  87
  88 kaeru_link_with = []
  89 kaeru_extra_deps = []
  90
  91 # CEF.
  92 exe_dir = join_paths(get_option('prefix'), 'lib/nageru')
  93 cef_dir = get_option('cef_dir')
  94 cef_build_type = get_option('cef_build_type')
  95 have_cef = (cef_dir != '')
  96 if have_cef
  97         # This is done in the top-level file; just kept here for reference.
  98         # add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  99
 100         system_cef = (cef_build_type == 'system')
 101         if system_cef
 102                 cef_lib_dir = cef_dir
 103                 cef_resource_dir = cef_dir
 104         else
 105                 cef_lib_dir = join_paths(cef_dir, cef_build_type)
 106                 cef_resource_dir = join_paths(cef_dir, 'Resources')
 107
 108                 nageru_include_dirs += include_directories(cef_dir)
 109                 nageru_include_dirs += include_directories(join_paths(cef_dir, 'include'))
 110                 nageru_build_rpath = cef_lib_dir
 111                 nageru_install_rpath = '$ORIGIN/'
 112         endif
 113
 114         # CEF wrapper library; not built as part of the CEF binary distribution,
 115         # but should be if CEF is installed as a system library.
 116         if system_cef
 117                 cefdlldep = cxx.find_library('cef_dll_wrapper')
 118                 nageru_deps += cefdlldep
 119         else
 120                 cmake = find_program('cmake')
 121                 cef_compile_script = find_program('nageru/scripts/compile_cef_dll_wrapper.sh')
 122
 123                 cef_dll_target = custom_target('libcef_dll_wrapper',
 124                         input: join_paths(cef_dir, 'libcef_dll/CMakeLists.txt'),
 125                         output: ['libcef_dll_wrapper.a'],
 126                         command: [cef_compile_script, '@BUILD_DIR@', cef_dir, cmake, '@OUTPUT@'])
 127
 128                 cefdlldep = declare_dependency(link_with: cef_dll_target)
 129                 nageru_deps += cefdlldep
 130         endif
 131
 132         cef_libs = ['libEGL.so', 'libGLESv2.so', 'snapshot_blob.bin', 'v8_context_snapshot.bin']
 133         cef_resources = ['resources.pak', 'chrome_100_percent.pak', 'chrome_200_percent.pak']
 134         if not get_option('cef_no_icudtl')
 135                 cef_resources += ['icudtl.dat']
 136         endif
 137         if cef_build_type != 'system'
 138                 cef_libs += ['libcef.so', 'libEGL.so', 'libGLESv2.so', 'libvk_swiftshader.so', 'libvulkan.so.1', 'vk_swiftshader_icd.json']
 139         endif
 140
 141         # Symlink the files into the build directory, so that running nageru without ninja install works.
 142         run_command('mkdir', '-p', join_paths(meson.current_build_dir(), 'locales/'), check: true)
 143         foreach file : cef_libs
 144                 run_command('ln', '-sf', join_paths(cef_lib_dir, file), meson.current_build_dir(), check: true)
 145                 install_data(join_paths(cef_lib_dir, file), install_dir: exe_dir)
 146         endforeach
 147         foreach file : cef_resources
 148                 run_command('ln', '-sf', join_paths(cef_resource_dir, file), meson.current_build_dir(), check: true)
 149                 install_data(join_paths(cef_resource_dir, file), install_dir: exe_dir)
 150         endforeach
 151         run_command('ln', '-sf', join_paths(cef_resource_dir, 'locales/en-US.pak'), join_paths(meson.current_build_dir(), 'locales/'), check: true)
 152         install_data(join_paths(cef_resource_dir, 'locales/en-US.pak'), install_dir: join_paths(exe_dir, 'locales'))
 153
 154         # NOTE: We link against libcef.so in the local directory, _not_ in the CEF directory,
 155         # since upstream CEF searches for icudtl.dat in whatever path dladdr() says libcef.so
 156         # comes from, and the upstream CEF tarballs have libcef.so and icudtl.dat in different
 157         # directories. Thus, get both from the local symlinks we just created.
 158         cefdep = cxx.find_library('cef', dirs: meson.current_build_dir())
 159         nageru_deps += cefdep
 160 endif
 161
 162 # bmusb.
 163 if embedded_bmusb
 164         bmusb_dir = include_directories('nageru/bmusb')
 165         nageru_include_dirs += bmusb_dir
 166
 167         bmusb = static_library('bmusb', 'nageru/bmusb/bmusb.cpp', 'nageru/bmusb/fake_capture.cpp',
 168                 dependencies: [libusbdep],
 169                 include_directories: [bmusb_dir])
 170         nageru_link_with += bmusb
 171         kaeru_link_with += bmusb
 172 else
 173         nageru_deps += bmusbdep
 174         kaeru_extra_deps += bmusbdep
 175 endif
 176
 177 # Protobuf compilation.
 178 gen = generator(protoc, \
 179         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 180         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/nageru', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 181 proto_generated = gen.process(['nageru/state.proto', 'nageru/json.proto', 'nageru/nageru_midi_mapping.proto'])
 182 protobuf_lib = static_library('nageru_protobufs', proto_generated, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 183 protobuf_hdrs = declare_dependency(sources: proto_generated)
 184 nageru_link_with += protobuf_lib
 185
 186 # Preprocess Qt as needed.
 187 qt_files = qt5.preprocess(
 188         moc_headers: ['nageru/analyzer.h', 'nageru/clickable_label.h', 'nageru/compression_reduction_meter.h', 'nageru/correlation_meter.h',
 189                 'nageru/ellipsis_label.h', 'nageru/glwidget.h', 'nageru/input_mapping_dialog.h', 'nageru/lrameter.h', 'nageru/mainwindow.h', 'nageru/midi_mapping_dialog.h',
 190                 'nageru/nonlinear_fader.h', 'nageru/vumeter.h', 'nageru/rgb_histogram.h'],
 191         ui_files: ['nageru/analyzer.ui', 'nageru/audio_expanded_view.ui', 'nageru/audio_miniview.ui', 'nageru/display.ui',
 192                 'nageru/input_mapping.ui', 'nageru/mainwindow.ui', 'nageru/midi_mapping.ui'],
 193         dependencies: qt5deps)
 194
 195 # Qt objects.
 196 nageru_srcs += ['nageru/glwidget.cpp', 'nageru/mainwindow.cpp', 'nageru/vumeter.cpp', 'nageru/lrameter.cpp', 'nageru/compression_reduction_meter.cpp',
 197         'nageru/correlation_meter.cpp', 'nageru/analyzer.cpp', 'nageru/input_mapping_dialog.cpp', 'nageru/midi_mapping_dialog.cpp',
 198         'nageru/nonlinear_fader.cpp', 'nageru/context_menus.cpp', 'nageru/vu_common.cpp', 'nageru/piecewise_interpolator.cpp', 'nageru/midi_mapper.cpp', 'nageru/rgb_histogram.cpp']
 199
 200 # Auxiliary objects used for nearly everything.
 201 aux_srcs = ['nageru/flags.cpp']
 202 aux = static_library('aux', aux_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 203 nageru_link_with += aux
 204
 205 # Audio objects.
 206 audio_mixer_srcs = ['nageru/audio_mixer.cpp', 'nageru/alsa_input.cpp', 'nageru/alsa_pool.cpp', 'nageru/ebu_r128_proc.cc', 'nageru/stereocompressor.cpp',
 207         'nageru/resampling_queue.cpp', 'nageru/flags.cpp', 'nageru/correlation_measurer.cpp', 'nageru/filter.cpp', 'nageru/input_mapping.cpp']
 208 audio = static_library('audio', audio_mixer_srcs, dependencies: [nageru_deps, protobuf_hdrs], include_directories: nageru_include_dirs)
 209 nageru_link_with += audio
 210
 211 # Mixer objects.
 212 nageru_srcs += ['nageru/chroma_subsampler.cpp', 'nageru/v210_converter.cpp', 'nageru/mixer.cpp', 'nageru/pbo_frame_allocator.cpp',
 213         'nageru/theme.cpp', 'nageru/scene.cpp', 'nageru/image_input.cpp', 'nageru/alsa_output.cpp',
 214         'nageru/timecode_renderer.cpp', 'nageru/tweaked_inputs.cpp', 'nageru/mjpeg_encoder.cpp', 'nageru/srt_metrics.cpp']
 215
 216 # Streaming and encoding objects (largely the set that is shared between Nageru and Kaeru).
 217 stream_srcs = ['nageru/quicksync_encoder.cpp', 'nageru/video_encoder.cpp',
 218         'nageru/x264_encoder.cpp', 'nageru/x264_dynamic.cpp', 'nageru/x264_speed_control.cpp',
 219         'nageru/audio_encoder.cpp', 'nageru/ffmpeg_util.cpp', 'nageru/ffmpeg_capture.cpp',
 220         'nageru/print_latency.cpp', 'nageru/basic_stats.cpp', 'nageru/ref_counted_frame.cpp',
 221         'nageru/v4l_output.cpp']
 222 if svtav1dep.found()
 223         stream_srcs += 'nageru/av1_encoder.cpp'
 224 endif
 225 stream = static_library('stream', stream_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 226 nageru_link_with += stream
 227
 228 # DeckLink.
 229 decklink_dir = include_directories('nageru/decklink', is_system: true)
 230 decklink_lib = static_library('decklink', 'nageru/decklink/DeckLinkAPIDispatch.cpp', include_directories: decklink_dir, cpp_args: '-w')
 231 nageru_link_with += decklink_lib
 232
 233 nageru_srcs += ['nageru/decklink_capture.cpp', 'nageru/decklink_util.cpp', 'nageru/decklink_output.cpp']
 234 nageru_include_dirs += decklink_dir
 235
 236 # CEF input.
 237 if have_cef
 238         nageru_srcs += ['nageru/nageru_cef_app.cpp', 'nageru/cef_capture.cpp']
 239 endif
 240
 241 nageru_srcs += qt_files
 242 nageru_srcs += proto_generated
 243
 244 # Shaders needed at runtime.
 245 shaders = ['nageru/cbcr_subsample.vert', 'nageru/cbcr_subsample.frag', 'nageru/uyvy_subsample.vert', 'nageru/uyvy_subsample.frag', 'nageru/v210_subsample.comp', 'nageru/timecode.vert', 'nageru/timecode.frag', 'nageru/timecode_10bit.frag']
 246 foreach shader : shaders
 247         run_command('ln', '-sf', join_paths(meson.current_source_dir(), shader), meson.current_build_dir(), check: true)
 248 endforeach
 249
 250 nageru_shader_srcs = bin2h_gen.process(shaders)
 251 nageru_srcs += nageru_shader_srcs
 252
 253 # Everything except main.cpp. (We do this because if you specify a .cpp file in
 254 # both Nageru and Kaeru, it gets compiled twice. In the older Makefiles, Kaeru
 255 # depended on a smaller set of objects.)
 256 core = static_library('core', nageru_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 257 nageru_link_with += core
 258
 259 # Nageru executable; it goes into /usr/lib/nageru since CEF files go there, too
 260 # (we can't put them straight into /usr/bin).
 261 executable('nageru', 'nageru/main.cpp',
 262         dependencies: nageru_deps,
 263         include_directories: nageru_include_dirs,
 264         link_with: nageru_link_with,
 265         build_rpath: nageru_build_rpath,
 266         install_rpath: nageru_install_rpath,
 267         install: true,
 268         install_dir: exe_dir
 269 )
 270 meson.add_install_script('nageru/scripts/setup_nageru_symlink.sh')
 271
 272 # Kaeru executable.
 273 executable('kaeru', 'nageru/kaeru.cpp',
 274         dependencies: [nageru_deps, kaeru_extra_deps],
 275         include_directories: nageru_include_dirs,
 276         link_with: [stream, aux, kaeru_link_with],
 277         install: true)
 278
 279 # Audio mixer microbenchmark.
 280 executable('benchmark_audio_mixer', 'nageru/benchmark_audio_mixer.cpp', dependencies: nageru_deps, include_directories: nageru_include_dirs, link_with: [audio, aux])
 281
 282 # These are needed for a default run.
 283 data_files = ['nageru/theme.lua', 'nageru/simple.lua', 'nageru/bg.jpeg', 'nageru/akai_midimix.midimapping', 'futatabi/behringer_cmd_pl1.midimapping']
 284 install_data(data_files, install_dir: join_paths(get_option('prefix'), 'share/nageru'))
 285 foreach file : data_files
 286         run_command('ln', '-sf', join_paths(meson.current_source_dir(), file), meson.current_build_dir(), check: true)
 287 endforeach
 288
 289 # Futatabi. (Not a subdir() because we don't want the output in nageru/nageru.)
 290
 291 # Protobuf compilation.
 292 gen = generator(protoc, \
 293         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 294         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/futatabi', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 295 proto_generated = gen.process('futatabi/state.proto', 'futatabi/frame.proto', 'futatabi/futatabi_midi_mapping.proto')
 296
 297 # Preprocess Qt as needed.
 298 moc_files = qt5.preprocess(
 299         moc_headers: ['futatabi/mainwindow.h', 'futatabi/jpeg_frame_view.h', 'futatabi/clip_list.h', 'futatabi/midi_mapping_dialog.h'],
 300         ui_files: ['futatabi/mainwindow.ui', 'futatabi/midi_mapping.ui'],
 301         qresources: ['futatabi/mainwindow.qrc'],
 302         dependencies: qt5deps)
 303
 304 # Flow objects.
 305 futatabi_srcs = ['futatabi/flow.cpp', 'futatabi/gpu_timers.cpp']
 306
 307 # All the other files.
 308 futatabi_srcs += ['futatabi/main.cpp', 'futatabi/player.cpp', 'futatabi/video_stream.cpp', 'futatabi/chroma_subsampler.cpp']
 309 futatabi_srcs += ['futatabi/vaapi_jpeg_decoder.cpp', 'futatabi/db.cpp', 'futatabi/ycbcr_converter.cpp', 'futatabi/flags.cpp']
 310 futatabi_srcs += ['futatabi/mainwindow.cpp', 'futatabi/jpeg_frame_view.cpp', 'futatabi/clip_list.cpp', 'futatabi/frame_on_disk.cpp']
 311 futatabi_srcs += ['futatabi/export.cpp', 'futatabi/midi_mapper.cpp', 'futatabi/midi_mapping_dialog.cpp']
 312 futatabi_srcs += ['futatabi/exif_parser.cpp', 'futatabi/pbo_pool.cpp']
 313 futatabi_srcs += moc_files
 314 futatabi_srcs += proto_generated
 315
 316 # Shaders needed at runtime.
 317 shaders = ['futatabi/chroma_subsample.vert', 'futatabi/densify.vert', 'futatabi/equations.vert', 'futatabi/hole_fill.vert', 'futatabi/motion_search.vert', 'futatabi/sor.vert', 'futatabi/splat.vert', 'futatabi/vs.vert']
 318 shaders += ['futatabi/add_base_flow.frag', 'futatabi/blend.frag', 'futatabi/chroma_subsample.frag', 'futatabi/densify.frag', 'futatabi/derivatives.frag', 'futatabi/diffusivity.frag',
 319         'futatabi/equations.frag', 'futatabi/gray.frag', 'futatabi/hole_blend.frag', 'futatabi/hole_fill.frag', 'futatabi/motion_search.frag', 'futatabi/prewarp.frag', 'futatabi/resize_flow.frag',
 320         'futatabi/sobel.frag', 'futatabi/sor.frag', 'futatabi/splat.frag']
 321
 322 foreach shader : shaders
 323         run_command('ln', '-sf', join_paths(meson.current_source_dir(), shader), meson.current_build_dir(), check: true)
 324 endforeach
 325
 326 futatabi_shader_srcs = bin2h_gen.process(shaders)
 327 futatabi_srcs += futatabi_shader_srcs
 328
 329 executable('futatabi', futatabi_srcs,
 330         dependencies: [shareddep, qt5deps, libjpegdep, movitdep, libmicrohttpddep, protobufdep, sqlite3dep, vax11dep, vadrmdep, x11dep, threaddep, libavformatdep, libavcodecdep, libavutildep, libswscaledep, eigendep],
 331         link_with: shared,
 332         include_directories: [include_directories('futatabi')],
 333         install: true)
 334
 335 # Test binaries for the optical flow code.
 336 if sdl2dep.found() and sdl2_imagedep.found()
 337         executable('flow', 'futatabi/flow_main.cpp', 'futatabi/flow.cpp', 'futatabi/gpu_timers.cpp', futatabi_shader_srcs, dependencies: [shareddep, epoxydep, sdl2dep, sdl2_imagedep])
 338 endif
 339 executable('eval', 'futatabi/eval.cpp', 'futatabi/util.cpp')
 340 executable('vis', 'futatabi/vis.cpp', 'futatabi/util.cpp')