git.sesse.net Git - xml-template/blob - tests/xml-diff.pl

   1 #! /usr/bin/perl
   2
   3 #
   4 # Compare two XML files for structural and content equivalence. Used for
   5 # regression testing.
   6 #
   7
   8 use strict;
   9 use warnings;
  10
  11 use XML::DOM;
  12 use XML::Parser;
  13 use XML::NamespaceSupport;
  14
  15 my $parser = XML::DOM::Parser->new;
  16 my $d1 = $parser->parsefile($ARGV[0]);
  17 my $d2 = $parser->parsefile($ARGV[1]);
  18 my $nsup1 = XML::NamespaceSupport->new;
  19 my $nsup2 = XML::NamespaceSupport->new;
  20
  21 compare($d1, $d2, $nsup1, $nsup2);
  22
  23 sub compare {
  24         my ($n1, $n2, $nsup1, $nsup2) = @_;
  25
  26         if ($n1->getNodeType != $n2->getNodeType) {
  27                 printf STDERR "Node types don't match (%u vs. %u)\n",
  28                         $n1->getNodeType, $n2->getNodeType;
  29                 exit(1);
  30         }
  31
  32         $nsup1->push_context;
  33         $nsup2->push_context;
  34
  35         if ($n1->getNodeType == XML::DOM::ELEMENT_NODE) {
  36                 process_namespaces($n1, $nsup1);
  37                 process_namespaces($n2, $nsup2);
  38         }
  39
  40         my ($nsuri1, undef, $lname1) = $nsup1->process_element_name($n1->getNodeName);
  41         my ($nsuri2, undef, $lname2) = $nsup2->process_element_name($n2->getNodeName);
  42
  43         $nsuri1 |= '';
  44         $nsuri2 |= '';
  45
  46         # compare element names
  47         unless ($nsuri1 eq $nsuri2 && $lname1 eq $lname2) {
  48                 print STDERR "$nsuri1/$lname1 != $nsuri2/$lname2\n";
  49                 exit(1);
  50         }
  51
  52         # compare attributes
  53         my $attrs1 = $n1->getAttributes;
  54         my $attrs2 = $n2->getAttributes;
  55
  56         # this will need some special care, since we ignore xmlns= attributes; defer
  57         # to its own function so it's easier to do comparison both ways
  58         compare_attr_list($attrs1, $attrs2, $nsup1, $nsup2) if (defined($attrs1));
  59         compare_attr_list($attrs2, $attrs1, $nsup2, $nsup1) if (defined($attrs2));
  60
  61         # if this is a text node, check the contents
  62         if ($n1->getNodeType == XML::DOM::TEXT_NODE) {
  63                 my $d1 = $n1->getData;
  64                 my $d2 = $n2->getData;
  65
  66                 # ignore leading/trailing whitespace
  67                 $d1 =~ s/^\s+//;
  68                 $d2 =~ s/^\s+//;
  69                 $d1 =~ s/\s+$//;
  70                 $d2 =~ s/\s+$//;
  71
  72                 # compress other whitespace
  73                 $d1 =~ s/\n/ /g;
  74                 $d1 =~ s/ +/ /g;
  75                 $d2 =~ s/\n/ /g;
  76                 $d2 =~ s/ +/ /g;
  77
  78                 if ($d1 ne $d2) {
  79                         print STDERR "$nsuri1/$lname1 has differing textual content ('$d1' vs. '$d2')\n";
  80                         exit(1);
  81                 }
  82         }
  83
  84         # this element is ok, let's compare all children
  85         my $c1 = $n1->getChildNodes;
  86         my $c2 = $n2->getChildNodes;
  87
  88         if ($c1->getLength != $c2->getLength) {
  89                 print STDERR "$nsuri1/$lname1 has differing number of children\n";
  90                 exit(1);
  91         }
  92
  93         for my $i (0..($c1->getLength-1)) {
  94                 compare($c1->item($i), $c2->item($i), $nsup1, $nsup2);
  95         }
  96
  97         $nsup1->pop_context;
  98         $nsup2->pop_context;
  99 }
 100
 101 sub process_namespaces {
 102         my ($node, $nsup) = @_;
 103
 104         my $attrs = $node->getAttributes;
 105         return unless defined($attrs);
 106
 107         for my $attr ($attrs->getValues) {
 108                 my $name = $attr->getName;
 109                 if ($name =~ /^xmlns:(.*)$/) {
 110                         $nsup->declare_prefix($1, $attr->getValue);
 111                 }
 112         }
 113 }
 114
 115 sub compare_attr_list {
 116         my ($attrs1, $attrs2, $nsup1, $nsup2) = @_;
 117
 118         for my $attr1 ($attrs1->getValues) {
 119                 my $name = $attr1->getName;
 120                 next if ($name =~ /^xmlns:(.*)$/);
 121
 122                 my ($nsuri1, undef, $lname1) = $nsup1->process_attribute_name($attr1->getName);
 123                 $nsuri1 |= '';
 124
 125                 if (!defined($attrs2)) {
 126                         # n2 has no attributes at all
 127                         print STDERR "Attribute $nsuri1/$lname1 exists on one side but not the other\n";
 128                         exit(1);
 129                 }
 130
 131                 my $attr2_found;
 132                 for my $attr2 ($attrs2->getValues) {
 133                         next if ($attr2->getName =~ /^xmlns:(.*)$/);
 134                         my ($nsuri2, undef, $lname2) = $nsup2->process_attribute_name($attr2->getName);
 135                         $nsuri2 |= '';
 136
 137                         if ($nsuri1 eq $nsuri2 && $lname1 eq $lname2) {
 138                                 $attr2_found = $attr2;
 139                                 last;
 140                         }
 141                 }
 142
 143                 if (!defined($attr2_found)) {
 144                         print STDERR "Attribute $nsuri1/$lname1 exists on one side but not the other\n";
 145                         last;
 146                 }
 147
 148                 if ($attr1->getValue ne $attr2_found->getValue) {
 149                         print STDERR "Attribute $nsuri1/$lname1 has differing values\n";
 150                 }
 151         }
 152 }