807b0035876e3a261dae1f2e0097c371d7160953
[remoteglot] / Position.pm
1 #! /usr/bin/perl
2 #
3 # There are too many chess modules on CPAN already, so here's another one...
4 #
5 use strict;
6 use warnings;
7 use MIME::Base64;
8
9 require 'Board.pm';
10
11 package Position;
12
13 # Takes in a FICS style 12-type position.
14 sub new {
15         my ($class, $str) = @_;
16         my $pos = {};
17         my (@x) = split / /, $str;
18
19         $pos->{'board'} = Board->new(@x[1..8]);
20         $pos->{'toplay'} = $x[9];
21         $pos->{'ep_file_num'} = $x[10];
22         $pos->{'white_castle_k'} = $x[11];
23         $pos->{'white_castle_q'} = $x[12];
24         $pos->{'black_castle_k'} = $x[13];
25         $pos->{'black_castle_q'} = $x[14];
26         $pos->{'time_since_100move_rule_reset'} = $x[15];
27         $pos->{'player_w'} = $x[17];
28         $pos->{'player_b'} = $x[18];
29         $pos->{'player_w'} =~ s/^W?[FCIG]M//;
30         $pos->{'player_b'} =~ s/^W?[FCIG]M//;
31         $pos->{'white_clock'} = $x[24];
32         $pos->{'black_clock'} = $x[25];
33         $pos->{'move_num'} = $x[26];
34         if ($x[27] =~ /([a-h][1-8])-([a-h][1-8])/) {
35                 $pos->{'last_move_uci'} = $1 . $2;
36         } else {
37                 $pos->{'last_move_uci'} = undef;
38         }
39         $pos->{'last_move'} = $x[29];
40         $pos->{'prettyprint_cache'} = {};
41
42         bless $pos, $class;
43         return $pos;
44 }
45
46 sub start_pos {
47         my ($class, $white, $black) = @_;
48         $white = "base64:" . MIME::Base64::encode_base64($white);
49         $black = "base64:" . MIME::Base64::encode_base64($black);
50         return $class->new("<12> rnbqkbnr pppppppp -------- -------- -------- -------- PPPPPPPP RNBQKBNR W -1 1 1 1 1 0 dummygamenum $white $black -2 dummytime dummyincrement 39 39 dummytime dummytime 1 none (0:00) none 0 0 0");
51 }
52
53 sub fen {
54         my $pos = shift;
55
56         # the board itself
57         my $fen = $pos->{'board'}->fen();
58
59         # white/black to move
60         $fen .= " ";
61         $fen .= lc($pos->{'toplay'});
62
63         # castling
64         my $castling = "";
65         $castling .= "K" if ($pos->{'white_castle_k'} == 1);
66         $castling .= "Q" if ($pos->{'white_castle_q'} == 1);
67         $castling .= "k" if ($pos->{'black_castle_k'} == 1);
68         $castling .= "q" if ($pos->{'black_castle_q'} == 1);
69         $castling = "-" if ($castling eq "");
70         # $castling = "-"; # chess960
71         $fen .= " ";
72         $fen .= $castling;
73
74         # en passant
75         my $ep = "-";
76         if ($pos->{'ep_file_num'} != -1) {
77                 my $col = $pos->{'ep_file_num'};
78                 $ep = (qw(a b c d e f g h))[$col];
79
80                 if ($pos->{'toplay'} eq 'B') {
81                         $ep .= "3";
82                 } else {
83                         $ep .= "6";
84                 }
85         }
86         $fen .= " ";
87         $fen .= $ep;
88
89         # half-move clock
90         $fen .= " ";
91         $fen .= $pos->{'time_since_100move_rule_reset'};
92
93         # full-move clock
94         $fen .= " ";
95         $fen .= $pos->{'move_num'};
96
97         return $fen;
98 }
99
100 sub to_json_hash {
101         my $pos = shift;
102         my $json = { %$pos, fen => $pos->fen() };
103         delete $json->{'board'};
104         delete $json->{'prettyprint_cache'};
105         delete $json->{'black_castle_k'};
106         delete $json->{'black_castle_q'};
107         delete $json->{'white_castle_k'};
108         delete $json->{'white_castle_q'};
109         delete $json->{'time_since_100move_rule_reset'};
110         if ($json->{'player_w'} =~ /^base64:(.*)$/) {
111                 $json->{'player_w'} = MIME::Base64::decode_base64($1);
112         }
113         if ($json->{'player_b'} =~ /^base64:(.*)$/) {
114                 $json->{'player_b'} = MIME::Base64::decode_base64($1);
115         }
116         return $json;
117 }
118
119 sub parse_pretty_move {
120         my ($pos, $move) = @_;
121         return $pos->{'board'}->parse_pretty_move($move, $pos->{'toplay'});
122 }
123
124 sub num_pieces {
125         my ($pos) = @_;
126         return $pos->{'board'}->num_pieces();
127 }
128
129 # Returns a new Position object.
130 sub make_move {
131         my ($pos, $from_row, $from_col, $to_row, $to_col, $promo) = @_;
132
133         my $from_square = _pos_to_square($from_row, $from_col);
134         my $to_square = _pos_to_square($to_row, $to_col);
135
136         my $np = {};
137         $np->{'board'} = $pos->{'board'}->make_move($from_row, $from_col, $to_row, $to_col, $promo);
138         if ($pos->{'toplay'} eq 'W') {
139                 $np->{'toplay'} = 'B';
140                 $np->{'move_num'} = $pos->{'move_num'};
141         } else {
142                 $np->{'toplay'} = 'W';
143                 $np->{'move_num'} = $pos->{'move_num'} + 1;
144         }
145
146         my $piece = $pos->{'board'}[$from_row][$from_col];
147         my $dest_piece = $pos->{'board'}[$to_row][$to_col];
148
149         # Find out if this was a two-step pawn move.
150         if (lc($piece) eq 'p' && abs($from_row - $to_row) == 2) {
151                 $np->{'ep_file_num'} = $from_col;
152         } else {
153                 $np->{'ep_file_num'} = -1;
154         }
155
156         # Castling rights.
157         $np->{'white_castle_k'} = $pos->{'white_castle_k'};
158         $np->{'white_castle_q'} = $pos->{'white_castle_q'};
159         $np->{'black_castle_k'} = $pos->{'black_castle_k'};
160         $np->{'black_castle_q'} = $pos->{'black_castle_q'};
161         if ($piece eq 'K') {
162                 $np->{'white_castle_k'} = 0;
163                 $np->{'white_castle_q'} = 0;
164         } elsif ($piece eq 'k') {
165                 $np->{'black_castle_k'} = 0;
166                 $np->{'black_castle_q'} = 0;
167         } elsif ($from_square eq 'a1' || $to_square eq 'a1') {
168                 $np->{'white_castle_q'} = 0;
169         } elsif ($from_square eq 'h1' || $to_square eq 'h1') {
170                 $np->{'white_castle_k'} = 0;
171         } elsif ($from_square eq 'a8' || $to_square eq 'a8') {
172                 $np->{'black_castle_q'} = 0;
173         } elsif ($from_square eq 'h8' || $to_square eq 'h8') {
174                 $np->{'black_castle_k'} = 0;
175         }
176
177         # 50-move rule.
178         if (lc($piece) eq 'p' || $dest_piece ne '-') {
179                 $np->{'time_since_100move_rule_reset'} = 0;
180         } else {
181                 $np->{'time_since_100move_rule_reset'} = $pos->{'time_since_100move_rule_reset'} + 1;
182         }
183         $np->{'player_w'} = $pos->{'player_w'};
184         $np->{'player_b'} = $pos->{'player_b'};
185         my ($move, $nb) = $pos->{'board'}->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
186         $np->{'last_move'} = $move;
187         $np->{'last_move_uci'} = Board::move_to_uci_notation($from_row, $from_col, $to_row, $to_col, $promo);
188
189         return bless $np;
190 }
191
192 # Returns a new Position object, and the parsed UCI move.
193 sub make_pretty_move {
194         my ($pos, $move) = @_;
195
196         my ($from_row, $from_col, $to_row, $to_col, $promo) = $pos->parse_pretty_move($move);
197         my $uci_move = Board::move_to_uci_notation($from_row, $from_col, $to_row, $to_col, $promo);
198         $pos = $pos->make_move($from_row, $from_col, $to_row, $to_col, $promo);
199         return ($pos, $uci_move);
200 }
201
202 sub _pos_to_square {
203         my ($row, $col) = @_;
204         return sprintf("%c%d", ord('a') + $col, 8 - $row);
205 }
206
207 sub apply_uci_pv {
208         my ($pos, @pv) = @_;
209
210         my $pvpos = $pos;
211         for my $pv_move (@pv) {
212                 my ($from_row, $from_col, $to_row, $to_col, $promo) = _parse_uci_move($pv_move);
213                 $pvpos = $pvpos->make_move($from_row, $from_col, $to_row, $to_col, $promo);
214         }
215
216         return $pvpos;
217 }
218
219 sub _col_letter_to_num {
220         return ord(shift) - ord('a');
221 }
222
223 sub _row_letter_to_num {
224         return 7 - (ord(shift) - ord('1'));
225 }
226
227 sub _parse_uci_move {
228         my $move = shift;
229         my $from_col = _col_letter_to_num(substr($move, 0, 1));
230         my $from_row = _row_letter_to_num(substr($move, 1, 1));
231         my $to_col   = _col_letter_to_num(substr($move, 2, 1));
232         my $to_row   = _row_letter_to_num(substr($move, 3, 1));
233         my $promo    = substr($move, 4, 1);
234         return ($from_row, $from_col, $to_row, $to_col, $promo);
235 }
236
237 1;