Inform the engine if we have a Chess960 game.
[remoteglot] / Board.pm
1 #! /usr/bin/perl
2 #
3 # There are too many chess modules on CPAN already, so here's another one...
4 #
5 use strict;
6 use warnings;
7
8 package Board;
9
10 sub new {
11         my ($class, @rows) = @_;
12         my $board = [];
13
14         for my $row (0..7) {
15                 for my $col (0..7) {
16                         $board->[$row][$col] = substr($rows[$row], $col, 1);
17                 }
18         }
19
20         return bless $board;
21 }
22
23 sub clone {
24         my ($board) = shift;
25         my $nb = [];
26
27         for my $row (0..7) {
28                 $nb->[$row] = [ @{$board->[$row]} ];
29         }
30
31         return bless $nb;
32 }
33
34 # Returns a new board.
35 sub make_move {
36         my ($board, $from_row, $from_col, $to_row, $to_col, $promo) = @_;
37         my $move = move_to_uci_notation($from_row, $from_col, $to_row, $to_col, $promo);
38         my $piece = $board->[$from_row][$from_col];
39         my $nb = $board->clone();
40
41         if ($piece eq '-') {
42                 die "Invalid move $move";
43         }
44
45         # white short castling
46         if ($move eq 'e1g1' && $piece eq 'K') {
47                 # king
48                 $nb->[7][4] = '-';
49                 $nb->[7][6] = $piece;
50
51                 # rook
52                 $nb->[7][7] = '-';
53                 $nb->[7][5] = 'R';
54
55                 return $nb;
56         }
57
58         # white long castling
59         if ($move eq 'e1c1' && $piece eq 'K') {
60                 # king
61                 $nb->[7][4] = '-';
62                 $nb->[7][2] = $piece;
63
64                 # rook
65                 $nb->[7][0] = '-';
66                 $nb->[7][3] = 'R';
67
68                 return $nb;
69         }
70
71         # black short castling
72         if ($move eq 'e8g8' && $piece eq 'k') {
73                 # king
74                 $nb->[0][4] = '-';
75                 $nb->[0][6] = $piece;
76
77                 # rook
78                 $nb->[0][7] = '-';
79                 $nb->[0][5] = 'r';
80
81                 return $nb;
82         }
83
84         # black long castling
85         if ($move eq 'e8c8' && $piece eq 'k') {
86                 # king
87                 $nb->[0][4] = '-';
88                 $nb->[0][2] = $piece;
89
90                 # rook
91                 $nb->[0][0] = '-';
92                 $nb->[0][3] = 'r';
93
94                 return $nb;
95         }
96
97         # check if the from-piece is a pawn
98         if (lc($piece) eq 'p') {
99                 # attack?
100                 if ($from_col != $to_col) {
101                         # en passant?
102                         if ($board->[$to_row][$to_col] eq '-') {
103                                 if ($piece eq 'p') {
104                                         $nb->[$to_row - 1][$to_col] = '-';
105                                 } else {
106                                         $nb->[$to_row + 1][$to_col] = '-';
107                                 }
108                         }
109                 }
110                 if (defined($promo) && $promo ne '') {
111                         if ($piece eq 'p') {
112                                 $piece = lc($promo);
113                         } else {
114                                 $piece = uc($promo);
115                         }
116                 }
117         }
118
119         # update the board
120         $nb->[$from_row][$from_col] = '-';
121         $nb->[$to_row][$to_col] = $piece;
122
123         return $nb;
124 }
125
126 sub _pos_to_square {
127         my ($row, $col) = @_;
128         return sprintf("%c%d", ord('a') + $col, 8 - $row);
129 }
130
131 sub _col_letter_to_num {
132         return ord(shift) - ord('a');
133 }
134
135 sub _row_letter_to_num {
136         return 7 - (ord(shift) - ord('1'));
137 }
138
139 sub _square_to_pos {
140         my ($square) = @_;
141         $square =~ /^([a-h])([1-8])$/ or die "Invalid square $square";  
142         return (_row_letter_to_num($2), _col_letter_to_num($1));
143 }
144
145 sub move_to_uci_notation {
146         my ($from_row, $from_col, $to_row, $to_col, $promo) = @_;
147         $promo //= "";
148         return _pos_to_square($from_row, $from_col) . _pos_to_square($to_row, $to_col) . $promo;
149 }
150
151 # Note: This is in general not a validation that the move is actually allowed
152 # (e.g. you can castle even though you're in check).
153 sub parse_pretty_move {
154         my ($board, $move, $toplay) = @_;
155
156         # Strip check or mate
157         $move =~ s/[+#]$//;
158
159         if ($move eq '0-0' or $move eq 'O-O') {
160                 if ($toplay eq 'W') {
161                         return (_square_to_pos('e1'), _square_to_pos('g1'));
162                 } else {
163                         return (_square_to_pos('e8'), _square_to_pos('g8'));
164                 }
165         } elsif ($move eq '0-0-0' or $move eq 'O-O-O') {
166                 if ($toplay eq 'W') {
167                         return (_square_to_pos('e1'), _square_to_pos('c1'));
168                 } else {
169                         return (_square_to_pos('e8'), _square_to_pos('c8'));
170                 }
171         }
172
173         # Parse promo
174         my $promo;
175         if ($move =~ s/=?([QRNB])$//) {
176                 $promo = $1;
177         }
178
179         $move =~ /^([KQRBN])?([a-h])?([1-8])?x?([a-h][1-8])$/ or die "Invalid move $move";
180         my $piece = $1;
181         my $from_col = defined($2) ? _col_letter_to_num($2) : undef;
182         my $from_row = defined($3) ? _row_letter_to_num($3) : undef;
183         if (!defined($piece) && (!defined($from_col) || !defined($from_row))) {
184                 $piece = 'P';
185         }
186         my ($to_row, $to_col) = _square_to_pos($4);
187         
188         # Find all possible from-squares that could have been meant.
189         my @squares = ();
190         my $side = 'K';
191         if ($toplay eq 'B') {
192                 $piece = lc($piece) if defined($piece);
193                 $side = 'k';
194         }
195         for my $row (0..7) {
196                 next if (defined($from_row) && $from_row != $row);
197                 for my $col (0..7) {
198                         next if (defined($from_col) && $from_col != $col);
199                         next if (defined($piece) && $board->[$row][$col] ne $piece);
200                         push @squares, [ $row, $col ];
201                 }
202         }
203         if (scalar @squares > 1) {
204                 # Filter out pieces which cannot reach this square.
205                 @squares = grep { $board->can_reach($piece, $_->[0], $_->[1], $to_row, $to_col) } @squares;
206         }
207         if (scalar @squares > 1) {
208                 # See if doing this move would put us in check
209                 # (yes, there are clients that expect us to do this).
210                 @squares = grep { !$board->make_move($_->[0], $_->[1], $to_row, $to_col, $promo)->in_check($side) } @squares;
211         }
212         if (scalar @squares == 0) {
213                 die "Impossible move $move";
214         }
215         if (scalar @squares != 1) {
216                 die "Ambigious move $move";
217         }
218         return (@{$squares[0]}, $to_row, $to_col, $promo);
219 }
220
221 sub fen {
222         my ($board) = @_;
223         my @rows = ();
224         for my $row (0..7) {
225                 my $str = join('', @{$board->[$row]});
226                 $str =~ s/(-+)/length($1)/ge;
227                 push @rows, $str;
228         }
229
230         return join('/', @rows);
231 }
232
233 # Returns a compact bit string describing the same data as fen().
234 # This is encoded using a Huffman-like encoding, and should be
235 # typically about 1/3 the number of bytes.
236 sub can_reach {
237         my ($board, $piece, $from_row, $from_col, $to_row, $to_col) = @_;
238         
239         # can't eat your own piece
240         my $dest_piece = $board->[$to_row][$to_col];
241         if ($dest_piece ne '-') {
242                 return 0 if (($piece eq lc($piece)) == ($dest_piece eq lc($dest_piece)));
243         }
244         
245         if ($piece eq 'p') {
246                 # black pawn
247                 if ($to_col == $from_col && $to_row == $from_row + 1) {
248                         return ($dest_piece eq '-');
249                 }
250                 if ($to_col == $from_col && $from_row == 1 && $to_row == 3) {
251                         my $middle_piece = $board->[2][$to_col];
252                         return ($dest_piece eq '-' && $middle_piece eq '-');
253                 }
254                 if (abs($to_col - $from_col) == 1 && $to_row == $from_row + 1) {
255                         if ($dest_piece eq '-') {
256                                 # En passant. TODO: check that the last move was indeed an EP move
257                                 return ($to_row == 5 && $board->[4][$to_col] eq 'P');
258                         } else {
259                                 return 1;
260                         }
261                 }
262                 return 0;
263         }
264         if ($piece eq 'P') {
265                 # white pawn
266                 if ($to_col == $from_col && $to_row == $from_row - 1) {
267                         return ($dest_piece eq '-');
268                 }
269                 if ($to_col == $from_col && $from_row == 6 && $to_row == 4) {
270                         my $middle_piece = $board->[5][$to_col];
271                         return ($dest_piece eq '-' && $middle_piece eq '-');
272                 }
273                 if (abs($to_col - $from_col) == 1 && $to_row == $from_row - 1) {
274                         if ($dest_piece eq '-') {
275                                 # En passant. TODO: check that the last move was indeed an EP move
276                                 return ($to_row == 2 && $board->[3][$to_col] eq 'p');
277                         } else {
278                                 return 1;
279                         }
280                 }
281                 return 0;
282         }
283         
284         if (lc($piece) eq 'r') {
285                 return 0 unless ($from_row == $to_row || $from_col == $to_col);
286
287                 # check that there's a clear passage
288                 if ($from_row == $to_row) {
289                         if ($from_col > $to_col) {
290                                 ($to_col, $from_col) = ($from_col, $to_col);
291                         }
292
293                         for my $c (($from_col+1)..($to_col-1)) {
294                                 my $middle_piece = $board->[$to_row][$c];
295                                 return 0 if ($middle_piece ne '-');
296                         }
297
298                         return 1;
299                 } else {
300                         if ($from_row > $to_row) {
301                                 ($to_row, $from_row) = ($from_row, $to_row);
302                         }
303
304                         for my $r (($from_row+1)..($to_row-1)) {
305                                 my $middle_piece = $board->[$r][$to_col];
306                                 return 0 if ($middle_piece ne '-');     
307                         }
308
309                         return 1;
310                 }
311         }
312         if (lc($piece) eq 'b') {
313                 return 0 unless (abs($from_row - $to_row) == abs($from_col - $to_col));
314
315                 my $dr = ($to_row - $from_row) / abs($to_row - $from_row);
316                 my $dc = ($to_col - $from_col) / abs($to_col - $from_col);
317
318                 my $r = $from_row + $dr;
319                 my $c = $from_col + $dc;
320
321                 while ($r != $to_row) {
322                         my $middle_piece = $board->[$r][$c];
323                         return 0 if ($middle_piece ne '-');
324                         
325                         $r += $dr;
326                         $c += $dc;
327                 }
328
329                 return 1;
330         }
331         if (lc($piece) eq 'n') {
332                 my $diff_r = abs($from_row - $to_row);
333                 my $diff_c = abs($from_col - $to_col);
334                 return 1 if ($diff_r == 2 && $diff_c == 1);
335                 return 1 if ($diff_r == 1 && $diff_c == 2);
336                 return 0;
337         }
338         if ($piece eq 'q') {
339                 return (can_reach($board, 'r', $from_row, $from_col, $to_row, $to_col) ||
340                         can_reach($board, 'b', $from_row, $from_col, $to_row, $to_col));
341         }
342         if ($piece eq 'Q') {
343                 return (can_reach($board, 'R', $from_row, $from_col, $to_row, $to_col) ||
344                         can_reach($board, 'B', $from_row, $from_col, $to_row, $to_col));
345         }
346         if (lc($piece) eq 'k') {
347                 return (abs($from_row - $to_row) <= 1 && abs($from_col - $to_col) <= 1);
348         }
349
350         # unknown piece
351         return 0;
352 }
353
354 # Like can_reach, but also checks the move doesn't put the side in check.
355 # We use this in prettyprint_move to reduce the disambiguation, because Chess.js
356 # needs moves to be in minimally disambiguated form.
357 sub can_legally_reach {
358         my ($board, $piece, $from_row, $from_col, $to_row, $to_col) = @_;
359
360         return 0 if (!can_reach($board, $piece, $from_row, $from_col, $to_row, $to_col));
361
362         my $nb = $board->make_move($from_row, $from_col, $to_row, $to_col);
363         my $side = ($piece eq lc($piece)) ? 'k' : 'K';
364
365         return !in_check($nb, $side);
366 }
367
368 my %pieces_against_side = (
369         k => { K => 1, Q => 1, R => 1, N => 1, B => 1, P => 1 },
370         K => { k => 1, q => 1, r => 1, n => 1, b => 1, p => 1 },
371 );
372
373 # Returns whether the given side (given as k or K for black and white) is in check.
374 sub in_check {
375         my ($board, $side) = @_;
376         my ($kr, $kc) = _find_piece($board, $side);
377
378         # check all pieces for the possibility of threatening this king
379         for my $row (0..7) {
380                 next unless grep { exists($pieces_against_side{$side}{$_}) } @{$board->[$row]};
381                 for my $col (0..7) {
382                         my $piece = $board->[$row][$col];
383                         next if ($piece eq '-');
384                         return 1 if ($board->can_reach($piece, $row, $col, $kr, $kc));
385                 }
386         }
387
388         return 0;
389 }
390
391 sub _find_piece {
392         my ($board, $piece) = @_;
393
394         for my $row (0..7) {
395                 next unless grep { $_ eq $piece } @{$board->[$row]};
396                 for my $col (0..7) {
397                         if ($board->[$row][$col] eq $piece) {
398                                 return ($row, $col);
399                         }
400                 }
401         }
402
403         return (undef, undef);
404 }
405
406 # Returns if the given side (given as k or K) is in mate.
407 sub in_mate {
408         my ($board, $side, $in_check) = @_;
409         return 0 if (!$in_check);
410
411         # try all possible moves for the side in check
412         for my $row (0..7) {
413                 for my $col (0..7) {
414                         my $piece = $board->[$row][$col];
415                         next if ($piece eq '-');
416
417                         if ($side eq 'K') {
418                                 next if ($piece eq lc($piece));
419                         } else {
420                                 next if ($piece eq uc($piece));
421                         }
422
423                         for my $dest_row (0..7) {
424                                 for my $dest_col (0..7) {
425                                         next if ($row == $dest_row && $col == $dest_col);
426                                         next unless ($board->can_reach($piece, $row, $col, $dest_row, $dest_col));
427
428                                         my $nb = $board->make_move($row, $col, $dest_row, $dest_col);
429                                         return 0 if (!$nb->in_check($side));
430                                 }
431                         }
432                 }
433         }
434
435         # nothing to do; mate
436         return 1;
437 }
438
439 # Returns the short algebraic form of the move, as well as the new position.
440 sub prettyprint_move {
441         my ($board, $from_row, $from_col, $to_row, $to_col, $promo) = @_;
442         my $pretty = $board->_prettyprint_move_no_check_or_mate($from_row, $from_col, $to_row, $to_col, $promo);
443
444         my $nb = $board->make_move($from_row, $from_col, $to_row, $to_col, $promo);
445
446         my $piece = $board->[$from_row][$from_col];
447         my $other_side = (uc($piece) eq $piece) ? 'k' : 'K';
448         my $in_check = $nb->in_check($other_side);
449         if ($nb->in_mate($other_side, $in_check)) {
450                 $pretty .= '#';
451         } elsif ($in_check) {
452                 $pretty .= '+';
453         }
454         return ($pretty, $nb);
455 }
456
457 sub num_pieces {
458         my ($board) = @_;
459
460         my $num = 0;
461         for my $row (0..7) {
462                 for my $col (0..7) {
463                         my $piece = $board->[$row][$col];
464                         ++$num if ($piece ne '-');
465                 }
466         }
467         return $num;    
468 }
469
470 sub _prettyprint_move_no_check_or_mate {
471         my ($board, $from_row, $from_col, $to_row, $to_col, $promo) = @_;
472         my $piece = $board->[$from_row][$from_col];
473         my $move = move_to_uci_notation($from_row, $from_col, $to_row, $to_col, $promo);
474
475         if ($piece eq '-') {
476                 die "Invalid move $move";
477         }
478
479         # white short castling
480         if ($move eq 'e1g1' && $piece eq 'K') {
481                 return 'O-O';
482         }
483
484         # white long castling
485         if ($move eq 'e1c1' && $piece eq 'K') {
486                 return 'O-O-O';
487         }
488
489         # black short castling
490         if ($move eq 'e8g8' && $piece eq 'k') {
491                 return 'O-O';
492         }
493
494         # black long castling
495         if ($move eq 'e8c8' && $piece eq 'k') {
496                 return 'O-O-O';
497         }
498
499         my $pretty;
500
501         # check if the from-piece is a pawn
502         if (lc($piece) eq 'p') {
503                 # attack?
504                 if ($from_col != $to_col) {
505                         $pretty = substr($move, 0, 1) . 'x' . _pos_to_square($to_row, $to_col);
506                 } else {
507                         $pretty = _pos_to_square($to_row, $to_col);
508                 }
509
510                 if (defined($promo) && $promo ne '') {
511                         # promotion
512                         $pretty .= "=";
513                         $pretty .= uc($promo);
514                 }
515                 return $pretty;
516         }
517
518         $pretty = uc($piece);
519
520         # see how many of these pieces could go here, in all
521         my $num_total = 0;
522         for my $col (0..7) {
523                 for my $row (0..7) {
524                         next unless ($board->[$row][$col] eq $piece);
525                         ++$num_total if ($board->can_legally_reach($piece, $row, $col, $to_row, $to_col));
526                 }
527         }
528
529         # see how many of these pieces from the given row could go here
530         my $num_row = 0;
531         for my $col (0..7) {
532                 next unless ($board->[$from_row][$col] eq $piece);
533                 ++$num_row if ($board->can_legally_reach($piece, $from_row, $col, $to_row, $to_col));
534         }
535
536         # and same for columns
537         my $num_col = 0;
538         for my $row (0..7) {
539                 next unless ($board->[$row][$from_col] eq $piece);
540                 ++$num_col if ($board->can_legally_reach($piece, $row, $from_col, $to_row, $to_col));
541         }
542
543         # see if we need to disambiguate
544         if ($num_total > 1) {
545                 if ($num_col == 1) {
546                         $pretty .= substr($move, 0, 1);
547                 } elsif ($num_row == 1) {
548                         $pretty .= substr($move, 1, 1);
549                 } else {
550                         $pretty .= substr($move, 0, 2);
551                 }
552         }
553
554         # attack?
555         if ($board->[$to_row][$to_col] ne '-') {
556                 $pretty .= 'x';
557         }
558
559         $pretty .= _pos_to_square($to_row, $to_col);
560         return $pretty;
561 }
562
563 1;