git.sesse.net Git - nageru/blob - meson.build

   1 project('nageru', 'cpp', default_options: ['buildtype=debugoptimized'], version: '1.8.0')
   2
   3 cxx = meson.get_compiler('cpp')
   4 qt5 = import('qt5')
   5 protoc = find_program('protoc')
   6
   7 embedded_bmusb = get_option('embedded_bmusb')
   8
   9 alsadep = dependency('alsa')
  10 bmusbdep = dependency('bmusb', required: not embedded_bmusb)
  11 dldep = cxx.find_library('dl')
  12 epoxydep = dependency('epoxy')
  13 libavcodecdep = dependency('libavcodec')
  14 libavformatdep = dependency('libavformat')
  15 libswresampledep = dependency('libswresample')
  16 libavutildep = dependency('libavutil')
  17 libjpegdep = dependency('libjpeg')
  18 libswscaledep = dependency('libswscale')
  19 libusbdep = dependency('libusb-1.0')
  20 luajitdep = dependency('luajit')
  21 movitdep = dependency('movit')
  22 protobufdep = dependency('protobuf')
  23 qcustomplotdep = cxx.find_library('qcustomplot')
  24 qt5deps = dependency('qt5', modules: ['Core', 'Gui', 'Widgets', 'OpenGLExtensions', 'OpenGL', 'Network'])
  25 sdl2_imagedep = dependency('SDL2_image')
  26 sdl2dep = dependency('sdl2')
  27 sqlite3dep = dependency('sqlite3')
  28 threaddep = dependency('threads')
  29 vadrmdep = dependency('libva-drm')
  30 vax11dep = dependency('libva-x11')
  31 x11dep = dependency('x11')
  32 x264dep = dependency('x264')
  33 zitaresamplerdep = cxx.find_library('zita-resampler')
  34
  35 # Use lld if we can; it links a lot faster than ld.bfd or gold.
  36 code = '''#include <stdio.h>
  37 int main() { printf("Hello, world!\n"); return 0; }
  38 '''
  39 if cxx.links(code, args: '-fuse-ld=lld', name: 'check for LLD')
  40         add_project_link_arguments('-fuse-ld=lld', language: 'cpp')
  41 endif
  42
  43 # Add the right MOVIT_SHADER_DIR definition.
  44 r = run_command('pkg-config', '--variable=shaderdir', 'movit')
  45 if r.returncode() != 0
  46         error('Movit pkg-config installation is broken.')
  47 endif
  48 add_project_arguments('-DMOVIT_SHADER_DIR="' + r.stdout().strip() + '"', language: 'cpp')
  49
  50 # Make the Nageru version available as a #define.
  51 add_project_arguments('-DNAGERU_VERSION="' + meson.project_version() + '"', language: 'cpp')
  52
  53 # DeckLink has these issues, and we include it from various places.
  54 if cxx.has_argument('-Wno-non-virtual-dtor')
  55         add_project_arguments('-Wno-non-virtual-dtor', language: 'cpp')
  56 endif
  57
  58 # This needs to be done before declaring any build targets.
  59 if get_option('cef_dir') != ''
  60         add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  61 endif
  62
  63 top_include = include_directories('.')
  64
  65 subdir('shared')
  66
  67 # Nageru. (Not a subdir() because we don't want the output in nageru/nageru.)
  68
  69 nageru_srcs = []
  70 nageru_deps = [shareddep, qt5deps, libjpegdep, movitdep, protobufdep,
  71         vax11dep, vadrmdep, x11dep, libavformatdep, libswresampledep, libavcodecdep, libavutildep,
  72         libswscaledep, libusbdep, luajitdep, dldep, x264dep, alsadep, zitaresamplerdep,
  73         qcustomplotdep, threaddep]
  74 nageru_include_dirs = [include_directories('nageru')]
  75 nageru_link_with = []
  76 nageru_build_rpath = ''
  77 nageru_install_rpath = ''
  78
  79 kaeru_link_with = []
  80 kaeru_extra_deps = []
  81
  82 # CEF.
  83 exe_dir = join_paths(get_option('prefix'), 'lib/nageru')
  84 cef_dir = get_option('cef_dir')
  85 cef_build_type = get_option('cef_build_type')
  86 have_cef = (cef_dir != '')
  87 if have_cef
  88         # This is done in the top-level file; just kept here for reference.
  89         # add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  90
  91         system_cef = (cef_build_type == 'system')
  92         if system_cef
  93                 cef_lib_dir = cef_dir
  94                 cef_resource_dir = '/usr/share/cef/Resources'
  95         else
  96                 cef_lib_dir = join_paths(cef_dir, cef_build_type)
  97                 cef_resource_dir = join_paths(cef_dir, 'Resources')
  98
  99                 nageru_include_dirs += include_directories(cef_dir)
 100                 nageru_include_dirs += include_directories(join_paths(cef_dir, 'include'))
 101                 nageru_build_rpath = cef_lib_dir
 102                 nageru_install_rpath = '$ORIGIN/'
 103         endif
 104
 105         cefdep = cxx.find_library('cef')
 106         nageru_deps += cefdep
 107
 108         # CEF wrapper library; not built as part of the CEF binary distribution,
 109         # but should be if CEF is installed as a system library.
 110         if system_cef
 111                 cefdlldep = cxx.find_library('cef_dll_wrapper')
 112                 nageru_deps += cefdlldep
 113         else
 114                 cmake = find_program('cmake')
 115                 cef_compile_script = find_program('scripts/compile_cef_dll_wrapper.sh')
 116
 117                 cef_dll_target = custom_target('libcef_dll_wrapper',
 118                         input: join_paths(cef_dir, 'libcef_dll/CMakeLists.txt'),
 119                         output: ['libcef_dll_wrapper.a', 'cef-stamp'],
 120                         command: [cef_compile_script, '@BUILD_DIR@', cef_dir, cmake, '@OUTPUT@'])
 121
 122                 # Putting the .a in sources seemingly hits a bug where the .a files get sorted
 123                 # in the wrong order. This is a workaround; see
 124                 # https://github.com/mesonbuild/meson/issues/3613#issuecomment-408276296 .
 125                 cefdlldep = declare_dependency(sources: cef_dll_target[1], link_args: cef_dll_target.full_path())
 126                 nageru_deps += cefdlldep
 127         endif
 128
 129         cef_libs = ['libEGL.so', 'libGLESv2.so', 'natives_blob.bin', 'snapshot_blob.bin', 'v8_context_snapshot.bin']
 130         cef_resources = ['cef.pak', 'cef_100_percent.pak', 'cef_200_percent.pak', 'cef_extensions.pak', 'devtools_resources.pak']
 131         if not get_option('cef_no_icudtl')
 132                 cef_resources += ['icudtl.dat']
 133         endif
 134         if cef_build_type != 'system'
 135                 cef_libs += ['libcef.so']
 136         endif
 137
 138         # Symlink the files into the build directory, so that running nageru without ninja install works.
 139         run_command('mkdir', join_paths(meson.current_build_dir(), 'locales/'))
 140         foreach file : cef_libs
 141                 run_command('ln', '-s', join_paths(cef_lib_dir, file), meson.current_build_dir())
 142                 install_data(join_paths(cef_lib_dir, file), install_dir: exe_dir)
 143         endforeach
 144         foreach file : cef_resources
 145                 run_command('ln', '-s', join_paths(cef_resource_dir, file), meson.current_build_dir())
 146                 install_data(join_paths(cef_resource_dir, file), install_dir: exe_dir)
 147         endforeach
 148         run_command('ln', '-s', join_paths(cef_resource_dir, 'locales/en-US.pak'), join_paths(meson.current_build_dir(), 'locales/'))
 149         install_data(join_paths(cef_resource_dir, 'locales/en-US.pak'), install_dir: join_paths(exe_dir, 'locales'))
 150 endif
 151
 152 # bmusb.
 153 if embedded_bmusb
 154         bmusb_dir = include_directories('bmusb')
 155         nageru_include_dirs += bmusb_dir
 156
 157         bmusb = static_library('bmusb', 'bmusb/bmusb.cpp', 'bmusb/fake_capture.cpp',
 158                 dependencies: [libusbdep],
 159                 include_directories: [bmusb_dir])
 160         nageru_link_with += bmusb
 161         kaeru_link_with += bmusb
 162 else
 163         nageru_deps += bmusbdep
 164         kaeru_extra_deps += bmusbdep
 165 endif
 166
 167 # Protobuf compilation.
 168 gen = generator(protoc, \
 169         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 170         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/nageru', '--cpp_out=@BUILD_DIR@', '@INPUT@'])
 171 proto_generated = gen.process(['nageru/state.proto', 'nageru/midi_mapping.proto', 'nageru/json.proto'])
 172 protobuf_lib = static_library('protobufs', proto_generated, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 173 protobuf_hdrs = declare_dependency(sources: proto_generated)
 174 nageru_link_with += protobuf_lib
 175
 176 # Preprocess Qt as needed.
 177 qt_files = qt5.preprocess(
 178         moc_headers: ['nageru/analyzer.h', 'nageru/clickable_label.h', 'nageru/compression_reduction_meter.h', 'nageru/correlation_meter.h',
 179                 'nageru/ellipsis_label.h', 'nageru/glwidget.h', 'nageru/input_mapping_dialog.h', 'nageru/lrameter.h', 'nageru/mainwindow.h', 'nageru/midi_mapping_dialog.h',
 180                 'nageru/nonlinear_fader.h', 'nageru/vumeter.h'],
 181         ui_files: ['nageru/analyzer.ui', 'nageru/audio_expanded_view.ui', 'nageru/audio_miniview.ui', 'nageru/display.ui',
 182                 'nageru/input_mapping.ui', 'nageru/mainwindow.ui', 'nageru/midi_mapping.ui'],
 183         dependencies: qt5deps)
 184
 185 # Qt objects.
 186 nageru_srcs += ['nageru/glwidget.cpp', 'nageru/mainwindow.cpp', 'nageru/vumeter.cpp', 'nageru/lrameter.cpp', 'nageru/compression_reduction_meter.cpp',
 187         'nageru/correlation_meter.cpp', 'nageru/analyzer.cpp', 'nageru/input_mapping_dialog.cpp', 'nageru/midi_mapping_dialog.cpp',
 188         'nageru/nonlinear_fader.cpp', 'nageru/context_menus.cpp', 'nageru/vu_common.cpp', 'nageru/piecewise_interpolator.cpp', 'nageru/midi_mapper.cpp']
 189
 190 # Auxiliary objects used for nearly everything.
 191 aux_srcs = ['nageru/flags.cpp']
 192 aux = static_library('aux', aux_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 193 nageru_link_with += aux
 194
 195 # Audio objects.
 196 audio_mixer_srcs = ['nageru/audio_mixer.cpp', 'nageru/alsa_input.cpp', 'nageru/alsa_pool.cpp', 'nageru/ebu_r128_proc.cc', 'nageru/stereocompressor.cpp',
 197         'nageru/resampling_queue.cpp', 'nageru/flags.cpp', 'nageru/correlation_measurer.cpp', 'nageru/filter.cpp', 'nageru/input_mapping.cpp']
 198 audio = static_library('audio', audio_mixer_srcs, dependencies: [nageru_deps, protobuf_hdrs], include_directories: nageru_include_dirs)
 199 nageru_link_with += audio
 200
 201 # Mixer objects.
 202 nageru_srcs += ['nageru/chroma_subsampler.cpp', 'nageru/v210_converter.cpp', 'nageru/mixer.cpp', 'nageru/pbo_frame_allocator.cpp',
 203         'nageru/theme.cpp', 'nageru/image_input.cpp', 'nageru/alsa_output.cpp',
 204         'nageru/timecode_renderer.cpp', 'nageru/tweaked_inputs.cpp', 'nageru/mjpeg_encoder.cpp']
 205
 206 # Streaming and encoding objects (largely the set that is shared between Nageru and Kaeru).
 207 stream_srcs = ['nageru/quicksync_encoder.cpp', 'nageru/x264_encoder.cpp', 'nageru/x264_dynamic.cpp', 'nageru/x264_speed_control.cpp', 'nageru/video_encoder.cpp',
 208         'nageru/audio_encoder.cpp', 'nageru/ffmpeg_util.cpp', 'nageru/ffmpeg_capture.cpp',
 209         'nageru/print_latency.cpp', 'nageru/basic_stats.cpp', 'nageru/ref_counted_frame.cpp']
 210 stream = static_library('stream', stream_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 211 nageru_link_with += stream
 212
 213 # DeckLink.
 214 nageru_srcs += ['nageru/decklink_capture.cpp', 'nageru/decklink_util.cpp', 'nageru/decklink_output.cpp',
 215         'nageru/decklink/DeckLinkAPIDispatch.cpp']
 216 decklink_dir = include_directories('nageru/decklink')
 217 nageru_include_dirs += decklink_dir
 218
 219 # CEF input.
 220 if have_cef
 221         nageru_srcs += ['nageru/nageru_cef_app.cpp', 'nageru/cef_capture.cpp']
 222 endif
 223
 224 nageru_srcs += qt_files
 225 nageru_srcs += proto_generated
 226
 227 # Shaders needed at runtime.
 228 shaders = ['nageru/cbcr_subsample.vert', 'nageru/cbcr_subsample.frag', 'nageru/uyvy_subsample.vert', 'nageru/uyvy_subsample.frag', 'nageru/v210_subsample.comp', 'nageru/timecode.vert', 'nageru/timecode.frag', 'nageru/timecode_10bit.frag']
 229 foreach shader : shaders
 230         run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 231 endforeach
 232
 233 nageru_shader_srcs = bin2h_gen.process(shaders)
 234 nageru_srcs += nageru_shader_srcs
 235
 236 # Everything except main.cpp. (We do this because if you specify a .cpp file in
 237 # both Nageru and Kaeru, it gets compiled twice. In the older Makefiles, Kaeru
 238 # depended on a smaller set of objects.)
 239 core = static_library('core', nageru_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 240 nageru_link_with += core
 241
 242 # Nageru executable; it goes into /usr/lib/nageru since CEF files go there, too
 243 # (we can't put them straight into /usr/bin).
 244 executable('nageru', 'nageru/main.cpp',
 245         dependencies: nageru_deps,
 246         include_directories: nageru_include_dirs,
 247         link_with: nageru_link_with,
 248         build_rpath: nageru_build_rpath,
 249         install_rpath: nageru_install_rpath,
 250         install: true,
 251         install_dir: exe_dir
 252 )
 253 meson.add_install_script('nageru/scripts/setup_nageru_symlink.sh')
 254
 255 # Kaeru executable.
 256 executable('kaeru', 'nageru/kaeru.cpp',
 257         dependencies: [nageru_deps, kaeru_extra_deps],
 258         include_directories: nageru_include_dirs,
 259         link_with: [stream, aux, kaeru_link_with],
 260         install: true)
 261
 262 # Audio mixer microbenchmark.
 263 executable('benchmark_audio_mixer', 'nageru/benchmark_audio_mixer.cpp', dependencies: nageru_deps, include_directories: nageru_include_dirs, link_with: [audio, aux])
 264
 265 # These are needed for a default run.
 266 data_files = ['nageru/theme.lua', 'nageru/simple.lua', 'nageru/bg.jpeg', 'nageru/akai_midimix.midimapping']
 267 install_data(data_files, install_dir: join_paths(get_option('prefix'), 'share/nageru'))
 268 foreach file : data_files
 269         run_command('ln', '-s', join_paths(meson.current_source_dir(), file), meson.current_build_dir())
 270 endforeach
 271
 272 # Futatabi. (Not a subdir() because we don't want the output in nageru/nageru.)
 273
 274 # Protobuf compilation.
 275 gen = generator(protoc, \
 276         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 277         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/futatabi', '--cpp_out=@BUILD_DIR@', '@INPUT@'])
 278 proto_generated = gen.process('futatabi/state.proto', 'futatabi/frame.proto')
 279
 280 # Preprocess Qt as needed.
 281 moc_files = qt5.preprocess(
 282         moc_headers: ['futatabi/mainwindow.h', 'futatabi/jpeg_frame_view.h', 'futatabi/clip_list.h'],
 283         ui_files: ['futatabi/mainwindow.ui'],
 284         dependencies: qt5deps)
 285
 286 # Flow objects.
 287 futatabi_srcs = ['futatabi/flow.cpp', 'futatabi/gpu_timers.cpp']
 288
 289 # All the other files.
 290 futatabi_srcs += ['futatabi/main.cpp', 'futatabi/player.cpp', 'futatabi/video_stream.cpp', 'futatabi/chroma_subsampler.cpp']
 291 futatabi_srcs += ['futatabi/vaapi_jpeg_decoder.cpp', 'futatabi/db.cpp', 'futatabi/ycbcr_converter.cpp', 'futatabi/flags.cpp']
 292 futatabi_srcs += ['futatabi/mainwindow.cpp', 'futatabi/jpeg_frame_view.cpp', 'futatabi/clip_list.cpp', 'futatabi/frame_on_disk.cpp']
 293 futatabi_srcs += ['futatabi/export.cpp']
 294 futatabi_srcs += moc_files
 295 futatabi_srcs += proto_generated
 296
 297 # Shaders needed at runtime.
 298 shaders = ['futatabi/chroma_subsample.vert', 'futatabi/densify.vert', 'futatabi/equations.vert', 'futatabi/hole_fill.vert', 'futatabi/motion_search.vert', 'futatabi/sor.vert', 'futatabi/splat.vert', 'futatabi/vs.vert']
 299 shaders += ['futatabi/add_base_flow.frag', 'futatabi/blend.frag', 'futatabi/chroma_subsample.frag', 'futatabi/densify.frag', 'futatabi/derivatives.frag', 'futatabi/diffusivity.frag',
 300         'futatabi/equations.frag', 'futatabi/gray.frag', 'futatabi/hole_blend.frag', 'futatabi/hole_fill.frag', 'futatabi/motion_search.frag', 'futatabi/prewarp.frag', 'futatabi/resize_flow.frag',
 301         'futatabi/sobel.frag', 'futatabi/sor.frag', 'futatabi/splat.frag']
 302
 303 foreach shader : shaders
 304         run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 305 endforeach
 306
 307 futatabi_shader_srcs = bin2h_gen.process(shaders)
 308 futatabi_srcs += futatabi_shader_srcs
 309
 310 executable('futatabi', futatabi_srcs,
 311         dependencies: [shareddep, qt5deps, libjpegdep, movitdep, libmicrohttpddep, protobufdep, sqlite3dep, vax11dep, vadrmdep, x11dep, libavformatdep, libavcodecdep, libavutildep, libswscaledep],
 312         link_with: shared,
 313         include_directories: [include_directories('futatabi')],
 314         install: true)
 315
 316 # Test binaries for the optical flow code.
 317 executable('flow', 'futatabi/flow_main.cpp', 'futatabi/flow.cpp', 'futatabi/gpu_timers.cpp', futatabi_shader_srcs, dependencies: [shareddep, epoxydep, sdl2dep, sdl2_imagedep])
 318 executable('eval', 'futatabi/eval.cpp', 'futatabi/util.cpp')
 319 executable('vis', 'futatabi/vis.cpp', 'futatabi/util.cpp')