git.sesse.net Git - nageru/blob - meson.build

   1 project('nageru', 'cpp', default_options: ['buildtype=debugoptimized'], version: '2.2.2-pre')
   2
   3 cxx = meson.get_compiler('cpp')
   4 qt5 = import('qt5')
   5 protoc = find_program('protoc')
   6
   7 embedded_bmusb = get_option('embedded_bmusb')
   8
   9 alsadep = dependency('alsa')
  10 bmusbdep = dependency('bmusb', required: not embedded_bmusb)
  11 dldep = cxx.find_library('dl')
  12 eigendep = dependency('eigen3')
  13 epoxydep = dependency('epoxy')
  14 libavcodecdep = dependency('libavcodec')
  15 libavformatdep = dependency('libavformat')
  16 libswresampledep = dependency('libswresample')
  17 libavutildep = dependency('libavutil')
  18 libdrmdep = dependency('libdrm')
  19 libjpegdep = dependency('libjpeg')
  20 libswscaledep = dependency('libswscale')
  21 libusbdep = dependency('libusb-1.0')
  22 luajitdep = dependency('luajit')
  23 movitdep = dependency('movit')
  24 protobufdep = dependency('protobuf')
  25 qt5deps = dependency('qt5', modules: ['Core', 'Gui', 'Widgets', 'OpenGLExtensions', 'OpenGL', 'Network'])
  26 sdl2_imagedep = dependency('SDL2_image', required: false)
  27 sdl2dep = dependency('sdl2', required: false)
  28 srtdep = dependency('srt', required: false)
  29 svtav1dep = dependency('SvtAv1Enc', required: false, version: '>=1.5.0')
  30 sqlite3dep = dependency('sqlite3')
  31 threaddep = dependency('threads')
  32 vadrmdep = dependency('libva-drm')
  33 vax11dep = dependency('libva-x11')
  34 x11dep = dependency('x11')
  35 x264dep = dependency('x264')
  36 zitaresamplerdep = cxx.find_library('zita-resampler')
  37
  38 # Use lld if we can; it links a lot faster than ld.bfd or gold.
  39 code = '''#include <stdio.h>
  40 int main() { printf("Hello, world!\n"); return 0; }
  41 '''
  42 if cxx.links(code, args: '-fuse-ld=lld', name: 'check for LLD')
  43         add_project_link_arguments('-fuse-ld=lld', language: 'cpp')
  44 endif
  45
  46 # Add the right MOVIT_SHADER_DIR definition.
  47 movit_shader_dir = movitdep.get_pkgconfig_variable('shaderdir')
  48 add_project_arguments('-DMOVIT_SHADER_DIR="' + movit_shader_dir + '"', language: 'cpp')
  49
  50 # Make the Nageru version available as a #define.
  51 add_project_arguments('-DNAGERU_VERSION="' + meson.project_version() + '"', language: 'cpp')
  52
  53 # Make the prefix (e.g. /usr/local) available as a #define.
  54 add_project_arguments('-DPREFIX="' + get_option('prefix') + '"', language: 'cpp')
  55
  56 # This needs to be done before declaring any build targets.
  57 if get_option('cef_dir') != ''
  58         add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  59 endif
  60
  61 if srtdep.found()
  62         # NOTE: Seemingly there's no way to figure out if we have OpenSSL libsrt
  63         # or gnutls libsrt, so we cannot check license compatibility here.
  64         add_project_arguments('-DHAVE_SRT=1', language: 'cpp')
  65 endif
  66 if svtav1dep.found()
  67         add_project_arguments('-DHAVE_AV1=1', language: 'cpp')
  68 endif
  69
  70 top_include = include_directories('.')
  71
  72 subdir('shared')
  73
  74 # Nageru. (Not a subdir() because we don't want the output in nageru/nageru.)
  75
  76 nageru_srcs = []
  77 nageru_deps = [shareddep, qt5deps, libjpegdep, movitdep, protobufdep,
  78         vax11dep, vadrmdep, x11dep, libavformatdep, libswresampledep, libavcodecdep, libavutildep,
  79         libswscaledep, libusbdep, luajitdep, dldep, x264dep, svtav1dep, alsadep, zitaresamplerdep,
  80         threaddep, eigendep, srtdep, libdrmdep]
  81 nageru_include_dirs = [include_directories('nageru')]
  82 nageru_link_with = []
  83 nageru_build_rpath = ''
  84 nageru_install_rpath = ''
  85
  86 kaeru_link_with = []
  87 kaeru_extra_deps = []
  88
  89 # CEF.
  90 exe_dir = join_paths(get_option('prefix'), 'lib/nageru')
  91 cef_dir = get_option('cef_dir')
  92 cef_build_type = get_option('cef_build_type')
  93 have_cef = (cef_dir != '')
  94 if have_cef
  95         # This is done in the top-level file; just kept here for reference.
  96         # add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  97
  98         system_cef = (cef_build_type == 'system')
  99         if system_cef
 100                 cef_lib_dir = cef_dir
 101                 cef_resource_dir = cef_dir
 102         else
 103                 cef_lib_dir = join_paths(cef_dir, cef_build_type)
 104                 cef_resource_dir = join_paths(cef_dir, 'Resources')
 105
 106                 nageru_include_dirs += include_directories(cef_dir)
 107                 nageru_include_dirs += include_directories(join_paths(cef_dir, 'include'))
 108                 nageru_build_rpath = cef_lib_dir
 109                 nageru_install_rpath = '$ORIGIN/'
 110         endif
 111
 112         # CEF wrapper library; not built as part of the CEF binary distribution,
 113         # but should be if CEF is installed as a system library.
 114         if system_cef
 115                 cefdlldep = cxx.find_library('cef_dll_wrapper')
 116                 nageru_deps += cefdlldep
 117         else
 118                 cmake = find_program('cmake')
 119                 cef_compile_script = find_program('nageru/scripts/compile_cef_dll_wrapper.sh')
 120
 121                 cef_dll_target = custom_target('libcef_dll_wrapper',
 122                         input: join_paths(cef_dir, 'libcef_dll/CMakeLists.txt'),
 123                         output: ['libcef_dll_wrapper.a', 'cef-stamp'],
 124                         command: [cef_compile_script, '@BUILD_DIR@', cef_dir, cmake, '@OUTPUT@'])
 125
 126                 # Putting the .a in sources seemingly hits a bug where the .a files get sorted
 127                 # in the wrong order. This is a workaround; see
 128                 # https://github.com/mesonbuild/meson/issues/3613#issuecomment-408276296 .
 129                 cefdlldep = declare_dependency(sources: cef_dll_target[1], link_args: cef_dll_target.full_path())
 130                 nageru_deps += cefdlldep
 131         endif
 132
 133         cef_libs = ['libEGL.so', 'libGLESv2.so', 'snapshot_blob.bin', 'v8_context_snapshot.bin']
 134         cef_resources = ['resources.pak', 'chrome_100_percent.pak', 'chrome_200_percent.pak']
 135         if not get_option('cef_no_icudtl')
 136                 cef_resources += ['icudtl.dat']
 137         endif
 138         if cef_build_type != 'system'
 139                 cef_libs += ['libcef.so', 'libEGL.so', 'libGLESv2.so', 'libvk_swiftshader.so', 'libvulkan.so.1', 'vk_swiftshader_icd.json']
 140         endif
 141
 142         # Symlink the files into the build directory, so that running nageru without ninja install works.
 143         run_command('mkdir', '-p', join_paths(meson.current_build_dir(), 'locales/'), check: true)
 144         foreach file : cef_libs
 145                 run_command('ln', '-sf', join_paths(cef_lib_dir, file), meson.current_build_dir(), check: true)
 146                 install_data(join_paths(cef_lib_dir, file), install_dir: exe_dir)
 147         endforeach
 148         foreach file : cef_resources
 149                 run_command('ln', '-sf', join_paths(cef_resource_dir, file), meson.current_build_dir(), check: true)
 150                 install_data(join_paths(cef_resource_dir, file), install_dir: exe_dir)
 151         endforeach
 152         run_command('ln', '-sf', join_paths(cef_resource_dir, 'locales/en-US.pak'), join_paths(meson.current_build_dir(), 'locales/'), check: true)
 153         install_data(join_paths(cef_resource_dir, 'locales/en-US.pak'), install_dir: join_paths(exe_dir, 'locales'))
 154
 155         # NOTE: We link against libcef.so in the local directory, _not_ in the CEF directory,
 156         # since upstream CEF searches for icudtl.dat in whatever path dladdr() says libcef.so
 157         # comes from, and the upstream CEF tarballs have libcef.so and icudtl.dat in different
 158         # directories. Thus, get both from the local symlinks we just created.
 159         cefdep = cxx.find_library('cef', dirs: meson.current_build_dir())
 160         nageru_deps += cefdep
 161 endif
 162
 163 # bmusb.
 164 if embedded_bmusb
 165         bmusb_dir = include_directories('nageru/bmusb')
 166         nageru_include_dirs += bmusb_dir
 167
 168         bmusb = static_library('bmusb', 'nageru/bmusb/bmusb.cpp', 'nageru/bmusb/fake_capture.cpp',
 169                 dependencies: [libusbdep],
 170                 include_directories: [bmusb_dir])
 171         nageru_link_with += bmusb
 172         kaeru_link_with += bmusb
 173 else
 174         nageru_deps += bmusbdep
 175         kaeru_extra_deps += bmusbdep
 176 endif
 177
 178 # Protobuf compilation.
 179 gen = generator(protoc, \
 180         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 181         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/nageru', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 182 proto_generated = gen.process(['nageru/state.proto', 'nageru/json.proto', 'nageru/nageru_midi_mapping.proto'])
 183 protobuf_lib = static_library('nageru_protobufs', proto_generated, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 184 protobuf_hdrs = declare_dependency(sources: proto_generated)
 185 nageru_link_with += protobuf_lib
 186
 187 # Preprocess Qt as needed.
 188 qt_files = qt5.preprocess(
 189         moc_headers: ['nageru/analyzer.h', 'nageru/clickable_label.h', 'nageru/compression_reduction_meter.h', 'nageru/correlation_meter.h',
 190                 'nageru/ellipsis_label.h', 'nageru/glwidget.h', 'nageru/input_mapping_dialog.h', 'nageru/lrameter.h', 'nageru/mainwindow.h', 'nageru/midi_mapping_dialog.h',
 191                 'nageru/nonlinear_fader.h', 'nageru/vumeter.h', 'nageru/rgb_histogram.h'],
 192         ui_files: ['nageru/analyzer.ui', 'nageru/audio_expanded_view.ui', 'nageru/audio_miniview.ui', 'nageru/display.ui',
 193                 'nageru/input_mapping.ui', 'nageru/mainwindow.ui', 'nageru/midi_mapping.ui'],
 194         dependencies: qt5deps)
 195
 196 # Qt objects.
 197 nageru_srcs += ['nageru/glwidget.cpp', 'nageru/mainwindow.cpp', 'nageru/vumeter.cpp', 'nageru/lrameter.cpp', 'nageru/compression_reduction_meter.cpp',
 198         'nageru/correlation_meter.cpp', 'nageru/analyzer.cpp', 'nageru/input_mapping_dialog.cpp', 'nageru/midi_mapping_dialog.cpp',
 199         'nageru/nonlinear_fader.cpp', 'nageru/context_menus.cpp', 'nageru/vu_common.cpp', 'nageru/piecewise_interpolator.cpp', 'nageru/midi_mapper.cpp', 'nageru/rgb_histogram.cpp']
 200
 201 # Auxiliary objects used for nearly everything.
 202 aux_srcs = ['nageru/flags.cpp']
 203 aux = static_library('aux', aux_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 204 nageru_link_with += aux
 205
 206 # Audio objects.
 207 audio_mixer_srcs = ['nageru/audio_mixer.cpp', 'nageru/alsa_input.cpp', 'nageru/alsa_pool.cpp', 'nageru/ebu_r128_proc.cc', 'nageru/stereocompressor.cpp',
 208         'nageru/resampling_queue.cpp', 'nageru/flags.cpp', 'nageru/correlation_measurer.cpp', 'nageru/filter.cpp', 'nageru/input_mapping.cpp']
 209 audio = static_library('audio', audio_mixer_srcs, dependencies: [nageru_deps, protobuf_hdrs], include_directories: nageru_include_dirs)
 210 nageru_link_with += audio
 211
 212 # Mixer objects.
 213 nageru_srcs += ['nageru/chroma_subsampler.cpp', 'nageru/v210_converter.cpp', 'nageru/mixer.cpp', 'nageru/pbo_frame_allocator.cpp',
 214         'nageru/theme.cpp', 'nageru/scene.cpp', 'nageru/image_input.cpp', 'nageru/alsa_output.cpp',
 215         'nageru/timecode_renderer.cpp', 'nageru/tweaked_inputs.cpp', 'nageru/mjpeg_encoder.cpp']
 216
 217 # Streaming and encoding objects (largely the set that is shared between Nageru and Kaeru).
 218 stream_srcs = ['nageru/quicksync_encoder.cpp', 'nageru/video_encoder.cpp',
 219         'nageru/x264_encoder.cpp', 'nageru/x264_dynamic.cpp', 'nageru/x264_speed_control.cpp',
 220         'nageru/audio_encoder.cpp', 'nageru/ffmpeg_util.cpp', 'nageru/ffmpeg_capture.cpp',
 221         'nageru/print_latency.cpp', 'nageru/basic_stats.cpp', 'nageru/ref_counted_frame.cpp',
 222         'nageru/v4l_output.cpp']
 223 if svtav1dep.found()
 224         stream_srcs += 'nageru/av1_encoder.cpp'
 225 endif
 226 stream = static_library('stream', stream_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 227 nageru_link_with += stream
 228
 229 # DeckLink.
 230 decklink_dir = include_directories('nageru/decklink', is_system: true)
 231 decklink_lib = static_library('decklink', 'nageru/decklink/DeckLinkAPIDispatch.cpp', include_directories: decklink_dir, cpp_args: '-w')
 232 nageru_link_with += decklink_lib
 233
 234 nageru_srcs += ['nageru/decklink_capture.cpp', 'nageru/decklink_util.cpp', 'nageru/decklink_output.cpp']
 235 nageru_include_dirs += decklink_dir
 236
 237 # CEF input.
 238 if have_cef
 239         nageru_srcs += ['nageru/nageru_cef_app.cpp', 'nageru/cef_capture.cpp']
 240 endif
 241
 242 nageru_srcs += qt_files
 243 nageru_srcs += proto_generated
 244
 245 # Shaders needed at runtime.
 246 shaders = ['nageru/cbcr_subsample.vert', 'nageru/cbcr_subsample.frag', 'nageru/uyvy_subsample.vert', 'nageru/uyvy_subsample.frag', 'nageru/v210_subsample.comp', 'nageru/timecode.vert', 'nageru/timecode.frag', 'nageru/timecode_10bit.frag']
 247 foreach shader : shaders
 248         run_command('ln', '-sf', join_paths(meson.current_source_dir(), shader), meson.current_build_dir(), check: true)
 249 endforeach
 250
 251 nageru_shader_srcs = bin2h_gen.process(shaders)
 252 nageru_srcs += nageru_shader_srcs
 253
 254 # Everything except main.cpp. (We do this because if you specify a .cpp file in
 255 # both Nageru and Kaeru, it gets compiled twice. In the older Makefiles, Kaeru
 256 # depended on a smaller set of objects.)
 257 core = static_library('core', nageru_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 258 nageru_link_with += core
 259
 260 # Nageru executable; it goes into /usr/lib/nageru since CEF files go there, too
 261 # (we can't put them straight into /usr/bin).
 262 executable('nageru', 'nageru/main.cpp',
 263         dependencies: nageru_deps,
 264         include_directories: nageru_include_dirs,
 265         link_with: nageru_link_with,
 266         build_rpath: nageru_build_rpath,
 267         install_rpath: nageru_install_rpath,
 268         install: true,
 269         install_dir: exe_dir
 270 )
 271 meson.add_install_script('nageru/scripts/setup_nageru_symlink.sh')
 272
 273 # Kaeru executable.
 274 executable('kaeru', 'nageru/kaeru.cpp',
 275         dependencies: [nageru_deps, kaeru_extra_deps],
 276         include_directories: nageru_include_dirs,
 277         link_with: [stream, aux, kaeru_link_with],
 278         install: true)
 279
 280 # Audio mixer microbenchmark.
 281 executable('benchmark_audio_mixer', 'nageru/benchmark_audio_mixer.cpp', dependencies: nageru_deps, include_directories: nageru_include_dirs, link_with: [audio, aux])
 282
 283 # These are needed for a default run.
 284 data_files = ['nageru/theme.lua', 'nageru/simple.lua', 'nageru/bg.jpeg', 'nageru/akai_midimix.midimapping', 'futatabi/behringer_cmd_pl1.midimapping']
 285 install_data(data_files, install_dir: join_paths(get_option('prefix'), 'share/nageru'))
 286 foreach file : data_files
 287         run_command('ln', '-sf', join_paths(meson.current_source_dir(), file), meson.current_build_dir(), check: true)
 288 endforeach
 289
 290 # Futatabi. (Not a subdir() because we don't want the output in nageru/nageru.)
 291
 292 # Protobuf compilation.
 293 gen = generator(protoc, \
 294         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 295         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/futatabi', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 296 proto_generated = gen.process('futatabi/state.proto', 'futatabi/frame.proto', 'futatabi/futatabi_midi_mapping.proto')
 297
 298 # Preprocess Qt as needed.
 299 moc_files = qt5.preprocess(
 300         moc_headers: ['futatabi/mainwindow.h', 'futatabi/jpeg_frame_view.h', 'futatabi/clip_list.h', 'futatabi/midi_mapping_dialog.h'],
 301         ui_files: ['futatabi/mainwindow.ui', 'futatabi/midi_mapping.ui'],
 302         qresources: ['futatabi/mainwindow.qrc'],
 303         dependencies: qt5deps)
 304
 305 # Flow objects.
 306 futatabi_srcs = ['futatabi/flow.cpp', 'futatabi/gpu_timers.cpp']
 307
 308 # All the other files.
 309 futatabi_srcs += ['futatabi/main.cpp', 'futatabi/player.cpp', 'futatabi/video_stream.cpp', 'futatabi/chroma_subsampler.cpp']
 310 futatabi_srcs += ['futatabi/vaapi_jpeg_decoder.cpp', 'futatabi/db.cpp', 'futatabi/ycbcr_converter.cpp', 'futatabi/flags.cpp']
 311 futatabi_srcs += ['futatabi/mainwindow.cpp', 'futatabi/jpeg_frame_view.cpp', 'futatabi/clip_list.cpp', 'futatabi/frame_on_disk.cpp']
 312 futatabi_srcs += ['futatabi/export.cpp', 'futatabi/midi_mapper.cpp', 'futatabi/midi_mapping_dialog.cpp']
 313 futatabi_srcs += ['futatabi/exif_parser.cpp', 'futatabi/pbo_pool.cpp']
 314 futatabi_srcs += moc_files
 315 futatabi_srcs += proto_generated
 316
 317 # Shaders needed at runtime.
 318 shaders = ['futatabi/chroma_subsample.vert', 'futatabi/densify.vert', 'futatabi/equations.vert', 'futatabi/hole_fill.vert', 'futatabi/motion_search.vert', 'futatabi/sor.vert', 'futatabi/splat.vert', 'futatabi/vs.vert']
 319 shaders += ['futatabi/add_base_flow.frag', 'futatabi/blend.frag', 'futatabi/chroma_subsample.frag', 'futatabi/densify.frag', 'futatabi/derivatives.frag', 'futatabi/diffusivity.frag',
 320         'futatabi/equations.frag', 'futatabi/gray.frag', 'futatabi/hole_blend.frag', 'futatabi/hole_fill.frag', 'futatabi/motion_search.frag', 'futatabi/prewarp.frag', 'futatabi/resize_flow.frag',
 321         'futatabi/sobel.frag', 'futatabi/sor.frag', 'futatabi/splat.frag']
 322
 323 foreach shader : shaders
 324         run_command('ln', '-sf', join_paths(meson.current_source_dir(), shader), meson.current_build_dir(), check: true)
 325 endforeach
 326
 327 futatabi_shader_srcs = bin2h_gen.process(shaders)
 328 futatabi_srcs += futatabi_shader_srcs
 329
 330 executable('futatabi', futatabi_srcs,
 331         dependencies: [shareddep, qt5deps, libjpegdep, movitdep, libmicrohttpddep, protobufdep, sqlite3dep, vax11dep, vadrmdep, x11dep, threaddep, libavformatdep, libavcodecdep, libavutildep, libswscaledep, eigendep],
 332         link_with: shared,
 333         include_directories: [include_directories('futatabi')],
 334         install: true)
 335
 336 # Test binaries for the optical flow code.
 337 if sdl2dep.found() and sdl2_imagedep.found()
 338         executable('flow', 'futatabi/flow_main.cpp', 'futatabi/flow.cpp', 'futatabi/gpu_timers.cpp', futatabi_shader_srcs, dependencies: [shareddep, epoxydep, sdl2dep, sdl2_imagedep])
 339 endif
 340 executable('eval', 'futatabi/eval.cpp', 'futatabi/util.cpp')
 341 executable('vis', 'futatabi/vis.cpp', 'futatabi/util.cpp')