git.sesse.net Git - plocate/blob - meson.build

   1 project('plocate', 'cpp', default_options: ['buildtype=debugoptimized','cpp_std=c++17'], version: '1.0.8-pre')
   2
   3 add_project_arguments('-DGROUPNAME="' + get_option('locategroup') + '"', language: 'cpp')
   4 add_project_arguments('-DUPDATEDB_CONF="/etc/updatedb.conf"', language: 'cpp')
   5 dbdir = join_paths(get_option('sharedstatedir'), 'plocate')
   6 dbfile = join_paths(dbdir, 'plocate.db')
   7 add_project_arguments('-DDBFILE="' + dbfile + '"', language: 'cpp')
   8 add_project_arguments('-DPACKAGE_NAME="plocate"', language: 'cpp')
   9 add_project_arguments('-DPACKAGE_VERSION="' + meson.project_version() + '"', language: 'cpp')
  10 add_project_arguments('-DPACKAGE_BUGREPORT="steinar+plocate@gunderson.no"', language: 'cpp')
  11
  12 cxx = meson.get_compiler('cpp')
  13 uringdep = dependency('liburing', required: false)
  14 zstddep = dependency('libzstd')
  15 threaddep = dependency('threads')
  16 atomicdep = cxx.find_library('atomic', required: false)
  17
  18 if not uringdep.found()
  19         add_project_arguments('-DWITHOUT_URING', language: 'cpp')
  20 endif
  21 if cxx.has_header('endian.h')
  22         add_project_arguments('-DHAS_ENDIAN_H', language: 'cpp')
  23 endif
  24
  25 # Function multiversioning is x86-only _and_ not available on certain targets
  26 # (they need “ifunc”, indirect functions, a GNU extension).
  27 code = '''__attribute__((target("default"))) void foo();
  28 __attribute__((target("sse2"))) void foo();
  29 void bar() { foo(); }'''
  30 if cxx.compiles(code, name: 'function multiversioning')
  31         add_project_arguments('-DHAS_FUNCTION_MULTIVERSIONING', language: 'cpp')
  32 endif
  33
  34 executable('plocate', ['plocate.cpp', 'io_uring_engine.cpp', 'turbopfor.cpp', 'parse_trigrams.cpp', 'serializer.cpp', 'access_rx_cache.cpp', 'needle.cpp', 'complete_pread.cpp'],
  35         dependencies: [uringdep, zstddep, threaddep, atomicdep],
  36         install: true,
  37         install_mode: ['rwxr-sr-x', 'root', 'mlocate'])
  38 executable('plocate-build', ['plocate-build.cpp', 'database-builder.cpp'],
  39         dependencies: [zstddep],
  40         install: true,
  41         install_dir: get_option('sbindir'))
  42 executable('updatedb', ['updatedb.cpp', 'database-builder.cpp', 'conf.cpp', 'lib.cpp', 'bind-mount.cpp', 'complete_pread.cpp'],
  43         dependencies: [zstddep, threaddep],
  44         install: true,
  45         install_dir: get_option('sbindir'))
  46
  47 conf_data = configuration_data()
  48 conf_data.set('PROCESSED_BY_MESON', '1')
  49 conf_data.set('sbindir', join_paths(get_option('prefix'), get_option('sbindir')))
  50 conf_data.set('locategroup', get_option('locategroup'))
  51 conf_data.set('dbfile', dbfile)
  52 update_script = configure_file(input: 'update-plocate.sh',
  53                output: 'update-plocate.sh',
  54                configuration: conf_data)
  55
  56 meson.add_install_script('mkdir', '-p', dbdir)
  57
  58 if get_option('install_cron')
  59         install_data(update_script,
  60                 install_dir: '/etc/cron.daily',
  61                 rename: 'plocate')
  62 endif
  63 install_man('plocate.1')
  64 install_man('plocate-build.8')
  65
  66 # Requires having TurboPFor checked out, so not built by default.
  67 # Unless you have a recent Meson, there's no apparently good way
  68 # of calling into that directory to run make, and we're not
  69 # replicating their build system, so it has to be manual.
  70 pfordir = meson.source_root() + '/TurboPFor-Integer-Compression'
  71 if run_command('[', '-r', pfordir + '/libic.a', ']').returncode() == 0
  72         turbopfordep = declare_dependency(
  73                 include_directories: include_directories('TurboPFor-Integer-Compression'),
  74                 dependencies: meson.get_compiler('cpp').find_library('ic', dirs: pfordir))
  75         executable('bench', ['bench.cpp', 'io_uring_engine.cpp', 'turbopfor.cpp'],
  76                 dependencies: [uringdep, turbopfordep],
  77                 build_by_default: false,
  78                 install: false)
  79 endif