git.sesse.net Git - plocate/blob - meson.build

   1 project('plocate', 'cpp', default_options: ['buildtype=debugoptimized','cpp_std=c++17'], version: '1.1.0')
   2
   3 add_project_arguments('-DGROUPNAME="' + get_option('locategroup') + '"', language: 'cpp')
   4 add_project_arguments('-DUPDATEDB_CONF="/etc/updatedb.conf"', language: 'cpp')
   5 dbdir = join_paths(get_option('sharedstatedir'), 'plocate')
   6 dbfile = join_paths(dbdir, 'plocate.db')
   7 add_project_arguments('-DDBFILE="' + dbfile + '"', language: 'cpp')
   8 add_project_arguments('-DPACKAGE_NAME="plocate"', language: 'cpp')
   9 add_project_arguments('-DPACKAGE_VERSION="' + meson.project_version() + '"', language: 'cpp')
  10 add_project_arguments('-DPACKAGE_BUGREPORT="steinar+plocate@gunderson.no"', language: 'cpp')
  11
  12 cxx = meson.get_compiler('cpp')
  13 uringdep = dependency('liburing', required: false)
  14 zstddep = dependency('libzstd')
  15 threaddep = dependency('threads')
  16 atomicdep = cxx.find_library('atomic', required: false)
  17
  18 if not uringdep.found()
  19         add_project_arguments('-DWITHOUT_URING', language: 'cpp')
  20 endif
  21 if cxx.has_header('endian.h')
  22         add_project_arguments('-DHAS_ENDIAN_H', language: 'cpp')
  23 endif
  24
  25 # Function multiversioning is x86-only _and_ not available on certain targets
  26 # (they need “ifunc”, indirect functions, a GNU extension).
  27 code = '''__attribute__((target("default"))) void foo();
  28 __attribute__((target("sse2"))) void foo();
  29 void bar() { foo(); }'''
  30 if cxx.compiles(code, name: 'function multiversioning')
  31         add_project_arguments('-DHAS_FUNCTION_MULTIVERSIONING', language: 'cpp')
  32 endif
  33
  34 executable('plocate', ['plocate.cpp', 'io_uring_engine.cpp', 'turbopfor.cpp', 'parse_trigrams.cpp', 'serializer.cpp', 'access_rx_cache.cpp', 'needle.cpp', 'complete_pread.cpp'],
  35         dependencies: [uringdep, zstddep, threaddep, atomicdep],
  36         install: true,
  37         install_mode: ['rwxr-sr-x', 'root', get_option('locategroup')])
  38 executable('plocate-build', ['plocate-build.cpp', 'database-builder.cpp'],
  39         dependencies: [zstddep],
  40         install: true,
  41         install_dir: get_option('sbindir'))
  42 executable('updatedb', ['updatedb.cpp', 'database-builder.cpp', 'conf.cpp', 'lib.cpp', 'bind-mount.cpp', 'complete_pread.cpp'],
  43         dependencies: [zstddep, threaddep],
  44         install: true,
  45         install_dir: get_option('sbindir'))
  46
  47 conf_data = configuration_data()
  48 conf_data.set('PROCESSED_BY_MESON', '1')
  49 conf_data.set('sbindir', join_paths(get_option('prefix'), get_option('sbindir')))
  50 conf_data.set('groupname', get_option('locategroup'))
  51 conf_data.set('dbfile', dbfile)
  52 conf_data.set('updatedb_conf', '/etc/updatedb.conf')
  53 update_script = configure_file(input: 'update-plocate.sh',
  54                output: 'update-plocate.sh',
  55                configuration: conf_data)
  56
  57 meson.add_install_script('mkdir.sh', dbdir)
  58
  59 if get_option('install_cron')
  60         install_data(update_script,
  61                 install_dir: '/etc/cron.daily',
  62                 rename: 'plocate')
  63 endif
  64 install_man('plocate.1')
  65 install_man('plocate-build.8')
  66
  67 updatedb_man = configure_file(input: 'updatedb.8.in',
  68                output: 'updatedb.8',
  69                configuration: conf_data)
  70 install_man(updatedb_man)
  71
  72 updatedb_conf_man = configure_file(input: 'updatedb.conf.5.in',
  73                output: 'updatedb.conf.5',
  74                configuration: conf_data)
  75 install_man(updatedb_conf_man)
  76
  77 if get_option('install_systemd')
  78         systemd = dependency('systemd', required: false)
  79         if systemd.found()
  80                 unitdir = systemd.get_pkgconfig_variable('systemdsystemunitdir')
  81                 updatedb_service = configure_file(input: 'plocate-updatedb.service.in',
  82                        output: 'plocate-updatedb.service',
  83                        configuration: conf_data)
  84                 install_data(updatedb_service, install_dir: unitdir)
  85                 install_data('plocate-updatedb.timer', install_dir: unitdir)
  86         endif
  87 endif
  88
  89 # Requires having TurboPFor checked out, so not built by default.
  90 # Unless you have a recent Meson, there's no apparently good way
  91 # of calling into that directory to run make, and we're not
  92 # replicating their build system, so it has to be manual.
  93 pfordir = meson.source_root() + '/TurboPFor-Integer-Compression'
  94 if run_command('[', '-r', pfordir + '/libic.a', ']').returncode() == 0
  95         turbopfordep = declare_dependency(
  96                 include_directories: include_directories('TurboPFor-Integer-Compression'),
  97                 dependencies: meson.get_compiler('cpp').find_library('ic', dirs: pfordir))
  98         executable('bench', ['bench.cpp', 'io_uring_engine.cpp', 'turbopfor.cpp'],
  99                 dependencies: [uringdep, turbopfordep],
 100                 build_by_default: false,
 101                 install: false)
 102 endif