git.sesse.net Git - narabu/blob - decoder.shader

   1 #version 430
   2 #extension GL_ARB_shader_clock : enable
   3
   4 #define ENABLE_TIMING 0
   5
   6 layout(local_size_x = 8, local_size_y = 8) in;
   7 layout(r8ui) uniform restrict readonly uimage2D cum2sym_tex;
   8 layout(rg16ui) uniform restrict readonly uimage2D dsyms_tex;
   9 layout(r8) uniform restrict writeonly image2D out_tex;
  10
  11 const uint prob_bits = 12;
  12 const uint prob_scale = 1 << prob_bits;
  13 const uint NUM_SYMS = 256;
  14 const uint ESCAPE_LIMIT = NUM_SYMS - 1;
  15
  16 // These need to be folded into quant_matrix.
  17 const float dc_scalefac = 8.0;
  18 const float quant_scalefac = 4.0;
  19
  20 const float quant_matrix[64] = {
  21          8, 16, 19, 22, 26, 27, 29, 34,
  22         16, 16, 22, 24, 27, 29, 34, 37,
  23         19, 22, 26, 27, 29, 34, 34, 38,
  24         22, 22, 26, 27, 29, 34, 37, 40,
  25         22, 26, 27, 29, 32, 35, 40, 48,
  26         26, 27, 29, 32, 35, 40, 48, 58,
  27         26, 27, 29, 34, 38, 46, 56, 69,
  28         27, 29, 35, 38, 46, 56, 69, 83
  29 };
  30 const uint ff_zigzag_direct[64] = {
  31     0,   1,  8, 16,  9,  2,  3, 10,
  32     17, 24, 32, 25, 18, 11,  4,  5,
  33     12, 19, 26, 33, 40, 48, 41, 34,
  34     27, 20, 13,  6,  7, 14, 21, 28,
  35     35, 42, 49, 56, 57, 50, 43, 36,
  36     29, 22, 15, 23, 30, 37, 44, 51,
  37     58, 59, 52, 45, 38, 31, 39, 46,
  38     53, 60, 61, 54, 47, 55, 62, 63
  39 };
  40
  41 layout(std430, binding = 9) buffer layoutName
  42 {
  43         uint data_SSBO[];
  44 };
  45 layout(std430, binding = 10) buffer layoutName2
  46 {
  47         uvec2 timing[10 * 64];
  48 };
  49
  50 struct CoeffStream {
  51         uint src_offset, src_len;
  52 };
  53 layout(std430, binding = 0) buffer whatever3
  54 {
  55         CoeffStream streams[];
  56 };
  57 uniform uint sign_bias_per_model[16];
  58
  59 const uint RANS_BYTE_L = (1u << 23);  // lower bound of our normalization interval
  60
  61 uint get_rans_byte(uint offset)
  62 {
  63         // We assume little endian.
  64         return bitfieldExtract(data_SSBO[offset >> 2], 8 * int(offset & 3u), 8);
  65 }
  66
  67 uint RansDecInit(inout uint offset)
  68 {
  69         uint x;
  70
  71         x  = get_rans_byte(offset);
  72         x |= get_rans_byte(offset + 1) << 8;
  73         x |= get_rans_byte(offset + 2) << 16;
  74         x |= get_rans_byte(offset + 3) << 24;
  75         offset += 4;
  76
  77         return x;
  78 }
  79
  80 uint RansDecGet(uint r, uint scale_bits)
  81 {
  82         return r & ((1u << scale_bits) - 1);
  83 }
  84
  85 void RansDecAdvance(inout uint rans, inout uint offset, const uint start, const uint freq, uint prob_bits)
  86 {
  87         const uint mask = (1u << prob_bits) - 1;
  88         rans = freq * (rans >> prob_bits) + (rans & mask) - start;
  89
  90         // renormalize
  91         while (rans < RANS_BYTE_L) {
  92                 rans = (rans << 8) | get_rans_byte(offset++);
  93         }
  94 }
  95
  96 uint cum2sym(uint bits, uint table)
  97 {
  98         return imageLoad(cum2sym_tex, ivec2(bits, table)).x;
  99 }
 100
 101 uvec2 get_dsym(uint k, uint table)
 102 {
 103         return imageLoad(dsyms_tex, ivec2(k, table)).xy;
 104 }
 105
 106 void idct_1d(inout float y0, inout float y1, inout float y2, inout float y3, inout float y4, inout float y5, inout float y6, inout float y7)
 107 {
 108         const float a1 = 0.7071067811865474;   // sqrt(2)
 109         const float a2 = 0.5411961001461971;   // cos(3/8 pi) * sqrt(2)
 110         const float a4 = 1.3065629648763766;   // cos(pi/8) * sqrt(2)
 111         // static const float a5 = 0.5 * (a4 - a2);
 112         const float a5 = 0.3826834323650897;
 113
 114         // phase 2 (phase 1 is just moving around)
 115         const float p2_4 = y5 - y3;
 116         const float p2_5 = y1 + y7;
 117         const float p2_6 = y1 - y7;
 118         const float p2_7 = y5 + y3;
 119
 120         // phase 3
 121         const float p3_2 = y2 - y6;
 122         const float p3_3 = y2 + y6;
 123         const float p3_5 = p2_5 - p2_7;
 124         const float p3_7 = p2_5 + p2_7;
 125
 126         // phase 4
 127         const float p4_2 = a1 * p3_2;
 128         const float p4_4 = p2_4 * a2 + (p2_4 + p2_6) * a5;  // Inverted.
 129         const float p4_5 = a1 * p3_5;
 130         const float p4_6 = p2_6 * a4 - (p2_4 + p2_6) * a5;
 131
 132         // phase 5
 133         const float p5_0 = y0 + y4;
 134         const float p5_1 = y0 - y4;
 135         const float p5_3 = p4_2 + p3_3;
 136
 137         // phase 6
 138         const float p6_0 = p5_0 + p5_3;
 139         const float p6_1 = p5_1 + p4_2;
 140         const float p6_2 = p5_1 - p4_2;
 141         const float p6_3 = p5_0 - p5_3;
 142         const float p6_5 = p4_5 + p4_4;
 143         const float p6_6 = p4_5 + p4_6;
 144         const float p6_7 = p4_6 + p3_7;
 145
 146         // phase 7
 147         y0 = p6_0 + p6_7;
 148         y1 = p6_1 + p6_6;
 149         y2 = p6_2 + p6_5;
 150         y3 = p6_3 - p4_4;
 151         y4 = p6_3 + p4_4;
 152         y5 = p6_2 - p6_5;
 153         y6 = p6_1 - p6_6;
 154         y7 = p6_0 - p6_7;
 155 }
 156
 157 shared float temp[64 * 8];
 158
 159 void pick_timer(inout uvec2 start, inout uvec2 t)
 160 {
 161 #if ENABLE_TIMING
 162         uvec2 now = clock2x32ARB();
 163
 164         uvec2 delta = now - start;
 165         if (now.x < start.x) {
 166                 --delta.y;
 167         }
 168
 169         uvec2 new_t = t + delta;
 170         if (new_t.x < t.x) {
 171                 ++new_t.y;
 172         }
 173         t = new_t;
 174
 175         start = clock2x32ARB();
 176 #endif
 177 }
 178
 179 void main()
 180 {
 181         uvec2 local_timing[10];
 182 #if ENABLE_TIMING
 183         for (int timer_idx = 0; timer_idx < 10; ++timer_idx) {
 184                 local_timing[timer_idx] = uvec2(0, 0);
 185         }
 186         uvec2 start = clock2x32ARB();
 187 #else
 188         uvec2 start;
 189 #endif
 190
 191         const uint num_blocks = 720 / 16;  // FIXME: make a uniform
 192         const uint thread_num = gl_LocalInvocationID.y * 8 + gl_LocalInvocationID.x;
 193
 194         const uint block_row = gl_WorkGroupID.y;
 195         //const uint coeff_num = ff_zigzag_direct[thread_num];
 196         const uint coeff_num = thread_num;
 197         const uint stream_num = coeff_num * num_blocks + block_row;
 198         //const uint stream_num = block_row * num_blocks + coeff_num;  // HACK
 199         const uint model_num = min((coeff_num % 8) + (coeff_num / 8), 7);
 200         const uint sign_bias = sign_bias_per_model[model_num];
 201
 202         // Initialize rANS decoder.
 203         uint offset = streams[stream_num].src_offset;
 204         uint rans = RansDecInit(offset);
 205
 206         float q = (coeff_num == 0) ? 1.0 : (quant_matrix[coeff_num] * quant_scalefac / 128.0 / sqrt(2.0));  // FIXME: fold
 207         q *= (1.0 / 255.0);
 208         //int w = (coeff_num == 0) ? 32 : int(quant_matrix[coeff_num]);
 209         int last_k = 0;
 210
 211         pick_timer(start, local_timing[0]);
 212
 213         for (uint block_idx = 40; block_idx --> 0; ) {
 214                 uint block_x = block_idx % 20;
 215                 uint block_y = block_idx / 20;
 216                 if (block_x == 19) last_k = 0;
 217
 218                 pick_timer(start, local_timing[1]);
 219
 220                 // rANS decode one coefficient across eight blocks (so 64x8 coefficients).
 221                 for (uint subblock_idx = 8; subblock_idx --> 0; ) {
 222                         // Read a symbol.
 223                         uint bottom_bits = RansDecGet(rans, prob_bits + 1);
 224                         bool sign = false;
 225                         if (bottom_bits >= sign_bias) {
 226                                 bottom_bits -= sign_bias;
 227                                 rans -= sign_bias;
 228                                 sign = true;
 229                         }
 230                         int k = int(cum2sym(bottom_bits, model_num));  // Can go out-of-bounds; that will return zero.
 231                         uvec2 sym = get_dsym(k, model_num);
 232                         RansDecAdvance(rans, offset, sym.x, sym.y, prob_bits + 1);
 233
 234                         if (k == ESCAPE_LIMIT) {
 235                                 k = int(RansDecGet(rans, prob_bits));
 236                                 RansDecAdvance(rans, offset, k, 1, prob_bits);
 237                         }
 238                         if (sign) {
 239                                 k = -k;
 240                         }
 241
 242                         if (coeff_num == 0) {
 243                                 k += last_k;
 244                                 last_k = k;
 245                         }
 246
 247                         temp[subblock_idx * 64 + coeff_num] = k * q;
 248                         //temp[subblock_idx * 64 + 8 * y + x] = (2 * k * w * 4) / 32;  // 100% matching unquant
 249                 }
 250
 251                 pick_timer(start, local_timing[2]);
 252
 253                 memoryBarrierShared();
 254                 barrier();
 255
 256                 pick_timer(start, local_timing[3]);
 257
 258                 // Horizontal DCT one row (so 64 rows).
 259                 idct_1d(temp[thread_num * 8 + 0],
 260                         temp[thread_num * 8 + 1],
 261                         temp[thread_num * 8 + 2],
 262                         temp[thread_num * 8 + 3],
 263                         temp[thread_num * 8 + 4],
 264                         temp[thread_num * 8 + 5],
 265                         temp[thread_num * 8 + 6],
 266                         temp[thread_num * 8 + 7]);
 267
 268                 pick_timer(start, local_timing[4]);
 269
 270                 memoryBarrierShared();
 271                 barrier();
 272
 273                 pick_timer(start, local_timing[5]);
 274
 275                 // Vertical DCT one row (so 64 columns).
 276                 uint row_offset = gl_LocalInvocationID.y * 64 + gl_LocalInvocationID.x;
 277                 idct_1d(temp[row_offset + 0 * 8],
 278                         temp[row_offset + 1 * 8],
 279                         temp[row_offset + 2 * 8],
 280                         temp[row_offset + 3 * 8],
 281                         temp[row_offset + 4 * 8],
 282                         temp[row_offset + 5 * 8],
 283                         temp[row_offset + 6 * 8],
 284                         temp[row_offset + 7 * 8]);
 285
 286                 pick_timer(start, local_timing[6]);
 287
 288                 uint y = block_row * 16 + block_y * 8;
 289                 uint x = block_x * 64 + gl_LocalInvocationID.y * 8 + gl_LocalInvocationID.x;
 290                 for (uint yl = 0; yl < 8; ++yl) {
 291                         imageStore(out_tex, ivec2(x, yl + y), vec4(temp[row_offset + yl * 8], 0.0, 0.0, 1.0));
 292                 }
 293
 294                 pick_timer(start, local_timing[7]);
 295
 296                 memoryBarrierShared();  // is this needed?
 297                 barrier();
 298
 299                 pick_timer(start, local_timing[8]);
 300                 pick_timer(start, local_timing[9]);  // should be nearly nothing
 301         }
 302
 303 #if ENABLE_TIMING
 304         for (int timer_idx = 0; timer_idx < 10; ++timer_idx) {
 305                 uint global_idx = thread_num * 10 + timer_idx;
 306
 307                 uint old_val = atomicAdd(timing[global_idx].x, local_timing[timer_idx].x);
 308                 if (old_val + local_timing[timer_idx].x < old_val) {
 309                         ++local_timing[timer_idx].y;
 310                 }
 311                 atomicAdd(timing[global_idx].y, local_timing[timer_idx].y);
 312         }
 313 #endif
 314 }