git.sesse.net Git - plocate/blob - meson.build

   1 project('plocate', 'cpp', default_options: ['buildtype=debugoptimized','cpp_std=c++17'], version: '1.0.6-pre')
   2
   3 # Make the version available as a #define.
   4 add_project_arguments('-DPLOCATE_VERSION="' + meson.project_version() + '"', language: 'cpp')
   5
   6 cxx = meson.get_compiler('cpp')
   7 uringdep = dependency('liburing', required: false)
   8 zstddep = dependency('libzstd')
   9 threaddep = dependency('threads')
  10 atomicdep = cxx.find_library('atomic', required: false)
  11
  12 if not uringdep.found()
  13         add_project_arguments('-DWITHOUT_URING', language: 'cpp')
  14 endif
  15
  16 # Function multiversioning is x86-only _and_ not available on certain targets
  17 # (they need “ifunc”, indirect functions, a GNU extension).
  18 code = '''__attribute__((target("default"))) void foo();
  19 __attribute__((target("sse2"))) void foo();
  20 void bar() { foo(); }'''
  21 if cxx.compiles(code, name: 'function multiversioning')
  22         add_project_arguments('-DHAS_FUNCTION_MULTIVERSIONING', language: 'cpp')
  23 endif
  24
  25 executable('plocate', ['plocate.cpp', 'io_uring_engine.cpp', 'turbopfor.cpp', 'parse_trigrams.cpp', 'serializer.cpp', 'access_rx_cache.cpp', 'needle.cpp'],
  26         dependencies: [uringdep, zstddep, threaddep, atomicdep],
  27         install: true,
  28         install_mode: ['rwxr-sr-x', 'root', 'mlocate'])
  29 executable('plocate-build', 'plocate-build.cpp',
  30         dependencies: [zstddep],
  31         install: true,
  32         install_dir: get_option('sbindir'))
  33
  34 conf_data = configuration_data()
  35 conf_data.set('PROCESSED_BY_MESON', '1')
  36 conf_data.set('sbindir', get_option('prefix') + '/' + get_option('sbindir'))
  37 conf_data.set('locategroup', get_option('locategroup'))
  38 update_script = configure_file(input: 'update-plocate.sh',
  39                output: 'update-plocate.sh',
  40                configuration: conf_data)
  41
  42 if get_option('install_cron')
  43         install_data(update_script,
  44                 install_dir: '/etc/cron.daily',
  45                 rename: 'plocate')
  46 endif
  47 install_man('plocate.1')
  48 install_man('plocate-build.8')
  49
  50 # Requires having TurboPFor checked out, so not built by default.
  51 # Unless you have a recent Meson, there's no apparently good way
  52 # of calling into that directory to run make, and we're not
  53 # replicating their build system, so it has to be manual.
  54 pfordir = meson.source_root() + '/TurboPFor-Integer-Compression'
  55 if run_command('[', '-r', pfordir + '/libic.a', ']').returncode() == 0
  56         turbopfordep = declare_dependency(
  57                 include_directories: include_directories('TurboPFor-Integer-Compression'),
  58                 dependencies: meson.get_compiler('cpp').find_library('ic', dirs: pfordir))
  59         executable('bench', ['bench.cpp', 'io_uring_engine.cpp', 'turbopfor.cpp'],
  60                 dependencies: [uringdep, turbopfordep],
  61                 build_by_default: false,
  62                 install: false)
  63 endif