git.sesse.net Git - nageru/blob - sor.frag

   1 #version 450 core
   2
   3 in vec2 tc;
   4 in float element_sum_idx;
   5 out vec2 diff_flow;
   6
   7 uniform sampler2D diff_flow_tex, smoothness_x_tex, smoothness_y_tex;
   8 uniform usampler2D equation_tex;
   9 uniform int phase;
  10
  11 // See pack_floats_shared() in equations.frag.
  12 vec2 unpack_floats_shared(uint c)
  13 {
  14         // Recover the exponent, and multiply it in. Add one because
  15         // we have denormalized mantissas, then another one because we
  16         // already reduced the exponent by one. Then subtract 20, because
  17         // we are going to shift up the number by 20 below to recover the sign bits.
  18         float normalizer = uintBitsToFloat(((c >> 1) & 0x7f800000u) - (18 << 23));
  19         normalizer *= (1.0 / 2047.0);
  20
  21         // Shift the values up so that we recover the sign bit, then normalize.
  22         float a = int(uint(c & 0x000fffu) << 20) * normalizer;
  23         float b = int(uint(c & 0xfff000u) << 8) * normalizer;
  24
  25         return vec2(a, b);
  26 }
  27
  28 void main()
  29 {
  30         // Red-black SOR: Every other pass, we update every other element in a
  31         // checkerboard pattern. This is rather suboptimal for the GPU, as it
  32         // just immediately throws away half of the warp, but it helps convergence
  33         // a _lot_ (rough testing indicates that five iterations of SOR is as good
  34         // as ~50 iterations of Jacobi). We could probably do better by reorganizing
  35         // the data into two-values-per-pixel, so-called “twinning buffering”,
  36         // but it makes for rather annoying code in the rest of the pipeline.
  37         int color = int(round(element_sum_idx)) & 1;
  38         if (color != phase) discard;
  39
  40         uvec4 equation = texture(equation_tex, tc);
  41         float inv_A11 = uintBitsToFloat(equation.x);
  42         float A12 = uintBitsToFloat(equation.y);
  43         float inv_A22 = uintBitsToFloat(equation.z);
  44         vec2 b = unpack_floats_shared(equation.w);
  45
  46         // Subtract the missing terms from the right-hand side
  47         // (it couldn't be done earlier, because we didn't know
  48         // the values of the neighboring pixels; they change for
  49         // each SOR iteration).
  50         float smooth_l = textureOffset(smoothness_x_tex, tc, ivec2(-1,  0)).x;
  51         float smooth_r = texture(smoothness_x_tex, tc).x;
  52         float smooth_d = textureOffset(smoothness_y_tex, tc, ivec2( 0, -1)).x;
  53         float smooth_u = texture(smoothness_y_tex, tc).x;
  54         b += smooth_l * textureOffset(diff_flow_tex, tc, ivec2(-1,  0)).xy;
  55         b += smooth_r * textureOffset(diff_flow_tex, tc, ivec2( 1,  0)).xy;
  56         b += smooth_d * textureOffset(diff_flow_tex, tc, ivec2( 0, -1)).xy;
  57         b += smooth_u * textureOffset(diff_flow_tex, tc, ivec2( 0,  1)).xy;
  58
  59         const float omega = 1.8;  // Marginally better than 1.6, it seems.
  60         diff_flow = texture(diff_flow_tex, tc).xy;
  61
  62         // From https://en.wikipedia.org/wiki/Successive_over-relaxation.
  63         float sigma_u = A12 * diff_flow.y;
  64         diff_flow.x += omega * ((b.x - sigma_u) * inv_A11 - diff_flow.x);
  65         float sigma_v = A12 * diff_flow.x;
  66         diff_flow.y += omega * ((b.y - sigma_v) * inv_A22 - diff_flow.y);
  67 }