git.sesse.net Git - plocate/blob - meson.build

   1 project('plocate', 'cpp', default_options: ['buildtype=debugoptimized','cpp_std=c++17'], version: '1.0.4-pre')
   2
   3 # Make the version available as a #define.
   4 add_project_arguments('-DPLOCATE_VERSION="' + meson.project_version() + '"', language: 'cpp')
   5
   6 cxx = meson.get_compiler('cpp')
   7 uringdep = dependency('liburing', required: false)
   8 zstddep = dependency('libzstd')
   9
  10 if not uringdep.found()
  11         add_project_arguments('-DWITHOUT_URING', language: 'cpp')
  12 endif
  13
  14 executable('plocate', ['plocate.cpp', 'io_uring_engine.cpp', 'turbopfor.cpp', 'parse_trigrams.cpp'],
  15         dependencies: [uringdep, zstddep],
  16         install: true,
  17         install_mode: ['rwxr-sr-x', 'root', 'mlocate'])
  18 executable('plocate-build', 'plocate-build.cpp',
  19         dependencies: [zstddep],
  20         install: true,
  21         install_dir: get_option('sbindir'))
  22
  23 conf_data = configuration_data()
  24 conf_data.set('PROCESSED_BY_MESON', '1')
  25 conf_data.set('sbindir', get_option('prefix') + '/' + get_option('sbindir'))
  26 conf_data.set('locategroup', get_option('locategroup'))
  27 update_script = configure_file(input: 'update-plocate.sh',
  28                output: 'update-plocate.sh',
  29                configuration: conf_data)
  30
  31 if get_option('install_cron')
  32         install_data(update_script,
  33                 install_dir: '/etc/cron.daily',
  34                 rename: 'plocate')
  35 endif
  36 install_man('plocate.1')
  37 install_man('plocate-build.8')
  38
  39 # Requires having TurboPFor checked out, so not built by default.
  40 # Unless you have a recent Meson, there's no apparently good way
  41 # of calling into that directory to run make, and we're not
  42 # replicating their build system, so it has to be manual.
  43 pfordir = meson.source_root() + '/TurboPFor-Integer-Compression'
  44 if run_command('[', '-r', pfordir + '/libic.a', ']').returncode() == 0
  45         turbopfordep = declare_dependency(
  46                 include_directories: include_directories('TurboPFor-Integer-Compression'),
  47                 dependencies: meson.get_compiler('cpp').find_library('ic', dirs: pfordir))
  48         executable('bench', ['bench.cpp', 'io_uring_engine.cpp', 'turbopfor.cpp'],
  49                 dependencies: [uringdep, turbopfordep],
  50                 build_by_default: false,
  51                 install: false)
  52 endif