git.sesse.net Git - remoteglot/blob - remoteglot.pl

   1 #! /usr/bin/perl
   2
   3 #
   4 # remoteglot - Connects an abitrary UCI-speaking engine to ICS for easier post-game
   5 #              analysis, or for live analysis of relayed games. (Do not use for
   6 #              cheating! Cheating is bad for your karma, and your abuser flag.)
   7 #
   8 # Copyright 2007 Steinar H. Gunderson <steinar+remoteglot@gunderson.no>
   9 # Licensed under the GNU General Public License, version 2.
  10 #
  11
  12 use AnyEvent;
  13 use AnyEvent::Handle;
  14 use AnyEvent::HTTP;
  15 use Chess::PGN::Parse;
  16 use EV;
  17 use Net::Telnet;
  18 use File::Slurp;
  19 use IPC::Open2;
  20 use Time::HiRes;
  21 use JSON::XS;
  22 use URI::Escape;
  23 use DBI;
  24 use DBD::Pg;
  25 require 'Position.pm';
  26 require 'Engine.pm';
  27 require 'config.pm';
  28 use strict;
  29 use warnings;
  30 no warnings qw(once);
  31
  32 # Program starts here
  33 my $latest_update = undef;
  34 my $output_timer = undef;
  35 my $http_timer = undef;
  36 my $stop_pgn_fetch = 0;
  37 my $tb_retry_timer = undef;
  38 my %tb_cache = ();
  39 my $tb_lookup_running = 0;
  40 my $last_written_json = undef;
  41
  42 # Persisted so we can restart.
  43 # TODO: Figure out an appropriate way to deal with database restarts
  44 # and/or Postgres going away entirely.
  45 my $dbh = DBI->connect($remoteglotconf::dbistr, $remoteglotconf::dbiuser, $remoteglotconf::dbipass)
  46         or die DBI->errstr;
  47 $dbh->{RaiseError} = 1;
  48
  49 $| = 1;
  50
  51 open(FICSLOG, ">ficslog.txt")
  52         or die "ficslog.txt: $!";
  53 print FICSLOG "Log starting.\n";
  54 select(FICSLOG);
  55 $| = 1;
  56
  57 open(UCILOG, ">ucilog.txt")
  58         or die "ucilog.txt: $!";
  59 print UCILOG "Log starting.\n";
  60 select(UCILOG);
  61 $| = 1;
  62
  63 open(TBLOG, ">tblog.txt")
  64         or die "tblog.txt: $!";
  65 print TBLOG "Log starting.\n";
  66 select(TBLOG);
  67 $| = 1;
  68
  69 select(STDOUT);
  70 umask 0022;  # analysis.json should not be served to users.
  71
  72 # open the chess engine
  73 my $engine = open_engine($remoteglotconf::engine_cmdline, 'E1', sub { handle_uci(@_, 1); });
  74 my $engine2 = open_engine($remoteglotconf::engine2_cmdline, 'E2', sub { handle_uci(@_, 0); });
  75 my $last_move;
  76 my $last_text = '';
  77 my ($pos_calculating, $pos_calculating_second_engine);
  78
  79 # If not undef, we've started calculating this position but haven't ever given out
  80 # any analysis for it, so we're on a forced timer to do so.
  81 my $pos_calculating_started = undef;
  82
  83 # If not undef, we've output this position, but without a main PV, so we're on
  84 # _another_ forced timer to do so.
  85 my $pos_pv_started = undef;
  86 my $last_output_had_pv = 0;
  87
  88 setoptions($engine, \%remoteglotconf::engine_config);
  89 uciprint($engine, "ucinewgame");
  90
  91 if (defined($engine2)) {
  92         setoptions($engine2, \%remoteglotconf::engine2_config);
  93         uciprint($engine2, "setoption name MultiPV value 500");
  94         uciprint($engine2, "ucinewgame");
  95 }
  96
  97 print "Chess engine ready.\n";
  98
  99 # now talk to FICS
 100 my ($t, $ev1);
 101 if (defined($remoteglotconf::server)) {
 102         $t = Net::Telnet->new(Timeout => 10, Prompt => '/fics% /');
 103         $t->input_log(\*FICSLOG);
 104         $t->open($remoteglotconf::server);
 105         $t->print($remoteglotconf::nick);
 106         $t->waitfor('/Press return to enter the server/');
 107         $t->cmd("");
 108
 109         # set some options
 110         $t->cmd("set shout 0");
 111         $t->cmd("set seek 0");
 112         $t->cmd("set style 12");
 113
 114         $ev1 = AnyEvent->io(
 115                 fh => fileno($t),
 116                 poll => 'r',
 117                 cb => sub {    # what callback to execute
 118                         while (1) {
 119                                 my $line = $t->getline(Timeout => 0, errmode => 'return');
 120                                 return if (!defined($line));
 121
 122                                 chomp $line;
 123                                 $line =~ tr/\r//d;
 124                                 handle_fics($line);
 125                         }
 126                 }
 127         );
 128 }
 129 if (defined($remoteglotconf::target)) {
 130         if ($remoteglotconf::target =~ /^(?:\/|https?:)/) {
 131                 fetch_pgn($remoteglotconf::target);
 132         } elsif (defined($t)) {
 133                 $t->cmd("observe $remoteglotconf::target");
 134         }
 135 }
 136 if (defined($t)) {
 137         print "FICS ready.\n";
 138 }
 139
 140 # Engine events have already been set up by Engine.pm.
 141 EV::run;
 142
 143 sub handle_uci {
 144         my ($engine, $line, $primary) = @_;
 145
 146         return if $line =~ /(upper|lower)bound/;
 147
 148         $line =~ s/  / /g;  # Sometimes needed for Zappa Mexico
 149         print UCILOG localtime() . " $engine->{'tag'} <= $line\n";
 150
 151         # If we've sent a stop command, gobble up lines until we see bestmove.
 152         return if ($engine->{'stopping'} && $line !~ /^bestmove/);
 153         $engine->{'stopping'} = 0;
 154
 155         if ($line =~ /^info/) {
 156                 my (@infos) = split / /, $line;
 157                 shift @infos;
 158
 159                 parse_infos($engine, @infos);
 160         }
 161         if ($line =~ /^id/) {
 162                 my (@ids) = split / /, $line;
 163                 shift @ids;
 164
 165                 parse_ids($engine, @ids);
 166         }
 167         output();
 168 }
 169
 170 my $getting_movelist = 0;
 171 my $pos_for_movelist = undef;
 172 my @uci_movelist = ();
 173 my @pretty_movelist = ();
 174
 175 sub handle_fics {
 176         my $line = shift;
 177         if ($line =~ /^<12> /) {
 178                 handle_position(Position->new($line));
 179                 $t->cmd("moves");
 180         }
 181         if ($line =~ /^Movelist for game /) {
 182                 my $pos = $pos_calculating;
 183                 if (defined($pos)) {
 184                         @uci_movelist = ();
 185                         @pretty_movelist = ();
 186                         $pos_for_movelist = Position->start_pos($pos->{'player_w'}, $pos->{'player_b'});
 187                         $getting_movelist = 1;
 188                 }
 189         }
 190         if ($getting_movelist &&
 191             $line =~ /^\s* \d+\. \s+                     # move number
 192                        (\S+) \s+ \( [\d:.]+ \) \s*       # first move, then time
 193                        (?: (\S+) \s+ \( [\d:.]+ \) )?    # second move, then time
 194                      /x) {
 195                 eval {
 196                         my $uci_move;
 197                         ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($1);
 198                         push @uci_movelist, $uci_move;
 199                         push @pretty_movelist, $1;
 200
 201                         if (defined($2)) {
 202                                 ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($2);
 203                                 push @uci_movelist, $uci_move;
 204                                 push @pretty_movelist, $2;
 205                         }
 206                 };
 207                 if ($@) {
 208                         warn "Error when getting FICS move history: $@";
 209                         $getting_movelist = 0;
 210                 }
 211         }
 212         if ($getting_movelist &&
 213             $line =~ /^\s+ \{.*\} \s+ (?: \* | 1\/2-1\/2 | 0-1 | 1-0 )/x) {
 214                 # End of movelist.
 215                 if (defined($pos_calculating)) {
 216                         if ($pos_calculating->fen() eq $pos_for_movelist->fen()) {
 217                                 $pos_calculating->{'history'} = \@pretty_movelist;
 218                         }
 219                 }
 220                 $getting_movelist = 0;
 221         }
 222         if ($line =~ /^([A-Za-z]+)(?:\([A-Z]+\))* tells you: (.*)$/) {
 223                 my ($who, $msg) = ($1, $2);
 224
 225                 next if (grep { $_ eq $who } (@remoteglotconf::masters) == 0);
 226
 227                 if ($msg =~ /^fics (.*?)$/) {
 228                         $t->cmd("tell $who Executing '$1' on FICS.");
 229                         $t->cmd($1);
 230                 } elsif ($msg =~ /^uci (.*?)$/) {
 231                         $t->cmd("tell $who Sending '$1' to the engine.");
 232                         print { $engine->{'write'} } "$1\n";
 233                 } elsif ($msg =~ /^pgn (.*?)$/) {
 234                         my $url = $1;
 235                         $t->cmd("tell $who Starting to poll '$url'.");
 236                         fetch_pgn($url);
 237                 } elsif ($msg =~ /^stoppgn$/) {
 238                         $t->cmd("tell $who Stopping poll.");
 239                         $stop_pgn_fetch = 1;
 240                         $http_timer = undef;
 241                 } elsif ($msg =~ /^quit$/) {
 242                         $t->cmd("tell $who Bye bye.");
 243                         exit;
 244                 } else {
 245                         $t->cmd("tell $who Couldn't understand '$msg', sorry.");
 246                 }
 247         }
 248         #print "FICS: [$line]\n";
 249 }
 250
 251 # Starts periodic fetching of PGNs from the given URL.
 252 sub fetch_pgn {
 253         my ($url) = @_;
 254         if ($url =~ m#^/#) {  # Local file.
 255                 eval {
 256                         local $/ = undef;
 257                         open my $fh, "<", $url
 258                                 or die "$url: $!";
 259                         my $pgn = <$fh>;
 260                         close $fh;
 261                         handle_pgn($pgn, '', $url);
 262                 };
 263                 if ($@) {
 264                         warn "$url: $@";
 265                         $http_timer = AnyEvent->timer(after => 1.0, cb => sub {
 266                                 fetch_pgn($url);
 267                         });
 268                 }
 269         } else {
 270                 AnyEvent::HTTP::http_get($url, sub {
 271                         handle_pgn(@_, $url);
 272                 });
 273         }
 274 }
 275
 276 my ($last_pgn_white, $last_pgn_black);
 277 my @last_pgn_uci_moves = ();
 278 my $pgn_hysteresis_counter = 0;
 279
 280 sub handle_pgn {
 281         my ($body, $header, $url) = @_;
 282
 283         if ($stop_pgn_fetch) {
 284                 $stop_pgn_fetch = 0;
 285                 $http_timer = undef;
 286                 return;
 287         }
 288
 289         my $pgn = Chess::PGN::Parse->new(undef, $body);
 290         if (!defined($pgn)) {
 291                 warn "Error in parsing PGN from $url [body='$body']\n";
 292         } elsif (!$pgn->read_game()) {
 293                 warn "Error in reading PGN game from $url [body='$body']\n";
 294         } elsif ($body !~ /^\[/) {
 295                 warn "Malformed PGN from $url [body='$body']\n";
 296         } else {
 297                 eval {
 298                         # Skip to the right game.
 299                         while (defined($remoteglotconf::pgn_filter) &&
 300                                !&$remoteglotconf::pgn_filter($pgn)) {
 301                                 $pgn->read_game() or die "Out of games during filtering";
 302                         }
 303
 304                         $pgn->parse_game({ save_comments => 'yes' });
 305                         my $white = $pgn->white;
 306                         my $black = $pgn->black;
 307                         $white =~ s/,.*//;  # Remove first name.
 308                         $black =~ s/,.*//;  # Remove first name.
 309                         my $tags = $pgn->tags();
 310                         my $pos;
 311                         if (exists($tags->{'FEN'})) {
 312                                 $pos = Position->from_fen($tags->{'FEN'});
 313                                 $pos->{'last_move'} = 'none';
 314                                 $pos->{'player_w'} = $white;
 315                                 $pos->{'player_b'} = $black;
 316                                 $pos->{'start_fen'} = $tags->{'FEN'};
 317                         } else {
 318                                 $pos = Position->start_pos($white, $black);
 319                         }
 320                         if (exists($tags->{'Variant'}) &&
 321                             $tags->{'Variant'} =~ /960|fischer/i) {
 322                                 $pos->{'chess960'} = 1;
 323                         } else {
 324                                 $pos->{'chess960'} = 0;
 325                         }
 326                         my $moves = $pgn->moves;
 327                         my @uci_moves = ();
 328                         my @repretty_moves = ();
 329                         for my $move (@$moves) {
 330                                 my ($npos, $uci_move) = $pos->make_pretty_move($move);
 331                                 push @uci_moves, $uci_move;
 332
 333                                 # Re-prettyprint the move.
 334                                 my ($from_row, $from_col, $to_row, $to_col, $promo) = parse_uci_move($uci_move);
 335                                 my ($pretty, undef) = $pos->{'board'}->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
 336                                 push @repretty_moves, $pretty;
 337                                 $pos = $npos;
 338                         }
 339                         if ($pgn->result eq '1-0' || $pgn->result eq '1/2-1/2' || $pgn->result eq '0-1') {
 340                                 $pos->{'result'} = $pgn->result;
 341                         }
 342                         $pos->{'history'} = \@repretty_moves;
 343
 344                         extract_clock($pgn, $pos);
 345
 346                         # Sometimes, PGNs lose a move or two for a short while,
 347                         # or people push out new ones non-atomically.
 348                         # Thus, if we PGN doesn't change names but becomes
 349                         # shorter, we mistrust it for a few seconds.
 350                         my $trust_pgn = 1;
 351                         if (defined($last_pgn_white) && defined($last_pgn_black) &&
 352                             $last_pgn_white eq $pgn->white &&
 353                             $last_pgn_black eq $pgn->black &&
 354                             scalar(@uci_moves) < scalar(@last_pgn_uci_moves)) {
 355                                 if (++$pgn_hysteresis_counter < 3) {
 356                                         $trust_pgn = 0;
 357                                 }
 358                         }
 359                         if ($trust_pgn) {
 360                                 $last_pgn_white = $pgn->white;
 361                                 $last_pgn_black = $pgn->black;
 362                                 @last_pgn_uci_moves = @uci_moves;
 363                                 $pgn_hysteresis_counter = 0;
 364                                 handle_position($pos);
 365                         }
 366                 };
 367                 if ($@) {
 368                         warn "Error in parsing moves from $url: $@\n";
 369                 }
 370         }
 371
 372         $http_timer = AnyEvent->timer(after => 1.0, cb => sub {
 373                 fetch_pgn($url);
 374         });
 375 }
 376
 377 sub handle_position {
 378         my ($pos) = @_;
 379         find_clock_start($pos, $pos_calculating);
 380
 381         # If we're already chewing on this and there's nothing else in the queue,
 382         # ignore it.
 383         if (defined($pos_calculating) && $pos->fen() eq $pos_calculating->fen()) {
 384                 $pos_calculating->{'result'} = $pos->{'result'};
 385                 for my $key ('white_clock', 'black_clock', 'white_clock_target', 'black_clock_target') {
 386                         $pos_calculating->{$key} //= $pos->{$key};
 387                 }
 388                 return;
 389         }
 390
 391         # If we're already thinking on something, stop and wait for the engine
 392         # to approve.
 393         if (defined($pos_calculating)) {
 394                 # Store the final data we have for this position in the history,
 395                 # with the precise clock information we just got from the new
 396                 # position. (Historic positions store the clock at the end of
 397                 # the position.)
 398                 #
 399                 # Do not output anything new to the main analysis; that's
 400                 # going to be obsolete really soon. (Exception: If we've never
 401                 # output anything for this move, ie., it didn't hit the 200ms
 402                 # limit, spit it out to the user anyway. It's probably a really
 403                 # fast blitz game or something, and it's good to show the moves
 404                 # as they come in even without great analysis.)
 405                 $pos_calculating->{'white_clock'} = $pos->{'white_clock'};
 406                 $pos_calculating->{'black_clock'} = $pos->{'black_clock'};
 407                 delete $pos_calculating->{'white_clock_target'};
 408                 delete $pos_calculating->{'black_clock_target'};
 409
 410                 if (defined($pos_calculating_started)) {
 411                         output_json(0);
 412                 } else {
 413                         output_json(1);
 414                 }
 415                 $pos_calculating_started = [Time::HiRes::gettimeofday];
 416                 $pos_pv_started = undef;
 417
 418                 # Ask the engine to stop; we will throw away its data until it
 419                 # sends us "bestmove", signaling the end of it.
 420                 $engine->{'stopping'} = 1;
 421                 uciprint($engine, "stop");
 422         }
 423
 424         # It's wrong to just give the FEN (the move history is useful,
 425         # and per the UCI spec, we should really have sent "ucinewgame"),
 426         # but it's easier, and it works around a Stockfish repetition issue.
 427         if ($engine->{'chess960'} != $pos->{'chess960'}) {
 428                 uciprint($engine, "setoption name UCI_Chess960 value " . ($pos->{'chess960'} ? 'true' : 'false'));
 429                 $engine->{'chess960'} = $pos->{'chess960'};
 430         }
 431         uciprint($engine, "position fen " . $pos->fen());
 432         uciprint($engine, "go infinite");
 433         $pos_calculating = $pos;
 434         $pos_calculating_started = [Time::HiRes::gettimeofday];
 435         $pos_pv_started = undef;
 436
 437         if (defined($engine2)) {
 438                 if (defined($pos_calculating_second_engine)) {
 439                         $engine2->{'stopping'} = 1;
 440                         uciprint($engine2, "stop");
 441                 }
 442                 if ($engine2->{'chess960'} != $pos->{'chess960'}) {
 443                         uciprint($engine2, "setoption name UCI_Chess960 value " . ($pos->{'chess960'} ? 'true' : 'false'));
 444                         $engine2->{'chess960'} = $pos->{'chess960'};
 445                 }
 446                 uciprint($engine2, "position fen " . $pos->fen());
 447                 uciprint($engine2, "go infinite");
 448                 $pos_calculating_second_engine = $pos;
 449                 $engine2->{'info'} = {};
 450         }
 451
 452         $engine->{'info'} = {};
 453         $last_move = time;
 454
 455         schedule_tb_lookup();
 456
 457         #
 458         # Output a command every move to note that we're
 459         # still paying attention -- this is a good tradeoff,
 460         # since if no move has happened in the last half
 461         # hour, the analysis/relay has most likely stopped
 462         # and we should stop hogging server resources.
 463         #
 464         if (defined($t)) {
 465                 $t->cmd("date");
 466         }
 467 }
 468
 469 sub parse_infos {
 470         my ($engine, @x) = @_;
 471         my $mpv = '';
 472
 473         my $info = $engine->{'info'};
 474
 475         # Search for "multipv" first of all, since e.g. Stockfish doesn't put it first.
 476         for my $i (0..$#x - 1) {
 477                 if ($x[$i] eq 'multipv') {
 478                         $mpv = $x[$i + 1];
 479                         next;
 480                 }
 481         }
 482
 483         my $prev_depth = $info->{'depth1'} // $info->{'depth'};
 484
 485         while (scalar @x > 0) {
 486                 if ($x[0] eq 'multipv') {
 487                         # Dealt with above
 488                         shift @x;
 489                         shift @x;
 490                         next;
 491                 }
 492                 if ($x[0] eq 'currmove' || $x[0] eq 'currmovenumber' || $x[0] eq 'cpuload') {
 493                         my $key = shift @x;
 494                         my $value = shift @x;
 495                         $info->{$key} = $value;
 496                         next;
 497                 }
 498                 if ($x[0] eq 'depth' || $x[0] eq 'seldepth' || $x[0] eq 'hashfull' ||
 499                     $x[0] eq 'time' || $x[0] eq 'nodes' || $x[0] eq 'nps' ||
 500                     $x[0] eq 'tbhits') {
 501                         my $key = shift @x;
 502                         my $value = shift @x;
 503                         $info->{$key . $mpv} = $value;
 504                         next;
 505                 }
 506                 if ($x[0] eq 'score') {
 507                         shift @x;
 508
 509                         delete $info->{'score_cp' . $mpv};
 510                         delete $info->{'score_mate' . $mpv};
 511                         delete $info->{'splicepos' . $mpv};
 512
 513                         while ($x[0] eq 'cp' || $x[0] eq 'mate') {
 514                                 if ($x[0] eq 'cp') {
 515                                         shift @x;
 516                                         $info->{'score_cp' . $mpv} = shift @x;
 517                                 } elsif ($x[0] eq 'mate') {
 518                                         shift @x;
 519                                         $info->{'score_mate' . $mpv} = shift @x;
 520                                 } else {
 521                                         shift @x;
 522                                 }
 523                         }
 524                         next;
 525                 }
 526                 if ($x[0] eq 'pv') {
 527                         $info->{'pv' . $mpv} = [ @x[1..$#x] ];
 528                         last;
 529                 }
 530                 if ($x[0] eq 'string' || $x[0] eq 'UCI_AnalyseMode' || $x[0] eq 'setting' || $x[0] eq 'contempt') {
 531                         last;
 532                 }
 533
 534                 #print "unknown info '$x[0]', trying to recover...\n";
 535                 #shift @x;
 536                 die "Unknown info '" . join(',', @x) . "'";
 537
 538         }
 539
 540         my $now_depth = $info->{'depth1'} // $info->{'depth'};
 541         if (defined($prev_depth) && POSIX::floor($now_depth / 10) > POSIX::floor($prev_depth / 10)) {
 542                 my $d = POSIX::floor($now_depth / 10) * 10;  # In case we skipped some.
 543                 complete_using_tbprobe($pos_calculating, $info, exists($info->{'depth1'}) ? '1' : '');
 544                 my $cp = $info->{'score_cp1'} // $info->{'score_cp'};
 545                 my $mate = $info->{'score_mate1'} // $info->{'score_mate'};
 546                 my $splicepos = $info->{'splicepos1'} // $info->{'splicepos'};
 547                 push @{$info->{'lowdepth'}}, [ $d, $cp, $mate, $splicepos ];
 548         }
 549 }
 550
 551 sub parse_ids {
 552         my ($engine, @x) = @_;
 553
 554         while (scalar @x > 0) {
 555                 if ($x[0] eq 'name') {
 556                         my $value = join(' ', @x);
 557                         $engine->{'id'}{'author'} = $value;
 558                         last;
 559                 }
 560
 561                 # unknown
 562                 shift @x;
 563         }
 564 }
 565
 566 sub prettyprint_pv_no_cache {
 567         my ($board, @pvs) = @_;
 568
 569         if (scalar @pvs == 0 || !defined($pvs[0])) {
 570                 return ();
 571         }
 572
 573         my @ret = ();
 574         for my $pv (@pvs) {
 575                 my ($from_row, $from_col, $to_row, $to_col, $promo) = parse_uci_move($pv);
 576                 my ($pretty, $nb) = $board->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
 577                 push @ret, $pretty;
 578                 $board = $nb;
 579         }
 580         return @ret;
 581 }
 582
 583 sub prettyprint_pv {
 584         my ($pos, @pvs) = @_;
 585
 586         my $cachekey = join('', @pvs);
 587         if (exists($pos->{'prettyprint_cache'}{$cachekey})) {
 588                 return @{$pos->{'prettyprint_cache'}{$cachekey}};
 589         } else {
 590                 my @res = prettyprint_pv_no_cache($pos->{'board'}, @pvs);
 591                 $pos->{'prettyprint_cache'}{$cachekey} = \@res;
 592                 return @res;
 593         }
 594 }
 595
 596 my %tbprobe_cache = ();
 597
 598 sub complete_using_tbprobe {
 599         my ($pos, $info, $mpv) = @_;
 600
 601         # We need Fathom installed to do standalone TB probes.
 602         return if (!defined($remoteglotconf::fathom_cmdline));
 603
 604         # If we already have a mate, don't bother; in some cases, it would even be
 605         # better than a tablebase score.
 606         return if defined($info->{'score_mate' . $mpv});
 607
 608         # If we have a draw or near-draw score, there's also not much interesting
 609         # we could add from a tablebase. We only really want mates.
 610         return if ($info->{'score_cp' . $mpv} >= -12250 && $info->{'score_cp' . $mpv} <= 12250);
 611
 612         # Run through the PV until we are at a 6-man position.
 613         # TODO: We could in theory only have 5-man data.
 614         my @pv = @{$info->{'pv' . $mpv}};
 615         my $key = $pos->fen() . " " . join('', @pv);
 616         my @moves = ();
 617         my $splicepos;
 618         if (exists($tbprobe_cache{$key})) {
 619                 my $c = $tbprobe_cache{$key};
 620                 @moves = @{$c->{'moves'}};
 621                 $splicepos = $c->{'splicepos'};
 622         } else {
 623                 if ($mpv ne '') {
 624                         # Force doing at least one move of the PV.
 625                         my $move = shift @pv;
 626                         push @moves, $move;
 627                         $pos = $pos->make_move(parse_uci_move($move));
 628                 }
 629
 630                 while ($pos->num_pieces() > 7 && $#pv > -1) {
 631                         my $move = shift @pv;
 632                         push @moves, $move;
 633                         $pos = $pos->make_move(parse_uci_move($move));
 634                 }
 635
 636                 return if ($pos->num_pieces() > 7);
 637
 638                 my $fen = $pos->fen();
 639                 my $pgn_text = `$remoteglotconf::fathom_cmdline "$fen"`;
 640                 my $pgn = Chess::PGN::Parse->new(undef, $pgn_text);
 641                 return if (!defined($pgn) || !$pgn->read_game() || ($pgn->result ne '0-1' && $pgn->result ne '1-0'));
 642                 $pgn->quick_parse_game;
 643
 644                 # Splice the PV from the tablebase onto what we have so far.
 645                 $splicepos = scalar @moves;
 646                 for my $move (@{$pgn->moves}) {
 647                         last if $move eq '#';
 648                         last if $move eq '1-0';
 649                         last if $move eq '0-1';
 650                         last if $move eq '1/2-1/2';
 651                         my $uci_move;
 652                         ($pos, $uci_move) = $pos->make_pretty_move($move);
 653                         push @moves, $uci_move;
 654                 }
 655
 656                 $tbprobe_cache{$key} = {
 657                         moves => \@moves,
 658                         splicepos => $splicepos
 659                 };
 660         }
 661
 662         $info->{'pv' . $mpv} = \@moves;
 663
 664         my $matelen = int((1 + scalar @moves) / 2);
 665         if ((scalar @moves) % 2 == 0) {
 666                 $info->{'score_mate' . $mpv} = -$matelen;
 667         } else {
 668                 $info->{'score_mate' . $mpv} = $matelen;
 669         }
 670         $info->{'splicepos' . $mpv} = $splicepos;
 671 }
 672
 673 sub output {
 674         #return;
 675
 676         return if (!defined($pos_calculating));
 677
 678         my $info = $engine->{'info'};
 679
 680         # Don't update too often.
 681         my $wait = $remoteglotconf::update_max_interval - Time::HiRes::tv_interval($latest_update);
 682         if (defined($pos_calculating_started)) {
 683                 my $new_pos_wait = $remoteglotconf::update_force_after_move - Time::HiRes::tv_interval($pos_calculating_started);
 684                 $wait = $new_pos_wait if ($new_pos_wait < $wait);
 685         }
 686         if (!$last_output_had_pv && has_pv($info)) {
 687                 if (!defined($pos_pv_started)) {
 688                         $pos_pv_started = [Time::HiRes::gettimeofday];
 689                 }
 690                 # We just got initial PV, and we're in a hurry since we gave out a blank one earlier,
 691                 # so give us just 200ms more to increase the quality and then force a display.
 692                 my $new_pos_wait = $remoteglotconf::update_force_after_move - Time::HiRes::tv_interval($pos_pv_started);
 693                 $wait = $new_pos_wait if ($new_pos_wait < $wait);
 694         }
 695         if ($wait > 0.0) {
 696                 $output_timer = AnyEvent->timer(after => $wait + 0.01, cb => \&output);
 697                 return;
 698         }
 699         $pos_pv_started = undef;
 700
 701         # We're outputting something for this position now, so the special handling
 702         # for new positions is off.
 703         undef $pos_calculating_started;
 704
 705         #
 706         # If we have tablebase data from a previous lookup, replace the
 707         # engine data with the data from the tablebase.
 708         #
 709         my $fen = $pos_calculating->fen();
 710         if (exists($tb_cache{$fen})) {
 711                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits splicepos)) {
 712                         delete $info->{$key . '1'};
 713                         delete $info->{$key};
 714                 }
 715                 $info->{'nodes'} = 0;
 716                 $info->{'nps'} = 0;
 717                 $info->{'depth'} = 0;
 718                 $info->{'seldepth'} = 0;
 719                 $info->{'tbhits'} = 0;
 720
 721                 my $t = $tb_cache{$fen};
 722                 my $pv = $t->{'pv'};
 723                 my $matelen = int((1 + $t->{'score'}) / 2);
 724                 if ($t->{'result'} eq '1/2-1/2') {
 725                         $info->{'score_cp'} = 0;
 726                 } elsif ($t->{'result'} eq '1-0') {
 727                         if ($pos_calculating->{'toplay'} eq 'B') {
 728                                 $info->{'score_mate'} = -$matelen;
 729                         } else {
 730                                 $info->{'score_mate'} = $matelen;
 731                         }
 732                 } else {
 733                         if ($pos_calculating->{'toplay'} eq 'B') {
 734                                 $info->{'score_mate'} = $matelen;
 735                         } else {
 736                                 $info->{'score_mate'} = -$matelen;
 737                         }
 738                 }
 739                 $info->{'pv'} = $pv;
 740                 $info->{'tablebase'} = 1;
 741         } else {
 742                 $info->{'tablebase'} = 0;
 743         }
 744
 745         #
 746         # Some programs _always_ report MultiPV, even with only one PV.
 747         # In this case, we simply use that data as if MultiPV was never
 748         # specified.
 749         #
 750         if (exists($info->{'pv1'}) && !exists($info->{'pv2'})) {
 751                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits splicepos)) {
 752                         if (exists($info->{$key . '1'})) {
 753                                 $info->{$key} = $info->{$key . '1'};
 754                         } else {
 755                                 delete $info->{$key};
 756                         }
 757                 }
 758         }
 759
 760         #
 761         # Check the PVs first. if they're invalid, just wait, as our data
 762         # is most likely out of sync. This isn't a very good solution, as
 763         # it can frequently miss stuff, but it's good enough for most users.
 764         #
 765         eval {
 766                 my $dummy;
 767                 if (exists($info->{'pv'})) {
 768                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv'}});
 769                 }
 770
 771                 my $mpv = 1;
 772                 while (exists($info->{'pv' . $mpv})) {
 773                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}});
 774                         ++$mpv;
 775                 }
 776         };
 777         if ($@) {
 778                 $engine->{'info'} = {};
 779                 return;
 780         }
 781
 782         # Now do our own Syzygy tablebase probes to convert scores like +123.45 to mate.
 783         if (exists($info->{'pv'})) {
 784                 complete_using_tbprobe($pos_calculating, $info, '');
 785         }
 786
 787         my $mpv = 1;
 788         while (exists($info->{'pv' . $mpv})) {
 789                 complete_using_tbprobe($pos_calculating, $info, $mpv);
 790                 ++$mpv;
 791         }
 792
 793         output_screen();
 794         output_json(0);
 795         $latest_update = [Time::HiRes::gettimeofday];
 796         $last_output_had_pv = has_pv($info);
 797 }
 798
 799 sub has_pv {
 800         my $info = shift;
 801         return 1 if (exists($info->{'pv'}) && (scalar(@{$info->{'pv'}}) > 0));
 802         return 1 if (exists($info->{'pv1'}) && (scalar(@{$info->{'pv1'}}) > 0));
 803         return 0;
 804 }
 805
 806 sub output_screen {
 807         my $info = $engine->{'info'};
 808         my $id = $engine->{'id'};
 809
 810         my $text = 'Analysis';
 811         if ($pos_calculating->{'last_move'} ne 'none') {
 812                 if ($pos_calculating->{'toplay'} eq 'W') {
 813                         $text .= sprintf ' after %u. ... %s', ($pos_calculating->{'move_num'}-1), $pos_calculating->{'last_move'};
 814                 } else {
 815                         $text .= sprintf ' after %u. %s', $pos_calculating->{'move_num'}, $pos_calculating->{'last_move'};
 816                 }
 817                 if (exists($id->{'name'})) {
 818                         $text .= ',';
 819                 }
 820         }
 821
 822         if (exists($id->{'name'})) {
 823                 $text .= " by $id->{'name'}:\n\n";
 824         } else {
 825                 $text .= ":\n\n";
 826         }
 827
 828         return unless (exists($pos_calculating->{'board'}));
 829
 830         if (exists($info->{'pv1'}) && exists($info->{'pv2'})) {
 831                 # multi-PV
 832                 my $mpv = 1;
 833                 while (exists($info->{'pv' . $mpv})) {
 834                         $text .= sprintf "  PV%2u", $mpv;
 835                         my $score = short_score($info, $pos_calculating, $mpv);
 836                         $text .= "  ($score)" if (defined($score));
 837
 838                         my $tbhits = '';
 839                         if (exists($info->{'tbhits' . $mpv}) && $info->{'tbhits' . $mpv} > 0) {
 840                                 if ($info->{'tbhits' . $mpv} == 1) {
 841                                         $tbhits = ", 1 tbhit";
 842                                 } else {
 843                                         $tbhits = sprintf ", %u tbhits", $info->{'tbhits' . $mpv};
 844                                 }
 845                         }
 846
 847                         if (exists($info->{'nodes' . $mpv}) && exists($info->{'nps' . $mpv}) && exists($info->{'depth' . $mpv})) {
 848                                 $text .= sprintf " (%5u kn, %3u kn/s, %2u ply$tbhits)",
 849                                         $info->{'nodes' . $mpv} / 1000, $info->{'nps' . $mpv} / 1000, $info->{'depth' . $mpv};
 850                         }
 851
 852                         $text .= ":\n";
 853                         $text .= "  " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}})) . "\n";
 854                         $text .= "\n";
 855                         ++$mpv;
 856                 }
 857         } else {
 858                 # single-PV
 859                 my $score = long_score($info, $pos_calculating, '');
 860                 $text .= "  $score\n" if defined($score);
 861                 $text .=  "  PV: " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv'}}));
 862                 $text .=  "\n";
 863
 864                 if (exists($info->{'nodes'}) && exists($info->{'nps'}) && exists($info->{'depth'})) {
 865                         $text .= sprintf "  %u nodes, %7u nodes/sec, depth %u ply",
 866                                 $info->{'nodes'}, $info->{'nps'}, $info->{'depth'};
 867                 }
 868                 if (exists($info->{'seldepth'})) {
 869                         $text .= sprintf " (%u selective)", $info->{'seldepth'};
 870                 }
 871                 if (exists($info->{'tbhits'}) && $info->{'tbhits'} > 0) {
 872                         if ($info->{'tbhits'} == 1) {
 873                                 $text .= ", one Syzygy hit";
 874                         } else {
 875                                 $text .= sprintf ", %u Syzygy hits", $info->{'tbhits'};
 876                         }
 877                 }
 878                 $text .= "\n\n";
 879         }
 880
 881         my @refutation_lines = ();
 882         if (defined($engine2)) {
 883                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
 884                         my $info = $engine2->{'info'};
 885                         last if (!exists($info->{'pv' . $mpv}));
 886                         eval {
 887                                 complete_using_tbprobe($pos_calculating_second_engine, $info, $mpv);
 888                                 my $pv = $info->{'pv' . $mpv};
 889                                 my $pretty_move = join('', prettyprint_pv($pos_calculating_second_engine, $pv->[0]));
 890                                 my @pretty_pv = prettyprint_pv($pos_calculating_second_engine, @$pv);
 891                                 if (scalar @pretty_pv > 5) {
 892                                         @pretty_pv = @pretty_pv[0..4];
 893                                         push @pretty_pv, "...";
 894                                 }
 895                                 my $key = $pretty_move;
 896                                 my $line = sprintf("  %-6s %6s %3s  %s",
 897                                         $pretty_move,
 898                                         short_score($info, $pos_calculating_second_engine, $mpv),
 899                                         "d" . $info->{'depth' . $mpv},
 900                                         join(', ', @pretty_pv));
 901                                 push @refutation_lines, [ $key, $line ];
 902                         };
 903                 }
 904         }
 905
 906         if ($#refutation_lines >= 0) {
 907                 $text .= "Shallow search of all legal moves:\n\n";
 908                 for my $line (sort { $a->[0] cmp $b->[0] } @refutation_lines) {
 909                         $text .= $line->[1] . "\n";
 910                 }
 911                 $text .= "\n\n";
 912         }
 913
 914         if ($last_text ne $text) {
 915                 print "\e[H\e[2J"; # clear the screen
 916                 print $text;
 917                 $last_text = $text;
 918         }
 919 }
 920
 921 sub output_json {
 922         my $historic_json_only = shift;
 923         my $info = $engine->{'info'};
 924
 925         my $json = {};
 926         $json->{'position'} = $pos_calculating->to_json_hash();
 927         $json->{'engine'} = $engine->{'id'};
 928         if (defined($remoteglotconf::engine_url)) {
 929                 $json->{'engine'}{'url'} = $remoteglotconf::engine_url;
 930         }
 931         if (defined($remoteglotconf::engine_details)) {
 932                 $json->{'engine'}{'details'} = $remoteglotconf::engine_details;
 933         }
 934         my @grpc_backends = ();
 935         if (defined($remoteglotconf::engine_grpc_backend)) {
 936                 push @grpc_backends, $remoteglotconf::engine_grpc_backend;
 937         }
 938         if (defined($remoteglotconf::engine2_grpc_backend)) {
 939                 push @grpc_backends, $remoteglotconf::engine2_grpc_backend;
 940         }
 941         $json->{'internal'}{'grpc_backends'} = \@grpc_backends;
 942         if (defined($remoteglotconf::move_source)) {
 943                 $json->{'move_source'} = $remoteglotconf::move_source;
 944         }
 945         if (defined($remoteglotconf::move_source_url)) {
 946                 $json->{'move_source_url'} = $remoteglotconf::move_source_url;
 947         }
 948         $json->{'score'} = score_digest($info, $pos_calculating, '');
 949         $json->{'using_lomonosov'} = defined($remoteglotconf::tb_serial_key);
 950
 951         $json->{'nodes'} = $info->{'nodes'};
 952         $json->{'nps'} = $info->{'nps'};
 953         $json->{'depth'} = $info->{'depth'};
 954         $json->{'tbhits'} = $info->{'tbhits'};
 955         $json->{'seldepth'} = $info->{'seldepth'};
 956         $json->{'tablebase'} = $info->{'tablebase'};
 957         $json->{'pv'} = [ prettyprint_pv($pos_calculating, @{$info->{'pv'}}) ];
 958
 959         $json->{'lowdepth'} = {};
 960         if (exists($info->{'lowdepth'})) {
 961                 for my $ld (@{$info->{'lowdepth'}}) {
 962                         $json->{'lowdepth'}{$ld->[0]} = score_digest_inner($ld->[1], $ld->[2], $ld->[3], 0, $pos_calculating);
 963                 }
 964         }
 965
 966         my %refutation_lines = ();
 967         my @refutation_lines = ();
 968         if (defined($engine2)) {
 969                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
 970                         my $info = $engine2->{'info'};
 971                         my $pretty_move = "";
 972                         my @pretty_pv = ();
 973                         last if (!exists($info->{'pv' . $mpv}));
 974
 975                         eval {
 976                                 complete_using_tbprobe($pos_calculating, $info, $mpv);
 977                                 my $pv = $info->{'pv' . $mpv};
 978                                 my $pretty_move = join('', prettyprint_pv($pos_calculating, $pv->[0]));
 979                                 my @pretty_pv = prettyprint_pv($pos_calculating, @$pv);
 980                                 $refutation_lines{$pretty_move} = {
 981                                         depth => $info->{'depth' . $mpv},
 982                                         score => score_digest($info, $pos_calculating, $mpv),
 983                                         move => $pretty_move,
 984                                         pv => \@pretty_pv,
 985                                 };
 986                                 if (exists($info->{'splicepos' . $mpv})) {
 987                                         $refutation_lines{$pretty_move}->{'splicepos'} = $info->{'splicepos' . $mpv};
 988                                 }
 989                         };
 990                 }
 991         }
 992         $json->{'refutation_lines'} = \%refutation_lines;
 993
 994         # Piece together historic score information, to the degree we have it.
 995         if (!$historic_json_only && exists($pos_calculating->{'history'})) {
 996                 my %score_history = ();
 997
 998                 local $dbh->{AutoCommit} = 0;
 999                 my $q = $dbh->prepare('SELECT * FROM scores WHERE id=?');
1000                 my $pos;
1001                 if (exists($pos_calculating->{'start_fen'})) {
1002                         $pos = Position->from_fen($pos_calculating->{'start_fen'});
1003                 } else {
1004                         $pos = Position->start_pos('white', 'black');
1005                 }
1006                 $pos->{'chess960'} = $pos_calculating->{'chess960'};
1007                 my $halfmove_num = 0;
1008                 for my $move (@{$pos_calculating->{'history'}}) {
1009                         my $id = id_for_pos($pos, $halfmove_num);
1010                         my $ref = $dbh->selectrow_hashref($q, undef, $id);
1011                         if (defined($ref)) {
1012                                 $score_history{$halfmove_num} = [
1013                                         $ref->{'score_type'},
1014                                         $ref->{'score_value'}
1015                                 ];
1016                         }
1017                         ++$halfmove_num;
1018                         ($pos) = $pos->make_pretty_move($move);
1019                 }
1020                 $q->finish;
1021                 $dbh->commit;
1022
1023                 # If at any point we are missing 10 consecutive moves,
1024                 # truncate the history there. This is so we don't get into
1025                 # a situation where we e.g. start analyzing at move 45,
1026                 # but we have analysis for 1. e4 from some completely different game
1027                 # and thus show a huge hole.
1028                 my $consecutive_missing = 0;
1029                 my $truncate_until = 0;
1030                 for (my $i = $halfmove_num; $i --> 0; ) {
1031                         if ($consecutive_missing >= 10) {
1032                                 delete $score_history{$i};
1033                                 next;
1034                         }
1035                         if (exists($score_history{$i})) {
1036                                 $consecutive_missing = 0;
1037                         } else {
1038                                 ++$consecutive_missing;
1039                         }
1040                 }
1041
1042                 $json->{'score_history'} = \%score_history;
1043         }
1044
1045         # Give out a list of other games going on. (Empty is fine.)
1046         # TODO: Don't bother reading our own file, the data will be stale anyway.
1047         if (!$historic_json_only) {
1048                 my @games = ();
1049
1050                 my $q = $dbh->prepare('SELECT * FROM current_games ORDER BY priority DESC, id');
1051                 $q->execute;
1052                 while (my $ref = $q->fetchrow_hashref) {
1053                         eval {
1054                                 my $other_game_contents = File::Slurp::read_file($ref->{'json_path'});
1055                                 my $other_game_json = JSON::XS::decode_json($other_game_contents);
1056
1057                                 die "Missing position" if (!exists($other_game_json->{'position'}));
1058                                 my $white = $other_game_json->{'position'}{'player_w'} // die 'Missing white';
1059                                 my $black = $other_game_json->{'position'}{'player_b'} // die 'Missing black';
1060
1061                                 my $game = {
1062                                         id => $ref->{'id'},
1063                                         name => "$white–$black",
1064                                         url => $ref->{'url'},
1065                                         hashurl => $ref->{'hash_url'},
1066                                 };
1067                                 if (defined($other_game_json->{'position'}{'result'})) {
1068                                         $game->{'result'} = $other_game_json->{'position'}{'result'};
1069                                 } else {
1070                                         $game->{'score'} = $other_game_json->{'score'};
1071                                 }
1072                                 push @games, $game;
1073                         };
1074                         if ($@) {
1075                                 warn "Could not add external game " . $ref->{'json_path'} . ": $@";
1076                         }
1077                 }
1078
1079                 if (scalar @games > 0) {
1080                         $json->{'games'} = \@games;
1081                 }
1082         }
1083
1084         my $json_enc = JSON::XS->new;
1085         $json_enc->canonical(1);
1086         my $encoded = $json_enc->encode($json);
1087         unless ($historic_json_only || !defined($remoteglotconf::json_output) ||
1088                 (defined($last_written_json) && $last_written_json eq $encoded)) {
1089                 atomic_set_contents($remoteglotconf::json_output, $encoded);
1090                 $last_written_json = $encoded;
1091         }
1092
1093         if (exists($pos_calculating->{'history'}) &&
1094             defined($remoteglotconf::json_history_dir)) {
1095                 my $id = id_for_pos($pos_calculating);
1096                 my $filename = $remoteglotconf::json_history_dir . "/" . $id . ".json";
1097
1098                 # Overwrite old analysis (assuming it exists at all) if we're
1099                 # using a different engine, or if we've calculated deeper.
1100                 # nodes is used as a tiebreaker. Don't bother about Multi-PV
1101                 # data; it's not that important.
1102                 my ($old_engine, $old_depth, $old_nodes) = get_json_analysis_stats($id);
1103                 my $new_depth = $json->{'depth'} // 0;
1104                 my $new_nodes = $json->{'nodes'} // 0;
1105                 if (!defined($old_engine) ||
1106                     $old_engine ne $json->{'engine'}{'name'} ||
1107                     $new_depth > $old_depth ||
1108                     ($new_depth == $old_depth && $new_nodes >= $old_nodes)) {
1109                         atomic_set_contents($filename, $encoded);
1110                         if (defined($json->{'score'})) {
1111                                 $dbh->do('INSERT INTO scores (id, score_type, score_value, engine, depth, nodes) VALUES (?,?,?,?,?,?) ' .
1112                                          '    ON CONFLICT (id) DO UPDATE SET ' .
1113                                          '        score_type=EXCLUDED.score_type, ' .
1114                                          '        score_value=EXCLUDED.score_value, ' .
1115                                          '        engine=EXCLUDED.engine, ' .
1116                                          '        depth=EXCLUDED.depth, ' .
1117                                          '        nodes=EXCLUDED.nodes',
1118                                         undef,
1119                                         $id, $json->{'score'}[0], $json->{'score'}[1],
1120                                         $json->{'engine'}{'name'}, $new_depth, $new_nodes);
1121                         }
1122                 }
1123         }
1124 }
1125
1126 sub atomic_set_contents {
1127         my ($filename, $contents) = @_;
1128
1129         open my $fh, ">", $filename . ".tmp"
1130                 or return;
1131         print $fh $contents;
1132         close $fh;
1133         rename($filename . ".tmp", $filename);
1134 }
1135
1136 sub id_for_pos {
1137         my ($pos, $halfmove_num) = @_;
1138
1139         $halfmove_num //= scalar @{$pos->{'history'}};
1140         (my $fen = $pos->fen()) =~ tr,/ ,-_,;
1141         return "move$halfmove_num-$fen";
1142 }
1143
1144 sub get_json_analysis_stats {
1145         my $id = shift;
1146         my $ref = $dbh->selectrow_hashref('SELECT * FROM scores WHERE id=?', undef, $id);
1147         if (defined($ref)) {
1148                 return ($ref->{'engine'}, $ref->{'depth'}, $ref->{'nodes'});
1149         } else {
1150                 return ('', 0, 0);
1151         }
1152 }
1153
1154 sub uciprint {
1155         my ($engine, $msg) = @_;
1156         $engine->print($msg);
1157         print UCILOG localtime() . " $engine->{'tag'} => $msg\n";
1158 }
1159
1160 sub short_score {
1161         my ($info, $pos, $mpv) = @_;
1162
1163         my $invert = ($pos->{'toplay'} eq 'B');
1164         if (defined($info->{'score_mate' . $mpv})) {
1165                 if ($invert) {
1166                         return sprintf "M%3d", -$info->{'score_mate' . $mpv};
1167                 } else {
1168                         return sprintf "M%3d", $info->{'score_mate' . $mpv};
1169                 }
1170         } else {
1171                 if (exists($info->{'score_cp' . $mpv})) {
1172                         my $score = $info->{'score_cp' . $mpv} * 0.01;
1173                         if ($score == 0) {
1174                                 if ($info->{'tablebase'}) {
1175                                         return "TB draw";
1176                                 } else {
1177                                         return " 0.00";
1178                                 }
1179                         }
1180                         if ($invert) {
1181                                 $score = -$score;
1182                         }
1183                         return sprintf "%+5.2f", $score;
1184                 }
1185         }
1186
1187         return undef;
1188 }
1189
1190 # Sufficient for computing long_score, short_score, plot_score and
1191 # (with side-to-play information) score_sort_key.
1192 sub score_digest {
1193         my ($info, $pos, $mpv) = @_;
1194         return score_digest_inner(
1195                 $info->{'score_cp' . $mpv},
1196                 $info->{'score_mate' . $mpv},
1197                 $info->{'splicepos' . $mpv},
1198                 $info->{'tablebase'},
1199                 $pos);
1200 }
1201
1202 sub score_digest_inner {
1203         my ($score, $mate, $sp, $tablebase, $pos) = @_;
1204         if (defined($mate)) {
1205                 if ($pos->{'toplay'} eq 'B') {
1206                         $mate = -$mate;
1207                 }
1208                 if (defined($sp)) {
1209                         if ($mate > 0) {
1210                                 return ['T', $sp];
1211                         } else {
1212                                 return ['t', $sp];
1213                         }
1214                 } else {
1215                         if ($mate > 0) {
1216                                 return ['M', $mate];
1217                         } elsif ($mate < 0) {
1218                                 return ['m', -$mate];
1219                         } elsif ($pos->{'toplay'} eq 'B') {
1220                                 return ['M', 0];
1221                         } else {
1222                                 return ['m', 0];
1223                         }
1224                 }
1225         } else {
1226                 if (defined($score)) {
1227                         if ($pos->{'toplay'} eq 'B') {
1228                                 $score = -$score;
1229                         }
1230                         if ($score == 0 && $tablebase) {
1231                                 return ['d', undef];
1232                         } else {
1233                                 return ['cp', int($score)];
1234                         }
1235                 }
1236         }
1237
1238         return undef;
1239 }
1240
1241 sub long_score {
1242         my ($info, $pos, $mpv) = @_;
1243
1244         if (defined($info->{'score_mate' . $mpv})) {
1245                 my $mate = $info->{'score_mate' . $mpv};
1246                 if ($pos->{'toplay'} eq 'B') {
1247                         $mate = -$mate;
1248                 }
1249                 if (exists($info->{'splicepos' . $mpv})) {
1250                         my $sp = $info->{'splicepos' . $mpv};
1251                         if ($mate > 0) {
1252                                 return sprintf "White wins in %u", int(($sp + 1) * 0.5);
1253                         } else {
1254                                 return sprintf "Black wins in %u", int(($sp + 1) * 0.5);
1255                         }
1256                 } else {
1257                         if ($mate > 0) {
1258                                 return sprintf "White mates in %u", $mate;
1259                         } else {
1260                                 return sprintf "Black mates in %u", -$mate;
1261                         }
1262                 }
1263         } else {
1264                 if (exists($info->{'score_cp' . $mpv})) {
1265                         my $score = $info->{'score_cp' . $mpv} * 0.01;
1266                         if ($score == 0) {
1267                                 if ($info->{'tablebase'}) {
1268                                         return "Theoretical draw";
1269                                 } else {
1270                                         return "Score:  0.00";
1271                                 }
1272                         }
1273                         if ($pos->{'toplay'} eq 'B') {
1274                                 $score = -$score;
1275                         }
1276                         return sprintf "Score: %+5.2f", $score;
1277                 }
1278         }
1279
1280         return undef;
1281 }
1282
1283 # For graphs; a single number in centipawns, capped at +/- 500.
1284 sub plot_score {
1285         my ($info, $pos, $mpv) = @_;
1286
1287         my $invert = ($pos->{'toplay'} eq 'B');
1288         if (defined($info->{'score_mate' . $mpv})) {
1289                 my $mate = $info->{'score_mate' . $mpv};
1290                 if ($invert) {
1291                         $mate = -$mate;
1292                 }
1293                 if ($mate > 0) {
1294                         return 500;
1295                 } else {
1296                         return -500;
1297                 }
1298         } else {
1299                 if (exists($info->{'score_cp' . $mpv})) {
1300                         my $score = $info->{'score_cp' . $mpv};
1301                         if ($invert) {
1302                                 $score = -$score;
1303                         }
1304                         $score = 500 if ($score > 500);
1305                         $score = -500 if ($score < -500);
1306                         return int($score);
1307                 }
1308         }
1309
1310         return undef;
1311 }
1312
1313 sub extract_clock {
1314         my ($pgn, $pos) = @_;
1315
1316         # Look for extended PGN clock tags.
1317         my $tags = $pgn->tags;
1318         if (exists($tags->{'WhiteClock'}) && exists($tags->{'BlackClock'})) {
1319                 $pos->{'white_clock'} = hms_to_sec($tags->{'WhiteClock'});
1320                 $pos->{'black_clock'} = hms_to_sec($tags->{'BlackClock'});
1321                 return;
1322         }
1323
1324         # Look for TCEC-style time comments.
1325         my $moves = $pgn->moves;
1326         my $comments = $pgn->comments;
1327         my $last_black_move = int((scalar @$moves) / 2);
1328         my $last_white_move = int((1 + scalar @$moves) / 2);
1329
1330         my $black_key = $last_black_move . "b";
1331         my $white_key = $last_white_move . "w";
1332
1333         if (exists($comments->{$white_key}) &&
1334             exists($comments->{$black_key}) &&
1335             $comments->{$white_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/ &&
1336             $comments->{$black_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/) {
1337                 $comments->{$white_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/;
1338                 $pos->{'white_clock'} = hms_to_sec($1);
1339                 $comments->{$black_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/;
1340                 $pos->{'black_clock'} = hms_to_sec($1);
1341                 return;
1342         }
1343
1344         delete $pos->{'white_clock'};
1345         delete $pos->{'black_clock'};
1346 }
1347
1348 sub hms_to_sec {
1349         my $hms = shift;
1350         return undef if (!defined($hms));
1351         $hms =~ /(\d+):(\d+):(\d+)/;
1352         return $1 * 3600 + $2 * 60 + $3;
1353 }
1354
1355 sub find_clock_start {
1356         my ($pos, $prev_pos) = @_;
1357
1358         # If the game is over, the clock is stopped.
1359         if (exists($pos->{'result'}) &&
1360             ($pos->{'result'} eq '1-0' ||
1361              $pos->{'result'} eq '1/2-1/2' ||
1362              $pos->{'result'} eq '0-1')) {
1363                 return;
1364         }
1365
1366         # When we don't have any moves, we assume the clock hasn't started yet.
1367         if ($pos->{'move_num'} == 1 && $pos->{'toplay'} eq 'W') {
1368                 if (defined($remoteglotconf::adjust_clocks_before_move)) {
1369                         &$remoteglotconf::adjust_clocks_before_move(\$pos->{'white_clock'}, \$pos->{'black_clock'}, 1, 'W');
1370                 }
1371                 return;
1372         }
1373
1374         # TODO(sesse): Maybe we can get the number of moves somehow else for FICS games.
1375         # The history is needed for id_for_pos.
1376         if (!exists($pos->{'history'})) {
1377                 return;
1378         }
1379
1380         my $id = id_for_pos($pos);
1381         my $clock_info = $dbh->selectrow_hashref('SELECT * FROM clock_info WHERE id=? AND COALESCE(white_clock_target, black_clock_target) >= EXTRACT(EPOCH FROM (CURRENT_TIMESTAMP - INTERVAL \'1 day\'));', undef, $id);
1382         if (defined($clock_info)) {
1383                 $pos->{'white_clock'} //= $clock_info->{'white_clock'};
1384                 $pos->{'black_clock'} //= $clock_info->{'black_clock'};
1385                 if ($pos->{'toplay'} eq 'W') {
1386                         $pos->{'white_clock_target'} = $clock_info->{'white_clock_target'};
1387                 } else {
1388                         $pos->{'black_clock_target'} = $clock_info->{'black_clock_target'};
1389                 }
1390                 return;
1391         }
1392
1393         # OK, we haven't seen this position before, so we assume the move
1394         # happened right now.
1395
1396         # See if we should do our own clock management (ie., clock information
1397         # is spurious or non-existent).
1398         if (defined($remoteglotconf::adjust_clocks_before_move)) {
1399                 my $wc = $pos->{'white_clock'} // $prev_pos->{'white_clock'};
1400                 my $bc = $pos->{'black_clock'} // $prev_pos->{'black_clock'};
1401                 if (defined($prev_pos->{'white_clock_target'})) {
1402                         $wc = $prev_pos->{'white_clock_target'} - time;
1403                 }
1404                 if (defined($prev_pos->{'black_clock_target'})) {
1405                         $bc = $prev_pos->{'black_clock_target'} - time;
1406                 }
1407                 &$remoteglotconf::adjust_clocks_before_move(\$wc, \$bc, $pos->{'move_num'}, $pos->{'toplay'});
1408                 $pos->{'white_clock'} = $wc;
1409                 $pos->{'black_clock'} = $bc;
1410         }
1411
1412         my $key = ($pos->{'toplay'} eq 'W') ? 'white_clock' : 'black_clock';
1413         if (!exists($pos->{$key})) {
1414                 # No clock information.
1415                 return;
1416         }
1417         my $time_left = $pos->{$key};
1418         my ($white_clock_target, $black_clock_target);
1419         if ($pos->{'toplay'} eq 'W') {
1420                 $white_clock_target = $pos->{'white_clock_target'} = time + $time_left;
1421         } else {
1422                 $black_clock_target = $pos->{'black_clock_target'} = time + $time_left;
1423         }
1424         local $dbh->{AutoCommit} = 0;
1425         $dbh->do('DELETE FROM clock_info WHERE id=?', undef, $id);
1426         $dbh->do('INSERT INTO clock_info (id, white_clock, black_clock, white_clock_target, black_clock_target) VALUES (?, ?, ?, ?, ?)', undef,
1427                 $id, $pos->{'white_clock'}, $pos->{'black_clock'}, $white_clock_target, $black_clock_target);
1428         $dbh->commit;
1429 }
1430
1431 sub schedule_tb_lookup {
1432         return if (!defined($remoteglotconf::tb_serial_key));
1433         my $pos = $pos_calculating;
1434         return if (exists($tb_cache{$pos->fen()}));
1435
1436         # If there's more than seven pieces, there's not going to be an answer,
1437         # so don't bother.
1438         return if ($pos->num_pieces() > 7);
1439
1440         # Max one at a time. If it's still relevant when it returns,
1441         # schedule_tb_lookup() will be called again.
1442         return if ($tb_lookup_running);
1443
1444         $tb_lookup_running = 1;
1445         my $url = 'http://tb7-api.chessok.com:6904/tasks/addtask?auth.login=' .
1446                 $remoteglotconf::tb_serial_key .
1447                 '&auth.password=aquarium&type=0&fen=' .
1448                 URI::Escape::uri_escape($pos->fen());
1449         print TBLOG "Downloading $url...\n";
1450         AnyEvent::HTTP::http_get($url, sub {
1451                 handle_tb_lookup_return(@_, $pos, $pos->fen());
1452         });
1453 }
1454
1455 sub handle_tb_lookup_return {
1456         my ($body, $header, $pos, $fen) = @_;
1457         print TBLOG "Response for [$fen]:\n";
1458         print TBLOG $header . "\n\n";
1459         print TBLOG $body . "\n\n";
1460         eval {
1461                 my $response = JSON::XS::decode_json($body);
1462                 if ($response->{'ErrorCode'} != 0) {
1463                         die "Unknown tablebase server error: " . $response->{'ErrorDesc'};
1464                 }
1465                 my $state = $response->{'Response'}{'StateString'};
1466                 if ($state eq 'COMPLETE') {
1467                         my $pgn = Chess::PGN::Parse->new(undef, $response->{'Response'}{'Moves'});
1468                         if (!defined($pgn) || !$pgn->read_game()) {
1469                                 warn "Error in parsing PGN\n";
1470                         } else {
1471                                 $pgn->quick_parse_game;
1472                                 my $pvpos = $pos;
1473                                 my $moves = $pgn->moves;
1474                                 my @uci_moves = ();
1475                                 for my $move (@$moves) {
1476                                         my $uci_move;
1477                                         ($pvpos, $uci_move) = $pvpos->make_pretty_move($move);
1478                                         push @uci_moves, $uci_move;
1479                                 }
1480                                 $tb_cache{$fen} = {
1481                                         result => $pgn->result,
1482                                         pv => \@uci_moves,
1483                                         score => $response->{'Response'}{'Score'},
1484                                 };
1485                                 output();
1486                         }
1487                 } elsif ($state =~ /QUEUED/ || $state =~ /PROCESSING/) {
1488                         # Try again in a second. Note that if we have changed
1489                         # position in the meantime, we might query a completely
1490                         # different position! But that's fine.
1491                 } else {
1492                         die "Unknown response state " . $state;
1493                 }
1494
1495                 # Wait a second before we schedule another one.
1496                 $tb_retry_timer = AnyEvent->timer(after => 1.0, cb => sub {
1497                         $tb_lookup_running = 0;
1498                         schedule_tb_lookup();
1499                 });
1500         };
1501         if ($@) {
1502                 warn "Error in tablebase lookup: $@";
1503
1504                 # Don't try this one again, but don't block new lookups either.
1505                 $tb_lookup_running = 0;
1506         }
1507 }
1508
1509 sub open_engine {
1510         my ($cmdline, $tag, $cb) = @_;
1511         return undef if (!defined($cmdline));
1512         return Engine->open($cmdline, $tag, $cb);
1513 }
1514
1515 sub col_letter_to_num {
1516         return ord(shift) - ord('a');
1517 }
1518
1519 sub row_letter_to_num {
1520         return 7 - (ord(shift) - ord('1'));
1521 }
1522
1523 sub parse_uci_move {
1524         my $move = shift;
1525         my $from_col = col_letter_to_num(substr($move, 0, 1));
1526         my $from_row = row_letter_to_num(substr($move, 1, 1));
1527         my $to_col   = col_letter_to_num(substr($move, 2, 1));
1528         my $to_row   = row_letter_to_num(substr($move, 3, 1));
1529         my $promo    = substr($move, 4, 1);
1530         return ($from_row, $from_col, $to_row, $to_col, $promo);
1531 }
1532
1533 sub setoptions {
1534         my ($engine, $config) = @_;
1535         uciprint($engine, "setoption name UCI_AnalyseMode value true");
1536         uciprint($engine, "setoption name Analysis Contempt value Off");
1537         if (exists($config->{'Threads'})) {  # Threads first, because clearing hash can be multithreaded then.
1538                 uciprint($engine, "setoption name Threads value " . $config->{'Threads'});
1539         }
1540         while (my ($key, $value) = each %$config) {
1541                 next if $key eq 'Threads';
1542                 uciprint($engine, "setoption name $key value $value");
1543         }
1544 }