git.sesse.net Git - nageru/blob - meson.build

   1 project('nageru', 'cpp', default_options: ['buildtype=debugoptimized'], version: '2.1.1-pre')
   2
   3 cxx = meson.get_compiler('cpp')
   4 qt5 = import('qt5')
   5 protoc = find_program('protoc')
   6
   7 embedded_bmusb = get_option('embedded_bmusb')
   8
   9 alsadep = dependency('alsa')
  10 bmusbdep = dependency('bmusb', required: not embedded_bmusb)
  11 dldep = cxx.find_library('dl')
  12 eigendep = dependency('eigen3')
  13 epoxydep = dependency('epoxy')
  14 libavcodecdep = dependency('libavcodec')
  15 libavformatdep = dependency('libavformat')
  16 libswresampledep = dependency('libswresample')
  17 libavutildep = dependency('libavutil')
  18 libdrmdep = dependency('libdrm')
  19 libjpegdep = dependency('libjpeg')
  20 libswscaledep = dependency('libswscale')
  21 libusbdep = dependency('libusb-1.0')
  22 luajitdep = dependency('luajit')
  23 movitdep = dependency('movit')
  24 protobufdep = dependency('protobuf')
  25 qcustomplotdep = cxx.find_library('qcustomplot')
  26 qt5deps = dependency('qt5', modules: ['Core', 'Gui', 'Widgets', 'OpenGLExtensions', 'OpenGL', 'Network'])
  27 sdl2_imagedep = dependency('SDL2_image', required: false)
  28 sdl2dep = dependency('sdl2', required: false)
  29 srtdep = dependency('srt', required: false)
  30 svtav1dep = dependency('SvtAv1Enc', required: false, version: '>=1.0.0')
  31 sqlite3dep = dependency('sqlite3')
  32 threaddep = dependency('threads')
  33 vadrmdep = dependency('libva-drm')
  34 vax11dep = dependency('libva-x11')
  35 x11dep = dependency('x11')
  36 x264dep = dependency('x264')
  37 zitaresamplerdep = cxx.find_library('zita-resampler')
  38
  39 # Use lld if we can; it links a lot faster than ld.bfd or gold.
  40 code = '''#include <stdio.h>
  41 int main() { printf("Hello, world!\n"); return 0; }
  42 '''
  43 if cxx.links(code, args: '-fuse-ld=lld', name: 'check for LLD')
  44         add_project_link_arguments('-fuse-ld=lld', language: 'cpp')
  45 endif
  46
  47 # Add the right MOVIT_SHADER_DIR definition.
  48 movit_shader_dir = movitdep.get_pkgconfig_variable('shaderdir')
  49 add_project_arguments('-DMOVIT_SHADER_DIR="' + movit_shader_dir + '"', language: 'cpp')
  50
  51 # Make the Nageru version available as a #define.
  52 add_project_arguments('-DNAGERU_VERSION="' + meson.project_version() + '"', language: 'cpp')
  53
  54 # Make the prefix (e.g. /usr/local) available as a #define.
  55 add_project_arguments('-DPREFIX="' + get_option('prefix') + '"', language: 'cpp')
  56
  57 # This needs to be done before declaring any build targets.
  58 if get_option('cef_dir') != ''
  59         add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  60 endif
  61
  62 if srtdep.found()
  63         # NOTE: Seemingly there's no way to figure out if we have OpenSSL libsrt
  64         # or gnutls libsrt, so we cannot check license compatibility here.
  65         add_project_arguments('-DHAVE_SRT=1', language: 'cpp')
  66 endif
  67 if svtav1dep.found()
  68         add_project_arguments('-DHAVE_AV1=1', language: 'cpp')
  69 endif
  70
  71 top_include = include_directories('.')
  72
  73 subdir('shared')
  74
  75 # Nageru. (Not a subdir() because we don't want the output in nageru/nageru.)
  76
  77 nageru_srcs = []
  78 nageru_deps = [shareddep, qt5deps, libjpegdep, movitdep, protobufdep,
  79         vax11dep, vadrmdep, x11dep, libavformatdep, libswresampledep, libavcodecdep, libavutildep,
  80         libswscaledep, libusbdep, luajitdep, dldep, x264dep, svtav1dep, alsadep, zitaresamplerdep,
  81         qcustomplotdep, threaddep, eigendep, srtdep, libdrmdep]
  82 nageru_include_dirs = [include_directories('nageru')]
  83 nageru_link_with = []
  84 nageru_build_rpath = ''
  85 nageru_install_rpath = ''
  86
  87 kaeru_link_with = []
  88 kaeru_extra_deps = []
  89
  90 # CEF.
  91 exe_dir = join_paths(get_option('prefix'), 'lib/nageru')
  92 cef_dir = get_option('cef_dir')
  93 cef_build_type = get_option('cef_build_type')
  94 have_cef = (cef_dir != '')
  95 if have_cef
  96         # This is done in the top-level file; just kept here for reference.
  97         # add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  98
  99         system_cef = (cef_build_type == 'system')
 100         if system_cef
 101                 cef_lib_dir = cef_dir
 102                 cef_resource_dir = cef_dir
 103         else
 104                 cef_lib_dir = join_paths(cef_dir, cef_build_type)
 105                 cef_resource_dir = join_paths(cef_dir, 'Resources')
 106
 107                 nageru_include_dirs += include_directories(cef_dir)
 108                 nageru_include_dirs += include_directories(join_paths(cef_dir, 'include'))
 109                 nageru_build_rpath = cef_lib_dir
 110                 nageru_install_rpath = '$ORIGIN/'
 111         endif
 112
 113         # CEF wrapper library; not built as part of the CEF binary distribution,
 114         # but should be if CEF is installed as a system library.
 115         if system_cef
 116                 cefdlldep = cxx.find_library('cef_dll_wrapper')
 117                 nageru_deps += cefdlldep
 118         else
 119                 cmake = find_program('cmake')
 120                 cef_compile_script = find_program('nageru/scripts/compile_cef_dll_wrapper.sh')
 121
 122                 cef_dll_target = custom_target('libcef_dll_wrapper',
 123                         input: join_paths(cef_dir, 'libcef_dll/CMakeLists.txt'),
 124                         output: ['libcef_dll_wrapper.a', 'cef-stamp'],
 125                         command: [cef_compile_script, '@BUILD_DIR@', cef_dir, cmake, '@OUTPUT@'])
 126
 127                 # Putting the .a in sources seemingly hits a bug where the .a files get sorted
 128                 # in the wrong order. This is a workaround; see
 129                 # https://github.com/mesonbuild/meson/issues/3613#issuecomment-408276296 .
 130                 cefdlldep = declare_dependency(sources: cef_dll_target[1], link_args: cef_dll_target.full_path())
 131                 nageru_deps += cefdlldep
 132         endif
 133
 134         cef_libs = ['libEGL.so', 'libGLESv2.so', 'snapshot_blob.bin', 'v8_context_snapshot.bin']
 135         cef_resources = ['resources.pak', 'chrome_100_percent.pak', 'chrome_200_percent.pak']
 136         if not get_option('cef_no_icudtl')
 137                 cef_resources += ['icudtl.dat']
 138         endif
 139         if cef_build_type != 'system'
 140                 cef_libs += ['libcef.so', 'libEGL.so', 'libGLESv2.so', 'libvk_swiftshader.so', 'libvulkan.so.1', 'vk_swiftshader_icd.json']
 141         endif
 142
 143         # Symlink the files into the build directory, so that running nageru without ninja install works.
 144         run_command('mkdir', '-p', join_paths(meson.current_build_dir(), 'locales/'), check: true)
 145         foreach file : cef_libs
 146                 run_command('ln', '-sf', join_paths(cef_lib_dir, file), meson.current_build_dir(), check: true)
 147                 install_data(join_paths(cef_lib_dir, file), install_dir: exe_dir)
 148         endforeach
 149         foreach file : cef_resources
 150                 run_command('ln', '-sf', join_paths(cef_resource_dir, file), meson.current_build_dir(), check: true)
 151                 install_data(join_paths(cef_resource_dir, file), install_dir: exe_dir)
 152         endforeach
 153         run_command('ln', '-sf', join_paths(cef_resource_dir, 'locales/en-US.pak'), join_paths(meson.current_build_dir(), 'locales/'), check: true)
 154         install_data(join_paths(cef_resource_dir, 'locales/en-US.pak'), install_dir: join_paths(exe_dir, 'locales'))
 155
 156         # NOTE: We link against libcef.so in the local directory, _not_ in the CEF directory,
 157         # since upstream CEF searches for icudtl.dat in whatever path dladdr() says libcef.so
 158         # comes from, and the upstream CEF tarballs have libcef.so and icudtl.dat in different
 159         # directories. Thus, get both from the local symlinks we just created.
 160         cefdep = cxx.find_library('cef', dirs: meson.current_build_dir())
 161         nageru_deps += cefdep
 162 endif
 163
 164 # bmusb.
 165 if embedded_bmusb
 166         bmusb_dir = include_directories('nageru/bmusb')
 167         nageru_include_dirs += bmusb_dir
 168
 169         bmusb = static_library('bmusb', 'nageru/bmusb/bmusb.cpp', 'nageru/bmusb/fake_capture.cpp',
 170                 dependencies: [libusbdep],
 171                 include_directories: [bmusb_dir])
 172         nageru_link_with += bmusb
 173         kaeru_link_with += bmusb
 174 else
 175         nageru_deps += bmusbdep
 176         kaeru_extra_deps += bmusbdep
 177 endif
 178
 179 # Protobuf compilation.
 180 gen = generator(protoc, \
 181         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 182         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/nageru', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 183 proto_generated = gen.process(['nageru/state.proto', 'nageru/json.proto', 'nageru/nageru_midi_mapping.proto'])
 184 protobuf_lib = static_library('nageru_protobufs', proto_generated, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 185 protobuf_hdrs = declare_dependency(sources: proto_generated)
 186 nageru_link_with += protobuf_lib
 187
 188 # Preprocess Qt as needed.
 189 qt_files = qt5.preprocess(
 190         moc_headers: ['nageru/analyzer.h', 'nageru/clickable_label.h', 'nageru/compression_reduction_meter.h', 'nageru/correlation_meter.h',
 191                 'nageru/ellipsis_label.h', 'nageru/glwidget.h', 'nageru/input_mapping_dialog.h', 'nageru/lrameter.h', 'nageru/mainwindow.h', 'nageru/midi_mapping_dialog.h',
 192                 'nageru/nonlinear_fader.h', 'nageru/vumeter.h'],
 193         ui_files: ['nageru/analyzer.ui', 'nageru/audio_expanded_view.ui', 'nageru/audio_miniview.ui', 'nageru/display.ui',
 194                 'nageru/input_mapping.ui', 'nageru/mainwindow.ui', 'nageru/midi_mapping.ui'],
 195         dependencies: qt5deps)
 196
 197 # Qt objects.
 198 nageru_srcs += ['nageru/glwidget.cpp', 'nageru/mainwindow.cpp', 'nageru/vumeter.cpp', 'nageru/lrameter.cpp', 'nageru/compression_reduction_meter.cpp',
 199         'nageru/correlation_meter.cpp', 'nageru/analyzer.cpp', 'nageru/input_mapping_dialog.cpp', 'nageru/midi_mapping_dialog.cpp',
 200         'nageru/nonlinear_fader.cpp', 'nageru/context_menus.cpp', 'nageru/vu_common.cpp', 'nageru/piecewise_interpolator.cpp', 'nageru/midi_mapper.cpp']
 201
 202 # Auxiliary objects used for nearly everything.
 203 aux_srcs = ['nageru/flags.cpp']
 204 aux = static_library('aux', aux_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 205 nageru_link_with += aux
 206
 207 # Audio objects.
 208 audio_mixer_srcs = ['nageru/audio_mixer.cpp', 'nageru/alsa_input.cpp', 'nageru/alsa_pool.cpp', 'nageru/ebu_r128_proc.cc', 'nageru/stereocompressor.cpp',
 209         'nageru/resampling_queue.cpp', 'nageru/flags.cpp', 'nageru/correlation_measurer.cpp', 'nageru/filter.cpp', 'nageru/input_mapping.cpp']
 210 audio = static_library('audio', audio_mixer_srcs, dependencies: [nageru_deps, protobuf_hdrs], include_directories: nageru_include_dirs)
 211 nageru_link_with += audio
 212
 213 # Mixer objects.
 214 nageru_srcs += ['nageru/chroma_subsampler.cpp', 'nageru/v210_converter.cpp', 'nageru/mixer.cpp', 'nageru/pbo_frame_allocator.cpp',
 215         'nageru/theme.cpp', 'nageru/scene.cpp', 'nageru/image_input.cpp', 'nageru/alsa_output.cpp',
 216         'nageru/timecode_renderer.cpp', 'nageru/tweaked_inputs.cpp', 'nageru/mjpeg_encoder.cpp']
 217
 218 # Streaming and encoding objects (largely the set that is shared between Nageru and Kaeru).
 219 stream_srcs = ['nageru/quicksync_encoder.cpp', 'nageru/video_encoder.cpp',
 220         'nageru/x264_encoder.cpp', 'nageru/x264_dynamic.cpp', 'nageru/x264_speed_control.cpp',
 221         'nageru/audio_encoder.cpp', 'nageru/ffmpeg_util.cpp', 'nageru/ffmpeg_capture.cpp',
 222         'nageru/print_latency.cpp', 'nageru/basic_stats.cpp', 'nageru/ref_counted_frame.cpp',
 223         'nageru/v4l_output.cpp']
 224 if svtav1dep.found()
 225         stream_srcs += 'nageru/av1_encoder.cpp'
 226 endif
 227 stream = static_library('stream', stream_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 228 nageru_link_with += stream
 229
 230 # DeckLink.
 231 decklink_dir = include_directories('nageru/decklink', is_system: true)
 232 decklink_lib = static_library('decklink', 'nageru/decklink/DeckLinkAPIDispatch.cpp', include_directories: decklink_dir, cpp_args: '-w')
 233 nageru_link_with += decklink_lib
 234
 235 nageru_srcs += ['nageru/decklink_capture.cpp', 'nageru/decklink_util.cpp', 'nageru/decklink_output.cpp']
 236 nageru_include_dirs += decklink_dir
 237
 238 # CEF input.
 239 if have_cef
 240         nageru_srcs += ['nageru/nageru_cef_app.cpp', 'nageru/cef_capture.cpp']
 241 endif
 242
 243 nageru_srcs += qt_files
 244 nageru_srcs += proto_generated
 245
 246 # Shaders needed at runtime.
 247 shaders = ['nageru/cbcr_subsample.vert', 'nageru/cbcr_subsample.frag', 'nageru/uyvy_subsample.vert', 'nageru/uyvy_subsample.frag', 'nageru/v210_subsample.comp', 'nageru/timecode.vert', 'nageru/timecode.frag', 'nageru/timecode_10bit.frag']
 248 foreach shader : shaders
 249         run_command('ln', '-sf', join_paths(meson.current_source_dir(), shader), meson.current_build_dir(), check: true)
 250 endforeach
 251
 252 nageru_shader_srcs = bin2h_gen.process(shaders)
 253 nageru_srcs += nageru_shader_srcs
 254
 255 # Everything except main.cpp. (We do this because if you specify a .cpp file in
 256 # both Nageru and Kaeru, it gets compiled twice. In the older Makefiles, Kaeru
 257 # depended on a smaller set of objects.)
 258 core = static_library('core', nageru_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 259 nageru_link_with += core
 260
 261 # Nageru executable; it goes into /usr/lib/nageru since CEF files go there, too
 262 # (we can't put them straight into /usr/bin).
 263 executable('nageru', 'nageru/main.cpp',
 264         dependencies: nageru_deps,
 265         include_directories: nageru_include_dirs,
 266         link_with: nageru_link_with,
 267         build_rpath: nageru_build_rpath,
 268         install_rpath: nageru_install_rpath,
 269         install: true,
 270         install_dir: exe_dir
 271 )
 272 meson.add_install_script('nageru/scripts/setup_nageru_symlink.sh')
 273
 274 # Kaeru executable.
 275 executable('kaeru', 'nageru/kaeru.cpp',
 276         dependencies: [nageru_deps, kaeru_extra_deps],
 277         include_directories: nageru_include_dirs,
 278         link_with: [stream, aux, kaeru_link_with],
 279         install: true)
 280
 281 # Audio mixer microbenchmark.
 282 executable('benchmark_audio_mixer', 'nageru/benchmark_audio_mixer.cpp', dependencies: nageru_deps, include_directories: nageru_include_dirs, link_with: [audio, aux])
 283
 284 # These are needed for a default run.
 285 data_files = ['nageru/theme.lua', 'nageru/simple.lua', 'nageru/bg.jpeg', 'nageru/akai_midimix.midimapping', 'futatabi/behringer_cmd_pl1.midimapping']
 286 install_data(data_files, install_dir: join_paths(get_option('prefix'), 'share/nageru'))
 287 foreach file : data_files
 288         run_command('ln', '-sf', join_paths(meson.current_source_dir(), file), meson.current_build_dir(), check: true)
 289 endforeach
 290
 291 # Futatabi. (Not a subdir() because we don't want the output in nageru/nageru.)
 292
 293 # Protobuf compilation.
 294 gen = generator(protoc, \
 295         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 296         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/futatabi', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 297 proto_generated = gen.process('futatabi/state.proto', 'futatabi/frame.proto', 'futatabi/futatabi_midi_mapping.proto')
 298
 299 # Preprocess Qt as needed.
 300 moc_files = qt5.preprocess(
 301         moc_headers: ['futatabi/mainwindow.h', 'futatabi/jpeg_frame_view.h', 'futatabi/clip_list.h', 'futatabi/midi_mapping_dialog.h'],
 302         ui_files: ['futatabi/mainwindow.ui', 'futatabi/midi_mapping.ui'],
 303         qresources: ['futatabi/mainwindow.qrc'],
 304         dependencies: qt5deps)
 305
 306 # Flow objects.
 307 futatabi_srcs = ['futatabi/flow.cpp', 'futatabi/gpu_timers.cpp']
 308
 309 # All the other files.
 310 futatabi_srcs += ['futatabi/main.cpp', 'futatabi/player.cpp', 'futatabi/video_stream.cpp', 'futatabi/chroma_subsampler.cpp']
 311 futatabi_srcs += ['futatabi/vaapi_jpeg_decoder.cpp', 'futatabi/db.cpp', 'futatabi/ycbcr_converter.cpp', 'futatabi/flags.cpp']
 312 futatabi_srcs += ['futatabi/mainwindow.cpp', 'futatabi/jpeg_frame_view.cpp', 'futatabi/clip_list.cpp', 'futatabi/frame_on_disk.cpp']
 313 futatabi_srcs += ['futatabi/export.cpp', 'futatabi/midi_mapper.cpp', 'futatabi/midi_mapping_dialog.cpp']
 314 futatabi_srcs += ['futatabi/exif_parser.cpp', 'futatabi/pbo_pool.cpp']
 315 futatabi_srcs += moc_files
 316 futatabi_srcs += proto_generated
 317
 318 # Shaders needed at runtime.
 319 shaders = ['futatabi/chroma_subsample.vert', 'futatabi/densify.vert', 'futatabi/equations.vert', 'futatabi/hole_fill.vert', 'futatabi/motion_search.vert', 'futatabi/sor.vert', 'futatabi/splat.vert', 'futatabi/vs.vert']
 320 shaders += ['futatabi/add_base_flow.frag', 'futatabi/blend.frag', 'futatabi/chroma_subsample.frag', 'futatabi/densify.frag', 'futatabi/derivatives.frag', 'futatabi/diffusivity.frag',
 321         'futatabi/equations.frag', 'futatabi/gray.frag', 'futatabi/hole_blend.frag', 'futatabi/hole_fill.frag', 'futatabi/motion_search.frag', 'futatabi/prewarp.frag', 'futatabi/resize_flow.frag',
 322         'futatabi/sobel.frag', 'futatabi/sor.frag', 'futatabi/splat.frag']
 323
 324 foreach shader : shaders
 325         run_command('ln', '-sf', join_paths(meson.current_source_dir(), shader), meson.current_build_dir(), check: true)
 326 endforeach
 327
 328 futatabi_shader_srcs = bin2h_gen.process(shaders)
 329 futatabi_srcs += futatabi_shader_srcs
 330
 331 executable('futatabi', futatabi_srcs,
 332         dependencies: [shareddep, qt5deps, libjpegdep, movitdep, libmicrohttpddep, protobufdep, sqlite3dep, vax11dep, vadrmdep, x11dep, threaddep, libavformatdep, libavcodecdep, libavutildep, libswscaledep, eigendep],
 333         link_with: shared,
 334         include_directories: [include_directories('futatabi')],
 335         install: true)
 336
 337 # Test binaries for the optical flow code.
 338 if sdl2dep.found() and sdl2_imagedep.found()
 339         executable('flow', 'futatabi/flow_main.cpp', 'futatabi/flow.cpp', 'futatabi/gpu_timers.cpp', futatabi_shader_srcs, dependencies: [shareddep, epoxydep, sdl2dep, sdl2_imagedep])
 340 endif
 341 executable('eval', 'futatabi/eval.cpp', 'futatabi/util.cpp')
 342 executable('vis', 'futatabi/vis.cpp', 'futatabi/util.cpp')