git.sesse.net Git - remoteglot/blob - remoteglot.pl

   1 #! /usr/bin/perl
   2
   3 #
   4 # remoteglot - Connects an abitrary UCI-speaking engine to ICS for easier post-game
   5 #              analysis, or for live analysis of relayed games. (Do not use for
   6 #              cheating! Cheating is bad for your karma, and your abuser flag.)
   7 #
   8 # Copyright 2007 Steinar H. Gunderson <steinar+remoteglot@gunderson.no>
   9 # Licensed under the GNU General Public License, version 2.
  10 #
  11
  12 use AnyEvent;
  13 use AnyEvent::Handle;
  14 use AnyEvent::HTTP;
  15 use Chess::PGN::Parse;
  16 use EV;
  17 use Net::Telnet;
  18 use File::Slurp;
  19 use IPC::Open2;
  20 use Time::HiRes;
  21 use JSON::XS;
  22 use URI::Escape;
  23 use DBI;
  24 use DBD::Pg;
  25 require 'Position.pm';
  26 require 'Engine.pm';
  27 require 'config.pm';
  28 use strict;
  29 use warnings;
  30 no warnings qw(once);
  31
  32 # Program starts here
  33 my $latest_update = undef;
  34 my $output_timer = undef;
  35 my $http_timer = undef;
  36 my $stop_pgn_fetch = 0;
  37 my $tb_retry_timer = undef;
  38 my %tb_cache = ();
  39 my $tb_lookup_running = 0;
  40 my $last_written_json = undef;
  41
  42 # Persisted so we can restart.
  43 # TODO: Figure out an appropriate way to deal with database restarts
  44 # and/or Postgres going away entirely.
  45 my $dbh = DBI->connect($remoteglotconf::dbistr, $remoteglotconf::dbiuser, $remoteglotconf::dbipass)
  46         or die DBI->errstr;
  47 $dbh->{RaiseError} = 1;
  48
  49 $| = 1;
  50
  51 open(FICSLOG, ">ficslog.txt")
  52         or die "ficslog.txt: $!";
  53 print FICSLOG "Log starting.\n";
  54 select(FICSLOG);
  55 $| = 1;
  56
  57 open(UCILOG, ">ucilog.txt")
  58         or die "ucilog.txt: $!";
  59 print UCILOG "Log starting.\n";
  60 select(UCILOG);
  61 $| = 1;
  62
  63 open(TBLOG, ">tblog.txt")
  64         or die "tblog.txt: $!";
  65 print TBLOG "Log starting.\n";
  66 select(TBLOG);
  67 $| = 1;
  68
  69 select(STDOUT);
  70 umask 0022;  # analysis.json should not be served to users.
  71
  72 # open the chess engine
  73 my $engine = open_engine($remoteglotconf::engine_cmdline, 'E1', sub { handle_uci(@_, 1); });
  74 my $engine2 = open_engine($remoteglotconf::engine2_cmdline, 'E2', sub { handle_uci(@_, 0); });
  75 my $last_move;
  76 my $last_text = '';
  77 my ($pos_calculating, $pos_calculating_second_engine);
  78
  79 # If not undef, we've started calculating this position but haven't ever given out
  80 # any analysis for it, so we're on a forced timer to do so.
  81 my $pos_calculating_started = undef;
  82
  83 # If not undef, we've output this position, but without a main PV, so we're on
  84 # _another_ forced timer to do so.
  85 my $pos_pv_started = undef;
  86 my $last_output_had_pv = 0;
  87
  88 setoptions($engine, \%remoteglotconf::engine_config);
  89 uciprint($engine, "ucinewgame");
  90
  91 if (defined($engine2)) {
  92         setoptions($engine2, \%remoteglotconf::engine2_config);
  93         uciprint($engine2, "setoption name MultiPV value 500");
  94         uciprint($engine2, "ucinewgame");
  95 }
  96
  97 print "Chess engine ready.\n";
  98
  99 # now talk to FICS
 100 my ($t, $ev1);
 101 if (defined($remoteglotconf::server)) {
 102         $t = Net::Telnet->new(Timeout => 10, Prompt => '/fics% /');
 103         $t->input_log(\*FICSLOG);
 104         $t->open($remoteglotconf::server);
 105         $t->print($remoteglotconf::nick);
 106         $t->waitfor('/Press return to enter the server/');
 107         $t->cmd("");
 108
 109         # set some options
 110         $t->cmd("set shout 0");
 111         $t->cmd("set seek 0");
 112         $t->cmd("set style 12");
 113
 114         $ev1 = AnyEvent->io(
 115                 fh => fileno($t),
 116                 poll => 'r',
 117                 cb => sub {    # what callback to execute
 118                         while (1) {
 119                                 my $line = $t->getline(Timeout => 0, errmode => 'return');
 120                                 return if (!defined($line));
 121
 122                                 chomp $line;
 123                                 $line =~ tr/\r//d;
 124                                 handle_fics($line);
 125                         }
 126                 }
 127         );
 128 }
 129 if (defined($remoteglotconf::target)) {
 130         if ($remoteglotconf::target =~ /^(?:\/|https?:)/) {
 131                 fetch_pgn($remoteglotconf::target);
 132         } elsif (defined($t)) {
 133                 $t->cmd("observe $remoteglotconf::target");
 134         }
 135 }
 136 if (defined($t)) {
 137         print "FICS ready.\n";
 138 }
 139
 140 # Engine events have already been set up by Engine.pm.
 141 EV::run;
 142
 143 sub handle_uci {
 144         my ($engine, $line, $primary) = @_;
 145
 146         return if $line =~ /(upper|lower)bound/;
 147
 148         $line =~ s/  / /g;  # Sometimes needed for Zappa Mexico
 149         print UCILOG localtime() . " $engine->{'tag'} <= $line\n";
 150
 151         # If we've sent a stop command, gobble up lines until we see bestmove.
 152         return if ($engine->{'stopping'} && $line !~ /^bestmove/);
 153         $engine->{'stopping'} = 0;
 154
 155         if ($line =~ /^info/) {
 156                 my (@infos) = split / /, $line;
 157                 shift @infos;
 158
 159                 parse_infos($engine, @infos);
 160         }
 161         if ($line =~ /^id/) {
 162                 my (@ids) = split / /, $line;
 163                 shift @ids;
 164
 165                 parse_ids($engine, @ids);
 166         }
 167         output();
 168 }
 169
 170 my $getting_movelist = 0;
 171 my $pos_for_movelist = undef;
 172 my @uci_movelist = ();
 173 my @pretty_movelist = ();
 174
 175 sub handle_fics {
 176         my $line = shift;
 177         if ($line =~ /^<12> /) {
 178                 handle_position(Position->new($line));
 179                 $t->cmd("moves");
 180         }
 181         if ($line =~ /^Movelist for game /) {
 182                 my $pos = $pos_calculating;
 183                 if (defined($pos)) {
 184                         @uci_movelist = ();
 185                         @pretty_movelist = ();
 186                         $pos_for_movelist = Position->start_pos($pos->{'player_w'}, $pos->{'player_b'});
 187                         $getting_movelist = 1;
 188                 }
 189         }
 190         if ($getting_movelist &&
 191             $line =~ /^\s* \d+\. \s+                     # move number
 192                        (\S+) \s+ \( [\d:.]+ \) \s*       # first move, then time
 193                        (?: (\S+) \s+ \( [\d:.]+ \) )?    # second move, then time
 194                      /x) {
 195                 eval {
 196                         my $uci_move;
 197                         ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($1);
 198                         push @uci_movelist, $uci_move;
 199                         push @pretty_movelist, $1;
 200
 201                         if (defined($2)) {
 202                                 ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($2);
 203                                 push @uci_movelist, $uci_move;
 204                                 push @pretty_movelist, $2;
 205                         }
 206                 };
 207                 if ($@) {
 208                         warn "Error when getting FICS move history: $@";
 209                         $getting_movelist = 0;
 210                 }
 211         }
 212         if ($getting_movelist &&
 213             $line =~ /^\s+ \{.*\} \s+ (?: \* | 1\/2-1\/2 | 0-1 | 1-0 )/x) {
 214                 # End of movelist.
 215                 if (defined($pos_calculating)) {
 216                         if ($pos_calculating->fen() eq $pos_for_movelist->fen()) {
 217                                 $pos_calculating->{'history'} = \@pretty_movelist;
 218                         }
 219                 }
 220                 $getting_movelist = 0;
 221         }
 222         if ($line =~ /^([A-Za-z]+)(?:\([A-Z]+\))* tells you: (.*)$/) {
 223                 my ($who, $msg) = ($1, $2);
 224
 225                 next if (grep { $_ eq $who } (@remoteglotconf::masters) == 0);
 226
 227                 if ($msg =~ /^fics (.*?)$/) {
 228                         $t->cmd("tell $who Executing '$1' on FICS.");
 229                         $t->cmd($1);
 230                 } elsif ($msg =~ /^uci (.*?)$/) {
 231                         $t->cmd("tell $who Sending '$1' to the engine.");
 232                         print { $engine->{'write'} } "$1\n";
 233                 } elsif ($msg =~ /^pgn (.*?)$/) {
 234                         my $url = $1;
 235                         $t->cmd("tell $who Starting to poll '$url'.");
 236                         fetch_pgn($url);
 237                 } elsif ($msg =~ /^stoppgn$/) {
 238                         $t->cmd("tell $who Stopping poll.");
 239                         $stop_pgn_fetch = 1;
 240                         $http_timer = undef;
 241                 } elsif ($msg =~ /^quit$/) {
 242                         $t->cmd("tell $who Bye bye.");
 243                         exit;
 244                 } else {
 245                         $t->cmd("tell $who Couldn't understand '$msg', sorry.");
 246                 }
 247         }
 248         #print "FICS: [$line]\n";
 249 }
 250
 251 # Starts periodic fetching of PGNs from the given URL.
 252 sub fetch_pgn {
 253         my ($url) = @_;
 254         if ($url =~ m#^/#) {  # Local file.
 255                 eval {
 256                         local $/ = undef;
 257                         open my $fh, "<", $url
 258                                 or die "$url: $!";
 259                         my $pgn = <$fh>;
 260                         close $fh;
 261                         handle_pgn($pgn, '', $url);
 262                 };
 263                 if ($@) {
 264                         warn "$url: $@";
 265                         $http_timer = AnyEvent->timer(after => 1.0, cb => sub {
 266                                 fetch_pgn($url);
 267                         });
 268                 }
 269         } else {
 270                 AnyEvent::HTTP::http_get($url, sub {
 271                         handle_pgn(@_, $url);
 272                 });
 273         }
 274 }
 275
 276 my ($last_pgn_white, $last_pgn_black);
 277 my @last_pgn_uci_moves = ();
 278 my $pgn_hysteresis_counter = 0;
 279
 280 sub handle_pgn {
 281         my ($body, $header, $url) = @_;
 282
 283         if ($stop_pgn_fetch) {
 284                 $stop_pgn_fetch = 0;
 285                 $http_timer = undef;
 286                 return;
 287         }
 288
 289         my $pgn = Chess::PGN::Parse->new(undef, $body);
 290         if (!defined($pgn)) {
 291                 warn "Error in parsing PGN from $url [body='$body']\n";
 292         } elsif (!$pgn->read_game()) {
 293                 warn "Error in reading PGN game from $url [body='$body']\n";
 294         } elsif ($body !~ /^\[/) {
 295                 warn "Malformed PGN from $url [body='$body']\n";
 296         } else {
 297                 eval {
 298                         # Skip to the right game.
 299                         while (defined($remoteglotconf::pgn_filter) &&
 300                                !&$remoteglotconf::pgn_filter($pgn)) {
 301                                 $pgn->read_game() or die "Out of games during filtering";
 302                         }
 303
 304                         $pgn->parse_game({ save_comments => 'yes' });
 305                         my $white = $pgn->white;
 306                         my $black = $pgn->black;
 307                         $white =~ s/,.*//;  # Remove first name.
 308                         $black =~ s/,.*//;  # Remove first name.
 309                         my $tags = $pgn->tags();
 310                         my $pos;
 311                         if (exists($tags->{'FEN'})) {
 312                                 $pos = Position->from_fen($tags->{'FEN'});
 313                                 $pos->{'last_move'} = 'none';
 314                                 $pos->{'player_w'} = $white;
 315                                 $pos->{'player_b'} = $black;
 316                                 $pos->{'start_fen'} = $tags->{'FEN'};
 317                         } else {
 318                                 $pos = Position->start_pos($white, $black);
 319                         }
 320                         if (exists($tags->{'Variant'}) &&
 321                             $tags->{'Variant'} =~ /960|fischer/i) {
 322                                 $pos->{'chess960'} = 1;
 323                         } else {
 324                                 $pos->{'chess960'} = 0;
 325                         }
 326                         my $moves = $pgn->moves;
 327                         my @uci_moves = ();
 328                         my @repretty_moves = ();
 329                         for my $move (@$moves) {
 330                                 my ($npos, $uci_move) = $pos->make_pretty_move($move);
 331                                 push @uci_moves, $uci_move;
 332
 333                                 # Re-prettyprint the move.
 334                                 my ($from_row, $from_col, $to_row, $to_col, $promo) = parse_uci_move($uci_move);
 335                                 my ($pretty, undef) = $pos->{'board'}->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
 336                                 push @repretty_moves, $pretty;
 337                                 $pos = $npos;
 338                         }
 339                         if ($pgn->result eq '1-0' || $pgn->result eq '1/2-1/2' || $pgn->result eq '0-1') {
 340                                 $pos->{'result'} = $pgn->result;
 341                         }
 342                         $pos->{'history'} = \@repretty_moves;
 343
 344                         extract_clock($pgn, $pos);
 345
 346                         # Sometimes, PGNs lose a move or two for a short while,
 347                         # or people push out new ones non-atomically.
 348                         # Thus, if we PGN doesn't change names but becomes
 349                         # shorter, we mistrust it for a few seconds.
 350                         my $trust_pgn = 1;
 351                         if (defined($last_pgn_white) && defined($last_pgn_black) &&
 352                             $last_pgn_white eq $pgn->white &&
 353                             $last_pgn_black eq $pgn->black &&
 354                             scalar(@uci_moves) < scalar(@last_pgn_uci_moves)) {
 355                                 if (++$pgn_hysteresis_counter < 3) {
 356                                         $trust_pgn = 0;
 357                                 }
 358                         }
 359                         if ($trust_pgn) {
 360                                 $last_pgn_white = $pgn->white;
 361                                 $last_pgn_black = $pgn->black;
 362                                 @last_pgn_uci_moves = @uci_moves;
 363                                 $pgn_hysteresis_counter = 0;
 364                                 handle_position($pos);
 365                         }
 366                 };
 367                 if ($@) {
 368                         warn "Error in parsing moves from $url: $@\n";
 369                 }
 370         }
 371
 372         $http_timer = AnyEvent->timer(after => 1.0, cb => sub {
 373                 fetch_pgn($url);
 374         });
 375 }
 376
 377 sub handle_position {
 378         my ($pos) = @_;
 379         find_clock_start($pos, $pos_calculating);
 380
 381         # If we're already chewing on this and there's nothing else in the queue,
 382         # ignore it.
 383         if (defined($pos_calculating) && $pos->fen() eq $pos_calculating->fen()) {
 384                 $pos_calculating->{'result'} = $pos->{'result'};
 385                 for my $key ('white_clock', 'black_clock', 'white_clock_target', 'black_clock_target') {
 386                         $pos_calculating->{$key} //= $pos->{$key};
 387                 }
 388                 return;
 389         }
 390
 391         # If we're already thinking on something, stop and wait for the engine
 392         # to approve.
 393         if (defined($pos_calculating)) {
 394                 # Store the final data we have for this position in the history,
 395                 # with the precise clock information we just got from the new
 396                 # position. (Historic positions store the clock at the end of
 397                 # the position.)
 398                 #
 399                 # Do not output anything new to the main analysis; that's
 400                 # going to be obsolete really soon. (Exception: If we've never
 401                 # output anything for this move, ie., it didn't hit the 200ms
 402                 # limit, spit it out to the user anyway. It's probably a really
 403                 # fast blitz game or something, and it's good to show the moves
 404                 # as they come in even without great analysis.)
 405                 $pos_calculating->{'white_clock'} = $pos->{'white_clock'};
 406                 $pos_calculating->{'black_clock'} = $pos->{'black_clock'};
 407                 delete $pos_calculating->{'white_clock_target'};
 408                 delete $pos_calculating->{'black_clock_target'};
 409
 410                 if (defined($pos_calculating_started)) {
 411                         output_json(0);
 412                 } else {
 413                         output_json(1);
 414                 }
 415                 $pos_calculating_started = [Time::HiRes::gettimeofday];
 416                 $pos_pv_started = undef;
 417
 418                 # Ask the engine to stop; we will throw away its data until it
 419                 # sends us "bestmove", signaling the end of it.
 420                 $engine->{'stopping'} = 1;
 421                 uciprint($engine, "stop");
 422         }
 423
 424         # It's wrong to just give the FEN (the move history is useful,
 425         # and per the UCI spec, we should really have sent "ucinewgame"),
 426         # but it's easier, and it works around a Stockfish repetition issue.
 427         if ($engine->{'chess960'} != $pos->{'chess960'}) {
 428                 uciprint($engine, "setoption name UCI_Chess960 value " . ($pos->{'chess960'} ? 'true' : 'false'));
 429                 $engine->{'chess960'} = $pos->{'chess960'};
 430         }
 431         uciprint($engine, "position fen " . $pos->fen());
 432         uciprint($engine, "go infinite");
 433         $pos_calculating = $pos;
 434         $pos_calculating_started = [Time::HiRes::gettimeofday];
 435         $pos_pv_started = undef;
 436
 437         if (defined($engine2)) {
 438                 if (defined($pos_calculating_second_engine)) {
 439                         $engine2->{'stopping'} = 1;
 440                         uciprint($engine2, "stop");
 441                 }
 442                 if ($engine2->{'chess960'} != $pos->{'chess960'}) {
 443                         uciprint($engine2, "setoption name UCI_Chess960 value " . ($pos->{'chess960'} ? 'true' : 'false'));
 444                         $engine2->{'chess960'} = $pos->{'chess960'};
 445                 }
 446                 uciprint($engine2, "position fen " . $pos->fen());
 447                 uciprint($engine2, "go infinite");
 448                 $pos_calculating_second_engine = $pos;
 449                 $engine2->{'info'} = {};
 450         }
 451
 452         $engine->{'info'} = {};
 453         $last_move = time;
 454
 455         schedule_tb_lookup();
 456
 457         #
 458         # Output a command every move to note that we're
 459         # still paying attention -- this is a good tradeoff,
 460         # since if no move has happened in the last half
 461         # hour, the analysis/relay has most likely stopped
 462         # and we should stop hogging server resources.
 463         #
 464         if (defined($t)) {
 465                 $t->cmd("date");
 466         }
 467 }
 468
 469 sub parse_infos {
 470         my ($engine, @x) = @_;
 471         my $mpv = '';
 472
 473         my $info = $engine->{'info'};
 474
 475         # Search for "multipv" first of all, since e.g. Stockfish doesn't put it first.
 476         for my $i (0..$#x - 1) {
 477                 if ($x[$i] eq 'multipv') {
 478                         $mpv = $x[$i + 1];
 479                         next;
 480                 }
 481         }
 482
 483         while (scalar @x > 0) {
 484                 if ($x[0] eq 'multipv') {
 485                         # Dealt with above
 486                         shift @x;
 487                         shift @x;
 488                         next;
 489                 }
 490                 if ($x[0] eq 'currmove' || $x[0] eq 'currmovenumber' || $x[0] eq 'cpuload') {
 491                         my $key = shift @x;
 492                         my $value = shift @x;
 493                         $info->{$key} = $value;
 494                         next;
 495                 }
 496                 if ($x[0] eq 'depth' || $x[0] eq 'seldepth' || $x[0] eq 'hashfull' ||
 497                     $x[0] eq 'time' || $x[0] eq 'nodes' || $x[0] eq 'nps' ||
 498                     $x[0] eq 'tbhits') {
 499                         my $key = shift @x;
 500                         my $value = shift @x;
 501                         $info->{$key . $mpv} = $value;
 502                         next;
 503                 }
 504                 if ($x[0] eq 'score') {
 505                         shift @x;
 506
 507                         delete $info->{'score_cp' . $mpv};
 508                         delete $info->{'score_mate' . $mpv};
 509
 510                         while ($x[0] eq 'cp' || $x[0] eq 'mate') {
 511                                 if ($x[0] eq 'cp') {
 512                                         shift @x;
 513                                         $info->{'score_cp' . $mpv} = shift @x;
 514                                 } elsif ($x[0] eq 'mate') {
 515                                         shift @x;
 516                                         $info->{'score_mate' . $mpv} = shift @x;
 517                                 } else {
 518                                         shift @x;
 519                                 }
 520                         }
 521                         next;
 522                 }
 523                 if ($x[0] eq 'pv') {
 524                         $info->{'pv' . $mpv} = [ @x[1..$#x] ];
 525                         last;
 526                 }
 527                 if ($x[0] eq 'string' || $x[0] eq 'UCI_AnalyseMode' || $x[0] eq 'setting' || $x[0] eq 'contempt') {
 528                         last;
 529                 }
 530
 531                 #print "unknown info '$x[0]', trying to recover...\n";
 532                 #shift @x;
 533                 die "Unknown info '" . join(',', @x) . "'";
 534
 535         }
 536 }
 537
 538 sub parse_ids {
 539         my ($engine, @x) = @_;
 540
 541         while (scalar @x > 0) {
 542                 if ($x[0] eq 'name') {
 543                         my $value = join(' ', @x);
 544                         $engine->{'id'}{'author'} = $value;
 545                         last;
 546                 }
 547
 548                 # unknown
 549                 shift @x;
 550         }
 551 }
 552
 553 sub prettyprint_pv_no_cache {
 554         my ($board, @pvs) = @_;
 555
 556         if (scalar @pvs == 0 || !defined($pvs[0])) {
 557                 return ();
 558         }
 559
 560         my @ret = ();
 561         for my $pv (@pvs) {
 562                 my ($from_row, $from_col, $to_row, $to_col, $promo) = parse_uci_move($pv);
 563                 my ($pretty, $nb) = $board->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
 564                 push @ret, $pretty;
 565                 $board = $nb;
 566         }
 567         return @ret;
 568 }
 569
 570 sub prettyprint_pv {
 571         my ($pos, @pvs) = @_;
 572
 573         my $cachekey = join('', @pvs);
 574         if (exists($pos->{'prettyprint_cache'}{$cachekey})) {
 575                 return @{$pos->{'prettyprint_cache'}{$cachekey}};
 576         } else {
 577                 my @res = prettyprint_pv_no_cache($pos->{'board'}, @pvs);
 578                 $pos->{'prettyprint_cache'}{$cachekey} = \@res;
 579                 return @res;
 580         }
 581 }
 582
 583 my %tbprobe_cache = ();
 584
 585 sub complete_using_tbprobe {
 586         my ($pos, $info, $mpv) = @_;
 587
 588         # We need Fathom installed to do standalone TB probes.
 589         return if (!defined($remoteglotconf::fathom_cmdline));
 590
 591         # If we already have a mate, don't bother; in some cases, it would even be
 592         # better than a tablebase score.
 593         return if defined($info->{'score_mate' . $mpv});
 594
 595         # If we have a draw or near-draw score, there's also not much interesting
 596         # we could add from a tablebase. We only really want mates.
 597         return if ($info->{'score_cp' . $mpv} >= -12250 && $info->{'score_cp' . $mpv} <= 12250);
 598
 599         # Run through the PV until we are at a 6-man position.
 600         # TODO: We could in theory only have 5-man data.
 601         my @pv = @{$info->{'pv' . $mpv}};
 602         my $key = $pos->fen() . " " . join('', @pv);
 603         my @moves = ();
 604         if (exists($tbprobe_cache{$key})) {
 605                 @moves = @{$tbprobe_cache{$key}};
 606         } else {
 607                 if ($mpv ne '') {
 608                         # Force doing at least one move of the PV.
 609                         my $move = shift @pv;
 610                         push @moves, $move;
 611                         $pos = $pos->make_move(parse_uci_move($move));
 612                 }
 613
 614                 while ($pos->num_pieces() > 7 && $#pv > -1) {
 615                         my $move = shift @pv;
 616                         push @moves, $move;
 617                         $pos = $pos->make_move(parse_uci_move($move));
 618                 }
 619
 620                 return if ($pos->num_pieces() > 7);
 621
 622                 my $fen = $pos->fen();
 623                 my $pgn_text = `$remoteglotconf::fathom_cmdline "$fen"`;
 624                 my $pgn = Chess::PGN::Parse->new(undef, $pgn_text);
 625                 return if (!defined($pgn) || !$pgn->read_game() || ($pgn->result ne '0-1' && $pgn->result ne '1-0'));
 626                 $pgn->quick_parse_game;
 627                 $info->{'pv' . $mpv} = \@moves;
 628
 629                 # Splice the PV from the tablebase onto what we have so far.
 630                 for my $move (@{$pgn->moves}) {
 631                         last if $move eq '#';
 632                         last if $move eq '1-0';
 633                         last if $move eq '0-1';
 634                         last if $move eq '1/2-1/2';
 635                         my $uci_move;
 636                         ($pos, $uci_move) = $pos->make_pretty_move($move);
 637                         push @moves, $uci_move;
 638                 }
 639
 640                 $tbprobe_cache{$key} = \@moves;
 641         }
 642
 643         $info->{'pv' . $mpv} = \@moves;
 644
 645         my $matelen = int((1 + scalar @moves) / 2);
 646         if ((scalar @moves) % 2 == 0) {
 647                 $info->{'score_mate' . $mpv} = -$matelen;
 648         } else {
 649                 $info->{'score_mate' . $mpv} = $matelen;
 650         }
 651 }
 652
 653 sub output {
 654         #return;
 655
 656         return if (!defined($pos_calculating));
 657
 658         my $info = $engine->{'info'};
 659
 660         # Don't update too often.
 661         my $wait = $remoteglotconf::update_max_interval - Time::HiRes::tv_interval($latest_update);
 662         if (defined($pos_calculating_started)) {
 663                 my $new_pos_wait = $remoteglotconf::update_force_after_move - Time::HiRes::tv_interval($pos_calculating_started);
 664                 $wait = $new_pos_wait if ($new_pos_wait < $wait);
 665         }
 666         if (!$last_output_had_pv && has_pv($info)) {
 667                 if (!defined($pos_pv_started)) {
 668                         $pos_pv_started = [Time::HiRes::gettimeofday];
 669                 }
 670                 # We just got initial PV, and we're in a hurry since we gave out a blank one earlier,
 671                 # so give us just 200ms more to increase the quality and then force a display.
 672                 my $new_pos_wait = $remoteglotconf::update_force_after_move - Time::HiRes::tv_interval($pos_pv_started);
 673                 $wait = $new_pos_wait if ($new_pos_wait < $wait);
 674         }
 675         if ($wait > 0.0) {
 676                 $output_timer = AnyEvent->timer(after => $wait + 0.01, cb => \&output);
 677                 return;
 678         }
 679         $pos_pv_started = undef;
 680
 681         # We're outputting something for this position now, so the special handling
 682         # for new positions is off.
 683         undef $pos_calculating_started;
 684
 685         #
 686         # If we have tablebase data from a previous lookup, replace the
 687         # engine data with the data from the tablebase.
 688         #
 689         my $fen = $pos_calculating->fen();
 690         if (exists($tb_cache{$fen})) {
 691                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
 692                         delete $info->{$key . '1'};
 693                         delete $info->{$key};
 694                 }
 695                 $info->{'nodes'} = 0;
 696                 $info->{'nps'} = 0;
 697                 $info->{'depth'} = 0;
 698                 $info->{'seldepth'} = 0;
 699                 $info->{'tbhits'} = 0;
 700
 701                 my $t = $tb_cache{$fen};
 702                 my $pv = $t->{'pv'};
 703                 my $matelen = int((1 + $t->{'score'}) / 2);
 704                 if ($t->{'result'} eq '1/2-1/2') {
 705                         $info->{'score_cp'} = 0;
 706                 } elsif ($t->{'result'} eq '1-0') {
 707                         if ($pos_calculating->{'toplay'} eq 'B') {
 708                                 $info->{'score_mate'} = -$matelen;
 709                         } else {
 710                                 $info->{'score_mate'} = $matelen;
 711                         }
 712                 } else {
 713                         if ($pos_calculating->{'toplay'} eq 'B') {
 714                                 $info->{'score_mate'} = $matelen;
 715                         } else {
 716                                 $info->{'score_mate'} = -$matelen;
 717                         }
 718                 }
 719                 $info->{'pv'} = $pv;
 720                 $info->{'tablebase'} = 1;
 721         } else {
 722                 $info->{'tablebase'} = 0;
 723         }
 724
 725         #
 726         # Some programs _always_ report MultiPV, even with only one PV.
 727         # In this case, we simply use that data as if MultiPV was never
 728         # specified.
 729         #
 730         if (exists($info->{'pv1'}) && !exists($info->{'pv2'})) {
 731                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
 732                         if (exists($info->{$key . '1'})) {
 733                                 $info->{$key} = $info->{$key . '1'};
 734                         } else {
 735                                 delete $info->{$key};
 736                         }
 737                 }
 738         }
 739
 740         #
 741         # Check the PVs first. if they're invalid, just wait, as our data
 742         # is most likely out of sync. This isn't a very good solution, as
 743         # it can frequently miss stuff, but it's good enough for most users.
 744         #
 745         eval {
 746                 my $dummy;
 747                 if (exists($info->{'pv'})) {
 748                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv'}});
 749                 }
 750
 751                 my $mpv = 1;
 752                 while (exists($info->{'pv' . $mpv})) {
 753                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}});
 754                         ++$mpv;
 755                 }
 756         };
 757         if ($@) {
 758                 $engine->{'info'} = {};
 759                 return;
 760         }
 761
 762         # Now do our own Syzygy tablebase probes to convert scores like +123.45 to mate.
 763         if (exists($info->{'pv'})) {
 764                 complete_using_tbprobe($pos_calculating, $info, '');
 765         }
 766
 767         my $mpv = 1;
 768         while (exists($info->{'pv' . $mpv})) {
 769                 complete_using_tbprobe($pos_calculating, $info, $mpv);
 770                 ++$mpv;
 771         }
 772
 773         output_screen();
 774         output_json(0);
 775         $latest_update = [Time::HiRes::gettimeofday];
 776         $last_output_had_pv = has_pv($info);
 777 }
 778
 779 sub has_pv {
 780         my $info = shift;
 781         return 1 if (exists($info->{'pv'}) && (scalar(@{$info->{'pv'}}) > 0));
 782         return 1 if (exists($info->{'pv1'}) && (scalar(@{$info->{'pv1'}}) > 0));
 783         return 0;
 784 }
 785
 786 sub output_screen {
 787         my $info = $engine->{'info'};
 788         my $id = $engine->{'id'};
 789
 790         my $text = 'Analysis';
 791         if ($pos_calculating->{'last_move'} ne 'none') {
 792                 if ($pos_calculating->{'toplay'} eq 'W') {
 793                         $text .= sprintf ' after %u. ... %s', ($pos_calculating->{'move_num'}-1), $pos_calculating->{'last_move'};
 794                 } else {
 795                         $text .= sprintf ' after %u. %s', $pos_calculating->{'move_num'}, $pos_calculating->{'last_move'};
 796                 }
 797                 if (exists($id->{'name'})) {
 798                         $text .= ',';
 799                 }
 800         }
 801
 802         if (exists($id->{'name'})) {
 803                 $text .= " by $id->{'name'}:\n\n";
 804         } else {
 805                 $text .= ":\n\n";
 806         }
 807
 808         return unless (exists($pos_calculating->{'board'}));
 809
 810         if (exists($info->{'pv1'}) && exists($info->{'pv2'})) {
 811                 # multi-PV
 812                 my $mpv = 1;
 813                 while (exists($info->{'pv' . $mpv})) {
 814                         $text .= sprintf "  PV%2u", $mpv;
 815                         my $score = short_score($info, $pos_calculating, $mpv);
 816                         $text .= "  ($score)" if (defined($score));
 817
 818                         my $tbhits = '';
 819                         if (exists($info->{'tbhits' . $mpv}) && $info->{'tbhits' . $mpv} > 0) {
 820                                 if ($info->{'tbhits' . $mpv} == 1) {
 821                                         $tbhits = ", 1 tbhit";
 822                                 } else {
 823                                         $tbhits = sprintf ", %u tbhits", $info->{'tbhits' . $mpv};
 824                                 }
 825                         }
 826
 827                         if (exists($info->{'nodes' . $mpv}) && exists($info->{'nps' . $mpv}) && exists($info->{'depth' . $mpv})) {
 828                                 $text .= sprintf " (%5u kn, %3u kn/s, %2u ply$tbhits)",
 829                                         $info->{'nodes' . $mpv} / 1000, $info->{'nps' . $mpv} / 1000, $info->{'depth' . $mpv};
 830                         }
 831
 832                         $text .= ":\n";
 833                         $text .= "  " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}})) . "\n";
 834                         $text .= "\n";
 835                         ++$mpv;
 836                 }
 837         } else {
 838                 # single-PV
 839                 my $score = long_score($info, $pos_calculating, '');
 840                 $text .= "  $score\n" if defined($score);
 841                 $text .=  "  PV: " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv'}}));
 842                 $text .=  "\n";
 843
 844                 if (exists($info->{'nodes'}) && exists($info->{'nps'}) && exists($info->{'depth'})) {
 845                         $text .= sprintf "  %u nodes, %7u nodes/sec, depth %u ply",
 846                                 $info->{'nodes'}, $info->{'nps'}, $info->{'depth'};
 847                 }
 848                 if (exists($info->{'seldepth'})) {
 849                         $text .= sprintf " (%u selective)", $info->{'seldepth'};
 850                 }
 851                 if (exists($info->{'tbhits'}) && $info->{'tbhits'} > 0) {
 852                         if ($info->{'tbhits'} == 1) {
 853                                 $text .= ", one Syzygy hit";
 854                         } else {
 855                                 $text .= sprintf ", %u Syzygy hits", $info->{'tbhits'};
 856                         }
 857                 }
 858                 $text .= "\n\n";
 859         }
 860
 861         my @refutation_lines = ();
 862         if (defined($engine2)) {
 863                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
 864                         my $info = $engine2->{'info'};
 865                         last if (!exists($info->{'pv' . $mpv}));
 866                         eval {
 867                                 complete_using_tbprobe($pos_calculating_second_engine, $info, $mpv);
 868                                 my $pv = $info->{'pv' . $mpv};
 869                                 my $pretty_move = join('', prettyprint_pv($pos_calculating_second_engine, $pv->[0]));
 870                                 my @pretty_pv = prettyprint_pv($pos_calculating_second_engine, @$pv);
 871                                 if (scalar @pretty_pv > 5) {
 872                                         @pretty_pv = @pretty_pv[0..4];
 873                                         push @pretty_pv, "...";
 874                                 }
 875                                 my $key = $pretty_move;
 876                                 my $line = sprintf("  %-6s %6s %3s  %s",
 877                                         $pretty_move,
 878                                         short_score($info, $pos_calculating_second_engine, $mpv),
 879                                         "d" . $info->{'depth' . $mpv},
 880                                         join(', ', @pretty_pv));
 881                                 push @refutation_lines, [ $key, $line ];
 882                         };
 883                 }
 884         }
 885
 886         if ($#refutation_lines >= 0) {
 887                 $text .= "Shallow search of all legal moves:\n\n";
 888                 for my $line (sort { $a->[0] cmp $b->[0] } @refutation_lines) {
 889                         $text .= $line->[1] . "\n";
 890                 }
 891                 $text .= "\n\n";
 892         }
 893
 894         if ($last_text ne $text) {
 895                 print "\e[H\e[2J"; # clear the screen
 896                 print $text;
 897                 $last_text = $text;
 898         }
 899 }
 900
 901 sub output_json {
 902         my $historic_json_only = shift;
 903         my $info = $engine->{'info'};
 904
 905         my $json = {};
 906         $json->{'position'} = $pos_calculating->to_json_hash();
 907         $json->{'engine'} = $engine->{'id'};
 908         if (defined($remoteglotconf::engine_url)) {
 909                 $json->{'engine'}{'url'} = $remoteglotconf::engine_url;
 910         }
 911         if (defined($remoteglotconf::engine_details)) {
 912                 $json->{'engine'}{'details'} = $remoteglotconf::engine_details;
 913         }
 914         my @grpc_backends = ();
 915         if (defined($remoteglotconf::engine_grpc_backend)) {
 916                 push @grpc_backends, $remoteglotconf::engine_grpc_backend;
 917         }
 918         if (defined($remoteglotconf::engine2_grpc_backend)) {
 919                 push @grpc_backends, $remoteglotconf::engine2_grpc_backend;
 920         }
 921         $json->{'internal'}{'grpc_backends'} = \@grpc_backends;
 922         if (defined($remoteglotconf::move_source)) {
 923                 $json->{'move_source'} = $remoteglotconf::move_source;
 924         }
 925         if (defined($remoteglotconf::move_source_url)) {
 926                 $json->{'move_source_url'} = $remoteglotconf::move_source_url;
 927         }
 928         $json->{'score'} = score_digest($info, $pos_calculating, '');
 929         $json->{'using_lomonosov'} = defined($remoteglotconf::tb_serial_key);
 930
 931         $json->{'nodes'} = $info->{'nodes'};
 932         $json->{'nps'} = $info->{'nps'};
 933         $json->{'depth'} = $info->{'depth'};
 934         $json->{'tbhits'} = $info->{'tbhits'};
 935         $json->{'seldepth'} = $info->{'seldepth'};
 936         $json->{'tablebase'} = $info->{'tablebase'};
 937         $json->{'pv'} = [ prettyprint_pv($pos_calculating, @{$info->{'pv'}}) ];
 938
 939         my %refutation_lines = ();
 940         my @refutation_lines = ();
 941         if (defined($engine2)) {
 942                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
 943                         my $info = $engine2->{'info'};
 944                         my $pretty_move = "";
 945                         my @pretty_pv = ();
 946                         last if (!exists($info->{'pv' . $mpv}));
 947
 948                         eval {
 949                                 complete_using_tbprobe($pos_calculating, $info, $mpv);
 950                                 my $pv = $info->{'pv' . $mpv};
 951                                 my $pretty_move = join('', prettyprint_pv($pos_calculating, $pv->[0]));
 952                                 my @pretty_pv = prettyprint_pv($pos_calculating, @$pv);
 953                                 $refutation_lines{$pretty_move} = {
 954                                         depth => $info->{'depth' . $mpv},
 955                                         score => score_digest($info, $pos_calculating, $mpv),
 956                                         move => $pretty_move,
 957                                         pv => \@pretty_pv,
 958                                 };
 959                         };
 960                 }
 961         }
 962         $json->{'refutation_lines'} = \%refutation_lines;
 963
 964         # Piece together historic score information, to the degree we have it.
 965         if (!$historic_json_only && exists($pos_calculating->{'history'})) {
 966                 my %score_history = ();
 967
 968                 local $dbh->{AutoCommit} = 0;
 969                 my $q = $dbh->prepare('SELECT * FROM scores WHERE id=?');
 970                 my $pos;
 971                 if (exists($pos_calculating->{'start_fen'})) {
 972                         $pos = Position->from_fen($pos_calculating->{'start_fen'});
 973                 } else {
 974                         $pos = Position->start_pos('white', 'black');
 975                 }
 976                 $pos->{'chess960'} = $pos_calculating->{'chess960'};
 977                 my $halfmove_num = 0;
 978                 for my $move (@{$pos_calculating->{'history'}}) {
 979                         my $id = id_for_pos($pos, $halfmove_num);
 980                         my $ref = $dbh->selectrow_hashref($q, undef, $id);
 981                         if (defined($ref)) {
 982                                 $score_history{$halfmove_num} = [
 983                                         $ref->{'score_type'},
 984                                         $ref->{'score_value'}
 985                                 ];
 986                         }
 987                         ++$halfmove_num;
 988                         ($pos) = $pos->make_pretty_move($move);
 989                 }
 990                 $q->finish;
 991                 $dbh->commit;
 992
 993                 # If at any point we are missing 10 consecutive moves,
 994                 # truncate the history there. This is so we don't get into
 995                 # a situation where we e.g. start analyzing at move 45,
 996                 # but we have analysis for 1. e4 from some completely different game
 997                 # and thus show a huge hole.
 998                 my $consecutive_missing = 0;
 999                 my $truncate_until = 0;
1000                 for (my $i = $halfmove_num; $i --> 0; ) {
1001                         if ($consecutive_missing >= 10) {
1002                                 delete $score_history{$i};
1003                                 next;
1004                         }
1005                         if (exists($score_history{$i})) {
1006                                 $consecutive_missing = 0;
1007                         } else {
1008                                 ++$consecutive_missing;
1009                         }
1010                 }
1011
1012                 $json->{'score_history'} = \%score_history;
1013         }
1014
1015         # Give out a list of other games going on. (Empty is fine.)
1016         # TODO: Don't bother reading our own file, the data will be stale anyway.
1017         if (!$historic_json_only) {
1018                 my @games = ();
1019
1020                 my $q = $dbh->prepare('SELECT * FROM current_games ORDER BY priority DESC, id');
1021                 $q->execute;
1022                 while (my $ref = $q->fetchrow_hashref) {
1023                         eval {
1024                                 my $other_game_contents = File::Slurp::read_file($ref->{'json_path'});
1025                                 my $other_game_json = JSON::XS::decode_json($other_game_contents);
1026
1027                                 die "Missing position" if (!exists($other_game_json->{'position'}));
1028                                 my $white = $other_game_json->{'position'}{'player_w'} // die 'Missing white';
1029                                 my $black = $other_game_json->{'position'}{'player_b'} // die 'Missing black';
1030
1031                                 my $game = {
1032                                         id => $ref->{'id'},
1033                                         name => "$white–$black",
1034                                         url => $ref->{'url'},
1035                                         hashurl => $ref->{'hash_url'},
1036                                 };
1037                                 if (defined($other_game_json->{'position'}{'result'})) {
1038                                         $game->{'result'} = $other_game_json->{'position'}{'result'};
1039                                 } else {
1040                                         $game->{'score'} = $other_game_json->{'score'};
1041                                 }
1042                                 push @games, $game;
1043                         };
1044                         if ($@) {
1045                                 warn "Could not add external game " . $ref->{'json_path'} . ": $@";
1046                         }
1047                 }
1048
1049                 if (scalar @games > 0) {
1050                         $json->{'games'} = \@games;
1051                 }
1052         }
1053
1054         my $json_enc = JSON::XS->new;
1055         $json_enc->canonical(1);
1056         my $encoded = $json_enc->encode($json);
1057         unless ($historic_json_only || !defined($remoteglotconf::json_output) ||
1058                 (defined($last_written_json) && $last_written_json eq $encoded)) {
1059                 atomic_set_contents($remoteglotconf::json_output, $encoded);
1060                 $last_written_json = $encoded;
1061         }
1062
1063         if (exists($pos_calculating->{'history'}) &&
1064             defined($remoteglotconf::json_history_dir)) {
1065                 my $id = id_for_pos($pos_calculating);
1066                 my $filename = $remoteglotconf::json_history_dir . "/" . $id . ".json";
1067
1068                 # Overwrite old analysis (assuming it exists at all) if we're
1069                 # using a different engine, or if we've calculated deeper.
1070                 # nodes is used as a tiebreaker. Don't bother about Multi-PV
1071                 # data; it's not that important.
1072                 my ($old_engine, $old_depth, $old_nodes) = get_json_analysis_stats($id);
1073                 my $new_depth = $json->{'depth'} // 0;
1074                 my $new_nodes = $json->{'nodes'} // 0;
1075                 if (!defined($old_engine) ||
1076                     $old_engine ne $json->{'engine'}{'name'} ||
1077                     $new_depth > $old_depth ||
1078                     ($new_depth == $old_depth && $new_nodes >= $old_nodes)) {
1079                         atomic_set_contents($filename, $encoded);
1080                         if (defined($json->{'score'})) {
1081                                 $dbh->do('INSERT INTO scores (id, score_type, score_value, engine, depth, nodes) VALUES (?,?,?,?,?,?) ' .
1082                                          '    ON CONFLICT (id) DO UPDATE SET ' .
1083                                          '        score_type=EXCLUDED.score_type, ' .
1084                                          '        score_value=EXCLUDED.score_value, ' .
1085                                          '        engine=EXCLUDED.engine, ' .
1086                                          '        depth=EXCLUDED.depth, ' .
1087                                          '        nodes=EXCLUDED.nodes',
1088                                         undef,
1089                                         $id, $json->{'score'}[0], $json->{'score'}[1],
1090                                         $json->{'engine'}{'name'}, $new_depth, $new_nodes);
1091                         }
1092                 }
1093         }
1094 }
1095
1096 sub atomic_set_contents {
1097         my ($filename, $contents) = @_;
1098
1099         open my $fh, ">", $filename . ".tmp"
1100                 or return;
1101         print $fh $contents;
1102         close $fh;
1103         rename($filename . ".tmp", $filename);
1104 }
1105
1106 sub id_for_pos {
1107         my ($pos, $halfmove_num) = @_;
1108
1109         $halfmove_num //= scalar @{$pos->{'history'}};
1110         (my $fen = $pos->fen()) =~ tr,/ ,-_,;
1111         return "move$halfmove_num-$fen";
1112 }
1113
1114 sub get_json_analysis_stats {
1115         my $id = shift;
1116         my $ref = $dbh->selectrow_hashref('SELECT * FROM scores WHERE id=?', undef, $id);
1117         if (defined($ref)) {
1118                 return ($ref->{'engine'}, $ref->{'depth'}, $ref->{'nodes'});
1119         } else {
1120                 return ('', 0, 0);
1121         }
1122 }
1123
1124 sub uciprint {
1125         my ($engine, $msg) = @_;
1126         $engine->print($msg);
1127         print UCILOG localtime() . " $engine->{'tag'} => $msg\n";
1128 }
1129
1130 sub short_score {
1131         my ($info, $pos, $mpv) = @_;
1132
1133         my $invert = ($pos->{'toplay'} eq 'B');
1134         if (defined($info->{'score_mate' . $mpv})) {
1135                 if ($invert) {
1136                         return sprintf "M%3d", -$info->{'score_mate' . $mpv};
1137                 } else {
1138                         return sprintf "M%3d", $info->{'score_mate' . $mpv};
1139                 }
1140         } else {
1141                 if (exists($info->{'score_cp' . $mpv})) {
1142                         my $score = $info->{'score_cp' . $mpv} * 0.01;
1143                         if ($score == 0) {
1144                                 if ($info->{'tablebase'}) {
1145                                         return "TB draw";
1146                                 } else {
1147                                         return " 0.00";
1148                                 }
1149                         }
1150                         if ($invert) {
1151                                 $score = -$score;
1152                         }
1153                         return sprintf "%+5.2f", $score;
1154                 }
1155         }
1156
1157         return undef;
1158 }
1159
1160 # Sufficient for computing long_score, short_score, plot_score and
1161 # (with side-to-play information) score_sort_key.
1162 sub score_digest {
1163         my ($info, $pos, $mpv) = @_;
1164
1165         if (defined($info->{'score_mate' . $mpv})) {
1166                 my $mate = $info->{'score_mate' . $mpv};
1167                 if ($pos->{'toplay'} eq 'B') {
1168                         $mate = -$mate;
1169                 }
1170                 return ['m', $mate];
1171         } else {
1172                 if (exists($info->{'score_cp' . $mpv})) {
1173                         my $score = $info->{'score_cp' . $mpv};
1174                         if ($pos->{'toplay'} eq 'B') {
1175                                 $score = -$score;
1176                         }
1177                         if ($score == 0 && $info->{'tablebase'}) {
1178                                 return ['d', undef];
1179                         } else {
1180                                 return ['cp', int($score)];
1181                         }
1182                 }
1183         }
1184
1185         return undef;
1186 }
1187
1188 sub long_score {
1189         my ($info, $pos, $mpv) = @_;
1190
1191         if (defined($info->{'score_mate' . $mpv})) {
1192                 my $mate = $info->{'score_mate' . $mpv};
1193                 if ($pos->{'toplay'} eq 'B') {
1194                         $mate = -$mate;
1195                 }
1196                 if ($mate > 0) {
1197                         return sprintf "White mates in %u", $mate;
1198                 } else {
1199                         return sprintf "Black mates in %u", -$mate;
1200                 }
1201         } else {
1202                 if (exists($info->{'score_cp' . $mpv})) {
1203                         my $score = $info->{'score_cp' . $mpv} * 0.01;
1204                         if ($score == 0) {
1205                                 if ($info->{'tablebase'}) {
1206                                         return "Theoretical draw";
1207                                 } else {
1208                                         return "Score:  0.00";
1209                                 }
1210                         }
1211                         if ($pos->{'toplay'} eq 'B') {
1212                                 $score = -$score;
1213                         }
1214                         return sprintf "Score: %+5.2f", $score;
1215                 }
1216         }
1217
1218         return undef;
1219 }
1220
1221 # For graphs; a single number in centipawns, capped at +/- 500.
1222 sub plot_score {
1223         my ($info, $pos, $mpv) = @_;
1224
1225         my $invert = ($pos->{'toplay'} eq 'B');
1226         if (defined($info->{'score_mate' . $mpv})) {
1227                 my $mate = $info->{'score_mate' . $mpv};
1228                 if ($invert) {
1229                         $mate = -$mate;
1230                 }
1231                 if ($mate > 0) {
1232                         return 500;
1233                 } else {
1234                         return -500;
1235                 }
1236         } else {
1237                 if (exists($info->{'score_cp' . $mpv})) {
1238                         my $score = $info->{'score_cp' . $mpv};
1239                         if ($invert) {
1240                                 $score = -$score;
1241                         }
1242                         $score = 500 if ($score > 500);
1243                         $score = -500 if ($score < -500);
1244                         return int($score);
1245                 }
1246         }
1247
1248         return undef;
1249 }
1250
1251 sub extract_clock {
1252         my ($pgn, $pos) = @_;
1253
1254         # Look for extended PGN clock tags.
1255         my $tags = $pgn->tags;
1256         if (exists($tags->{'WhiteClock'}) && exists($tags->{'BlackClock'})) {
1257                 $pos->{'white_clock'} = hms_to_sec($tags->{'WhiteClock'});
1258                 $pos->{'black_clock'} = hms_to_sec($tags->{'BlackClock'});
1259                 return;
1260         }
1261
1262         # Look for TCEC-style time comments.
1263         my $moves = $pgn->moves;
1264         my $comments = $pgn->comments;
1265         my $last_black_move = int((scalar @$moves) / 2);
1266         my $last_white_move = int((1 + scalar @$moves) / 2);
1267
1268         my $black_key = $last_black_move . "b";
1269         my $white_key = $last_white_move . "w";
1270
1271         if (exists($comments->{$white_key}) &&
1272             exists($comments->{$black_key}) &&
1273             $comments->{$white_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/ &&
1274             $comments->{$black_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/) {
1275                 $comments->{$white_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/;
1276                 $pos->{'white_clock'} = hms_to_sec($1);
1277                 $comments->{$black_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/;
1278                 $pos->{'black_clock'} = hms_to_sec($1);
1279                 return;
1280         }
1281
1282         delete $pos->{'white_clock'};
1283         delete $pos->{'black_clock'};
1284 }
1285
1286 sub hms_to_sec {
1287         my $hms = shift;
1288         return undef if (!defined($hms));
1289         $hms =~ /(\d+):(\d+):(\d+)/;
1290         return $1 * 3600 + $2 * 60 + $3;
1291 }
1292
1293 sub find_clock_start {
1294         my ($pos, $prev_pos) = @_;
1295
1296         # If the game is over, the clock is stopped.
1297         if (exists($pos->{'result'}) &&
1298             ($pos->{'result'} eq '1-0' ||
1299              $pos->{'result'} eq '1/2-1/2' ||
1300              $pos->{'result'} eq '0-1')) {
1301                 return;
1302         }
1303
1304         # When we don't have any moves, we assume the clock hasn't started yet.
1305         if ($pos->{'move_num'} == 1 && $pos->{'toplay'} eq 'W') {
1306                 if (defined($remoteglotconf::adjust_clocks_before_move)) {
1307                         &$remoteglotconf::adjust_clocks_before_move(\$pos->{'white_clock'}, \$pos->{'black_clock'}, 1, 'W');
1308                 }
1309                 return;
1310         }
1311
1312         # TODO(sesse): Maybe we can get the number of moves somehow else for FICS games.
1313         # The history is needed for id_for_pos.
1314         if (!exists($pos->{'history'})) {
1315                 return;
1316         }
1317
1318         my $id = id_for_pos($pos);
1319         my $clock_info = $dbh->selectrow_hashref('SELECT * FROM clock_info WHERE id=? AND COALESCE(white_clock_target, black_clock_target) >= EXTRACT(EPOCH FROM (CURRENT_TIMESTAMP - INTERVAL \'1 day\'));', undef, $id);
1320         if (defined($clock_info)) {
1321                 $pos->{'white_clock'} //= $clock_info->{'white_clock'};
1322                 $pos->{'black_clock'} //= $clock_info->{'black_clock'};
1323                 if ($pos->{'toplay'} eq 'W') {
1324                         $pos->{'white_clock_target'} = $clock_info->{'white_clock_target'};
1325                 } else {
1326                         $pos->{'black_clock_target'} = $clock_info->{'black_clock_target'};
1327                 }
1328                 return;
1329         }
1330
1331         # OK, we haven't seen this position before, so we assume the move
1332         # happened right now.
1333
1334         # See if we should do our own clock management (ie., clock information
1335         # is spurious or non-existent).
1336         if (defined($remoteglotconf::adjust_clocks_before_move)) {
1337                 my $wc = $pos->{'white_clock'} // $prev_pos->{'white_clock'};
1338                 my $bc = $pos->{'black_clock'} // $prev_pos->{'black_clock'};
1339                 if (defined($prev_pos->{'white_clock_target'})) {
1340                         $wc = $prev_pos->{'white_clock_target'} - time;
1341                 }
1342                 if (defined($prev_pos->{'black_clock_target'})) {
1343                         $bc = $prev_pos->{'black_clock_target'} - time;
1344                 }
1345                 &$remoteglotconf::adjust_clocks_before_move(\$wc, \$bc, $pos->{'move_num'}, $pos->{'toplay'});
1346                 $pos->{'white_clock'} = $wc;
1347                 $pos->{'black_clock'} = $bc;
1348         }
1349
1350         my $key = ($pos->{'toplay'} eq 'W') ? 'white_clock' : 'black_clock';
1351         if (!exists($pos->{$key})) {
1352                 # No clock information.
1353                 return;
1354         }
1355         my $time_left = $pos->{$key};
1356         my ($white_clock_target, $black_clock_target);
1357         if ($pos->{'toplay'} eq 'W') {
1358                 $white_clock_target = $pos->{'white_clock_target'} = time + $time_left;
1359         } else {
1360                 $black_clock_target = $pos->{'black_clock_target'} = time + $time_left;
1361         }
1362         local $dbh->{AutoCommit} = 0;
1363         $dbh->do('DELETE FROM clock_info WHERE id=?', undef, $id);
1364         $dbh->do('INSERT INTO clock_info (id, white_clock, black_clock, white_clock_target, black_clock_target) VALUES (?, ?, ?, ?, ?)', undef,
1365                 $id, $pos->{'white_clock'}, $pos->{'black_clock'}, $white_clock_target, $black_clock_target);
1366         $dbh->commit;
1367 }
1368
1369 sub schedule_tb_lookup {
1370         return if (!defined($remoteglotconf::tb_serial_key));
1371         my $pos = $pos_calculating;
1372         return if (exists($tb_cache{$pos->fen()}));
1373
1374         # If there's more than seven pieces, there's not going to be an answer,
1375         # so don't bother.
1376         return if ($pos->num_pieces() > 7);
1377
1378         # Max one at a time. If it's still relevant when it returns,
1379         # schedule_tb_lookup() will be called again.
1380         return if ($tb_lookup_running);
1381
1382         $tb_lookup_running = 1;
1383         my $url = 'http://tb7-api.chessok.com:6904/tasks/addtask?auth.login=' .
1384                 $remoteglotconf::tb_serial_key .
1385                 '&auth.password=aquarium&type=0&fen=' .
1386                 URI::Escape::uri_escape($pos->fen());
1387         print TBLOG "Downloading $url...\n";
1388         AnyEvent::HTTP::http_get($url, sub {
1389                 handle_tb_lookup_return(@_, $pos, $pos->fen());
1390         });
1391 }
1392
1393 sub handle_tb_lookup_return {
1394         my ($body, $header, $pos, $fen) = @_;
1395         print TBLOG "Response for [$fen]:\n";
1396         print TBLOG $header . "\n\n";
1397         print TBLOG $body . "\n\n";
1398         eval {
1399                 my $response = JSON::XS::decode_json($body);
1400                 if ($response->{'ErrorCode'} != 0) {
1401                         die "Unknown tablebase server error: " . $response->{'ErrorDesc'};
1402                 }
1403                 my $state = $response->{'Response'}{'StateString'};
1404                 if ($state eq 'COMPLETE') {
1405                         my $pgn = Chess::PGN::Parse->new(undef, $response->{'Response'}{'Moves'});
1406                         if (!defined($pgn) || !$pgn->read_game()) {
1407                                 warn "Error in parsing PGN\n";
1408                         } else {
1409                                 $pgn->quick_parse_game;
1410                                 my $pvpos = $pos;
1411                                 my $moves = $pgn->moves;
1412                                 my @uci_moves = ();
1413                                 for my $move (@$moves) {
1414                                         my $uci_move;
1415                                         ($pvpos, $uci_move) = $pvpos->make_pretty_move($move);
1416                                         push @uci_moves, $uci_move;
1417                                 }
1418                                 $tb_cache{$fen} = {
1419                                         result => $pgn->result,
1420                                         pv => \@uci_moves,
1421                                         score => $response->{'Response'}{'Score'},
1422                                 };
1423                                 output();
1424                         }
1425                 } elsif ($state =~ /QUEUED/ || $state =~ /PROCESSING/) {
1426                         # Try again in a second. Note that if we have changed
1427                         # position in the meantime, we might query a completely
1428                         # different position! But that's fine.
1429                 } else {
1430                         die "Unknown response state " . $state;
1431                 }
1432
1433                 # Wait a second before we schedule another one.
1434                 $tb_retry_timer = AnyEvent->timer(after => 1.0, cb => sub {
1435                         $tb_lookup_running = 0;
1436                         schedule_tb_lookup();
1437                 });
1438         };
1439         if ($@) {
1440                 warn "Error in tablebase lookup: $@";
1441
1442                 # Don't try this one again, but don't block new lookups either.
1443                 $tb_lookup_running = 0;
1444         }
1445 }
1446
1447 sub open_engine {
1448         my ($cmdline, $tag, $cb) = @_;
1449         return undef if (!defined($cmdline));
1450         return Engine->open($cmdline, $tag, $cb);
1451 }
1452
1453 sub col_letter_to_num {
1454         return ord(shift) - ord('a');
1455 }
1456
1457 sub row_letter_to_num {
1458         return 7 - (ord(shift) - ord('1'));
1459 }
1460
1461 sub parse_uci_move {
1462         my $move = shift;
1463         my $from_col = col_letter_to_num(substr($move, 0, 1));
1464         my $from_row = row_letter_to_num(substr($move, 1, 1));
1465         my $to_col   = col_letter_to_num(substr($move, 2, 1));
1466         my $to_row   = row_letter_to_num(substr($move, 3, 1));
1467         my $promo    = substr($move, 4, 1);
1468         return ($from_row, $from_col, $to_row, $to_col, $promo);
1469 }
1470
1471 sub setoptions {
1472         my ($engine, $config) = @_;
1473         uciprint($engine, "setoption name UCI_AnalyseMode value true");
1474         uciprint($engine, "setoption name Analysis Contempt value Off");
1475         if (exists($config->{'Threads'})) {  # Threads first, because clearing hash can be multithreaded then.
1476                 uciprint($engine, "setoption name Threads value " . $config->{'Threads'});
1477         }
1478         while (my ($key, $value) = each %$config) {
1479                 next if $key eq 'Threads';
1480                 uciprint($engine, "setoption name $key value $value");
1481         }
1482 }