git.sesse.net Git - skvidarsync/blob - bin/sync.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 no warnings qw(once);
   5 use Crypt::JWT;
   6 use JSON::XS;
   7 use LWP::UserAgent;
   8 use DBI;
   9 use POSIX;
  10 binmode STDOUT, ':utf8';
  11 binmode STDERR, ':utf8';
  12 use utf8;
  13
  14 # TODO:
  15 # - detect moves between groups
  16 # - better daemon behavior
  17
  18 require '../include/config.pm';
  19
  20 my @log = ();
  21
  22 sub get_oauth_bearer_token {
  23         my $ua = shift;
  24         my $now = time();
  25         my $jwt = JSON::XS::encode_json({
  26                 "iss" => $config::jwt_key->{'client_email'},
  27                 "scope" => "https://www.googleapis.com/auth/spreadsheets",
  28                 "aud" => "https://www.googleapis.com/oauth2/v4/token",
  29                 "exp" => $now + 1800,
  30                 "iat" => $now,
  31         });
  32         my $jws_token = Crypt::JWT::encode_jwt(payload=>$jwt, alg=>'RS256', key=>\$config::jwt_key->{'private_key'});
  33         my $response = $ua->post('https://www.googleapis.com/oauth2/v4/token', [
  34                 'grant_type' => 'urn:ietf:params:oauth:grant-type:jwt-bearer',
  35                 'assertion' => $jws_token ]);
  36         return JSON::XS::decode_json($response->decoded_content)->{'access_token'};
  37 }
  38
  39 sub get_slack_name {
  40         my ($ua, $userid) = @_;
  41         my $req = HTTP::Request->new('GET', 'https://slack.com/api/users.info?user=' . $userid, [
  42                'Authorization' => 'Bearer ' . $config::oauth_token
  43         ]);
  44         my $response = $ua->request($req);
  45         die $response->status_line if !$response->is_success;
  46
  47         my $user_json = JSON::XS::decode_json($response->decoded_content);
  48         die "Something went wrong: " . $response->decoded_content if (!defined($user_json) || !$user_json->{'ok'});
  49
  50         return $user_json->{'user'}{'real_name'};
  51 }
  52
  53 sub get_spreadsheet_name {
  54         my $cell = shift;
  55         my $name = $cell->{'userEnteredValue'}{'stringValue'};
  56         return undef if (!defined($name));
  57         return undef if ($name =~ /^G[1-4]\.[1-5]/);
  58         $name =~ s/🆕//;
  59         $name =~ s/\(.*\)//g;
  60         $name =~ s/\[.*\]//g;
  61         $name =~ s/ - .*//;
  62         $name =~ s/G\d\.\d?\??//;
  63         $name =~ s/\?//g;
  64         $name =~ s/\s*$//;
  65         $name =~ s/^\s*//;
  66         return $name;
  67 }
  68
  69 sub matches_name {
  70         my ($slack_name, $spreadsheet_name) = @_;
  71         if (lc($slack_name) eq lc($spreadsheet_name)) {
  72                 return 1;
  73         }
  74
  75         my @ap = split /\s+/, $slack_name;
  76         my @bp = split /\s+/, $spreadsheet_name;
  77         if (scalar @ap >= 2 && scalar @bp >= 2 && lc($ap[0]) eq lc($bp[0])) {
  78                 # First name matches, try to match some surname
  79                 my $found = 0;
  80                 for my $ai (1..$#ap) {
  81                         for my $bi (1..$#bp) {
  82                                 $found = 1 if (lc($ap[$ai]) eq lc($bp[$bi]));
  83                         }
  84                 }
  85                 if ($found) {
  86                         skv_log("Fuzzy-matchet $slack_name -> $spreadsheet_name.");
  87                         return 1;
  88                 }
  89         }
  90
  91         return 0;
  92 }
  93
  94 sub format_cell_names_for_seen {
  95         my $seen = shift;
  96         my @cells = map { chr(ord('A') + $_->[2]) . $_->[1] } @$seen;
  97         return join(', ', @cells);
  98 }
  99
 100 sub skv_log {
 101         my $msg = shift;
 102         print STDERR "$msg\n";
 103         push @log, $msg;
 104 }
 105
 106 sub serialize_skv_log_to_sheet {
 107         return {
 108                 updateCells => {
 109                         rows => [{
 110                                 values => [{
 111                                         userEnteredValue => { stringValue => join("\n", @log) }
 112                                 }]
 113                         }],
 114                         fields => 'userEnteredValue.stringValue',
 115                         range => {
 116                                 sheetId => $config::log_tab_id,
 117                                 startRowIndex => 0,
 118                                 endRowIndex => 1,
 119                                 startColumnIndex => 0,
 120                                 endColumnIndex => 1
 121                         }
 122                 }
 123         };
 124 }
 125
 126 sub sheet_batch_update {
 127         my ($ua, $token, @requests) = @_;
 128         my $update = {
 129                 requests => \@requests
 130         };
 131         my $response = $ua->post(
 132                 'https://sheets.googleapis.com/v4/spreadsheets/' . $config::sheet_id . ':batchUpdate?key=' . $config::gsheets_api_key,
 133                 Content => JSON::XS::encode_json($update),
 134                 Content_type => 'application/json;charset=UTF-8',
 135                 Authorization => 'Bearer ' . $token
 136         );
 137         die $response->decoded_content if !$response->is_success;
 138 }
 139
 140 sub get_spreadsheet_with_title {
 141         my ($ua, $token, $wanted_sheet_title) = @_;
 142
 143         # See if we have any spreadsheets that match this title.
 144         my $response = $ua->get('https://sheets.googleapis.com/v4/spreadsheets/' . $config::sheet_id . '?key=' . $config::gsheets_api_key . '&fields=sheets/properties',
 145                 Authorization => 'Bearer ' . $token
 146         );
 147         my $sheets_json = JSON::XS::decode_json($response->decoded_content);
 148         my ($tab_name, $tab_id);
 149         for my $sheet (@{$sheets_json->{'sheets'}}) {
 150                 my $title = $sheet->{'properties'}{'title'};
 151                 my $sheet_id = $sheet->{'properties'}{'sheetId'};
 152                 if ($title =~ /\Q$wanted_sheet_title\E/) {
 153                         # skv_log("Synkroniserer ($config::invitation_channel, $invitation_ts) mot arket “$title” (fane-ID $sheet_id).");
 154                         return ($title, $sheet_id);
 155                 }
 156         }
 157         return (undef, undef);
 158 }
 159
 160 skv_log("Siste sync startet: " . POSIX::ctime(time));
 161
 162 # Initialize the handles we need for communication.
 163 my $dbh = DBI->connect("dbi:Pg:dbname=$config::dbname;host=127.0.0.1", $config::dbuser, $config::dbpass, {RaiseError => 1})
 164         or die "Could not connect to Postgres: " . DBI->errstr;
 165 my $ua = LWP::UserAgent->new('SKVidarLang/1.0');
 166 my $token = get_oauth_bearer_token($ua);
 167
 168 # Find the newest message, and what it is linked to.
 169 # TODO: Support more than one, and test better for errors here.
 170 my $q = $dbh->prepare('select * from message_sheet_link where channel=? order by ts desc limit 1');
 171 $q->execute($config::invitation_channel);
 172 my $linkref = $q->fetchrow_hashref;
 173 my $invitation_ts = $linkref->{'ts'};
 174 my $wanted_sheet_title = $linkref->{'sheet_title'};
 175 die "Could not get newest sheet title" if (!defined($wanted_sheet_title));
 176
 177 my ($tab_name, $tab_id) = get_spreadsheet_with_title($ua, $token, $wanted_sheet_title);
 178 if (!defined($tab_name)) {
 179         skv_log("Fant ikke noen fane med “$wanted_sheet_title” i navnet; kan ikke synkronisere.\n");
 180         sheet_batch_update($ua, $token, [ serialize_skv_log_to_sheet() ]);
 181         die;
 182 }
 183
 184 # Find everyone who are marked as attending on Slack (via reactions).
 185 $q = $dbh->prepare('SELECT DISTINCT userid FROM current_reactions WHERE channel=? AND ts=? AND reaction IN (\'heart\', \'open_mouth\')');
 186 $q->execute($config::invitation_channel, $invitation_ts);
 187 my @attending_userids = ();
 188 while (my $ref = $q->fetchrow_hashref) {
 189         push @attending_userids, $ref->{'userid'};
 190 }
 191
 192 # Get the list of all people in the sheet (we're going to need them soon anyway).
 193 my $response = $ua->get('https://sheets.googleapis.com/v4/spreadsheets/' . $config::sheet_id . '?key=' . $config::gsheets_api_key . '&ranges=' . $tab_name . '!A9:Z5000&fields=sheets/data/rowData/values/userEnteredValue',
 194         Authorization => 'Bearer ' . $token
 195 );
 196 my $main_sheet_json = JSON::XS::decode_json($response->decoded_content);
 197
 198 # Duplicate detection
 199 my %seen_names = ();
 200 {
 201         my $main_sheet_rows = $main_sheet_json->{'sheets'}[0]{'data'}[0]{'rowData'};
 202         my $rowno = 9;
 203         for my $row (@$main_sheet_rows) {
 204                 my $colno = 0;
 205                 for my $val (@{$row->{'values'}}) {
 206                         my $name = get_spreadsheet_name($val);
 207                         if (defined($name)) {
 208                                 push @{$seen_names{lc $name}}, [$name, $rowno, $colno];
 209                         }
 210                         ++$colno;
 211                 }
 212                 ++$rowno;
 213         }
 214         for my $name (sort keys %seen_names) {
 215                 my $seen = $seen_names{$name};
 216                 if (scalar @$seen >= 2) {
 217                         my $exemplar = $seen->[0][0];
 218                         skv_log("Duplikat: $exemplar (" . format_cell_names_for_seen($seen) . ")");
 219                 }
 220         }
 221 }
 222
 223 # Get our existing Slack->name mapping, from the sheets.
 224 my %slack_userid_to_real_name = ();
 225 my %slack_userid_to_slack_name = ();
 226 my %slack_userid_to_row = ();
 227 my %real_name_to_slack_userid = ();
 228 $response = $ua->get('https://sheets.googleapis.com/v4/spreadsheets/' . $config::sheet_id . '?key=' . $config::gsheets_api_key . '&ranges=Slack-mapping!A5:C5000&fields=sheets/data/rowData/values/userEnteredValue',
 229         Authorization => 'Bearer ' . $token
 230 );
 231 my $mapping_sheet_json = JSON::XS::decode_json($response->decoded_content);
 232 my $mapping_sheet_rows = $mapping_sheet_json->{'sheets'}[0]{'data'}[0]{'rowData'};
 233 my $cur_row = 5;
 234 for my $row (@$mapping_sheet_rows) {
 235         my $slack_id = $row->{'values'}[0]{'userEnteredValue'}{'stringValue'};
 236         my $slack_name = $row->{'values'}[1]{'userEnteredValue'}{'stringValue'};
 237         my $real_name = get_spreadsheet_name($row->{'values'}[2]);  # TODO support more
 238         $slack_userid_to_row{$slack_id} = $cur_row++;
 239         next if (!defined($slack_name));
 240         $slack_userid_to_slack_name{$slack_id} = $slack_name;
 241         next if (!defined($real_name));
 242         $slack_userid_to_real_name{$slack_id} = $real_name;
 243         $real_name_to_slack_userid{$real_name} = $slack_id;
 244 }
 245
 246 # See which ones we don't have a mapping for, and look them up in Slack.
 247 # TODO: Use an append call instead of $cur_row?
 248 my @slack_mapping_updates = ();
 249 for my $userid (@attending_userids) {
 250         next if (exists($slack_userid_to_real_name{$userid}));
 251
 252         # Make sure they have a row in the spreadsheet.
 253         my $write_row;
 254         if (exists($slack_userid_to_row{$userid})) {
 255                 $write_row = $slack_userid_to_row{$userid};
 256         } else {
 257                 $write_row = $cur_row++;
 258                 $slack_userid_to_row{$userid} = $write_row;
 259                 push @slack_mapping_updates, {
 260                         range => "Slack-mapping!A$write_row:A$write_row",
 261                         values => [ [ $userid ]]
 262                 };
 263         }
 264
 265         # Fetch their Slack name if we don't already have it.
 266         my $slack_name;
 267         if (exists($slack_userid_to_slack_name{$userid})) {
 268                 $slack_name = $slack_userid_to_slack_name{$userid};
 269         } else {
 270                 $slack_userid_to_slack_name{$userid} = $slack_name;
 271                 $slack_name = get_slack_name($ua, $userid);
 272                 push @slack_mapping_updates, {
 273                         range => "Slack-mapping!B$write_row:B$write_row",
 274                         values => [ [ $slack_name ]]
 275                 };
 276                 $slack_userid_to_slack_name{$userid} = $slack_name;
 277         }
 278
 279         if (exists($seen_names{lc $slack_name})) {
 280                 # The name exists exactly, once or more, so it's a direct match and we ignore any fuzz.
 281                 $slack_userid_to_real_name{$userid} = $slack_name;
 282                 push @slack_mapping_updates, {
 283                         range => "Slack-mapping!C$write_row:C$write_row",
 284                         values => [ [ $slack_name ]]
 285                 };
 286         } else {
 287                 # Do a search through all the available names in the sheet to find an obvious(ish) match.
 288                 my @candidates = ();
 289                 my $main_sheet_rows = $main_sheet_json->{'sheets'}[0]{'data'}[0]{'rowData'};
 290                 for my $row (@$main_sheet_rows) {
 291                         for my $val (@{$row->{'values'}}) {
 292                                 my $name = get_spreadsheet_name($val);
 293                                 if (defined($name) && matches_name($slack_name, $name)) {
 294                                         push @candidates, $name;
 295                                 }
 296                         }
 297                 }
 298                 if ($#candidates == -1) {
 299                         skv_log("$slack_name ($userid) er påmeldt på Slack, men fant ikke et regneark-navn for dem.");
 300                 } elsif ($#candidates == 0) {
 301                         my $name = $candidates[0];
 302                         $slack_userid_to_real_name{$userid} = $name;
 303                         push @slack_mapping_updates, {
 304                                 range => "Slack-mapping!C$write_row:C$write_row",
 305                                 values => [ [ $name ]]
 306                         };
 307                 } else {
 308                         skv_log("$slack_name ($userid) er påmeldt på Slack, men hadde flere fuzzy-matcher; vet ikke hvilket regneark-navn som skal brukes.");
 309                 }
 310         }
 311 }
 312 my $update = {
 313         valueInputOption => 'USER_ENTERED',
 314         data => \@slack_mapping_updates
 315 };
 316 $response = $ua->post(
 317         'https://sheets.googleapis.com/v4/spreadsheets/' . $config::sheet_id . '/values:batchUpdate?key=' . $config::gsheets_api_key,
 318         Content => JSON::XS::encode_json($update),
 319         Content_type => 'application/json;charset=UTF-8',
 320         Authorization => 'Bearer ' . $token
 321 );
 322 die $response->decoded_content if (!$response->is_success);
 323
 324 # Find the list of names to mark yellow.
 325 my %want_names = ();
 326 my $main_sheet_rows = $main_sheet_json->{'sheets'}[0]{'data'}[0]{'rowData'};
 327 for my $userid (@attending_userids) {
 328         next if (!exists($slack_userid_to_real_name{$userid}));
 329         my $slack_name = $slack_userid_to_slack_name{$userid};
 330         my $real_name = $slack_userid_to_real_name{$userid};
 331
 332         # See if we can find them in the spreadsheet.
 333         if (!exists($seen_names{lc $real_name})) {
 334                 skv_log("$slack_name ($userid) er påmeldt på Slack, og er mappet til $real_name, men var ikke i noen gruppe.");
 335         } else {
 336                 my $seen = $seen_names{lc $real_name};
 337                 if (scalar @$seen >= 2) {
 338                         skv_log("$slack_name ($userid) er påmeldt på Slack, men står flere steder (se over); vet ikke hvilken celle som skal brukes.");
 339                 } else {
 340                         $want_names{$seen->[0][0]} = 1;
 341                 }
 342         }
 343 }
 344
 345 # Find the list of names we already marked yellow.
 346 my %have_names = ();
 347 $dbh->{AutoCommit} = 0;
 348 $dbh->do('SET TRANSACTION ISOLATION LEVEL SERIALIZABLE');
 349 $q = $dbh->prepare('SELECT name FROM applied WHERE channel=? AND ts=?');
 350 $q->execute($config::invitation_channel, $invitation_ts);
 351 while (my $ref = $q->fetchrow_hashref) {
 352         $have_names{$ref->{'name'}} = 1;
 353 }
 354
 355 # Find the diff between the two.
 356 my @diffs = ();
 357 for my $real_name (keys %want_names) {
 358         next if (exists($have_names{$real_name}));
 359         skv_log("Markerer at $real_name skal på trening.");
 360         push @diffs, [
 361                 $real_name,
 362                 {
 363                         backgroundColor => {
 364                                 red => 1,
 365                                 green => 1,
 366                                 blue => 0,
 367                                 alpha => 1
 368                         }
 369                 }
 370         ];
 371         $dbh->do('INSERT INTO applied (channel, ts, name) VALUES (?, ?, ?)', undef,
 372                 $config::invitation_channel, $invitation_ts, $real_name);
 373 }
 374 for my $real_name (keys %have_names) {
 375         next if (exists($want_names{$real_name}));
 376         skv_log("Fjerner at $real_name skal på trening.");
 377         push @diffs, [
 378                 $real_name,
 379                 {
 380                         backgroundColor => {
 381                                 red => 1,
 382                                 green => 1,
 383                                 blue => 1,
 384                                 alpha => 0
 385                         }
 386                 }
 387         ];
 388         $dbh->do('DELETE FROM applied WHERE channel=? AND ts=? AND name=?', undef,
 389                 $config::invitation_channel, $invitation_ts, $real_name);
 390 }
 391
 392 my @yellow_updates = ();
 393 if (scalar @diffs > 0) {
 394         # Now fill in the actual stuff.
 395         for my $diff (@diffs) {
 396                 my $real_name = $diff->[0];
 397
 398                 # See if we can find them in the spreadsheet.
 399                 # FIXME use seen_names
 400                 my $rowno = 8;  # zero-indexed
 401                 my $found = 0;
 402                 for my $row (@$main_sheet_rows) {
 403                         my $colno = 0;
 404                         for my $val (@{$row->{'values'}}) {
 405                                 my $name = get_spreadsheet_name($val);
 406                                 if (defined($name) && $real_name eq $name) {
 407                                         push @yellow_updates, {
 408                                                 updateCells => {
 409                                                         rows => [{
 410                                                                 values => [{
 411                                                                         userEnteredFormat => $diff->[1]
 412                                                                 }]
 413                                                         }],
 414                                                         fields => 'userEnteredFormat.backgroundColor',
 415                                                         range => {
 416                                                                 sheetId => $tab_id,
 417                                                                 startRowIndex => $rowno,
 418                                                                 endRowIndex => $rowno + 1,
 419                                                                 startColumnIndex => $colno,
 420                                                                 endColumnIndex => $colno + 1
 421                                                         }
 422                                                 }
 423                                         };
 424                                         $found = 1;
 425                                 }
 426                                 ++$colno;
 427                         }
 428                         ++$rowno;
 429                 }
 430
 431                 if ($found) {
 432                 } else {
 433                         skv_log("Ønsket å fjerne at $real_name skulle på trening, men de var ikke i regnearket lenger.");
 434                 }
 435         }
 436 }
 437
 438 # Add the reaction log. (This only takes into account the last change
 439 # for each user; earlier ones are irrelevant and don't count. But it
 440 # doesn't deduplicate across reactions. Meh.)
 441 $q = $dbh->prepare('select userid,event_type,reaction,to_char(event_ts,\'YYYY-mm-dd HH24:MI\') as event_ts from ( select distinct on (channel,ts,userid,reaction) userid,event_type,reaction,timestamptz \'1970-01-01 utc\' + event_ts::float * interval \'1 second\' as event_ts from reaction_log where channel=? and ts=? and reaction in (\'heart\',\'open_mouth\') order by channel,ts,userid,reaction,event_ts desc ) t1 where event_ts > current_timestamp - interval \'8 hours\' order by event_ts desc limit 50');
 442 $q->execute($config::invitation_channel, $invitation_ts);
 443 my @recent_changes = ();
 444 while (my $ref = $q->fetchrow_hashref) {
 445         my $msg = $ref->{'event_ts'};
 446         if ($ref->{'event_type'} eq 'reaction_added') {
 447                 $msg .= ' +';
 448         } else {
 449                 $msg .= ' –';
 450         }
 451         if ($ref->{'reaction'} eq 'open_mouth') {
 452                 $msg .= '😮';
 453         } else {
 454                 $msg .= '❤️';
 455         }
 456         $msg .= ' ';
 457         if (exists($slack_userid_to_real_name{$ref->{'userid'}})) {
 458                 $msg .= $slack_userid_to_real_name{$ref->{'userid'}};
 459         } elsif (exists($slack_userid_to_slack_name{$ref->{'userid'}})) {
 460                 $msg .= $slack_userid_to_slack_name{$ref->{'userid'}} . ' (fant ikke regneark-navn)';
 461         } else {
 462                 # Should only happen if we didn't see the initial reaction_add, only reaction_remove.
 463                 $msg .= $ref->{'userid'} . ' (fant ikke Slack-navn)';
 464         }
 465         push @recent_changes, { values => [{ userEnteredValue => { stringValue => $msg } }] };
 466 }
 467 while (scalar @recent_changes < 50) {
 468         push @recent_changes, { values => [{ userEnteredValue => { stringValue => '' } }] };
 469 }
 470 push @yellow_updates, {
 471         updateCells => {
 472                 rows => \@recent_changes,
 473                 fields => 'userEnteredValue.stringValue',
 474                 range => {
 475                         sheetId => $config::log_tab_id,
 476                         startRowIndex => 4,
 477                         endRowIndex => 4 + scalar @recent_changes,
 478                         startColumnIndex => 0,
 479                         endColumnIndex => 1
 480                 }
 481         }
 482 };
 483
 484 # Push the final set of updates (including the log).
 485 skv_log("Ferdig.");
 486 push @yellow_updates, serialize_skv_log_to_sheet();
 487 sheet_batch_update($ua, $token, \@yellow_updates);
 488 $dbh->commit;