git.sesse.net Git - nageru/blob - nageru/meson.build

   1 qt5 = import('qt5')
   2 protoc = find_program('protoc')
   3 cxx = meson.get_compiler('cpp')
   4
   5 embedded_bmusb = get_option('embedded_bmusb')
   6
   7 alsadep = dependency('alsa')
   8 bmusbdep = dependency('bmusb', required: not embedded_bmusb)
   9 dldep = cxx.find_library('dl')
  10 epoxydep = dependency('epoxy')
  11 libavcodecdep = dependency('libavcodec')
  12 libavformatdep = dependency('libavformat')
  13 libavresampledep = dependency('libavresample')
  14 libavutildep = dependency('libavutil')
  15 libjpegdep = dependency('libjpeg')
  16 libswscaledep = dependency('libswscale')
  17 libusbdep = dependency('libusb-1.0')
  18 luajitdep = dependency('luajit')
  19 movitdep = dependency('movit')
  20 protobufdep = dependency('protobuf')
  21 qcustomplotdep = cxx.find_library('qcustomplot')
  22 qt5deps = dependency('qt5', modules: ['Core', 'Gui', 'Widgets', 'OpenGLExtensions', 'OpenGL', 'PrintSupport'])
  23 threaddep = dependency('threads')
  24 vadrmdep = dependency('libva-drm')
  25 vax11dep = dependency('libva-x11')
  26 x11dep = dependency('x11')
  27 x264dep = dependency('x264')
  28 zitaresamplerdep = cxx.find_library('zita-resampler')
  29
  30 srcs = []
  31 nageru_deps = [shareddep, qt5deps, libjpegdep, movitdep, protobufdep,
  32         vax11dep, vadrmdep, x11dep, libavformatdep, libavresampledep, libavcodecdep, libavutildep,
  33         libswscaledep, libusbdep, luajitdep, dldep, x264dep, alsadep, zitaresamplerdep,
  34         qcustomplotdep, threaddep]
  35 nageru_include_dirs = []
  36 nageru_link_with = []
  37 nageru_build_rpath = ''
  38 nageru_install_rpath = ''
  39
  40 kaeru_link_with = []
  41 kaeru_extra_deps = []
  42
  43 # CEF.
  44 exe_dir = join_paths(get_option('prefix'), 'lib/nageru')
  45 cef_dir = get_option('cef_dir')
  46 cef_build_type = get_option('cef_build_type')
  47 have_cef = (cef_dir != '')
  48 if have_cef
  49         # This is done in the top-level file; just kept here for reference.
  50         # add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  51
  52         system_cef = (cef_build_type == 'system')
  53         if system_cef
  54                 cef_lib_dir = cef_dir
  55                 cef_resource_dir = '/usr/share/cef/Resources'
  56         else
  57                 cef_lib_dir = join_paths(cef_dir, cef_build_type)
  58                 cef_resource_dir = join_paths(cef_dir, 'Resources')
  59
  60                 nageru_include_dirs += include_directories(cef_dir)
  61                 nageru_include_dirs += include_directories(join_paths(cef_dir, 'include'))
  62                 nageru_build_rpath = cef_lib_dir
  63                 nageru_install_rpath = '$ORIGIN/'
  64         endif
  65
  66         cefdep = cxx.find_library('cef')
  67         nageru_deps += cefdep
  68
  69         # CEF wrapper library; not built as part of the CEF binary distribution,
  70         # but should be if CEF is installed as a system library.
  71         if system_cef
  72                 cefdlldep = cxx.find_library('cef_dll_wrapper')
  73                 nageru_deps += cefdlldep
  74         else
  75                 cmake = find_program('cmake')
  76                 cef_compile_script = find_program('scripts/compile_cef_dll_wrapper.sh')
  77
  78                 cef_dll_target = custom_target('libcef_dll_wrapper',
  79                         input: join_paths(cef_dir, 'libcef_dll/CMakeLists.txt'),
  80                         output: ['libcef_dll_wrapper.a', 'cef-stamp'],
  81                         command: [cef_compile_script, '@BUILD_DIR@', cef_dir, cmake, '@OUTPUT@'])
  82
  83                 # Putting the .a in sources seemingly hits a bug where the .a files get sorted
  84                 # in the wrong order. This is a workaround; see
  85                 # https://github.com/mesonbuild/meson/issues/3613#issuecomment-408276296 .
  86                 cefdlldep = declare_dependency(sources: cef_dll_target[1], link_args: cef_dll_target.full_path())
  87                 nageru_deps += cefdlldep
  88         endif
  89
  90         cef_libs = ['libEGL.so', 'libGLESv2.so', 'natives_blob.bin', 'snapshot_blob.bin', 'v8_context_snapshot.bin']
  91         cef_resources = ['cef.pak', 'cef_100_percent.pak', 'cef_200_percent.pak', 'cef_extensions.pak', 'devtools_resources.pak']
  92         if not get_option('cef_no_icudtl')
  93                 cef_resources += ['icudtl.dat']
  94         endif
  95         if cef_build_type != 'system'
  96                 cef_libs += ['libcef.so']
  97         endif
  98
  99         # Symlink the files into the build directory, so that running nageru without ninja install works.
 100         run_command('mkdir', join_paths(meson.current_build_dir(), 'locales/'))
 101         foreach file : cef_libs
 102                 run_command('ln', '-s', join_paths(cef_lib_dir, file), meson.current_build_dir())
 103                 install_data(join_paths(cef_lib_dir, file), install_dir: exe_dir)
 104         endforeach
 105         foreach file : cef_resources
 106                 run_command('ln', '-s', join_paths(cef_resource_dir, file), meson.current_build_dir())
 107                 install_data(join_paths(cef_resource_dir, file), install_dir: exe_dir)
 108         endforeach
 109         run_command('ln', '-s', join_paths(cef_resource_dir, 'locales/en-US.pak'), join_paths(meson.current_build_dir(), 'locales/'))
 110         install_data(join_paths(cef_resource_dir, 'locales/en-US.pak'), install_dir: join_paths(exe_dir, 'locales'))
 111 endif
 112
 113 # bmusb.
 114 if embedded_bmusb
 115         bmusb_dir = include_directories('bmusb')
 116         nageru_include_dirs += bmusb_dir
 117
 118         bmusb = static_library('bmusb', 'bmusb/bmusb.cpp', 'bmusb/fake_capture.cpp',
 119                 dependencies: [libusbdep],
 120                 include_directories: [bmusb_dir])
 121         nageru_link_with += bmusb
 122         kaeru_link_with += bmusb
 123 else
 124         nageru_deps += bmusbdep
 125         kaeru_extra_deps += bmusbdep
 126 endif
 127
 128 # Protobuf compilation.
 129 gen = generator(protoc, \
 130         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 131         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@', '--cpp_out=@BUILD_DIR@', '@INPUT@'])
 132 proto_generated = gen.process(['state.proto', 'midi_mapping.proto', 'json.proto'])
 133 protobuf_lib = static_library('protobufs', proto_generated, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 134 protobuf_hdrs = declare_dependency(sources: proto_generated)
 135 nageru_link_with += protobuf_lib
 136
 137 # Preprocess Qt as needed.
 138 qt_files = qt5.preprocess(
 139         moc_headers: ['aboutdialog.h', 'analyzer.h', 'clickable_label.h', 'compression_reduction_meter.h', 'correlation_meter.h',
 140                 'ellipsis_label.h', 'glwidget.h', 'input_mapping_dialog.h', 'lrameter.h', 'mainwindow.h', 'midi_mapping_dialog.h',
 141                 'nonlinear_fader.h', 'vumeter.h'],
 142         ui_files: ['aboutdialog.ui', 'analyzer.ui', 'audio_expanded_view.ui', 'audio_miniview.ui', 'display.ui',
 143                 'input_mapping.ui', 'mainwindow.ui', 'midi_mapping.ui'],
 144         dependencies: qt5deps)
 145
 146 # Qt objects.
 147 srcs += ['glwidget.cpp', 'mainwindow.cpp', 'vumeter.cpp', 'lrameter.cpp', 'compression_reduction_meter.cpp',
 148         'correlation_meter.cpp', 'aboutdialog.cpp', 'analyzer.cpp', 'input_mapping_dialog.cpp', 'midi_mapping_dialog.cpp',
 149         'nonlinear_fader.cpp', 'context_menus.cpp', 'vu_common.cpp', 'piecewise_interpolator.cpp', 'midi_mapper.cpp']
 150
 151 # Auxiliary objects used for nearly everything.
 152 aux_srcs = ['flags.cpp']
 153 aux = static_library('aux', aux_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 154 nageru_link_with += aux
 155
 156 # Audio objects.
 157 audio_mixer_srcs = ['audio_mixer.cpp', 'alsa_input.cpp', 'alsa_pool.cpp', 'ebu_r128_proc.cc', 'stereocompressor.cpp',
 158         'resampling_queue.cpp', 'flags.cpp', 'correlation_measurer.cpp', 'filter.cpp', 'input_mapping.cpp']
 159 audio = static_library('audio', audio_mixer_srcs, dependencies: [nageru_deps, protobuf_hdrs], include_directories: nageru_include_dirs)
 160 nageru_link_with += audio
 161
 162 # Mixer objects.
 163 srcs += ['chroma_subsampler.cpp', 'v210_converter.cpp', 'mixer.cpp', 'pbo_frame_allocator.cpp',
 164         'theme.cpp', 'image_input.cpp', 'alsa_output.cpp',
 165         'timecode_renderer.cpp', 'tweaked_inputs.cpp', 'mjpeg_encoder.cpp']
 166
 167 # Streaming and encoding objects (largely the set that is shared between Nageru and Kaeru).
 168 stream_srcs = ['quicksync_encoder.cpp', 'x264_encoder.cpp', 'x264_dynamic.cpp', 'x264_speed_control.cpp', 'video_encoder.cpp',
 169         'audio_encoder.cpp', 'ffmpeg_util.cpp', 'ffmpeg_capture.cpp',
 170         'print_latency.cpp', 'basic_stats.cpp', 'ref_counted_frame.cpp']
 171 stream = static_library('stream', stream_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 172 nageru_link_with += stream
 173
 174 # DeckLink.
 175 srcs += ['decklink_capture.cpp', 'decklink_util.cpp', 'decklink_output.cpp',
 176         'decklink/DeckLinkAPIDispatch.cpp']
 177 decklink_dir = include_directories('decklink')
 178 nageru_include_dirs += decklink_dir
 179
 180 # CEF input.
 181 if have_cef
 182         srcs += ['nageru_cef_app.cpp', 'cef_capture.cpp']
 183 endif
 184
 185 srcs += qt_files
 186 srcs += proto_generated
 187
 188 # Shaders needed at runtime.
 189 shaders = ['cbcr_subsample.vert', 'cbcr_subsample.frag', 'uyvy_subsample.vert', 'uyvy_subsample.frag', 'v210_subsample.comp', 'timecode.vert', 'timecode.frag', 'timecode_10bit.frag']
 190 foreach shader : shaders
 191   run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 192 endforeach
 193
 194 shader_srcs = bin2h_gen.process(shaders)
 195 srcs += shader_srcs
 196
 197 # Everything except main.cpp. (We do this because if you specify a .cpp file in
 198 # both Nageru and Kaeru, it gets compiled twice. In the older Makefiles, Kaeru
 199 # depended on a smaller set of objects.)
 200 core = static_library('core', srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 201 nageru_link_with += core
 202
 203 # Nageru executable; it goes into /usr/lib/nageru since CEF files go there, too
 204 # (we can't put them straight into /usr/bin).
 205 executable('nageru', 'main.cpp',
 206         dependencies: nageru_deps,
 207         include_directories: nageru_include_dirs,
 208         link_with: nageru_link_with,
 209         build_rpath: nageru_build_rpath,
 210         install_rpath: nageru_install_rpath,
 211         install: true,
 212         install_dir: exe_dir
 213 )
 214 meson.add_install_script('scripts/setup_nageru_symlink.sh')
 215
 216 # Kaeru executable.
 217 executable('kaeru', 'kaeru.cpp',
 218         dependencies: [nageru_deps, kaeru_extra_deps],
 219         include_directories: nageru_include_dirs,
 220         link_with: [stream, aux, kaeru_link_with],
 221         install: true)
 222
 223 # Audio mixer microbenchmark.
 224 executable('benchmark_audio_mixer', 'benchmark_audio_mixer.cpp', dependencies: nageru_deps, include_directories: nageru_include_dirs, link_with: [audio, aux])
 225
 226 # These are needed for a default run.
 227 data_files = ['theme.lua', 'simple.lua', 'bg.jpeg', 'akai_midimix.midimapping']
 228 install_data(data_files, install_dir: join_paths(get_option('prefix'), 'share/nageru'))
 229 foreach file : data_files
 230         run_command('ln', '-s', join_paths(meson.current_source_dir(), file), meson.current_build_dir())
 231 endforeach