git.sesse.net Git - narabu/blob - rans.shader

   1 #version 440
   2 #extension GL_NV_gpu_shader5 : enable
   3
   4 layout(local_size_x = 1) in;
   5
   6 const uint prob_bits = 12;
   7 const uint prob_scale = 1 << prob_bits;
   8 const uint RANS_BYTE_L = (1u << 23);
   9 const uint BLOCKS_PER_STREAM = 320;
  10 const uint STREAM_BUF_SIZE = 1024;  // 1 kB per stream ought to be enough for everyone :-)
  11 const uint NUM_SYMS = 256;
  12 const uint ESCAPE_LIMIT = NUM_SYMS - 1;
  13
  14 #define MAPPING(s0, s1, s2, s3, s4, s5, s6, s7) ((s0) | (s1 << 2) | (s2 << 4) | (s3 << 6) | (s4 << 8) | (s5 << 10) | (s6 << 12) | (s7 << 14))
  15
  16 const uint luma_mapping[8] = {
  17         MAPPING(0, 0, 1, 1, 2, 2, 3, 3),
  18         MAPPING(0, 0, 1, 2, 2, 2, 3, 3),
  19         MAPPING(1, 1, 2, 2, 2, 3, 3, 3),
  20         MAPPING(1, 1, 2, 2, 2, 3, 3, 3),
  21         MAPPING(1, 2, 2, 2, 2, 3, 3, 3),
  22         MAPPING(2, 2, 2, 2, 3, 3, 3, 3),
  23         MAPPING(2, 2, 3, 3, 3, 3, 3, 3),
  24         MAPPING(3, 3, 3, 3, 3, 3, 3, 3),
  25 };
  26
  27 layout(std430, binding = 10) buffer outputBuf
  28 {
  29         uint8_t rans_output[];
  30 };
  31
  32 layout(std430, binding = 11) buffer outputBuf2
  33 {
  34         uint rans_start_offset[];
  35 };
  36
  37 layout(std140, binding = 13) uniform DistBlock
  38 {
  39         uvec4 ransdist[4 * 256];
  40         uint sign_biases[4];
  41 };
  42
  43 struct RansEncoder {
  44         uint stream_num;   // const
  45         uint lut_base;     // const
  46         uint sign_bias;    // const
  47         uint rans_offset;
  48         uint rans;
  49 };
  50
  51 layout(r16ui) uniform restrict readonly uimage2D dc_ac7_tex;
  52 layout(r16ui) uniform restrict readonly uimage2D ac1_ac6_tex;
  53 layout(r16ui) uniform restrict readonly uimage2D ac2_ac5_tex;
  54 layout(r8i) uniform restrict readonly iimage2D ac3_tex;
  55 layout(r8i) uniform restrict readonly iimage2D ac4_tex;
  56
  57 void RansEncInit(uint streamgroup_num, uint coeff_row, uint coeff_col, uint dist_num, out RansEncoder enc)
  58 {
  59         enc.stream_num = streamgroup_num * 64 + coeff_row * 8 + coeff_col;
  60         enc.lut_base = dist_num * 256;
  61         enc.sign_bias = sign_biases[dist_num];
  62         enc.rans_offset = enc.stream_num * STREAM_BUF_SIZE + STREAM_BUF_SIZE;  // Starts at the end.
  63         enc.rans = RANS_BYTE_L;
  64 }
  65
  66 void RansEncRenorm(inout uint rans, inout uint rans_offset, uint freq, uint prob_bits)
  67 {
  68         uint x_max = ((RANS_BYTE_L >> prob_bits) << 8) * freq; // this turns into a shift.
  69         while (rans >= x_max) {
  70                 rans_output[--rans_offset] = uint8_t(rans & 0xffu);
  71                 rans >>= 8;
  72         }
  73 }
  74
  75 void RansEncPut(inout uint rans, inout uint rans_offset, uint start, uint freq, uint prob_bits)
  76 {
  77         RansEncRenorm(rans, rans_offset, freq, prob_bits);
  78         rans = ((rans / freq) << prob_bits) + (rans % freq) + start;
  79 }
  80
  81 void RansEncPutSymbol(inout uint rans, inout uint rans_offset, uvec4 sym)
  82 {
  83         uint x_max = sym.x;
  84         uint rcp_freq = sym.y;
  85         uint bias = sym.z;
  86         uint rcp_shift = (sym.w & 0xffffu);
  87         uint cmpl_freq = (sym.w >> 16);
  88
  89         // renormalize
  90         while (rans >= x_max) {
  91                 rans_output[--rans_offset] = uint8_t(rans & 0xffu);
  92                 rans >>= 8;
  93         }
  94
  95         uint q, unused;
  96         umulExtended(rans, rcp_freq, q, unused);
  97         rans += bias + (q >> rcp_shift) * cmpl_freq;
  98 }
  99
 100 void RansEncFlush(uint rans, inout uint rans_offset)
 101 {
 102         rans_offset -= 4;
 103         rans_output[rans_offset + 0] = uint8_t(rans >> 0);
 104         rans_output[rans_offset + 1] = uint8_t(rans >> 8);
 105         rans_output[rans_offset + 2] = uint8_t(rans >> 16);
 106         rans_output[rans_offset + 3] = uint8_t(rans >> 24);
 107 }
 108
 109 int sign_extend(uint coeff, uint bits)
 110 {
 111         return int(coeff << (32 - bits)) >> (32 - bits);
 112 }
 113
 114 void encode_coeff(int signed_k, inout RansEncoder enc)
 115 {
 116         uint k = abs(signed_k);
 117
 118         if (k >= ESCAPE_LIMIT) {
 119                 // Put the coefficient as a 1/(2^12) symbol _before_
 120                 // the 255 coefficient, since the decoder will read the
 121                 // 255 coefficient first.
 122                 RansEncPut(enc.rans, enc.rans_offset, k, 1, prob_bits);
 123                 k = ESCAPE_LIMIT;
 124         }
 125
 126         uvec4 sym = ransdist[enc.lut_base + ((k - 1) & (NUM_SYMS - 1))];
 127         RansEncPutSymbol(enc.rans, enc.rans_offset, sym);
 128
 129         if (signed_k < 0) {
 130                 enc.rans += enc.sign_bias;
 131         }
 132 }
 133
 134 void encode_end(inout RansEncoder enc)
 135 {
 136         RansEncFlush(enc.rans, enc.rans_offset);
 137         rans_start_offset[enc.stream_num] = enc.rans_offset;
 138 }
 139
 140 void encode_9_7(uint streamgroup_num, uint coeff_row, layout(r16ui) restrict readonly uimage2D tex, uint col1, uint col2, uint dist1, uint dist2)
 141 {
 142         RansEncoder enc1, enc2;
 143         RansEncInit(streamgroup_num, coeff_row, col1, dist1, enc1);
 144         RansEncInit(streamgroup_num, coeff_row, col2, dist2, enc2);
 145
 146         for (uint subblock_idx = 0; subblock_idx < BLOCKS_PER_STREAM; ++subblock_idx) {
 147                 // TODO: Use SSBOs instead of a texture?
 148                 uint x = (streamgroup_num * BLOCKS_PER_STREAM + subblock_idx) % 160;
 149                 uint y = (streamgroup_num * BLOCKS_PER_STREAM + subblock_idx) / 160;
 150                 uint f = imageLoad(tex, ivec2(x, y * 8 + coeff_row)).x;
 151
 152                 encode_coeff(sign_extend(f & 0x1ffu, 9), enc1);
 153                 encode_coeff(sign_extend(f >> 9, 7), enc2);
 154         }
 155
 156         encode_end(enc1);
 157         encode_end(enc2);
 158 }
 159
 160 void encode_8(uint streamgroup_num, uint coeff_row, layout(r8i) restrict readonly iimage2D tex, uint col, uint dist)
 161 {
 162         RansEncoder enc;
 163         RansEncInit(streamgroup_num, coeff_row, col, dist, enc);
 164
 165         for (uint subblock_idx = 0; subblock_idx < BLOCKS_PER_STREAM; ++subblock_idx) {
 166                 // TODO: Use SSBOs instead of a texture?
 167                 uint x = (streamgroup_num * BLOCKS_PER_STREAM + subblock_idx) % 160;
 168                 uint y = (streamgroup_num * BLOCKS_PER_STREAM + subblock_idx) / 160;
 169                 int f = imageLoad(tex, ivec2(x, y * 8 + coeff_row)).x;
 170
 171                 encode_coeff(f, enc);
 172         }
 173
 174         encode_end(enc);
 175 }
 176
 177 void main()
 178 {
 179         uint streamgroup_num = gl_WorkGroupID.x;
 180         uint coeff_row = gl_WorkGroupID.y;    // 0..7
 181         uint coeff_colset = gl_WorkGroupID.z;   // 0 = dc+ac7, 1 = ac1+ac6, 2 = ac2+ac5, 3 = ac3, 4 = ac5
 182         uint m = luma_mapping[coeff_row];
 183
 184         // TODO: DC coeff pred
 185
 186         if (coeff_colset == 0) {
 187                 uint dist_dc = bitfieldExtract(m, 0, 2);
 188                 uint dist_ac7 = bitfieldExtract(m, 14, 2);
 189                 encode_9_7(streamgroup_num, coeff_row, dc_ac7_tex, 0, 7, dist_dc, dist_ac7);
 190         } else if (coeff_colset == 1) {
 191                 uint dist_ac1 = bitfieldExtract(m, 2, 2);
 192                 uint dist_ac6 = bitfieldExtract(m, 12, 2);
 193                 encode_9_7(streamgroup_num, coeff_row, ac1_ac6_tex, 1, 6, dist_ac1, dist_ac6);
 194         } else if (coeff_colset == 2) {
 195                 uint dist_ac2 = bitfieldExtract(m, 4, 2);
 196                 uint dist_ac5 = bitfieldExtract(m, 10, 2);
 197                 encode_9_7(streamgroup_num, coeff_row, ac2_ac5_tex, 2, 5, dist_ac2, dist_ac5);
 198         } else if (coeff_colset == 3) {
 199                 uint dist_ac3 = bitfieldExtract(m, 6, 2);
 200                 encode_8(streamgroup_num, coeff_row, ac3_tex, 3, dist_ac3);
 201         } else {
 202                 uint dist_ac4 = bitfieldExtract(m, 8, 2);
 203                 encode_8(streamgroup_num, coeff_row, ac4_tex, 4, dist_ac4);
 204         }
 205 }