git.sesse.net Git - remoteglot-book/blob - www/opening-stats.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 use CGI;
   5 use JSON::XS;
   6 use lib '..';
   7 use Position;
   8 use IPC::Open2;
   9 use Chess::PGN::Parse;
  10
  11 our %openings = ();
  12 read_openings();
  13
  14 my $cgi = CGI->new;
  15 my ($chld_out, $chld_in);
  16 my $pid = IPC::Open2::open2($chld_out, $chld_in, "../binlookup", "../open.mtbl", "40");
  17
  18 # Root position. Basically ignore everything except the opening (and later some root game stuff).
  19 my $fen = $cgi->param('fen') // 'rnbqkbnr/pppppppp/8/8/8/8/PPPPPPPP/RNBQKBNR w KQkq - 0 1';
  20 my $includetransp = $cgi->param('includetransp') // 1;
  21
  22 my $pos = Position->from_fen($fen);
  23 my ($json_root_pos, $root_aux_data) = get_json_move($pos, undef, $chld_in, $chld_out);  # TODO: include previous hash if $includetransp == 0
  24 my $opening = $openings{$json_root_pos->{'opening_num'}} // 'A00: Start position';
  25
  26 my @json_moves = ($json_root_pos);
  27
  28 my $root_game;
  29 eval {
  30         if (!exists($root_aux_data->{'pgn_file_number'}) ||
  31             !exists($root_aux_data->{'pgn_start_position'})) {
  32                 die "Missing PGN position data."
  33         }
  34         my $pgntext = read_root_pgn($root_aux_data->{'pgn_file_number'}, $root_aux_data->{'pgn_start_position'});
  35         my $pgn = Chess::PGN::Parse->new(undef, $pgntext);
  36         $pgn->read_game() or die;
  37         $pgn->parse_game() or die;
  38
  39         my $tags = $pgn->tags;
  40         $root_game = {};
  41         $root_game->{'white'} = $pgn->white;
  42         $root_game->{'white_elo'} = $tags->{'WhiteElo'};
  43         $root_game->{'black'} = $pgn->black;
  44         $root_game->{'black_elo'} = $tags->{'BlackElo'};
  45         $root_game->{'event'} = $pgn->event;
  46         $root_game->{'date'} = $pgn->date;
  47         $root_game->{'result'} = $pgn->result;
  48         $root_game->{'eco'} = $pgn->eco;
  49         $root_game->{'moves'} = int(((scalar @{$pgn->moves}) + 1) / 2);
  50 };
  51
  52 # Explore one move out.
  53 for my $move (@{$root_aux_data->{'moves'}}) {
  54         my ($np, $uci_move) = $pos->make_pretty_move($move);
  55         my $json_pos;
  56         if ($includetransp) {
  57                 ($json_pos, undef) = get_json_move($np, undef, $chld_in, $chld_out);
  58         } else {
  59                 ($json_pos, undef) = get_json_move($np, $root_aux_data->{'pos_hash'}, $chld_in, $chld_out);
  60         }
  61         $json_pos->{'move'} = $move;
  62         push @json_moves, $json_pos;
  63 }
  64
  65 print $cgi->header(-type=>'application/json');
  66 print JSON::XS::encode_json({ moves => \@json_moves, opening => $opening, root_game => $root_game });
  67
  68 sub read_openings {
  69         open my $fh, "../openings.txt"
  70                 or die "../openings.txt: $!";
  71         for my $line (<$fh>) {
  72                 chomp $line;
  73                 my ($hash, $eco, $opening, $variation, $subvariation) = split /\t/, $line;
  74                 if ($variation eq '') {
  75                         $openings{$hash} = $eco . ": " . $opening;
  76                 } else {
  77                         $openings{$hash} = $eco . ": " . $opening . ": " . $variation;
  78                 }
  79         }
  80         close $fh;
  81 }
  82
  83 sub read_root_pgn {
  84         my ($pgn_file_number, $pgn_start_position) = @_;
  85         my @pgnnames;
  86         open my $pgnnamesfh, "<", "../pgnnames.txt"
  87                 or die "../pgnnames.txt: $!";
  88         while (<$pgnnamesfh>) {
  89                 chomp;
  90                 push @pgnnames, $_;
  91         }
  92         close $pgnnamesfh;
  93
  94         if ($pgn_file_number > $#pgnnames) {
  95                 die "Unknown PGN file number $pgn_file_number";
  96         }
  97
  98         my $root_pgn;
  99         open my $pgnfh, "<", "../" . $pgnnames[$pgn_file_number]
 100                 or die $pgnnames[$pgn_file_number] . ": $!";
 101         sysseek($pgnfh, $pgn_start_position, 0)
 102                 or die "Could not seek to $pgn_start_position: $!";
 103         sysread($pgnfh, $root_pgn, 32768)
 104                 or die "Could not read PGN from $pgn_start_position at $pgnnames[$pgn_file_number]: $!";
 105         close $pgnfh;
 106         $root_pgn =~ s/^.*?(\[Event )/$1/s;
 107         $root_pgn =~ s/^(.+?)\[Event .*/$1/s;
 108
 109         return $root_pgn;
 110 }
 111
 112 sub get_json_move {
 113         my ($pos, $filter_prev_pos_hash, $chld_in, $chld_out) = @_;
 114         my $hex = unpack('H*', $pos->bitpacked_fen);
 115         if (defined($filter_prev_pos_hash)) {
 116                 $hex .= unpack('H*', pack('S', $filter_prev_pos_hash));
 117         }
 118         print $chld_in $hex, "\n";
 119
 120         # Read the hash of this position.
 121         chomp (my $pos_hash = <$chld_out>);
 122
 123         chomp (my $line = <$chld_out>);
 124         if ($line eq '-') {
 125                 return ({}, {});
 126         }
 127
 128         my ($white, $draw, $black, $opening_num, $white_sum_elo, $black_sum_elo, $num_elo, $timestamp, $pgn_file_number, $pgn_start_position, @moves) = split / /, $line;
 129         my $json_pos = {
 130                 white => $white,
 131                 draw => $draw,
 132                 black => $black,
 133                 white_avg_elo => $num_elo == 0 ? undef : $white_sum_elo / $num_elo,
 134                 black_avg_elo => $num_elo == 0 ? undef : $black_sum_elo / $num_elo,
 135                 num_elo => $num_elo,
 136                 opening_num => $opening_num,
 137         };
 138         my $aux_data = {  # Only relevant for the root.
 139                 pos_hash => $pos_hash * 1,
 140                 moves => \@moves,
 141                 pgn_file_number => $pgn_file_number,
 142                 pgn_start_position => $pgn_start_position,
 143         };
 144         return ($json_pos, $aux_data);
 145 }