git.sesse.net Git - remoteglot-book/blob - www/opening-stats.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 use CGI;
   5 use JSON::XS;
   6 use lib '..';
   7 use Position;
   8 use IPC::Open2;
   9 use Chess::PGN::Parse;
  10
  11 our %openings = ();
  12 read_openings();
  13
  14 my $cgi = CGI->new;
  15 my ($chld_out, $chld_in);
  16 my $pid = IPC::Open2::open2($chld_out, $chld_in, "../binlookup", "../open.mtbl", "40");
  17
  18 # Root position. Basically ignore everything except the opening (and later some root game stuff).
  19 my $fen = $cgi->param('fen') // 'rnbqkbnr/pppppppp/8/8/8/8/PPPPPPPP/RNBQKBNR w KQkq - 0 1';
  20 my $includetransp = $cgi->param('includetransp') // 1;
  21
  22 my $pos = Position->from_fen($fen);
  23 my ($json_root_pos, $root_aux_data) = get_json_move($pos, undef, $chld_in, $chld_out);
  24
  25 my $opening = $openings{$json_root_pos->{'opening_num'}} // 'A00: Start position';
  26 my @json_moves = ($json_root_pos);
  27
  28 my $root_game;
  29 eval {
  30         if (!exists($root_aux_data->{'pgn_file_number'}) ||
  31             !exists($root_aux_data->{'pgn_start_position'})) {
  32                 die "Missing PGN position data."
  33         }
  34         my $pgntext = read_root_pgn($root_aux_data->{'pgn_file_number'}, $root_aux_data->{'pgn_start_position'});
  35         my $pgn = Chess::PGN::Parse->new(undef, $pgntext);
  36         $pgn->read_game() or die;
  37         $pgn->parse_game() or die;
  38
  39         my $tags = $pgn->tags;
  40         $root_game = {};
  41         $root_game->{'white'} = $pgn->white;
  42         $root_game->{'white_elo'} = $tags->{'WhiteElo'};
  43         $root_game->{'black'} = $pgn->black;
  44         $root_game->{'black_elo'} = $tags->{'BlackElo'};
  45         $root_game->{'event'} = $pgn->event;
  46         $root_game->{'date'} = $pgn->date;
  47         $root_game->{'result'} = $pgn->result;
  48         $root_game->{'eco'} = $pgn->eco;
  49         $root_game->{'moves'} = int(((scalar @{$pgn->moves}) + 1) / 2);
  50 };
  51
  52 # Explore one move out.
  53 my $white_left = $json_root_pos->{'white'};
  54 my $draw_left = $json_root_pos->{'draw'};
  55 my $black_left = $json_root_pos->{'black'};
  56 for my $move (@{$root_aux_data->{'moves'}}) {
  57         my ($np, $uci_move) = $pos->make_pretty_move($move);
  58         my $json_pos;
  59
  60         my ($json_pos_only_this_root, undef) = get_json_move($np, $root_aux_data->{'pos_hash'}, $chld_in, $chld_out);
  61         $white_left -= $json_pos_only_this_root->{'white'};
  62         $draw_left -= $json_pos_only_this_root->{'draw'};
  63         $black_left -= $json_pos_only_this_root->{'black'};
  64
  65         if ($includetransp) {
  66                 ($json_pos, undef) = get_json_move($np, undef, $chld_in, $chld_out);
  67
  68                 # See if this move exists only due to transpositions.
  69                 if (!defined($json_pos_only_this_root)) {
  70                         $json_pos->{'transpose_only'} = 1;
  71                 }
  72         } else {
  73                 $json_pos = $json_pos_only_this_root;
  74         }
  75         $json_pos->{'move'} = $move;
  76         push @json_moves, $json_pos;
  77 }
  78
  79 # If there are any positions that are not accounted for by any moves,
  80 # these have to be games that end here. Add them as pseudo-moves so as
  81 # not to confuse the user.
  82 for my $result (['1-0', 'white', $white_left], ['1/2-1/2', 'draw', $draw_left], ['0-1', 'black', $black_left]) {
  83         next if ($result->[2] == 0);
  84         my $move = {
  85                 move => $result->[0],
  86                 white => 0,
  87                 draw => 0,
  88                 black => 0
  89         };
  90         $move->{$result->[1]} = $result->[2];
  91         push @json_moves, $move;
  92 }
  93
  94 # Get stats for the root position, for the human index.
  95 my $start_pos = Position->start_pos("white", "black");
  96 my ($json_start_pos, undef) = get_json_move($start_pos, 0, $chld_in, $chld_out);
  97 my $total_games = $json_start_pos->{'white'} + $json_start_pos->{'draw'} + $json_start_pos->{'black'};
  98 my $computer_games = $json_start_pos->{'computer'} * 1;
  99
 100 print $cgi->header(-type=>'application/json');
 101 print JSON::XS::encode_json({
 102         moves => \@json_moves,
 103         opening => $opening,
 104         root_game => $root_game,
 105         total_games => $total_games,
 106         computer_games => $computer_games
 107 });
 108
 109 sub read_openings {
 110         open my $fh, "../openings.txt"
 111                 or die "../openings.txt: $!";
 112         for my $line (<$fh>) {
 113                 chomp $line;
 114                 my ($hash, $eco, $opening, $variation, $subvariation) = split /\t/, $line;
 115                 if ($variation eq '') {
 116                         $openings{$hash} = $eco . ": " . $opening;
 117                 } else {
 118                         $openings{$hash} = $eco . ": " . $opening . ": " . $variation;
 119                 }
 120         }
 121         close $fh;
 122 }
 123
 124 sub read_root_pgn {
 125         my ($pgn_file_number, $pgn_start_position) = @_;
 126         my @pgnnames;
 127         open my $pgnnamesfh, "<", "../pgnnames.txt"
 128                 or die "../pgnnames.txt: $!";
 129         while (<$pgnnamesfh>) {
 130                 chomp;
 131                 push @pgnnames, $_;
 132         }
 133         close $pgnnamesfh;
 134
 135         if ($pgn_file_number > $#pgnnames) {
 136                 die "Unknown PGN file number $pgn_file_number";
 137         }
 138
 139         my $root_pgn;
 140         open my $pgnfh, "<", "../" . $pgnnames[$pgn_file_number]
 141                 or die $pgnnames[$pgn_file_number] . ": $!";
 142         sysseek($pgnfh, $pgn_start_position, 0)
 143                 or die "Could not seek to $pgn_start_position: $!";
 144         sysread($pgnfh, $root_pgn, 32768)
 145                 or die "Could not read PGN from $pgn_start_position at $pgnnames[$pgn_file_number]: $!";
 146         close $pgnfh;
 147         $root_pgn =~ s/^.*?(\[Event )/$1/s;
 148         $root_pgn =~ s/^(.+?)\[Event .*/$1/s;
 149
 150         return $root_pgn;
 151 }
 152
 153 sub get_json_move {
 154         my ($pos, $filter_prev_pos_hash, $chld_in, $chld_out) = @_;
 155         my $bpfen_hex = unpack('H*', $pos->bitpacked_fen);
 156         my $prev_pos_hash_hex = '';
 157         if (defined($filter_prev_pos_hash)) {
 158                 $prev_pos_hash_hex .= unpack('H*', pack('S', $filter_prev_pos_hash));
 159         }
 160         print $chld_in $bpfen_hex, "\n", $prev_pos_hash_hex, "\n";
 161
 162         # Read the hash of this position.
 163         chomp (my $pos_hash = <$chld_out>);
 164
 165         chomp (my $line = <$chld_out>);
 166         if ($line eq '-') {
 167                 warn "Missing pos '" . $pos->fen . "' " . $filter_prev_pos_hash;
 168                 return (undef, undef);
 169         }
 170
 171         my ($white, $draw, $black, $computer, $opening_num, $white_sum_elo, $black_sum_elo, $num_elo, $timestamp, $pgn_file_number, $pgn_start_position, @moves) = split / /, $line;
 172         my $json_pos = {
 173                 white => $white,
 174                 draw => $draw,
 175                 black => $black,
 176                 computer => $computer,
 177                 white_avg_elo => $num_elo == 0 ? undef : $white_sum_elo / $num_elo,
 178                 black_avg_elo => $num_elo == 0 ? undef : $black_sum_elo / $num_elo,
 179                 num_elo => $num_elo,
 180                 opening_num => $opening_num,
 181         };
 182         my $aux_data = {  # Only relevant for the root.
 183                 pos_hash => $pos_hash * 1,
 184                 moves => \@moves,
 185                 pgn_file_number => $pgn_file_number,
 186                 pgn_start_position => $pgn_start_position,
 187         };
 188         return ($json_pos, $aux_data);
 189 }