git.sesse.net Git - remoteglot-book/blob - www/opening-stats.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 use CGI;
   5 use JSON::XS;
   6 use lib '..';
   7 use Position;
   8 use IPC::Open2;
   9 use Chess::PGN::Parse;
  10
  11 our %openings = ();
  12 read_openings();
  13
  14 my $cgi = CGI->new;
  15 my ($chld_out, $chld_in);
  16 my $pid = IPC::Open2::open2($chld_out, $chld_in, "../binlookup", "../open.mtbl", "40");
  17
  18 # Root position. Basically ignore everything except the opening (and later some root game stuff).
  19 my $fen = $cgi->param('fen') // 'rnbqkbnr/pppppppp/8/8/8/8/PPPPPPPP/RNBQKBNR w KQkq - 0 1';
  20 my $pos = Position->from_fen($fen);
  21 my $hex = unpack('H*', $pos->bitpacked_fen);
  22 print $chld_in $hex, "\n";
  23 chomp (my $line = <$chld_out>);
  24
  25 my ($white, $draw, $black, $opening_num, $white_avg_elo, $black_avg_elo, $num_elo, $timestamp, $pgn_file_number, $pgn_start_position, @moves) = split / /, $line;
  26 my $opening = $openings{$opening_num} // 'A00: Start position';
  27
  28 my $root_game;
  29 eval {
  30         die "Missing PGN position data." if (!defined($pgn_file_number) || !defined($pgn_start_position));
  31         my $pgntext = read_root_pgn($pgn_file_number, $pgn_start_position);
  32         my $pgn = Chess::PGN::Parse->new(undef, $pgntext);
  33         $pgn->read_game() or die;
  34         $pgn->parse_game() or die;
  35
  36         my $tags = $pgn->tags;
  37         $root_game = {};
  38         $root_game->{'white'} = $pgn->white;
  39         $root_game->{'white_elo'} = $tags->{'WhiteElo'};
  40         $root_game->{'black'} = $pgn->black;
  41         $root_game->{'black_elo'} = $tags->{'BlackElo'};
  42         $root_game->{'event'} = $pgn->event;
  43         $root_game->{'date'} = $pgn->date;
  44         $root_game->{'result'} = $pgn->result;
  45         $root_game->{'eco'} = $pgn->eco;
  46         $root_game->{'moves'} = scalar @{$pgn->moves};
  47 };
  48
  49 # Explore one move out.
  50 my @json_moves = ();
  51 for my $move (@moves) {
  52         my ($np, $uci_move) = $pos->make_pretty_move($move);
  53         my $hex = unpack('H*', $np->bitpacked_fen);
  54         print $chld_in $hex, "\n";
  55         my $line = <$chld_out>;
  56         my ($white, $draw, $black, $opening_num, $white_avg_elo, $black_avg_elo, $num_elo) = split / /, $line;
  57         push @json_moves, {
  58                 move => $move,
  59                 white => $white * 1,
  60                 draw => $draw * 1,
  61                 black => $black * 1,
  62                 white_avg_elo => $white_avg_elo * 1,
  63                 black_avg_elo => $black_avg_elo * 1,
  64                 num_elo => $num_elo * 1
  65         };
  66 }
  67
  68 print $cgi->header(-type=>'application/json');
  69 print JSON::XS::encode_json({ moves => \@json_moves, opening => $opening, root_game => $root_game });
  70
  71 sub read_openings {
  72         open my $fh, "../openings.txt"
  73                 or die "../openings.txt: $!";
  74         for my $line (<$fh>) {
  75                 chomp $line;
  76                 my ($hash, $eco, $opening, $variation, $subvariation) = split /\t/, $line;
  77                 if ($variation eq '') {
  78                         $openings{$hash} = $eco . ": " . $opening;
  79                 } else {
  80                         $openings{$hash} = $eco . ": " . $opening . ": " . $variation;
  81                 }
  82         }
  83         close $fh;
  84 }
  85
  86 sub read_root_pgn {
  87         my @pgnnames;
  88         open my $pgnnamesfh, "<", "../pgnnames.txt"
  89                 or die "../pgnnames.txt: $!";
  90         while (<$pgnnamesfh>) {
  91                 chomp;
  92                 push @pgnnames, $_;
  93         }
  94         close $pgnnamesfh;
  95
  96         if ($pgn_file_number > $#pgnnames) {
  97                 die "Unknown PGN file number $pgn_file_number";
  98         }
  99
 100         my $root_pgn;
 101         open my $pgnfh, "<", "../" . $pgnnames[$pgn_file_number]
 102                 or die $pgnnames[$pgn_file_number] . ": $!";
 103         sysseek($pgnfh, $pgn_start_position, 0)
 104                 or die "Could not seek to $pgn_start_position: $!";
 105         sysread($pgnfh, $root_pgn, 32768)
 106                 or die "Could not read PGN from $pgn_start_position at $pgnnames[$pgn_file_number]: $!";
 107         close $pgnfh;
 108         $root_pgn =~ s/^.*?(\[Event )/$1/s;
 109         $root_pgn =~ s/^(.+?)\[Event .*/$1/s;
 110
 111         return $root_pgn;
 112 }