git.sesse.net Git - narabu/blob - decoder.shader

   1 #version 430
   2 #extension GL_ARB_shader_clock : enable
   3
   4 #define ENABLE_TIMING 0
   5
   6 layout(local_size_x = 8, local_size_y = 8) in;
   7 layout(r8ui) uniform restrict readonly uimage2D cum2sym_tex;
   8 layout(rg16ui) uniform restrict readonly uimage2D dsyms_tex;
   9 layout(r8) uniform restrict writeonly image2D out_tex;
  10
  11 const uint prob_bits = 12;
  12 const uint prob_scale = 1 << prob_bits;
  13 const uint NUM_SYMS = 256;
  14 const uint ESCAPE_LIMIT = NUM_SYMS - 1;
  15
  16 // These need to be folded into quant_matrix.
  17 const float dc_scalefac = 8.0;
  18 const float quant_scalefac = 4.0;
  19
  20 const float quant_matrix[64] = {
  21          8, 16, 19, 22, 26, 27, 29, 34,
  22         16, 16, 22, 24, 27, 29, 34, 37,
  23         19, 22, 26, 27, 29, 34, 34, 38,
  24         22, 22, 26, 27, 29, 34, 37, 40,
  25         22, 26, 27, 29, 32, 35, 40, 48,
  26         26, 27, 29, 32, 35, 40, 48, 58,
  27         26, 27, 29, 34, 38, 46, 56, 69,
  28         27, 29, 35, 38, 46, 56, 69, 83
  29 };
  30 const uint ff_zigzag_direct[64] = {
  31     0,   1,  8, 16,  9,  2,  3, 10,
  32     17, 24, 32, 25, 18, 11,  4,  5,
  33     12, 19, 26, 33, 40, 48, 41, 34,
  34     27, 20, 13,  6,  7, 14, 21, 28,
  35     35, 42, 49, 56, 57, 50, 43, 36,
  36     29, 22, 15, 23, 30, 37, 44, 51,
  37     58, 59, 52, 45, 38, 31, 39, 46,
  38     53, 60, 61, 54, 47, 55, 62, 63
  39 };
  40
  41 layout(std430, binding = 9) buffer layoutName
  42 {
  43         uint data_SSBO[];
  44 };
  45 layout(std430, binding = 10) buffer layoutName2
  46 {
  47         uvec2 timing[10 * 64];
  48 };
  49
  50 struct CoeffStream {
  51         uint src_offset, src_len;
  52 };
  53 layout(std430, binding = 0) buffer whatever3
  54 {
  55         CoeffStream streams[];
  56 };
  57 uniform uint sign_bias_per_model[16];
  58
  59 const uint RANS_BYTE_L = (1u << 23);  // lower bound of our normalization interval
  60
  61 uint last_offset = -1, ransbuf;
  62
  63 uint get_rans_byte(uint offset)
  64 {
  65         if (last_offset != (offset >> 2)) {
  66                 last_offset = offset >> 2;
  67                 ransbuf = data_SSBO[offset >> 2];
  68         }
  69         return bitfieldExtract(ransbuf, 8 * int(offset & 3u), 8);
  70
  71         // We assume little endian.
  72 //      return bitfieldExtract(data_SSBO[offset >> 2], 8 * int(offset & 3u), 8);
  73 }
  74
  75 uint RansDecInit(inout uint offset)
  76 {
  77         uint x;
  78
  79         x  = get_rans_byte(offset);
  80         x |= get_rans_byte(offset + 1) << 8;
  81         x |= get_rans_byte(offset + 2) << 16;
  82         x |= get_rans_byte(offset + 3) << 24;
  83         offset += 4;
  84
  85         return x;
  86 }
  87
  88 uint RansDecGet(uint r, uint scale_bits)
  89 {
  90         return r & ((1u << scale_bits) - 1);
  91 }
  92
  93 void RansDecAdvance(inout uint rans, inout uint offset, const uint start, const uint freq, uint prob_bits)
  94 {
  95         const uint mask = (1u << prob_bits) - 1;
  96         rans = freq * (rans >> prob_bits) + (rans & mask) - start;
  97
  98         // renormalize
  99         while (rans < RANS_BYTE_L) {
 100                 rans = (rans << 8) | get_rans_byte(offset++);
 101         }
 102 }
 103
 104 uint cum2sym(uint bits, uint table)
 105 {
 106         return imageLoad(cum2sym_tex, ivec2(bits, table)).x;
 107 }
 108
 109 uvec2 get_dsym(uint k, uint table)
 110 {
 111         return imageLoad(dsyms_tex, ivec2(k, table)).xy;
 112 }
 113
 114 void idct_1d(inout float y0, inout float y1, inout float y2, inout float y3, inout float y4, inout float y5, inout float y6, inout float y7)
 115 {
 116         const float a1 = 0.7071067811865474;   // sqrt(2)
 117         const float a2 = 0.5411961001461971;   // cos(3/8 pi) * sqrt(2)
 118         const float a4 = 1.3065629648763766;   // cos(pi/8) * sqrt(2)
 119         // static const float a5 = 0.5 * (a4 - a2);
 120         const float a5 = 0.3826834323650897;
 121
 122         // phase 2 (phase 1 is just moving around)
 123         const float p2_4 = y5 - y3;
 124         const float p2_5 = y1 + y7;
 125         const float p2_6 = y1 - y7;
 126         const float p2_7 = y5 + y3;
 127
 128         // phase 3
 129         const float p3_2 = y2 - y6;
 130         const float p3_3 = y2 + y6;
 131         const float p3_5 = p2_5 - p2_7;
 132         const float p3_7 = p2_5 + p2_7;
 133
 134         // phase 4
 135         const float p4_2 = a1 * p3_2;
 136         const float p4_4 = p2_4 * a2 + (p2_4 + p2_6) * a5;  // Inverted.
 137         const float p4_5 = a1 * p3_5;
 138         const float p4_6 = p2_6 * a4 - (p2_4 + p2_6) * a5;
 139
 140         // phase 5
 141         const float p5_0 = y0 + y4;
 142         const float p5_1 = y0 - y4;
 143         const float p5_3 = p4_2 + p3_3;
 144
 145         // phase 6
 146         const float p6_0 = p5_0 + p5_3;
 147         const float p6_1 = p5_1 + p4_2;
 148         const float p6_2 = p5_1 - p4_2;
 149         const float p6_3 = p5_0 - p5_3;
 150         const float p6_5 = p4_5 + p4_4;
 151         const float p6_6 = p4_5 + p4_6;
 152         const float p6_7 = p4_6 + p3_7;
 153
 154         // phase 7
 155         y0 = p6_0 + p6_7;
 156         y1 = p6_1 + p6_6;
 157         y2 = p6_2 + p6_5;
 158         y3 = p6_3 - p4_4;
 159         y4 = p6_3 + p4_4;
 160         y5 = p6_2 - p6_5;
 161         y6 = p6_1 - p6_6;
 162         y7 = p6_0 - p6_7;
 163 }
 164
 165 shared float temp[64 * 8];
 166
 167 void pick_timer(inout uvec2 start, inout uvec2 t)
 168 {
 169 #if ENABLE_TIMING
 170         uvec2 now = clock2x32ARB();
 171
 172         uvec2 delta = now - start;
 173         if (now.x < start.x) {
 174                 --delta.y;
 175         }
 176
 177         uvec2 new_t = t + delta;
 178         if (new_t.x < t.x) {
 179                 ++new_t.y;
 180         }
 181         t = new_t;
 182
 183         start = clock2x32ARB();
 184 #endif
 185 }
 186
 187 void main()
 188 {
 189         uvec2 local_timing[10];
 190 #if ENABLE_TIMING
 191         for (int timer_idx = 0; timer_idx < 10; ++timer_idx) {
 192                 local_timing[timer_idx] = uvec2(0, 0);
 193         }
 194         uvec2 start = clock2x32ARB();
 195 #else
 196         uvec2 start;
 197 #endif
 198
 199         const uint num_blocks = 720 / 16;  // FIXME: make a uniform
 200         const uint thread_num = gl_LocalInvocationID.y * 8 + gl_LocalInvocationID.x;
 201
 202         const uint block_row = gl_WorkGroupID.y;
 203         //const uint coeff_num = ff_zigzag_direct[thread_num];
 204         const uint coeff_num = thread_num;
 205         const uint stream_num = coeff_num * num_blocks + block_row;
 206         //const uint stream_num = block_row * num_blocks + coeff_num;  // HACK
 207         const uint model_num = min((coeff_num % 8) + (coeff_num / 8), 7);
 208         const uint sign_bias = sign_bias_per_model[model_num];
 209
 210         // Initialize rANS decoder.
 211         uint offset = streams[stream_num].src_offset;
 212         uint rans = RansDecInit(offset);
 213
 214         float q = (coeff_num == 0) ? 1.0 : (quant_matrix[coeff_num] * quant_scalefac / 128.0 / sqrt(2.0));  // FIXME: fold
 215         q *= (1.0 / 255.0);
 216         //int w = (coeff_num == 0) ? 32 : int(quant_matrix[coeff_num]);
 217         int last_k = 0;
 218
 219         pick_timer(start, local_timing[0]);
 220
 221         for (uint block_idx = 40; block_idx --> 0; ) {
 222                 uint block_x = block_idx % 20;
 223                 uint block_y = block_idx / 20;
 224                 if (block_x == 19) last_k = 0;
 225
 226                 pick_timer(start, local_timing[1]);
 227
 228                 // rANS decode one coefficient across eight blocks (so 64x8 coefficients).
 229                 for (uint subblock_idx = 8; subblock_idx --> 0; ) {
 230                         // Read a symbol.
 231                         uint bottom_bits = RansDecGet(rans, prob_bits + 1);
 232                         bool sign = false;
 233                         if (bottom_bits >= sign_bias) {
 234                                 bottom_bits -= sign_bias;
 235                                 rans -= sign_bias;
 236                                 sign = true;
 237                         }
 238                         int k = int(cum2sym(bottom_bits, model_num));  // Can go out-of-bounds; that will return zero.
 239                         uvec2 sym = get_dsym(k, model_num);
 240                         RansDecAdvance(rans, offset, sym.x, sym.y, prob_bits + 1);
 241
 242                         if (k == ESCAPE_LIMIT) {
 243                                 k = int(RansDecGet(rans, prob_bits));
 244                                 RansDecAdvance(rans, offset, k, 1, prob_bits);
 245                         }
 246                         if (sign) {
 247                                 k = -k;
 248                         }
 249
 250                         if (coeff_num == 0) {
 251                                 k += last_k;
 252                                 last_k = k;
 253                         }
 254
 255                         temp[subblock_idx * 64 + coeff_num] = k * q;
 256                         //temp[subblock_idx * 64 + 8 * y + x] = (2 * k * w * 4) / 32;  // 100% matching unquant
 257                 }
 258
 259                 pick_timer(start, local_timing[2]);
 260
 261                 memoryBarrierShared();
 262                 barrier();
 263
 264                 pick_timer(start, local_timing[3]);
 265
 266                 // Horizontal DCT one row (so 64 rows).
 267                 idct_1d(temp[thread_num * 8 + 0],
 268                         temp[thread_num * 8 + 1],
 269                         temp[thread_num * 8 + 2],
 270                         temp[thread_num * 8 + 3],
 271                         temp[thread_num * 8 + 4],
 272                         temp[thread_num * 8 + 5],
 273                         temp[thread_num * 8 + 6],
 274                         temp[thread_num * 8 + 7]);
 275
 276                 pick_timer(start, local_timing[4]);
 277
 278                 memoryBarrierShared();
 279                 barrier();
 280
 281                 pick_timer(start, local_timing[5]);
 282
 283                 // Vertical DCT one row (so 64 columns).
 284                 uint row_offset = gl_LocalInvocationID.y * 64 + gl_LocalInvocationID.x;
 285                 idct_1d(temp[row_offset + 0 * 8],
 286                         temp[row_offset + 1 * 8],
 287                         temp[row_offset + 2 * 8],
 288                         temp[row_offset + 3 * 8],
 289                         temp[row_offset + 4 * 8],
 290                         temp[row_offset + 5 * 8],
 291                         temp[row_offset + 6 * 8],
 292                         temp[row_offset + 7 * 8]);
 293
 294                 pick_timer(start, local_timing[6]);
 295
 296                 uint y = block_row * 16 + block_y * 8;
 297                 uint x = block_x * 64 + gl_LocalInvocationID.y * 8 + gl_LocalInvocationID.x;
 298                 for (uint yl = 0; yl < 8; ++yl) {
 299                         imageStore(out_tex, ivec2(x, yl + y), vec4(temp[row_offset + yl * 8], 0.0, 0.0, 1.0));
 300                 }
 301
 302                 pick_timer(start, local_timing[7]);
 303
 304                 memoryBarrierShared();  // is this needed?
 305                 barrier();
 306
 307                 pick_timer(start, local_timing[8]);
 308                 pick_timer(start, local_timing[9]);  // should be nearly nothing
 309         }
 310
 311 #if ENABLE_TIMING
 312         for (int timer_idx = 0; timer_idx < 10; ++timer_idx) {
 313                 uint global_idx = thread_num * 10 + timer_idx;
 314
 315                 uint old_val = atomicAdd(timing[global_idx].x, local_timing[timer_idx].x);
 316                 if (old_val + local_timing[timer_idx].x < old_val) {
 317                         ++local_timing[timer_idx].y;
 318                 }
 319                 atomicAdd(timing[global_idx].y, local_timing[timer_idx].y);
 320         }
 321 #endif
 322 }