git.sesse.net Git - nageru/blob - futatabi/meson.build

   1 qt5 = import('qt5')
   2 protoc = find_program('protoc')
   3
   4 epoxydep = dependency('epoxy')
   5 libavcodecdep = dependency('libavcodec')
   6 libavformatdep = dependency('libavformat')
   7 libavutildep = dependency('libavutil')
   8 libjpegdep = dependency('libjpeg')
   9 libmicrohttpddep = dependency('libmicrohttpd')
  10 libswscaledep = dependency('libswscale')
  11 movitdep = dependency('movit')
  12 protobufdep = dependency('protobuf')
  13 qt5deps = dependency('qt5', modules: ['Core', 'Gui', 'Widgets', 'OpenGLExtensions', 'OpenGL', 'PrintSupport'])
  14 sdl2_imagedep = dependency('SDL2_image')
  15 sdl2dep = dependency('sdl2')
  16 sqlite3dep = dependency('sqlite3')
  17 vadrmdep = dependency('libva-drm')
  18 vax11dep = dependency('libva-x11')
  19 x11dep = dependency('x11')
  20
  21 # Add the right MOVIT_SHADER_DIR definition.
  22 r = run_command('pkg-config', '--variable=shaderdir', 'movit')
  23 if r.returncode() != 0
  24   error('Movit pkg-config installation is broken.')
  25 endif
  26 add_global_arguments('-DMOVIT_SHADER_DIR="' + r.stdout().strip() + '"', language: 'cpp')
  27
  28 # Protobuf compilation.
  29 gen = generator(protoc, \
  30   output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
  31   arguments : ['--proto_path=@CURRENT_SOURCE_DIR@', '--cpp_out=@BUILD_DIR@', '@INPUT@'])
  32 proto_generated = gen.process('state.proto', 'frame.proto')
  33
  34 # Preprocess Qt as needed.
  35 moc_files = qt5.preprocess(
  36   moc_headers: ['mainwindow.h', 'jpeg_frame_view.h', 'clip_list.h'],
  37   ui_files: ['mainwindow.ui'],
  38   dependencies: qt5deps)
  39
  40 # Flow objects.
  41 srcs = ['flow.cpp', 'gpu_timers.cpp']
  42
  43 # All the other files.
  44 srcs += ['ffmpeg_raii.cpp', 'main.cpp', 'player.cpp', 'httpd.cpp', 'mux.cpp', 'metacube2.cpp', 'video_stream.cpp', 'context.cpp', 'chroma_subsampler.cpp']
  45 srcs += ['vaapi_jpeg_decoder.cpp', 'memcpy_interleaved.cpp', 'db.cpp', 'disk_space_estimator.cpp', 'ycbcr_converter.cpp', 'flags.cpp']
  46 srcs += ['mainwindow.cpp', 'jpeg_frame_view.cpp', 'clip_list.cpp', 'frame_on_disk.cpp']
  47 srcs += moc_files
  48 srcs += proto_generated
  49
  50 # Shaders needed at runtime.
  51 shaders = ['chroma_subsample.vert', 'densify.vert', 'equations.vert', 'hole_fill.vert', 'motion_search.vert', 'sor.vert', 'splat.vert', 'vs.vert']
  52 shaders += ['add_base_flow.frag', 'blend.frag', 'chroma_subsample.frag', 'densify.frag', 'derivatives.frag', 'diffusivity.frag',
  53   'equations.frag', 'gray.frag', 'hole_blend.frag', 'hole_fill.frag', 'motion_search.frag', 'prewarp.frag', 'resize_flow.frag',
  54   'sobel.frag', 'sor.frag', 'splat.frag']
  55
  56 foreach shader : shaders
  57   run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
  58 endforeach
  59
  60 bin2h = executable('bin2h', 'bin2h.cpp')
  61 bin2h_gen = generator(bin2h, \
  62   output    : ['@PLAINNAME@.cpp'],
  63   arguments : ['@INPUT@', '@PLAINNAME@', '@OUTPUT@'])
  64 shader_srcs = bin2h_gen.process(shaders)
  65 srcs += shader_srcs
  66
  67 executable('futatabi', srcs, dependencies: [qt5deps, libjpegdep, movitdep, libmicrohttpddep, protobufdep, sqlite3dep, vax11dep, vadrmdep, x11dep, libavformatdep, libavcodecdep, libavutildep, libswscaledep])
  68 executable('flow', 'flow_main.cpp', 'flow.cpp', 'gpu_timers.cpp', shader_srcs, dependencies: [epoxydep, sdl2dep, sdl2_imagedep])
  69 executable('eval', 'eval.cpp', 'util.cpp')
  70 executable('vis', 'vis.cpp', 'util.cpp')