git.sesse.net Git - remoteglot-book/blob - www/opening-stats.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 use CGI;
   5 use JSON::XS;
   6 use lib '..';
   7 use Position;
   8 use IPC::Open2;
   9 use Chess::PGN::Parse;
  10
  11 our %openings = ();
  12 read_openings();
  13
  14 my $cgi = CGI->new;
  15 my ($chld_out, $chld_in);
  16 my $pid = IPC::Open2::open2($chld_out, $chld_in, "../binlookup", "../open.mtbl", "40");
  17
  18 # Root position. Basically ignore everything except the opening (and later some root game stuff).
  19 my $fen = $cgi->param('fen') // 'rnbqkbnr/pppppppp/8/8/8/8/PPPPPPPP/RNBQKBNR w KQkq - 0 1';
  20 my $includetransp = $cgi->param('includetransp') // 1;
  21
  22 my $pos = Position->from_fen($fen);
  23 my ($json_root_pos, $root_aux_data) = get_json_move($pos, undef, $chld_in, $chld_out);
  24
  25 my $opening = $openings{$json_root_pos->{'opening_num'}} // 'A00: Start position';
  26 my @json_moves = ($json_root_pos);
  27
  28 my $root_game;
  29 eval {
  30         if (!exists($root_aux_data->{'pgn_file_number'}) ||
  31             !exists($root_aux_data->{'pgn_start_position'})) {
  32                 die "Missing PGN position data."
  33         }
  34         my $pgntext = read_root_pgn($root_aux_data->{'pgn_file_number'}, $root_aux_data->{'pgn_start_position'});
  35         my $pgn = Chess::PGN::Parse->new(undef, $pgntext);
  36         $pgn->read_game() or die;
  37         $pgn->parse_game() or die;
  38
  39         my $tags = $pgn->tags;
  40         $root_game = {};
  41         $root_game->{'white'} = $pgn->white;
  42         $root_game->{'white_elo'} = $tags->{'WhiteElo'};
  43         $root_game->{'black'} = $pgn->black;
  44         $root_game->{'black_elo'} = $tags->{'BlackElo'};
  45         $root_game->{'event'} = $pgn->event;
  46         $root_game->{'date'} = $pgn->date;
  47         $root_game->{'result'} = $pgn->result;
  48         $root_game->{'eco'} = $pgn->eco;
  49         $root_game->{'moves'} = int(((scalar @{$pgn->moves}) + 1) / 2);
  50 };
  51
  52 # Explore one move out.
  53 for my $move (@{$root_aux_data->{'moves'}}) {
  54         my ($np, $uci_move) = $pos->make_pretty_move($move);
  55         my $json_pos;
  56         if ($includetransp) {
  57                 ($json_pos, undef) = get_json_move($np, undef, $chld_in, $chld_out);
  58
  59                 # See if this move exists only due to transpositions.
  60                 my ($alt_json_pos, undef) = get_json_move($np, $root_aux_data->{'pos_hash'}, $chld_in, $chld_out);
  61                 if (!defined($alt_json_pos)) {
  62                         $json_pos->{'transpose_only'} = 1;
  63                 }
  64         } else {
  65                 ($json_pos, undef) = get_json_move($np, $root_aux_data->{'pos_hash'}, $chld_in, $chld_out);
  66         }
  67         $json_pos->{'move'} = $move;
  68         push @json_moves, $json_pos;
  69 }
  70
  71 print $cgi->header(-type=>'application/json');
  72 print JSON::XS::encode_json({ moves => \@json_moves, opening => $opening, root_game => $root_game });
  73
  74 sub read_openings {
  75         open my $fh, "../openings.txt"
  76                 or die "../openings.txt: $!";
  77         for my $line (<$fh>) {
  78                 chomp $line;
  79                 my ($hash, $eco, $opening, $variation, $subvariation) = split /\t/, $line;
  80                 if ($variation eq '') {
  81                         $openings{$hash} = $eco . ": " . $opening;
  82                 } else {
  83                         $openings{$hash} = $eco . ": " . $opening . ": " . $variation;
  84                 }
  85         }
  86         close $fh;
  87 }
  88
  89 sub read_root_pgn {
  90         my ($pgn_file_number, $pgn_start_position) = @_;
  91         my @pgnnames;
  92         open my $pgnnamesfh, "<", "../pgnnames.txt"
  93                 or die "../pgnnames.txt: $!";
  94         while (<$pgnnamesfh>) {
  95                 chomp;
  96                 push @pgnnames, $_;
  97         }
  98         close $pgnnamesfh;
  99
 100         if ($pgn_file_number > $#pgnnames) {
 101                 die "Unknown PGN file number $pgn_file_number";
 102         }
 103
 104         my $root_pgn;
 105         open my $pgnfh, "<", "../" . $pgnnames[$pgn_file_number]
 106                 or die $pgnnames[$pgn_file_number] . ": $!";
 107         sysseek($pgnfh, $pgn_start_position, 0)
 108                 or die "Could not seek to $pgn_start_position: $!";
 109         sysread($pgnfh, $root_pgn, 32768)
 110                 or die "Could not read PGN from $pgn_start_position at $pgnnames[$pgn_file_number]: $!";
 111         close $pgnfh;
 112         $root_pgn =~ s/^.*?(\[Event )/$1/s;
 113         $root_pgn =~ s/^(.+?)\[Event .*/$1/s;
 114
 115         return $root_pgn;
 116 }
 117
 118 sub get_json_move {
 119         my ($pos, $filter_prev_pos_hash, $chld_in, $chld_out) = @_;
 120         my $bpfen_hex = unpack('H*', $pos->bitpacked_fen);
 121         my $prev_pos_hash_hex = '';
 122         if (defined($filter_prev_pos_hash)) {
 123                 $prev_pos_hash_hex .= unpack('H*', pack('S', $filter_prev_pos_hash));
 124         }
 125         print $chld_in $bpfen_hex, "\n", $prev_pos_hash_hex, "\n";
 126
 127         # Read the hash of this position.
 128         chomp (my $pos_hash = <$chld_out>);
 129
 130         chomp (my $line = <$chld_out>);
 131         if ($line eq '-') {
 132                 warn "Missing pos '" . $pos->fen . "' " . $filter_prev_pos_hash;
 133                 return (undef, undef);
 134         }
 135
 136         my ($white, $draw, $black, $opening_num, $white_sum_elo, $black_sum_elo, $num_elo, $timestamp, $pgn_file_number, $pgn_start_position, @moves) = split / /, $line;
 137         my $json_pos = {
 138                 white => $white,
 139                 draw => $draw,
 140                 black => $black,
 141                 white_avg_elo => $num_elo == 0 ? undef : $white_sum_elo / $num_elo,
 142                 black_avg_elo => $num_elo == 0 ? undef : $black_sum_elo / $num_elo,
 143                 num_elo => $num_elo,
 144                 opening_num => $opening_num,
 145         };
 146         my $aux_data = {  # Only relevant for the root.
 147                 pos_hash => $pos_hash * 1,
 148                 moves => \@moves,
 149                 pgn_file_number => $pgn_file_number,
 150                 pgn_start_position => $pgn_start_position,
 151         };
 152         return ($json_pos, $aux_data);
 153 }