Version bump.
[remoteglot] / remoteglot.pl
1 #! /usr/bin/perl
2
3 #
4 # remoteglot - Connects an abitrary UCI-speaking engine to ICS for easier post-game
5 #              analysis, or for live analysis of relayed games. (Do not use for
6 #              cheating! Cheating is bad for your karma, and your abuser flag.)
7 #
8 # Copyright 2007 Steinar H. Gunderson <steinar+remoteglot@gunderson.no>
9 # Licensed under the GNU General Public License, version 2.
10 #
11
12 use AnyEvent;
13 use AnyEvent::Handle;
14 use AnyEvent::HTTP;
15 use Chess::PGN::Parse;
16 use EV;
17 use Net::Telnet;
18 use File::Slurp;
19 use IPC::Open2;
20 use Time::HiRes;
21 use JSON::XS;
22 use URI::Escape;
23 use DBI;
24 use DBD::Pg;
25 require 'Position.pm';
26 require 'Engine.pm';
27 require 'config.pm';
28 use strict;
29 use warnings;
30 no warnings qw(once);
31
32 # Program starts here
33 my $latest_update = undef;
34 my $output_timer = undef;
35 my $http_timer = undef;
36 my $stop_pgn_fetch = 0;
37 my $tb_retry_timer = undef;
38 my %tb_cache = ();
39 my $tb_lookup_running = 0;
40 my $last_written_json = undef;
41
42 # Persisted so we can restart.
43 # TODO: Figure out an appropriate way to deal with database restarts
44 # and/or Postgres going away entirely.
45 my $dbh = DBI->connect($remoteglotconf::dbistr, $remoteglotconf::dbiuser, $remoteglotconf::dbipass)
46         or die DBI->errstr;
47 $dbh->{RaiseError} = 1;
48
49 $| = 1;
50
51 open(FICSLOG, ">ficslog.txt")
52         or die "ficslog.txt: $!";
53 print FICSLOG "Log starting.\n";
54 select(FICSLOG);
55 $| = 1;
56
57 open(UCILOG, ">ucilog.txt")
58         or die "ucilog.txt: $!";
59 print UCILOG "Log starting.\n";
60 select(UCILOG);
61 $| = 1;
62
63 open(TBLOG, ">tblog.txt")
64         or die "tblog.txt: $!";
65 print TBLOG "Log starting.\n";
66 select(TBLOG);
67 $| = 1;
68
69 select(STDOUT);
70 umask 0022;
71
72 # open the chess engine
73 my $engine = open_engine($remoteglotconf::engine_cmdline, 'E1', sub { handle_uci(@_, 1); });
74 my $engine2 = open_engine($remoteglotconf::engine2_cmdline, 'E2', sub { handle_uci(@_, 0); });
75 my $last_move;
76 my $last_text = '';
77 my ($pos_waiting, $pos_calculating, $pos_calculating_second_engine);
78
79 uciprint($engine, "setoption name UCI_AnalyseMode value true");
80 while (my ($key, $value) = each %remoteglotconf::engine_config) {
81         uciprint($engine, "setoption name $key value $value");
82 }
83 uciprint($engine, "ucinewgame");
84
85 if (defined($engine2)) {
86         uciprint($engine2, "setoption name UCI_AnalyseMode value true");
87         while (my ($key, $value) = each %remoteglotconf::engine2_config) {
88                 uciprint($engine2, "setoption name $key value $value");
89         }
90         uciprint($engine2, "setoption name MultiPV value 500");
91         uciprint($engine2, "ucinewgame");
92 }
93
94 print "Chess engine ready.\n";
95
96 # now talk to FICS
97 my $t = Net::Telnet->new(Timeout => 10, Prompt => '/fics% /');
98 $t->input_log(\*FICSLOG);
99 $t->open($remoteglotconf::server);
100 $t->print($remoteglotconf::nick);
101 $t->waitfor('/Press return to enter the server/');
102 $t->cmd("");
103
104 # set some options
105 $t->cmd("set shout 0");
106 $t->cmd("set seek 0");
107 $t->cmd("set style 12");
108
109 my $ev1 = AnyEvent->io(
110         fh => fileno($t),
111         poll => 'r',
112         cb => sub {    # what callback to execute
113                 while (1) {
114                         my $line = $t->getline(Timeout => 0, errmode => 'return');
115                         return if (!defined($line));
116
117                         chomp $line;
118                         $line =~ tr/\r//d;
119                         handle_fics($line);
120                 }
121         }
122 );
123 if (defined($remoteglotconf::target)) {
124         if ($remoteglotconf::target =~ /^http:/) {
125                 fetch_pgn($remoteglotconf::target);
126         } else {
127                 $t->cmd("observe $remoteglotconf::target");
128         }
129 }
130 print "FICS ready.\n";
131
132 # Engine events have already been set up by Engine.pm.
133 EV::run;
134
135 sub handle_uci {
136         my ($engine, $line, $primary) = @_;
137
138         return if $line =~ /(upper|lower)bound/;
139
140         $line =~ s/  / /g;  # Sometimes needed for Zappa Mexico
141         print UCILOG localtime() . " $engine->{'tag'} <= $line\n";
142         if ($line =~ /^info/) {
143                 my (@infos) = split / /, $line;
144                 shift @infos;
145
146                 parse_infos($engine, @infos);
147         }
148         if ($line =~ /^id/) {
149                 my (@ids) = split / /, $line;
150                 shift @ids;
151
152                 parse_ids($engine, @ids);
153         }
154         if ($line =~ /^bestmove/) {
155                 if ($primary) {
156                         return if (!$remoteglotconf::uci_assume_full_compliance);
157                         if (defined($pos_waiting)) {
158                                 uciprint($engine, "position fen " . $pos_waiting->fen());
159                                 uciprint($engine, "go infinite");
160
161                                 $pos_calculating = $pos_waiting;
162                                 $pos_waiting = undef;
163                         }
164                 } else {
165                         $engine2->{'info'} = {};
166                         my $pos = $pos_waiting // $pos_calculating;
167                         uciprint($engine2, "position fen " . $pos->fen());
168                         uciprint($engine2, "go infinite");
169                         $pos_calculating_second_engine = $pos;
170                 }
171         }
172         output();
173 }
174
175 my $getting_movelist = 0;
176 my $pos_for_movelist = undef;
177 my @uci_movelist = ();
178 my @pretty_movelist = ();
179
180 sub handle_fics {
181         my $line = shift;
182         if ($line =~ /^<12> /) {
183                 handle_position(Position->new($line));
184                 $t->cmd("moves");
185         }
186         if ($line =~ /^Movelist for game /) {
187                 my $pos = $pos_waiting // $pos_calculating;
188                 if (defined($pos)) {
189                         @uci_movelist = ();
190                         @pretty_movelist = ();
191                         $pos_for_movelist = Position->start_pos($pos->{'player_w'}, $pos->{'player_b'});
192                         $getting_movelist = 1;
193                 }
194         }
195         if ($getting_movelist &&
196             $line =~ /^\s* \d+\. \s+                     # move number
197                        (\S+) \s+ \( [\d:.]+ \) \s*       # first move, then time
198                        (?: (\S+) \s+ \( [\d:.]+ \) )?    # second move, then time 
199                      /x) {
200                 eval {
201                         my $uci_move;
202                         ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($1);
203                         push @uci_movelist, $uci_move;
204                         push @pretty_movelist, $1;
205
206                         if (defined($2)) {
207                                 ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($2);
208                                 push @uci_movelist, $uci_move;
209                                 push @pretty_movelist, $2;
210                         }
211                 };
212                 if ($@) {
213                         warn "Error when getting FICS move history: $@";
214                         $getting_movelist = 0;
215                 }
216         }
217         if ($getting_movelist &&
218             $line =~ /^\s+ \{.*\} \s+ (?: \* | 1\/2-1\/2 | 0-1 | 1-0 )/x) {
219                 # End of movelist.
220                 for my $pos ($pos_waiting, $pos_calculating) {
221                         next if (!defined($pos));
222                         if ($pos->fen() eq $pos_for_movelist->fen()) {
223                                 $pos->{'pretty_history'} = \@pretty_movelist;
224                         }
225                 }
226                 $getting_movelist = 0;
227         }
228         if ($line =~ /^([A-Za-z]+)(?:\([A-Z]+\))* tells you: (.*)$/) {
229                 my ($who, $msg) = ($1, $2);
230
231                 next if (grep { $_ eq $who } (@remoteglotconf::masters) == 0);
232
233                 if ($msg =~ /^fics (.*?)$/) {
234                         $t->cmd("tell $who Executing '$1' on FICS.");
235                         $t->cmd($1);
236                 } elsif ($msg =~ /^uci (.*?)$/) {
237                         $t->cmd("tell $who Sending '$1' to the engine.");
238                         print { $engine->{'write'} } "$1\n";
239                 } elsif ($msg =~ /^pgn (.*?)$/) {
240                         my $url = $1;
241                         $t->cmd("tell $who Starting to poll '$url'.");
242                         fetch_pgn($url);
243                 } elsif ($msg =~ /^stoppgn$/) {
244                         $t->cmd("tell $who Stopping poll.");
245                         $stop_pgn_fetch = 1;
246                         $http_timer = undef;
247                 } elsif ($msg =~ /^quit$/) {
248                         $t->cmd("tell $who Bye bye.");
249                         exit;
250                 } else {
251                         $t->cmd("tell $who Couldn't understand '$msg', sorry.");
252                 }
253         }
254         #print "FICS: [$line]\n";
255 }
256
257 # Starts periodic fetching of PGNs from the given URL.
258 sub fetch_pgn {
259         my ($url) = @_;
260         AnyEvent::HTTP::http_get($url, sub {
261                 handle_pgn(@_, $url);
262         });
263 }
264
265 my ($last_pgn_white, $last_pgn_black);
266 my @last_pgn_uci_moves = ();
267 my $pgn_hysteresis_counter = 0;
268
269 sub handle_pgn {
270         my ($body, $header, $url) = @_;
271
272         if ($stop_pgn_fetch) {
273                 $stop_pgn_fetch = 0;
274                 $http_timer = undef;
275                 return;
276         }
277
278         my $pgn = Chess::PGN::Parse->new(undef, $body);
279         if (!defined($pgn)) {
280                 warn "Error in parsing PGN from $url [body='$body']\n";
281         } elsif (!$pgn->read_game()) {
282                 warn "Error in reading PGN game from $url [body='$body']\n";
283         } elsif ($body !~ /^\[/) {
284                 warn "Malformed PGN from $url [body='$body']\n";
285         } else {
286                 eval {
287                         # Skip to the right game.
288                         while (defined($remoteglotconf::pgn_filter) &&
289                                !&$remoteglotconf::pgn_filter($pgn)) {
290                                 $pgn->read_game() or die "Out of games during filtering";
291                         }
292
293                         $pgn->parse_game({ save_comments => 'yes' });
294                         my $white = $pgn->white;
295                         my $black = $pgn->black;
296                         $white =~ s/,.*//;  # Remove first name.
297                         $black =~ s/,.*//;  # Remove first name.
298                         my $pos = Position->start_pos($white, $black);
299                         my $moves = $pgn->moves;
300                         my @uci_moves = ();
301                         my @repretty_moves = ();
302                         for my $move (@$moves) {
303                                 my ($npos, $uci_move) = $pos->make_pretty_move($move);
304                                 push @uci_moves, $uci_move;
305
306                                 # Re-prettyprint the move.
307                                 my ($from_row, $from_col, $to_row, $to_col, $promo) = parse_uci_move($uci_move);
308                                 my ($pretty, undef) = $pos->{'board'}->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
309                                 push @repretty_moves, $pretty;
310                                 $pos = $npos;
311                         }
312                         if ($pgn->result eq '1-0' || $pgn->result eq '1/2-1/2' || $pgn->result eq '0-1') {
313                                 $pos->{'result'} = $pgn->result;
314                         }
315                         $pos->{'pretty_history'} = \@repretty_moves;
316
317                         extract_clock($pgn, $pos);
318
319                         # Sometimes, PGNs lose a move or two for a short while,
320                         # or people push out new ones non-atomically. 
321                         # Thus, if we PGN doesn't change names but becomes
322                         # shorter, we mistrust it for a few seconds.
323                         my $trust_pgn = 1;
324                         if (defined($last_pgn_white) && defined($last_pgn_black) &&
325                             $last_pgn_white eq $pgn->white &&
326                             $last_pgn_black eq $pgn->black &&
327                             scalar(@uci_moves) < scalar(@last_pgn_uci_moves)) {
328                                 if (++$pgn_hysteresis_counter < 3) {
329                                         $trust_pgn = 0; 
330                                 }
331                         }
332                         if ($trust_pgn) {
333                                 $last_pgn_white = $pgn->white;
334                                 $last_pgn_black = $pgn->black;
335                                 @last_pgn_uci_moves = @uci_moves;
336                                 $pgn_hysteresis_counter = 0;
337                                 handle_position($pos);
338                         }
339                 };
340                 if ($@) {
341                         warn "Error in parsing moves from $url: $@\n";
342                 }
343         }
344         
345         $http_timer = AnyEvent->timer(after => 1.0, cb => sub {
346                 fetch_pgn($url);
347         });
348 }
349
350 sub handle_position {
351         my ($pos) = @_;
352         find_clock_start($pos, $pos_calculating);
353                 
354         # if this is already in the queue, ignore it (just update the result)
355         if (defined($pos_waiting) && $pos->fen() eq $pos_waiting->fen()) {
356                 $pos_waiting->{'result'} = $pos->{'result'};
357                 return;
358         }
359
360         # if we're already chewing on this and there's nothing else in the queue,
361         # also ignore it
362         if (!defined($pos_waiting) && defined($pos_calculating) &&
363             $pos->fen() eq $pos_calculating->fen()) {
364                 $pos_calculating->{'result'} = $pos->{'result'};
365                 return;
366         }
367
368         # if we're already thinking on something, stop and wait for the engine
369         # to approve
370         if (defined($pos_calculating)) {
371                 # Store the final data we have for this position in the history,
372                 # with the precise clock information we just got from the new
373                 # position. (Historic positions store the clock at the end of
374                 # the position.)
375                 #
376                 # Do not output anything new to the main analysis; that's
377                 # going to be obsolete really soon.
378                 $pos_calculating->{'white_clock'} = $pos->{'white_clock'};
379                 $pos_calculating->{'black_clock'} = $pos->{'black_clock'};
380                 delete $pos_calculating->{'white_clock_target'};
381                 delete $pos_calculating->{'black_clock_target'};
382                 output_json(1);
383
384                 if (!defined($pos_waiting)) {
385                         uciprint($engine, "stop");
386                 }
387                 if ($remoteglotconf::uci_assume_full_compliance) {
388                         $pos_waiting = $pos;
389                 } else {
390                         uciprint($engine, "position fen " . $pos->fen());
391                         uciprint($engine, "go infinite");
392                         $pos_calculating = $pos;
393                 }
394         } else {
395                 # it's wrong just to give the FEN (the move history is useful,
396                 # and per the UCI spec, we should really have sent "ucinewgame"),
397                 # but it's easier
398                 uciprint($engine, "position fen " . $pos->fen());
399                 uciprint($engine, "go infinite");
400                 $pos_calculating = $pos;
401         }
402
403         if (defined($engine2)) {
404                 if (defined($pos_calculating_second_engine)) {
405                         uciprint($engine2, "stop");
406                 } else {
407                         uciprint($engine2, "position fen " . $pos->fen());
408                         uciprint($engine2, "go infinite");
409                         $pos_calculating_second_engine = $pos;
410                 }
411                 $engine2->{'info'} = {};
412         }
413
414         $engine->{'info'} = {};
415         $last_move = time;
416
417         schedule_tb_lookup();
418
419         # 
420         # Output a command every move to note that we're
421         # still paying attention -- this is a good tradeoff,
422         # since if no move has happened in the last half
423         # hour, the analysis/relay has most likely stopped
424         # and we should stop hogging server resources.
425         #
426         $t->cmd("date");
427 }
428
429 sub parse_infos {
430         my ($engine, @x) = @_;
431         my $mpv = '';
432
433         my $info = $engine->{'info'};
434
435         # Search for "multipv" first of all, since e.g. Stockfish doesn't put it first.
436         for my $i (0..$#x - 1) {
437                 if ($x[$i] eq 'multipv') {
438                         $mpv = $x[$i + 1];
439                         next;
440                 }
441         }
442
443         while (scalar @x > 0) {
444                 if ($x[0] eq 'multipv') {
445                         # Dealt with above
446                         shift @x;
447                         shift @x;
448                         next;
449                 }
450                 if ($x[0] eq 'currmove' || $x[0] eq 'currmovenumber' || $x[0] eq 'cpuload') {
451                         my $key = shift @x;
452                         my $value = shift @x;
453                         $info->{$key} = $value;
454                         next;
455                 }
456                 if ($x[0] eq 'depth' || $x[0] eq 'seldepth' || $x[0] eq 'hashfull' ||
457                     $x[0] eq 'time' || $x[0] eq 'nodes' || $x[0] eq 'nps' ||
458                     $x[0] eq 'tbhits') {
459                         my $key = shift @x;
460                         my $value = shift @x;
461                         $info->{$key . $mpv} = $value;
462                         next;
463                 }
464                 if ($x[0] eq 'score') {
465                         shift @x;
466
467                         delete $info->{'score_cp' . $mpv};
468                         delete $info->{'score_mate' . $mpv};
469
470                         while ($x[0] eq 'cp' || $x[0] eq 'mate') {
471                                 if ($x[0] eq 'cp') {
472                                         shift @x;
473                                         $info->{'score_cp' . $mpv} = shift @x;
474                                 } elsif ($x[0] eq 'mate') {
475                                         shift @x;
476                                         $info->{'score_mate' . $mpv} = shift @x;
477                                 } else {
478                                         shift @x;
479                                 }
480                         }
481                         next;
482                 }
483                 if ($x[0] eq 'pv') {
484                         $info->{'pv' . $mpv} = [ @x[1..$#x] ];
485                         last;
486                 }
487                 if ($x[0] eq 'string' || $x[0] eq 'UCI_AnalyseMode' || $x[0] eq 'setting' || $x[0] eq 'contempt') {
488                         last;
489                 }
490
491                 #print "unknown info '$x[0]', trying to recover...\n";
492                 #shift @x;
493                 die "Unknown info '" . join(',', @x) . "'";
494
495         }
496 }
497
498 sub parse_ids {
499         my ($engine, @x) = @_;
500
501         while (scalar @x > 0) {
502                 if ($x[0] eq 'name') {
503                         my $value = join(' ', @x);
504                         $engine->{'id'}{'author'} = $value;
505                         last;
506                 }
507
508                 # unknown
509                 shift @x;
510         }
511 }
512
513 sub prettyprint_pv_no_cache {
514         my ($board, @pvs) = @_;
515
516         if (scalar @pvs == 0 || !defined($pvs[0])) {
517                 return ();
518         }
519
520         my $pv = shift @pvs;
521         my ($from_row, $from_col, $to_row, $to_col, $promo) = parse_uci_move($pv);
522         my ($pretty, $nb) = $board->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
523         return ( $pretty, prettyprint_pv_no_cache($nb, @pvs) );
524 }
525
526 sub prettyprint_pv {
527         my ($pos, @pvs) = @_;
528
529         my $cachekey = join('', @pvs);
530         if (exists($pos->{'prettyprint_cache'}{$cachekey})) {
531                 return @{$pos->{'prettyprint_cache'}{$cachekey}};
532         } else {
533                 my @res = prettyprint_pv_no_cache($pos->{'board'}, @pvs);
534                 $pos->{'prettyprint_cache'}{$cachekey} = \@res;
535                 return @res;
536         }
537 }
538
539 sub complete_using_tbprobe {
540         my ($pos, $info, $mpv) = @_;
541
542         # We need Fathom installed to do standalone TB probes.
543         return if (!defined($remoteglotconf::fathom_cmdline));
544
545         # If we already have a mate, don't bother; in some cases, it would even be
546         # better than a tablebase score.
547         return if defined($info->{'score_mate' . $mpv});
548
549         # If we have a draw or near-draw score, there's also not much interesting
550         # we could add from a tablebase. We only really want mates.
551         return if ($info->{'score_cp' . $mpv} >= -12250 && $info->{'score_cp' . $mpv} <= 12250);
552
553         # Run through the PV until we are at a 6-man position.
554         # TODO: We could in theory only have 5-man data.
555         my @pv = @{$info->{'pv' . $mpv}};
556         my $key = join('', @pv);
557         my @moves = ();
558         if (exists($pos->{'tbprobe_cache'}{$key})) {
559                 @moves = $pos->{'tbprobe_cache'}{$key};
560         } else {
561                 while ($pos->num_pieces() > 6 && $#pv > -1) {
562                         my $move = shift @pv;
563                         push @moves, $move;
564                         $pos = $pos->make_move(parse_uci_move($move));
565                 }
566
567                 return if ($pos->num_pieces() > 6);
568
569                 my $fen = $pos->fen();
570                 my $pgn_text = `fathom --path=/srv/syzygy "$fen"`;
571                 my $pgn = Chess::PGN::Parse->new(undef, $pgn_text);
572                 return if (!defined($pgn) || !$pgn->read_game() || ($pgn->result ne '0-1' && $pgn->result ne '1-0'));
573                 $pgn->quick_parse_game;
574                 $info->{'pv' . $mpv} = \@moves;
575
576                 # Splice the PV from the tablebase onto what we have so far.
577                 for my $move (@{$pgn->moves}) {
578                         my $uci_move;
579                         ($pos, $uci_move) = $pos->make_pretty_move($move);
580                         push @moves, $uci_move;
581                 }
582         }
583
584         $info->{'pv' . $mpv} = \@moves;
585
586         my $matelen = int((1 + scalar @moves) / 2);
587         if ((scalar @moves) % 2 == 0) {
588                 $info->{'score_mate' . $mpv} = -$matelen;
589         } else {
590                 $info->{'score_mate' . $mpv} = $matelen;
591         }
592 }
593
594 sub output {
595         #return;
596
597         return if (!defined($pos_calculating));
598
599         # Don't update too often.
600         my $age = Time::HiRes::tv_interval($latest_update);
601         if ($age < $remoteglotconf::update_max_interval) {
602                 my $wait = $remoteglotconf::update_max_interval + 0.01 - $age;
603                 $output_timer = AnyEvent->timer(after => $wait, cb => \&output);
604                 return;
605         }
606         
607         my $info = $engine->{'info'};
608
609         #
610         # If we have tablebase data from a previous lookup, replace the
611         # engine data with the data from the tablebase.
612         #
613         my $fen = $pos_calculating->fen();
614         if (exists($tb_cache{$fen})) {
615                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
616                         delete $info->{$key . '1'};
617                         delete $info->{$key};
618                 }
619                 $info->{'nodes'} = 0;
620                 $info->{'nps'} = 0;
621                 $info->{'depth'} = 0;
622                 $info->{'seldepth'} = 0;
623                 $info->{'tbhits'} = 0;
624
625                 my $t = $tb_cache{$fen};
626                 my $pv = $t->{'pv'};
627                 my $matelen = int((1 + $t->{'score'}) / 2);
628                 if ($t->{'result'} eq '1/2-1/2') {
629                         $info->{'score_cp'} = 0;
630                 } elsif ($t->{'result'} eq '1-0') {
631                         if ($pos_calculating->{'toplay'} eq 'B') {
632                                 $info->{'score_mate'} = -$matelen;
633                         } else {
634                                 $info->{'score_mate'} = $matelen;
635                         }
636                 } else {
637                         if ($pos_calculating->{'toplay'} eq 'B') {
638                                 $info->{'score_mate'} = $matelen;
639                         } else {
640                                 $info->{'score_mate'} = -$matelen;
641                         }
642                 }
643                 $info->{'pv'} = $pv;
644                 $info->{'tablebase'} = 1;
645         } else {
646                 $info->{'tablebase'} = 0;
647         }
648         
649         #
650         # Some programs _always_ report MultiPV, even with only one PV.
651         # In this case, we simply use that data as if MultiPV was never
652         # specified.
653         #
654         if (exists($info->{'pv1'}) && !exists($info->{'pv2'})) {
655                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
656                         if (exists($info->{$key . '1'})) {
657                                 $info->{$key} = $info->{$key . '1'};
658                         } else {
659                                 delete $info->{$key};
660                         }
661                 }
662         }
663         
664         #
665         # Check the PVs first. if they're invalid, just wait, as our data
666         # is most likely out of sync. This isn't a very good solution, as
667         # it can frequently miss stuff, but it's good enough for most users.
668         #
669         eval {
670                 my $dummy;
671                 if (exists($info->{'pv'})) {
672                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv'}});
673                 }
674         
675                 my $mpv = 1;
676                 while (exists($info->{'pv' . $mpv})) {
677                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}});
678                         ++$mpv;
679                 }
680         };
681         if ($@) {
682                 $engine->{'info'} = {};
683                 return;
684         }
685
686         # Now do our own Syzygy tablebase probes to convert scores like +123.45 to mate.
687         if (exists($info->{'pv'})) {
688                 complete_using_tbprobe($pos_calculating, $info, '');
689         }
690
691         my $mpv = 1;
692         while (exists($info->{'pv' . $mpv})) {
693                 complete_using_tbprobe($pos_calculating, $info, $mpv);
694                 ++$mpv;
695         }
696
697         output_screen();
698         output_json(0);
699         $latest_update = [Time::HiRes::gettimeofday];
700 }
701
702 sub output_screen {
703         my $info = $engine->{'info'};
704         my $id = $engine->{'id'};
705
706         my $text = 'Analysis';
707         if ($pos_calculating->{'last_move'} ne 'none') {
708                 if ($pos_calculating->{'toplay'} eq 'W') {
709                         $text .= sprintf ' after %u. ... %s', ($pos_calculating->{'move_num'}-1), $pos_calculating->{'last_move'};
710                 } else {
711                         $text .= sprintf ' after %u. %s', $pos_calculating->{'move_num'}, $pos_calculating->{'last_move'};
712                 }
713                 if (exists($id->{'name'})) {
714                         $text .= ',';
715                 }
716         }
717
718         if (exists($id->{'name'})) {
719                 $text .= " by $id->{'name'}:\n\n";
720         } else {
721                 $text .= ":\n\n";
722         }
723
724         return unless (exists($pos_calculating->{'board'}));
725                 
726         if (exists($info->{'pv1'}) && exists($info->{'pv2'})) {
727                 # multi-PV
728                 my $mpv = 1;
729                 while (exists($info->{'pv' . $mpv})) {
730                         $text .= sprintf "  PV%2u", $mpv;
731                         my $score = short_score($info, $pos_calculating, $mpv);
732                         $text .= "  ($score)" if (defined($score));
733
734                         my $tbhits = '';
735                         if (exists($info->{'tbhits' . $mpv}) && $info->{'tbhits' . $mpv} > 0) {
736                                 if ($info->{'tbhits' . $mpv} == 1) {
737                                         $tbhits = ", 1 tbhit";
738                                 } else {
739                                         $tbhits = sprintf ", %u tbhits", $info->{'tbhits' . $mpv};
740                                 }
741                         }
742
743                         if (exists($info->{'nodes' . $mpv}) && exists($info->{'nps' . $mpv}) && exists($info->{'depth' . $mpv})) {
744                                 $text .= sprintf " (%5u kn, %3u kn/s, %2u ply$tbhits)",
745                                         $info->{'nodes' . $mpv} / 1000, $info->{'nps' . $mpv} / 1000, $info->{'depth' . $mpv};
746                         }
747
748                         $text .= ":\n";
749                         $text .= "  " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}})) . "\n";
750                         $text .= "\n";
751                         ++$mpv;
752                 }
753         } else {
754                 # single-PV
755                 my $score = long_score($info, $pos_calculating, '');
756                 $text .= "  $score\n" if defined($score);
757                 $text .=  "  PV: " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv'}}));
758                 $text .=  "\n";
759
760                 if (exists($info->{'nodes'}) && exists($info->{'nps'}) && exists($info->{'depth'})) {
761                         $text .= sprintf "  %u nodes, %7u nodes/sec, depth %u ply",
762                                 $info->{'nodes'}, $info->{'nps'}, $info->{'depth'};
763                 }
764                 if (exists($info->{'seldepth'})) {
765                         $text .= sprintf " (%u selective)", $info->{'seldepth'};
766                 }
767                 if (exists($info->{'tbhits'}) && $info->{'tbhits'} > 0) {
768                         if ($info->{'tbhits'} == 1) {
769                                 $text .= ", one Syzygy hit";
770                         } else {
771                                 $text .= sprintf ", %u Syzygy hits", $info->{'tbhits'};
772                         }
773                 }
774                 $text .= "\n\n";
775         }
776
777         #$text .= book_info($pos_calculating->fen(), $pos_calculating->{'board'}, $pos_calculating->{'toplay'});
778
779         my @refutation_lines = ();
780         if (defined($engine2)) {
781                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
782                         my $info = $engine2->{'info'};
783                         last if (!exists($info->{'pv' . $mpv}));
784                         eval {
785                                 complete_using_tbprobe($pos_calculating_second_engine, $info, $mpv);
786                                 my $pv = $info->{'pv' . $mpv};
787                                 my $pretty_move = join('', prettyprint_pv($pos_calculating_second_engine, $pv->[0]));
788                                 my @pretty_pv = prettyprint_pv($pos_calculating_second_engine, @$pv);
789                                 if (scalar @pretty_pv > 5) {
790                                         @pretty_pv = @pretty_pv[0..4];
791                                         push @pretty_pv, "...";
792                                 }
793                                 my $key = $pretty_move;
794                                 my $line = sprintf("  %-6s %6s %3s  %s",
795                                         $pretty_move,
796                                         short_score($info, $pos_calculating_second_engine, $mpv),
797                                         "d" . $info->{'depth' . $mpv},
798                                         join(', ', @pretty_pv));
799                                 push @refutation_lines, [ $key, $line ];
800                         };
801                 }
802         }
803
804         if ($#refutation_lines >= 0) {
805                 $text .= "Shallow search of all legal moves:\n\n";
806                 for my $line (sort { $a->[0] cmp $b->[0] } @refutation_lines) {
807                         $text .= $line->[1] . "\n";
808                 }
809                 $text .= "\n\n";        
810         }       
811
812         if ($last_text ne $text) {
813                 print "\e[H\e[2J"; # clear the screen
814                 print $text;
815                 $last_text = $text;
816         }
817 }
818
819 sub output_json {
820         my $historic_json_only = shift;
821         my $info = $engine->{'info'};
822
823         my $json = {};
824         $json->{'position'} = $pos_calculating->to_json_hash();
825         $json->{'engine'} = $engine->{'id'};
826         if (defined($remoteglotconf::engine_url)) {
827                 $json->{'engine'}{'url'} = $remoteglotconf::engine_url;
828         }
829         if (defined($remoteglotconf::engine_details)) {
830                 $json->{'engine'}{'details'} = $remoteglotconf::engine_details;
831         }
832         if (defined($remoteglotconf::move_source)) {
833                 $json->{'move_source'} = $remoteglotconf::move_source;
834         }
835         if (defined($remoteglotconf::move_source_url)) {
836                 $json->{'move_source_url'} = $remoteglotconf::move_source_url;
837         }
838         $json->{'score'} = score_digest($info, $pos_calculating, '');
839         $json->{'using_lomonosov'} = defined($remoteglotconf::tb_serial_key);
840
841         $json->{'nodes'} = $info->{'nodes'};
842         $json->{'nps'} = $info->{'nps'};
843         $json->{'depth'} = $info->{'depth'};
844         $json->{'tbhits'} = $info->{'tbhits'};
845         $json->{'seldepth'} = $info->{'seldepth'};
846         $json->{'tablebase'} = $info->{'tablebase'};
847
848         $json->{'pv_uci'} = $info->{'pv'};  # Still needs to be there for the JS to calculate arrows; only for the primary PV, though!
849         $json->{'pv_pretty'} = [ prettyprint_pv($pos_calculating, @{$info->{'pv'}}) ];
850
851         my %refutation_lines = ();
852         my @refutation_lines = ();
853         if (defined($engine2)) {
854                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
855                         my $info = $engine2->{'info'};
856                         my $pretty_move = "";
857                         my @pretty_pv = ();
858                         last if (!exists($info->{'pv' . $mpv}));
859
860                         eval {
861                                 complete_using_tbprobe($pos_calculating, $info, $mpv);
862                                 my $pv = $info->{'pv' . $mpv};
863                                 my $pretty_move = join('', prettyprint_pv($pos_calculating, $pv->[0]));
864                                 my @pretty_pv = prettyprint_pv($pos_calculating, @$pv);
865                                 $refutation_lines{$pv->[0]} = {
866                                         sort_key => $pretty_move,
867                                         depth => $info->{'depth' . $mpv},
868                                         score => score_digest($info, $pos_calculating, $mpv),
869                                         pretty_move => $pretty_move,
870                                         pv_pretty => \@pretty_pv,
871                                 };
872                         };
873                 }
874         }
875         $json->{'refutation_lines'} = \%refutation_lines;
876
877         # Piece together historic score information, to the degree we have it.
878         if (!$historic_json_only && exists($pos_calculating->{'pretty_history'})) {
879                 my %score_history = ();
880
881                 my $q = $dbh->prepare('SELECT * FROM scores WHERE id=?');
882                 my $pos = Position->start_pos('white', 'black');
883                 my $halfmove_num = 0;
884                 for my $move (@{$pos_calculating->{'pretty_history'}}) {
885                         my $id = id_for_pos($pos, $halfmove_num);
886                         my $ref = $dbh->selectrow_hashref($q, undef, $id);
887                         if (defined($ref)) {
888                                 $score_history{$halfmove_num} = [
889                                         $ref->{'score_type'},
890                                         $ref->{'score_value'}
891                                 ];
892                         }
893                         ++$halfmove_num;
894                         ($pos) = $pos->make_pretty_move($move);
895                 }
896                 $q->finish;
897
898                 # If at any point we are missing 10 consecutive moves,
899                 # truncate the history there. This is so we don't get into
900                 # a situation where we e.g. start analyzing at move 45,
901                 # but we have analysis for 1. e4 from some completely different game
902                 # and thus show a huge hole.
903                 my $consecutive_missing = 0;
904                 my $truncate_until = 0;
905                 for (my $i = $halfmove_num; $i --> 0; ) {
906                         if ($consecutive_missing >= 10) {
907                                 delete $score_history{$i};
908                                 next;
909                         }
910                         if (exists($score_history{$i})) {
911                                 $consecutive_missing = 0;
912                         } else {
913                                 ++$consecutive_missing;
914                         }
915                 }
916
917                 $json->{'score_history'} = \%score_history;
918         }
919
920         # Give out a list of other games going on. (Empty is fine.)
921         # TODO: Don't bother reading our own file, the data will be stale anyway.
922         if (!$historic_json_only) {
923                 my @games = ();
924
925                 my $q = $dbh->prepare('SELECT * FROM current_games ORDER BY priority DESC, id');
926                 $q->execute;
927                 while (my $ref = $q->fetchrow_hashref) {
928                         eval {
929                                 my $other_game_contents = File::Slurp::read_file($ref->{'json_path'});
930                                 my $other_game_json = JSON::XS::decode_json($other_game_contents);
931
932                                 die "Missing position" if (!exists($other_game_json->{'position'}));
933                                 my $white = $other_game_json->{'position'}{'player_w'} // die 'Missing white';
934                                 my $black = $other_game_json->{'position'}{'player_b'} // die 'Missing black';
935
936                                 my $game = {
937                                         id => $ref->{'id'},
938                                         name => "$white–$black",
939                                         url => $ref->{'url'},
940                                         hashurl => $ref->{'hash_url'},
941                                 };
942                                 if (defined($other_game_json->{'position'}{'result'})) {
943                                         $game->{'result'} = $other_game_json->{'position'}{'result'};
944                                 } else {
945                                         $game->{'score'} = $other_game_json->{'score'};
946                                 }
947                                 push @games, $game;
948                         };
949                         if ($@) {
950                                 warn "Could not add external game " . $ref->{'json_path'} . ": $@";
951                         }
952                 }
953
954                 if (scalar @games > 0) {
955                         $json->{'games'} = \@games;
956                 }
957         }
958
959         my $json_enc = JSON::XS->new;
960         $json_enc->canonical(1);
961         my $encoded = $json_enc->encode($json);
962         unless ($historic_json_only || !defined($remoteglotconf::json_output) ||
963                 (defined($last_written_json) && $last_written_json eq $encoded)) {
964                 atomic_set_contents($remoteglotconf::json_output, $encoded);
965                 $last_written_json = $encoded;
966         }
967
968         if (exists($pos_calculating->{'pretty_history'}) &&
969             defined($remoteglotconf::json_history_dir)) {
970                 my $id = id_for_pos($pos_calculating);
971                 my $filename = $remoteglotconf::json_history_dir . "/" . $id . ".json";
972
973                 # Overwrite old analysis (assuming it exists at all) if we're
974                 # using a different engine, or if we've calculated deeper.
975                 # nodes is used as a tiebreaker. Don't bother about Multi-PV
976                 # data; it's not that important.
977                 my ($old_engine, $old_depth, $old_nodes) = get_json_analysis_stats($id);
978                 my $new_depth = $json->{'depth'} // 0;
979                 my $new_nodes = $json->{'nodes'} // 0;
980                 if (!defined($old_engine) ||
981                     $old_engine ne $json->{'engine'}{'name'} ||
982                     $new_depth > $old_depth ||
983                     ($new_depth == $old_depth && $new_nodes >= $old_nodes)) {
984                         atomic_set_contents($filename, $encoded);
985                         if (defined($json->{'score'})) {
986                                 $dbh->do('INSERT INTO scores (id, score_type, score_value, engine, depth, nodes) VALUES (?,?,?,?,?,?) ' .
987                                          '    ON CONFLICT (id) DO UPDATE SET ' .
988                                          '        score_type=EXCLUDED.score_type, ' .
989                                          '        score_value=EXCLUDED.score_value, ' .
990                                          '        engine=EXCLUDED.engine, ' .
991                                          '        depth=EXCLUDED.depth, ' .
992                                          '        nodes=EXCLUDED.nodes',
993                                         undef,
994                                         $id, $json->{'score'}[0], $json->{'score'}[1],
995                                         $json->{'engine'}{'name'}, $new_depth, $new_nodes);
996                         }
997                 }
998         }
999 }
1000
1001 sub atomic_set_contents {
1002         my ($filename, $contents) = @_;
1003
1004         open my $fh, ">", $filename . ".tmp"
1005                 or return;
1006         print $fh $contents;
1007         close $fh;
1008         rename($filename . ".tmp", $filename);
1009 }
1010
1011 sub id_for_pos {
1012         my ($pos, $halfmove_num) = @_;
1013
1014         $halfmove_num //= scalar @{$pos->{'pretty_history'}};
1015         (my $fen = $pos->fen()) =~ tr,/ ,-_,;
1016         return "move$halfmove_num-$fen";
1017 }
1018
1019 sub get_json_analysis_stats {
1020         my $id = shift;
1021         my $ref = $dbh->selectrow_hashref('SELECT * FROM scores WHERE id=?', undef, $id);
1022         if (defined($ref)) {
1023                 return ($ref->{'engine'}, $ref->{'depth'}, $ref->{'nodes'});
1024         } else {
1025                 return ('', 0, 0);
1026         }
1027 }
1028
1029 sub uciprint {
1030         my ($engine, $msg) = @_;
1031         $engine->print($msg);
1032         print UCILOG localtime() . " $engine->{'tag'} => $msg\n";
1033 }
1034
1035 sub short_score {
1036         my ($info, $pos, $mpv) = @_;
1037
1038         my $invert = ($pos->{'toplay'} eq 'B');
1039         if (defined($info->{'score_mate' . $mpv})) {
1040                 if ($invert) {
1041                         return sprintf "M%3d", -$info->{'score_mate' . $mpv};
1042                 } else {
1043                         return sprintf "M%3d", $info->{'score_mate' . $mpv};
1044                 }
1045         } else {
1046                 if (exists($info->{'score_cp' . $mpv})) {
1047                         my $score = $info->{'score_cp' . $mpv} * 0.01;
1048                         if ($score == 0) {
1049                                 if ($info->{'tablebase'}) {
1050                                         return "TB draw";
1051                                 } else {
1052                                         return " 0.00";
1053                                 }
1054                         }
1055                         if ($invert) {
1056                                 $score = -$score;
1057                         }
1058                         return sprintf "%+5.2f", $score;
1059                 }
1060         }
1061
1062         return undef;
1063 }
1064
1065 # Sufficient for computing long_score, short_score, plot_score and
1066 # (with side-to-play information) score_sort_key.
1067 sub score_digest {
1068         my ($info, $pos, $mpv) = @_;
1069
1070         if (defined($info->{'score_mate' . $mpv})) {
1071                 my $mate = $info->{'score_mate' . $mpv};
1072                 if ($pos->{'toplay'} eq 'B') {
1073                         $mate = -$mate;
1074                 }
1075                 return ['m', $mate];
1076         } else {
1077                 if (exists($info->{'score_cp' . $mpv})) {
1078                         my $score = $info->{'score_cp' . $mpv};
1079                         if ($pos->{'toplay'} eq 'B') {
1080                                 $score = -$score;
1081                         }
1082                         if ($score == 0 && $info->{'tablebase'}) {
1083                                 return ['d', undef];
1084                         } else {
1085                                 return ['cp', $score];
1086                         }
1087                 }
1088         }
1089
1090         return undef;
1091 }
1092
1093 sub long_score {
1094         my ($info, $pos, $mpv) = @_;
1095
1096         if (defined($info->{'score_mate' . $mpv})) {
1097                 my $mate = $info->{'score_mate' . $mpv};
1098                 if ($pos->{'toplay'} eq 'B') {
1099                         $mate = -$mate;
1100                 }
1101                 if ($mate > 0) {
1102                         return sprintf "White mates in %u", $mate;
1103                 } else {
1104                         return sprintf "Black mates in %u", -$mate;
1105                 }
1106         } else {
1107                 if (exists($info->{'score_cp' . $mpv})) {
1108                         my $score = $info->{'score_cp' . $mpv} * 0.01;
1109                         if ($score == 0) {
1110                                 if ($info->{'tablebase'}) {
1111                                         return "Theoretical draw";
1112                                 } else {
1113                                         return "Score:  0.00";
1114                                 }
1115                         }
1116                         if ($pos->{'toplay'} eq 'B') {
1117                                 $score = -$score;
1118                         }
1119                         return sprintf "Score: %+5.2f", $score;
1120                 }
1121         }
1122
1123         return undef;
1124 }
1125
1126 # For graphs; a single number in centipawns, capped at +/- 500.
1127 sub plot_score {
1128         my ($info, $pos, $mpv) = @_;
1129
1130         my $invert = ($pos->{'toplay'} eq 'B');
1131         if (defined($info->{'score_mate' . $mpv})) {
1132                 my $mate = $info->{'score_mate' . $mpv};
1133                 if ($invert) {
1134                         $mate = -$mate;
1135                 }
1136                 if ($mate > 0) {
1137                         return 500;
1138                 } else {
1139                         return -500;
1140                 }
1141         } else {
1142                 if (exists($info->{'score_cp' . $mpv})) {
1143                         my $score = $info->{'score_cp' . $mpv};
1144                         if ($invert) {
1145                                 $score = -$score;
1146                         }
1147                         $score = 500 if ($score > 500);
1148                         $score = -500 if ($score < -500);
1149                         return int($score);
1150                 }
1151         }
1152
1153         return undef;
1154 }
1155
1156 my %book_cache = ();
1157 sub book_info {
1158         my ($fen, $board, $toplay) = @_;
1159
1160         if (exists($book_cache{$fen})) {
1161                 return $book_cache{$fen};
1162         }
1163
1164         my $ret = `./booklook $fen`;
1165         return "" if ($ret =~ /Not found/ || $ret eq '');
1166
1167         my @moves = ();
1168
1169         for my $m (split /\n/, $ret) {
1170                 my ($move, $annotation, $win, $draw, $lose, $rating, $rating_div) = split /,/, $m;
1171
1172                 my $pmove;
1173                 if ($move eq '')  {
1174                         $pmove = '(current)';
1175                 } else {
1176                         ($pmove) = prettyprint_pv_no_cache($board, $move);
1177                         $pmove .= $annotation;
1178                 }
1179
1180                 my $score;
1181                 if ($toplay eq 'W') {
1182                         $score = 1.0 * $win + 0.5 * $draw + 0.0 * $lose;
1183                 } else {
1184                         $score = 0.0 * $win + 0.5 * $draw + 1.0 * $lose;
1185                 }
1186                 my $n = $win + $draw + $lose;
1187                 
1188                 my $percent;
1189                 if ($n == 0) {
1190                         $percent = "     ";
1191                 } else {
1192                         $percent = sprintf "%4u%%", int(100.0 * $score / $n + 0.5);
1193                 }
1194
1195                 push @moves, [ $pmove, $n, $percent, $rating ];
1196         }
1197
1198         @moves[1..$#moves] = sort { $b->[2] cmp $a->[2] } @moves[1..$#moves];
1199         
1200         my $text = "Book moves:\n\n              Perf.     N     Rating\n\n";
1201         for my $m (@moves) {
1202                 $text .= sprintf "  %-10s %s   %6u    %4s\n", $m->[0], $m->[2], $m->[1], $m->[3]
1203         }
1204
1205         return $text;
1206 }
1207
1208 sub extract_clock {
1209         my ($pgn, $pos) = @_;
1210
1211         # Look for extended PGN clock tags.
1212         my $tags = $pgn->tags;
1213         if (exists($tags->{'WhiteClock'}) && exists($tags->{'BlackClock'})) {
1214                 $pos->{'white_clock'} = hms_to_sec($tags->{'WhiteClock'});
1215                 $pos->{'black_clock'} = hms_to_sec($tags->{'BlackClock'});
1216                 return;
1217         }
1218
1219         # Look for TCEC-style time comments.
1220         my $moves = $pgn->moves;
1221         my $comments = $pgn->comments;
1222         my $last_black_move = int((scalar @$moves) / 2);
1223         my $last_white_move = int((1 + scalar @$moves) / 2);
1224
1225         my $black_key = $last_black_move . "b";
1226         my $white_key = $last_white_move . "w";
1227
1228         if (exists($comments->{$white_key}) &&
1229             exists($comments->{$black_key}) &&
1230             $comments->{$white_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/ &&
1231             $comments->{$black_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/) {
1232                 $comments->{$white_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/;
1233                 $pos->{'white_clock'} = hms_to_sec($1);
1234                 $comments->{$black_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/;
1235                 $pos->{'black_clock'} = hms_to_sec($1);
1236                 return;
1237         }
1238
1239         delete $pos->{'white_clock'};
1240         delete $pos->{'black_clock'};
1241 }
1242
1243 sub hms_to_sec {
1244         my $hms = shift;
1245         return undef if (!defined($hms));
1246         $hms =~ /(\d+):(\d+):(\d+)/;
1247         return $1 * 3600 + $2 * 60 + $3;
1248 }
1249
1250 sub find_clock_start {
1251         my ($pos, $prev_pos) = @_;
1252
1253         # If the game is over, the clock is stopped.
1254         if (exists($pos->{'result'}) &&
1255             ($pos->{'result'} eq '1-0' ||
1256              $pos->{'result'} eq '1/2-1/2' ||
1257              $pos->{'result'} eq '0-1')) {
1258                 return;
1259         }
1260
1261         # When we don't have any moves, we assume the clock hasn't started yet.
1262         if ($pos->{'move_num'} == 1 && $pos->{'toplay'} eq 'W') {
1263                 if (defined($remoteglotconf::adjust_clocks_before_move)) {
1264                         &$remoteglotconf::adjust_clocks_before_move(\$pos->{'white_clock'}, \$pos->{'black_clock'}, 1, 'W');
1265                 }
1266                 return;
1267         }
1268
1269         # TODO(sesse): Maybe we can get the number of moves somehow else for FICS games.
1270         # The history is needed for id_for_pos.
1271         if (!exists($pos->{'pretty_history'})) {
1272                 return;
1273         }
1274
1275         my $id = id_for_pos($pos);
1276         my $clock_info = $dbh->selectrow_hashref('SELECT * FROM clock_info WHERE id=?', undef, $id);
1277         if (defined($clock_info)) {
1278                 $pos->{'white_clock'} //= $clock_info->{'white_clock'};
1279                 $pos->{'black_clock'} //= $clock_info->{'black_clock'};
1280                 if ($pos->{'toplay'} eq 'W') {
1281                         $pos->{'white_clock_target'} = $clock_info->{'white_clock_target'};
1282                 } else {
1283                         $pos->{'black_clock_target'} = $clock_info->{'black_clock_target'};
1284                 }
1285                 return;
1286         }
1287
1288         # OK, we haven't seen this position before, so we assume the move
1289         # happened right now.
1290
1291         # See if we should do our own clock management (ie., clock information
1292         # is spurious or non-existent).
1293         if (defined($remoteglotconf::adjust_clocks_before_move)) {
1294                 my $wc = $pos->{'white_clock'} // $prev_pos->{'white_clock'};
1295                 my $bc = $pos->{'black_clock'} // $prev_pos->{'black_clock'};
1296                 if (defined($prev_pos->{'white_clock_target'})) {
1297                         $wc = $prev_pos->{'white_clock_target'} - time;
1298                 }
1299                 if (defined($prev_pos->{'black_clock_target'})) {
1300                         $bc = $prev_pos->{'black_clock_target'} - time;
1301                 }
1302                 &$remoteglotconf::adjust_clocks_before_move(\$wc, \$bc, $pos->{'move_num'}, $pos->{'toplay'});
1303                 $pos->{'white_clock'} = $wc;
1304                 $pos->{'black_clock'} = $bc;
1305         }
1306
1307         my $key = ($pos->{'toplay'} eq 'W') ? 'white_clock' : 'black_clock';
1308         if (!exists($pos->{$key})) {
1309                 # No clock information.
1310                 return;
1311         }
1312         my $time_left = $pos->{$key};
1313         my ($white_clock_target, $black_clock_target);
1314         if ($pos->{'toplay'} eq 'W') {
1315                 $white_clock_target = $pos->{'white_clock_target'} = time + $time_left;
1316         } else {
1317                 $black_clock_target = $pos->{'black_clock_target'} = time + $time_left;
1318         }
1319         local $dbh->{AutoCommit} = 0;
1320         $dbh->do('DELETE FROM clock_info WHERE id=?', undef, $id);
1321         $dbh->do('INSERT INTO clock_info (id, white_clock, black_clock, white_clock_target, black_clock_target) VALUES (?, ?, ?, ?, ?)', undef,
1322                 $id, $pos->{'white_clock'}, $pos->{'black_clock'}, $white_clock_target, $black_clock_target);
1323         $dbh->commit;
1324 }
1325
1326 sub schedule_tb_lookup {
1327         return if (!defined($remoteglotconf::tb_serial_key));
1328         my $pos = $pos_waiting // $pos_calculating;
1329         return if (exists($tb_cache{$pos->fen()}));
1330
1331         # If there's more than seven pieces, there's not going to be an answer,
1332         # so don't bother.
1333         return if ($pos->num_pieces() > 7);
1334
1335         # Max one at a time. If it's still relevant when it returns,
1336         # schedule_tb_lookup() will be called again.
1337         return if ($tb_lookup_running);
1338
1339         $tb_lookup_running = 1;
1340         my $url = 'http://158.250.18.203:6904/tasks/addtask?auth.login=' .
1341                 $remoteglotconf::tb_serial_key .
1342                 '&auth.password=aquarium&type=0&fen=' . 
1343                 URI::Escape::uri_escape($pos->fen());
1344         print TBLOG "Downloading $url...\n";
1345         AnyEvent::HTTP::http_get($url, sub {
1346                 handle_tb_lookup_return(@_, $pos, $pos->fen());
1347         });
1348 }
1349
1350 sub handle_tb_lookup_return {
1351         my ($body, $header, $pos, $fen) = @_;
1352         print TBLOG "Response for [$fen]:\n";
1353         print TBLOG $header . "\n\n";
1354         print TBLOG $body . "\n\n";
1355         eval {
1356                 my $response = JSON::XS::decode_json($body);
1357                 if ($response->{'ErrorCode'} != 0) {
1358                         die "Unknown tablebase server error: " . $response->{'ErrorDesc'};
1359                 }
1360                 my $state = $response->{'Response'}{'StateString'};
1361                 if ($state eq 'COMPLETE') {
1362                         my $pgn = Chess::PGN::Parse->new(undef, $response->{'Response'}{'Moves'});
1363                         if (!defined($pgn) || !$pgn->read_game()) {
1364                                 warn "Error in parsing PGN\n";
1365                         } else {
1366                                 $pgn->quick_parse_game;
1367                                 my $pvpos = $pos;
1368                                 my $moves = $pgn->moves;
1369                                 my @uci_moves = ();
1370                                 for my $move (@$moves) {
1371                                         my $uci_move;
1372                                         ($pvpos, $uci_move) = $pvpos->make_pretty_move($move);
1373                                         push @uci_moves, $uci_move;
1374                                 }
1375                                 $tb_cache{$fen} = {
1376                                         result => $pgn->result,
1377                                         pv => \@uci_moves,
1378                                         score => $response->{'Response'}{'Score'},
1379                                 };
1380                                 output();
1381                         }
1382                 } elsif ($state =~ /QUEUED/ || $state =~ /PROCESSING/) {
1383                         # Try again in a second. Note that if we have changed
1384                         # position in the meantime, we might query a completely
1385                         # different position! But that's fine.
1386                 } else {
1387                         die "Unknown response state " . $state;
1388                 }
1389
1390                 # Wait a second before we schedule another one.
1391                 $tb_retry_timer = AnyEvent->timer(after => 1.0, cb => sub {
1392                         $tb_lookup_running = 0;
1393                         schedule_tb_lookup();
1394                 });
1395         };
1396         if ($@) {
1397                 warn "Error in tablebase lookup: $@";
1398
1399                 # Don't try this one again, but don't block new lookups either.
1400                 $tb_lookup_running = 0;
1401         }
1402 }
1403
1404 sub open_engine {
1405         my ($cmdline, $tag, $cb) = @_;
1406         return undef if (!defined($cmdline));
1407         return Engine->open($cmdline, $tag, $cb);
1408 }
1409
1410 sub col_letter_to_num {
1411         return ord(shift) - ord('a');
1412 }
1413
1414 sub row_letter_to_num {
1415         return 7 - (ord(shift) - ord('1'));
1416 }
1417
1418 sub parse_uci_move {
1419         my $move = shift;
1420         my $from_col = col_letter_to_num(substr($move, 0, 1));
1421         my $from_row = row_letter_to_num(substr($move, 1, 1));
1422         my $to_col   = col_letter_to_num(substr($move, 2, 1));
1423         my $to_row   = row_letter_to_num(substr($move, 3, 1));
1424         my $promo    = substr($move, 4, 1);
1425         return ($from_row, $from_col, $to_row, $to_col, $promo);
1426 }