git.sesse.net Git - vlc/blob - extras/buildsystem/cmake/include/config.cmake

   1 ###########################################################
   2 # System Includes
   3 ###########################################################
   4 include( CheckIncludeFile )
   5 include (CheckTypeSize)
   6 include (CheckCSourceCompiles)
   7 include (CheckSymbolExists)
   8 include (CheckLibraryExists)
   9
  10 ###########################################################
  11 # Options
  12 ###########################################################
  13 # Options moved before the custom macro includes because those macros need path values, if the ENABLE_CONTRIB
  14 # has been set.
  15
  16 OPTION( ENABLE_HTTPD           "Enable httpd server" ON )
  17 OPTION( ENABLE_VLM             "Enable vlm" ON )
  18 OPTION( ENABLE_DYNAMIC_PLUGINS "Enable dynamic plugin" ON )
  19 OPTION( UPDATE_CHECK           "Enable automatic new version checking" OFF )
  20 OPTION( ENABLE_NO_SYMBOL_CHECK "Don't check symbols of modules against libvlc. (Enabling this option speeds up compilation)" OFF )
  21 OPTION( ENABLE_CONTRIB         "Attempt to use VLC contrib system to get the third-party libraries" ON )
  22
  23 if(ENABLE_CONTRIB)
  24
  25   set( CONTRIB_INCLUDE ${CMAKE_SOURCE_DIR}/extras/contrib/include)
  26   set( CONTRIB_LIB ${CMAKE_SOURCE_DIR}/extras/contrib/lib)
  27   set( CONTRIB_PROGRAM ${CMAKE_SOURCE_DIR}/extras/contrib/bin)
  28   set( CMAKE_LIBRARY_PATH ${CONTRIB_LIB} ${CMAKE_LIBRARY_PATH} )
  29   set( CMAKE_PROGRAM_PATH ${CONTRIB_PROGRAM} ${CMAKE_PROGRAM_PATH} )
  30   set( CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${CONTRIB_LIB}" )
  31   set( CMAKE_CXX_LINK_FLAGS "${CMAKE_CXX_LINK_FLAGS} -L${CONTRIB_LIB}" )
  32   set( CMAKE_SHARED_MODULE_CREATE_C_FLAGS "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
  33   set( CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
  34   set( CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
  35   set( CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
  36
  37   # include extras/contrib/include in the header search pathes
  38   include_directories(${CONTRIB_INCLUDE})
  39   set( CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${CONTRIB_INCLUDE} )
  40
  41   # include the extras/contrib/bin to the search path, otherwise, when finding programs it will automatically
  42   # default to system applications (e.g. we should favor the extras/contrib/bin/pkg-config over the system defined
  43   # one).
  44   if(WIN32)
  45     set( ENV{PATH} "${CONTRIB_PROGRAM};$ENV{PATH}" )
  46   else(WIN32)
  47     set( ENV{PATH} "${CONTRIB_PROGRAM}:$ENV{PATH}" )
  48   endif(WIN32)
  49 endif(ENABLE_CONTRIB)
  50
  51 ###########################################################
  52 # Custom Macro Includes
  53 ###########################################################
  54
  55 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_include_files.cmake )
  56 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_functions_exist.cmake )
  57 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_add_compile_flag.cmake )
  58 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_type.cmake )
  59 include( ${CMAKE_SOURCE_DIR}/cmake/pkg_check_modules.cmake )
  60
  61 ###########################################################
  62 # Versioning
  63 ###########################################################
  64
  65 set(VLC_VERSION_MAJOR 0)
  66 set(VLC_VERSION_MINOR 9)
  67 set(VLC_VERSION_PATCH 0)
  68 set(VLC_VERSION_EXTRA "-svn")
  69 set(VLC_VERSION ${VLC_VERSION_MAJOR}.${VLC_VERSION_MINOR}.${VLC_VERSION_PATCH}${VLC_VERSION_EXTRA})
  70
  71 set(PACKAGE "vlc")
  72 set(PACKAGE_VERSION "${VLC_VERSION}")
  73 set(PACKAGE_STRING "vlc")
  74 set(VERSION_MESSAGE "vlc-${VLC_VERSION}")
  75 set(COPYRIGHT_MESSAGE "Copyright © the VideoLAN team")
  76 set(COPYRIGHT_YEARS "2001-2008")
  77 set(PACKAGE_VERSION_EXTRA "${VLC_VERSION_EXTRA}")
  78 set(PACKAGE_VERSION_MAJOR "${VLC_VERSION_MAJOR}")
  79 set(PACKAGE_VERSION_MINOR "${VLC_VERSION_MINOR}")
  80 set(PACKAGE_VERSION_REVISION "${VLC_VERSION_PATCH}")
  81
  82 ###########################################################
  83 # Preflight Checks
  84 ###########################################################
  85
  86 IF (NOT CMAKE_BUILD_TYPE)
  87     set(CMAKE_BUILD_TYPE "Debug" CACHE STRING  "build type determining compiler flags" FORCE )
  88 endif(NOT CMAKE_BUILD_TYPE )
  89
  90 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  91     set(DEBUG ON)
  92     add_definitions(-DDEBUG=1)
  93     set(NDEBUG OFF)
  94 endif(CMAKE_BUILD_TYPE STREQUAL "Debug")
  95
  96 set( HAVE_DYNAMIC_PLUGINS ${ENABLE_DYNAMIC_PLUGINS})
  97 set( LIBEXT ${CMAKE_SHARED_MODULE_SUFFIX})
  98
  99 ###########################################################
 100 # Headers checks
 101 ###########################################################
 102
 103 vlc_check_include_files (malloc.h stdbool.h locale.h)
 104 vlc_check_include_files (stddef.h stdlib.h sys/stat.h)
 105 vlc_check_include_files (stdio.h stdint.h inttypes.h)
 106 vlc_check_include_files (signal.h unistd.h dirent.h)
 107 vlc_check_include_files (netinet/in.h netinet/udplite.h)
 108 vlc_check_include_files (arpa/inet.h net/if.h)
 109 vlc_check_include_files (netdb.h fcntl.h sys/time.h poll.h)
 110 vlc_check_include_files (errno.h time.h alloca.h)
 111 vlc_check_include_files (limits.h)
 112
 113 vlc_check_include_files (string.h strings.h getopt.h)
 114
 115 vlc_check_include_files (dlfcn.h dl.h)
 116
 117 vlc_check_include_files (kernel/OS.h)
 118 vlc_check_include_files (memory.h)
 119 vlc_check_include_files (mach-o/dyld.h)
 120
 121 vlc_check_include_files (pthread.h)
 122
 123 find_package (Threads)
 124
 125 ###########################################################
 126 # Functions/structures checks
 127 ###########################################################
 128
 129 set(CMAKE_REQUIRED_LIBRARIES c)
 130 set(CMAKE_EXTRA_INCLUDE_FILES string.h)
 131 vlc_check_functions_exist(strcpy strcasecmp)
 132 vlc_check_functions_exist(strcasestr strdup)
 133 vlc_check_functions_exist(strndup stricmp strnicmp)
 134 vlc_check_functions_exist(atof strtoll atoll lldiv)
 135 vlc_check_functions_exist(strlcpy stristr strnlen strsep)
 136 vlc_check_functions_exist(strtod strtof strtol stroul)
 137 vlc_check_functions_exist(stroull)
 138 set(CMAKE_EXTRA_INCLUDE_FILES)
 139
 140 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 141 vlc_check_functions_exist(vasprintf)
 142 set(CMAKE_EXTRA_INCLUDE_FILES)
 143
 144 set(CMAKE_EXTRA_INCLUDE_FILES libc.h)
 145 vlc_check_functions_exist(fork)
 146 set(CMAKE_EXTRA_INCLUDE_FILES)
 147
 148 set(CMAKE_EXTRA_INCLUDE_FILES stdlib.h)
 149 vlc_check_functions_exist(putenv getenv setenv)
 150 vlc_check_functions_exist(putenv getenv setenv)
 151 set(CMAKE_EXTRA_INCLUDE_FILES)
 152
 153 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 154 vlc_check_functions_exist(snprintf asprintf)
 155 vlc_check_functions_exist(putenv getenv setenv)
 156 set(CMAKE_EXTRA_INCLUDE_FILES)
 157
 158 set(CMAKE_EXTRA_INCLUDE_FILES unistd.h)
 159 vlc_check_functions_exist(isatty getcwd getuid swab)
 160 set(CMAKE_EXTRA_INCLUDE_FILES)
 161
 162 set(CMAKE_EXTRA_INCLUDE_FILES sys/stat.h)
 163 vlc_check_functions_exist(lstat fstat stat)
 164 set(CMAKE_EXTRA_INCLUDE_FILES)
 165
 166 set(CMAKE_EXTRA_INCLUDE_FILES arpa/inet.h)
 167 vlc_check_functions_exist(inet_aton inet_ntop inet_pton)
 168 set(CMAKE_EXTRA_INCLUDE_FILES)
 169
 170 set(CMAKE_EXTRA_INCLUDE_FILES sys/mman.h)
 171 vlc_check_functions_exist(mmap)
 172 set(CMAKE_EXTRA_INCLUDE_FILES)
 173
 174 set(CMAKE_REQUIRED_LIBRARIES)
 175
 176 check_library_exists(poll poll "" HAVE_POLL)
 177
 178 check_c_source_compiles(
 179 "#include <langinfo.h>
 180 int main() { char* cs = nl_langinfo(CODESET); }"
 181 HAVE_LANGINFO_CODESET)
 182
 183 vlc_check_type("struct addrinfo" "sys/socket.h;netdb.h")
 184 if(HAVE_STRUCT_ADDRINFO)
 185   set(HAVE_ADDRINFO ON)
 186 endif(HAVE_STRUCT_ADDRINFO)
 187 vlc_check_type("struct timespec" "time.h")
 188
 189 check_c_source_compiles (
 190 "#include <stdint.h> \n #ifdef UINTMAX \n #error no uintmax
 191  #endif
 192  int main() { return 0;}" HAVE_STDINT_H_WITH_UINTMAX)
 193
 194 check_symbol_exists(ntohl "sys/param.h"  NTOHL_IN_SYS_PARAM_H)
 195 check_symbol_exists(scandir "dirent.h"   HAVE_SCANDIR)
 196 check_symbol_exists(localtime_r "time.h" HAVE_LOCALTIME_R)
 197 check_symbol_exists(alloca "alloca.h"    HAVE_ALLOCA)
 198
 199 check_symbol_exists(va_copy "stdarg.h"   HAVE_VACOPY)
 200 check_symbol_exists(__va_copy "stdarg.h" HAVE___VA_COPY)
 201
 202
 203 check_symbol_exists(getnameinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETNAMEINFO)
 204 check_symbol_exists(getaddrinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETADDRINFO)
 205 if(NOT HAVE_GETADDRINFO)
 206     check_library_exists(getaddrinfo nsl "" HAVE_GETADDRINFO)
 207 endif(NOT HAVE_GETADDRINFO)
 208
 209 vlc_check_functions_exist(iconv)
 210 if(NOT HAVE_ICONV)
 211     set(LIBICONV "iconv")
 212     check_library_exists(iconv iconv "" HAVE_ICONV)
 213 endif(NOT HAVE_ICONV)
 214 set(CMAKE_REQUIRED_LIBRARIES ${LIBICONV})
 215 CHECK_C_SOURCE_COMPILES(" #include <iconv.h>
 216  int main() { return iconv(0, (char **)0, 0, (char**)0, 0); }" ICONV_NO_CONST)
 217 if( ICONV_NO_CONST )
 218   set( ICONV_CONST "const" )
 219 else( ICONV_NO_CONST )
 220   set( ICONV_CONST " ")
 221 endif( ICONV_NO_CONST )
 222 set(CMAKE_REQUIRED_LIBRARIES)
 223
 224 check_library_exists(rt clock_nanosleep "" HAVE_CLOCK_NANOSLEEP)
 225 if (HAVE_CLOCK_NANOSLEEP)
 226     set(LIBRT "rt")
 227 endif (HAVE_CLOCK_NANOSLEEP)
 228
 229 check_library_exists(m pow "" HAVE_LIBM)
 230 if (HAVE_LIBM)
 231     set (LIBM "m")
 232 endif (HAVE_LIBM)
 233
 234 check_symbol_exists(connect "sys/types.h;sys/socket.h" HAVE_CONNECT)
 235 if(NOT HAVE_CONNECT)
 236     check_library_exists(connect socket "" HAVE_CONNECT)
 237     if(NOT HAVE_CONNECT)
 238         vlc_module_add_link_libraries(libvlc connect)
 239         vlc_module_add_link_libraries(cdda   connect)
 240         vlc_module_add_link_libraries(cddax  connect)
 241     endif(NOT HAVE_CONNECT)
 242 endif(NOT HAVE_CONNECT)
 243
 244 ###########################################################
 245 # Other check
 246 ###########################################################
 247
 248 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_test_inline.cmake )
 249
 250 ###########################################################
 251 # Platform check
 252 ###########################################################
 253
 254 if(APPLE)
 255     include( ${CMAKE_SOURCE_DIR}/cmake/vlc_find_frameworks.cmake )
 256
 257     # Mac OS X (10.4 and 10.5)  can't poll a tty properly
 258     # So we deactivate its uses
 259     set(HAVE_POLL OFF)
 260
 261     if(ENABLE_NO_SYMBOL_CHECK)
 262         set(DYNAMIC_LOOKUP "-undefined dynamic_lookup")
 263     else(ENABLE_NO_SYMBOL_CHECK)
 264         set(DYNAMIC_LOOKUP)
 265     endif(ENABLE_NO_SYMBOL_CHECK)
 266     set(CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS
 267      "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} ${DYNAMIC_LOOKUP}")
 268     set(CMAKE_SHARED_MODULE_CREATE_C_FLAGS
 269      "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} ${DYNAMIC_LOOKUP}")
 270
 271     # For pre-10.5
 272     set( CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_C_FLAGS} -fno-common")
 273
 274     set(SYS_DARWIN 1)
 275     add_definitions(-std=gnu99) # Hack for obj-c files to be compiled with gnu99
 276     vlc_enable_modules(macosx minimal_macosx opengllayer
 277                        access_eyetv quartztext auhal)
 278
 279     # On Pre-10.5
 280     vlc_module_add_link_flags (ffmpeg "-read_only_relocs warning")
 281
 282    # vlc_check_include_files (ApplicationServices/ApplicationServices.h)
 283    # vlc_check_include_files (Carbon/Carbon.h)
 284    # vlc_check_include_files (CoreAudio/CoreAudio.h)
 285
 286    # check_symbol_exists (CFLocaleCopyCurrent "CoreFoundation/CoreFoundation.h" "" HAVE_CFLOCALECOPYCURRENT)
 287    # check_symbol_exists (CFPreferencesCopyAppValue "CoreFoundation/CoreFoundation.h" "" HAVE_CFPREFERENCESCOPYAPPVALUE)
 288
 289     vlc_find_frameworks(Cocoa Carbon OpenGL AGL IOKit Quicktime
 290                         WebKit QuartzCore Foundation ApplicationServices
 291                         CoreAudio AudioUnit AudioToolbox)
 292     vlc_module_add_link_libraries(macosx
 293         ${Cocoa_FRAMEWORKS}
 294         ${IOKit_FRAMEWORKS}
 295         ${OpenGL_FRAMEWORKS}
 296         ${AGL_FRAMEWORKS}
 297         ${Quicktime_FRAMEWORKS}
 298         ${WebKit_FRAMEWORKS})
 299     vlc_module_add_link_libraries(minimal_macosx
 300         ${Cocoa_FRAMEWORKS}
 301         ${Carbon_FRAMEWORKS}
 302         ${OpenGL_FRAMEWORKS}
 303         ${AGL_FRAMEWORKS})
 304     vlc_module_add_link_libraries(access_eyetv
 305         ${Foundation_FRAMEWORKS})
 306     vlc_module_add_link_libraries(opengllayer
 307          ${Cocoa_FRAMEWORKS}
 308          ${QuartzCore_FRAMEWORKS}
 309          ${OpenGL_FRAMEWORKS} )
 310     vlc_module_add_link_libraries(quartztext
 311          ${Carbon_FRAMEWORKS}
 312          ${ApplicationServices_FRAMEWORKS} )
 313     vlc_module_add_link_libraries(auhal
 314          ${Carbon_FRAMEWORKS}
 315          ${CoreAudio_FRAMEWORKS}
 316          ${AudioUnit_FRAMEWORKS}
 317          ${AudioToolbox_FRAMEWORKS} )
 318     vlc_module_add_link_libraries(mp4 ${IOKit_FRAMEWORKS} )
 319     vlc_module_add_link_libraries(mkv ${IOKit_FRAMEWORKS} )
 320
 321     add_executable(VLC MACOSX_BUNDLE src/vlc.c)
 322     target_link_libraries(VLC libvlc)
 323     set( MacOS ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/MacOS )
 324     add_custom_command(
 325         TARGET VLC
 326         POST_BUILD
 327         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 328         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx
 329         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx
 330         COMMAND for i in vlc.xcodeproj Resources README.MacOSX.rtf\; do cp -R ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx\; done
 331         COMMAND for i in AUTHORS COPYING THANKS\;do cp ${CMAKE_CURRENT_SOURCE_DIR}/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp\; done
 332         COMMAND for i in AppleRemote.h AppleRemote.m about.h about.m applescript.h applescript.m controls.h controls.m equalizer.h equalizer.m intf.h intf.m macosx.m misc.h misc.m open.h open.m output.h output.m playlist.h playlist.m playlistinfo.h playlistinfo.m prefs_widgets.h prefs_widgets.m prefs.h prefs.m vout.h voutqt.m voutgl.m wizard.h wizard.m extended.h extended.m bookmarks.h bookmarks.m sfilters.h sfilters.m update.h update.m interaction.h interaction.m embeddedwindow.h embeddedwindow.m fspanel.h fspanel.m vout.m\; do cp ${CMAKE_CURRENT_SOURCE_DIR}/modules/gui/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx\; done
 333         COMMAND cd ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx && xcodebuild -target vlc | grep -vE '^\([ \\t]|$$\)' && cd ../../../../ && cp ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Info.plist ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents && cp -R ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Resources/English.lproj ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources
 334         COMMAND cp -r ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/Resources ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents
 335         COMMAND find -d ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources -type d -name \\.svn -exec rm -rf {} "\;"
 336         COMMAND rm -rf ${MacOS}/modules ${MacOS}/locale ${MacOS}/share
 337         COMMAND ln -s ${CMAKE_CURRENT_SOURCE_DIR}/share ${MacOS}/share
 338         COMMAND ln -s ${CMAKE_CURRENT_BINARY_DIR}/modules ${MacOS}/modules
 339         COMMAND find ${CMAKE_BINARY_DIR}/po -name *.gmo -exec sh -c \"mkdir -p ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES\; ln -s {} ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES/vlc.mo\" "\;"
 340         COMMAND ln -sf VLC ${MacOS}/clivlc #useless?
 341         COMMAND printf "APPLVLC#" > ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/PkgInfo
 342         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 343     )
 344     set( MacOS )
 345
 346 endif(APPLE)
 347
 348 ###########################################################
 349 # info
 350 ###########################################################
 351
 352 macro(command_to_configvar command var)
 353  execute_process(
 354   COMMAND sh -c "${command}"
 355   OUTPUT_VARIABLE ${var}
 356   OUTPUT_STRIP_TRAILING_WHITESPACE)
 357  string( REPLACE "\n" "\\n" ${var} "${${var}}")
 358 endmacro(command_to_configvar)
 359
 360 command_to_configvar( "whoami" VLC_COMPILE_BY )
 361 command_to_configvar( "hostname" VLC_COMPILE_HOST )
 362 command_to_configvar( "hostname" VLC_COMPILE_DOMAIN )
 363 command_to_configvar( "${CMAKE_C_COMPILER} --version" VLC_COMPILER )
 364 # FIXME: WTF? this is not the configure line!
 365 command_to_configvar( "${CMAKE_C_COMPILER} --version" CONFIGURE_LINE )
 366 set( VLC_COMPILER "${CMAKE_C_COMPILER}" )
 367
 368 ###########################################################
 369 # Modules: Following are all listed in options
 370 ###########################################################
 371
 372 # This module will be enabled but user could disabled it
 373 vlc_enable_modules(dummy logger memcpy)
 374 vlc_enable_modules(mpgv mpga m4v m4a h264 vc1 demux_cdg cdg ps pva avi mp4 rawdv rawvid nsv real aiff mjpeg demuxdump flacsys tta)
 375 vlc_enable_modules(cvdsub svcdsub spudec subsdec subsusf t140 dvbsub cc mpeg_audio lpcm a52 dts cinepak flac)
 376 vlc_enable_modules(deinterlace invert adjust transform wave ripple psychedelic gradient motionblur rv32 rotate noise grain extract sharpen seamcarving)
 377 vlc_enable_modules(converter_fixed mono)
 378 vlc_enable_modules(trivial_resampler ugly_resampler)
 379 vlc_enable_modules(trivial_channel_mixer trivial_mixer)
 380 vlc_enable_modules(playlist export nsc xtag)
 381 vlc_enable_modules(i420_rgb grey_yuv rawvideo blend scale image logo magnify puzzle colorthres)
 382 vlc_enable_modules(wav araw subtitle vobsub adpcm a52sys dtssys au ty voc xa nuv smf)
 383 vlc_enable_modules(access_directory access_file access_udp access_tcp)
 384 vlc_enable_modules(access_http access_mms access_ftp)
 385 vlc_enable_modules(access_filter_bandwidth)
 386 vlc_enable_modules(packetizer_mpegvideo packetizer_h264)
 387 vlc_enable_modules(packetizer_mpeg4video packetizer_mpeg4audio)
 388 vlc_enable_modules(packetizer_vc1)
 389 vlc_enable_modules(spatializer)
 390 vlc_enable_modules(asf)
 391
 392 if(NOT mingwce)
 393    set(enabled ON)
 394 endif(NOT mingwce)
 395 vlc_register_modules(${enabled} access_fake access_filter_timeshift access_filter_record access_filter_dump)
 396 vlc_register_modules(${enabled} gestures rc telnet hotkeys showintf marq podcast shout sap fake folder)
 397 vlc_register_modules(${enabled} rss mosaic wall motiondetect clone crop erase bluescreen alphamask gaussianblur)
 398 vlc_register_modules(${enabled} i420_yuy2 i422_yuy2 i420_ymga i422_i420 yuy2_i422 yuy2_i420 chroma_chain)
 399 vlc_register_modules(${enabled} aout_file linear_resampler bandlimited_resampler)
 400 vlc_register_modules(${enabled} float32_mixer spdif_mixer simple_channel_mixer)
 401 vlc_register_modules(${enabled} dolby_surround_decoder headphone_channel_mixer normvol equalizer param_eq)
 402 vlc_register_modules(${enabled} converter_float a52tospdif dtstospdif audio_format)
 403 set(enabled)
 404
 405 if(NOT WIN32)
 406    vlc_enable_modules(screensaver)
 407 endif(NOT WIN32)
 408
 409 # This module is disabled because the CMakeList.txt which
 410 # is generated isn't correct. We'll put that back
 411 # when cmake will be accepted as default build system
 412 vlc_disable_modules(motion)
 413
 414 ###########################################################
 415 # libraries
 416 ###########################################################
 417
 418 include_directories(${CONTRIB_INCLUDE})
 419
 420 #fixme: use find_package(cddb 0.9.5)
 421 pkg_check_modules(LIBCDDB libcddb>=0.9.5)
 422 if(${LIBCDDB_FOUND})
 423   vlc_module_add_link_libraries(cdda ${LIBCDDB_LIBRARIES})
 424   vlc_add_module_compile_flag(cdda ${LIBCDDB_CFLAGS} )
 425 endif(${LIBCDDB_FOUND})
 426
 427 find_package(Dlopen)
 428 set(HAVE_DL_DLOPEN ${Dlopen_FOUND})
 429
 430 # Advanced Linux Sound Architecture (ALSA)
 431 pkg_check_modules(ALSA alsa>=1.0.0-rc4)
 432 if (${ALSA_FOUND})
 433   set (HAVE_ALSA_NEW_API "1")
 434 else (${ALSA_FOUND})
 435   pkg_check_modules(ALSA alsa)
 436 endif (${ALSA_FOUND})
 437
 438 if (${ALSA_FOUND})
 439   set (HAVE_ALSA "1")
 440   vlc_enable_modules(alsa)
 441   vlc_add_module_compile_flag(alsa ${ALSA_CFLAGS})
 442   vlc_module_add_link_libraries(alsa ${ALSA_LIBRARIES})
 443 endif (${ALSA_FOUND})
 444
 445 # Open Sound System (OSS)
 446 # TODO
 447
 448 find_package(FFmpeg)
 449 if(FFmpeg_FOUND)
 450   string(REPLACE ";" " " FFmpeg_CFLAGS "${FFmpeg_CFLAGS}")
 451   set( CMAKE_REQUIRED_FLAGS_saved ${CMAKE_REQUIRED_FLAGS} )
 452   set( CMAKE_REQUIRED_FLAGS ${FFmpeg_CFLAGS} )
 453
 454   vlc_check_include_files (libavcodec/avcodec.h ffmpeg/avcodec.h)
 455   vlc_check_include_files (libavutil/avutil.h ffmpeg/avutil.h)
 456   vlc_check_include_files (libswscale/swscale.h ffmpeg/swscale.h)
 457
 458   check_include_files ("stdint.h;postproc/postprocess.h" HAVE_POSTPROC_POSTPROCESS_H)
 459   vlc_enable_modules(ffmpeg)
 460   vlc_add_module_compile_flag(ffmpeg ${FFmpeg_CFLAGS})
 461   vlc_module_add_link_libraries(ffmpeg ${FFmpeg_LIBRARIES})
 462
 463   set( CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS_saved} )
 464   set( CMAKE_REQUIRED_FLAGS_saved )
 465 endif(FFmpeg_FOUND)
 466
 467 find_package(Lua)
 468 if(Lua_FOUND)
 469   set(HAVE_LUA TRUE)
 470   vlc_enable_modules(lua)
 471   vlc_check_include_files (lua.h lualib.h)
 472   vlc_add_module_compile_flag(lua ${Lua_CFLAGS} )
 473   vlc_module_add_link_libraries(lua ${Lua_LIBRARIES})
 474 endif(Lua_FOUND)
 475
 476 find_package(Qt4)
 477 if(QT4_FOUND)
 478   set(HAVE_QT4 TRUE)
 479   include_directories(${QT_INCLUDES})
 480   vlc_check_include_files (qt.h)
 481   vlc_enable_modules(qt4)
 482   vlc_add_module_compile_flag(qt4 ${QT_CFLAGS} )
 483   vlc_module_add_link_libraries(qt4 ${QT_QTCORE_LIBRARY} ${QT_QTGUI_LIBRARY})
 484
 485   # Define our own qt4_wrap_ui macro to match wanted behaviour
 486   MACRO (VLC_QT4_WRAP_UI outfiles )
 487     FOREACH (it ${ARGN})
 488      string(REPLACE ".ui" ".h" outfile "${it}")
 489       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 490       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 491       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 492         COMMAND mkdir -p `dirname ${outfile}`
 493         COMMAND ${QT_UIC_EXECUTABLE}
 494         ARGS -o ${outfile} ${infile}
 495         MAIN_DEPENDENCY ${infile})
 496       SET(${outfiles} ${${outfiles}} ${outfile})
 497     ENDFOREACH (it)
 498   ENDMACRO (VLC_QT4_WRAP_UI)
 499
 500   MACRO (VLC_QT4_GENERATE_MOC outfiles flags )
 501     string(REGEX MATCHALL "[^\\ ]+" flags_list ${flags})
 502     FOREACH (it ${ARGN})
 503       string(REPLACE ".hpp" ".moc.cpp" outfile "${it}")
 504       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 505       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 506       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 507         COMMAND mkdir -p `dirname ${outfile}`
 508         COMMAND ${QT_MOC_EXECUTABLE}
 509         ARGS ${flags_list}
 510         ARGS -I ${CMAKE_BINARY_DIR}/include
 511         ARGS -o ${outfile} ${infile}
 512         MAIN_DEPENDENCY ${it}
 513         )
 514       SET(${outfiles} ${${outfiles}} ${outfile})
 515     ENDFOREACH (it)
 516   ENDMACRO (VLC_QT4_GENERATE_MOC)
 517
 518
 519 endif(QT4_FOUND)
 520
 521 find_package(OpenGL)
 522 if(OPENGL_FOUND)
 523   vlc_enable_modules(opengl)
 524   vlc_check_include_files (gl/gl.h)
 525   vlc_check_include_files (gl/glu.h)
 526   vlc_check_include_files (gl/glx.h)
 527   vlc_add_module_compile_flag(opengl ${OPENGL_CFLAGS})
 528   vlc_module_add_link_libraries(opengl ${OPENGL_LIBRARIES})
 529 endif(OPENGL_FOUND)
 530
 531 find_package(Matroska 0.7.7)
 532 if(Matroska_FOUND)
 533   vlc_enable_modules(mkv)
 534   vlc_check_include_files (matroska/KaxAttachments.h)
 535   vlc_check_include_files (matroska/KaxVersion.h)
 536   vlc_module_add_link_libraries(mkv ${Matroska_LIBRARIES})
 537 endif(Matroska_FOUND)
 538
 539 find_package(Live555)
 540 if(Live555_FOUND)
 541   vlc_enable_modules(live555)
 542   vlc_add_module_compile_flag(live555 ${Live555_CFLAGS})
 543   vlc_module_add_link_libraries(live555 ${Live555_LIBRARIES})
 544 endif(Live555_FOUND)
 545
 546 find_package(Curses)
 547 if(CURSES_LIBRARIES)
 548   vlc_enable_modules(ncurses)
 549   vlc_module_add_link_libraries(ncurses ${CURSES_LIBRARIES})
 550 endif(CURSES_LIBRARIES)
 551
 552 find_package(X11)
 553 if(X11_FOUND)
 554   vlc_enable_modules(x11 panoramix)
 555   vlc_check_include_files (X11/Xlib.h)
 556   vlc_module_add_link_libraries(x11       ${X11_LIBRARIES})
 557   vlc_module_add_link_libraries(panoramix ${X11_LIBRARIES})
 558 endif(X11_FOUND)
 559
 560 find_package(Mpeg2)
 561 if(Mpeg2_FOUND)
 562   vlc_enable_modules(libmpeg2)
 563   check_include_files ("stdint.h;mpeg2dec/mpeg2.h" HAVE_MPEG2DEC_MPEG2_H)
 564   vlc_module_add_link_libraries(libmpeg2 ${Mpeg2_LIBRARIES})
 565 endif(Mpeg2_FOUND)
 566
 567 find_package(Dvbpsi)
 568 if(Dvbpsi_FOUND)
 569   vlc_enable_modules(ts)
 570   check_include_files ("stdint.h;dvbpsi/dvbpsi.h;dvbpsi/demux.h;dvbpsi/descriptor.h;dvbpsi/pat.h;dvbpsi/pmt.h;dvbpsi/sdt.h;dvbpsi/dr.h" HAVE_DVBPSI_DR_H)
 571   vlc_module_add_link_libraries(ts ${Dvbpsi_LIBRARIES})
 572 endif(Dvbpsi_FOUND)
 573
 574 set(CMAKE_REQUIRED_INCLUDES)
 575
 576 ###########################################################
 577 # Final configuration
 578 ###########################################################
 579
 580 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/include/config.h)