git.sesse.net Git - remoteglot-book/blob - www/opening-stats.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 use CGI;
   5 use JSON::XS;
   6 use lib '..';
   7 use Position;
   8 use IPC::Open2;
   9 use Chess::PGN::Parse;
  10
  11 our %openings = ();
  12 read_openings();
  13
  14 my $cgi = CGI->new;
  15 my ($chld_out, $chld_in);
  16 my $pid = IPC::Open2::open2($chld_out, $chld_in, "../binlookup", "../open.mtbl", "40");
  17
  18 # Root position. Basically ignore everything except the opening (and later some root game stuff).
  19 my $fen = $cgi->param('fen') // 'rnbqkbnr/pppppppp/8/8/8/8/PPPPPPPP/RNBQKBNR w KQkq - 0 1';
  20 my $prevfen = $cgi->param('prevfen') // '';
  21 my $includetransp = $cgi->param('includetransp') // 1;
  22
  23 my $pos = Position->from_fen($fen);
  24 my ($json_root_pos, $root_aux_data);
  25 if ($includetransp) {
  26         ($json_root_pos, $root_aux_data) = get_json_move($pos, undef, $chld_in, $chld_out);
  27 } else {
  28         my $prev_pos_hash = 0;
  29         if ($prevfen ne '') {
  30                 my $prevpos = Position->from_fen($prevfen);
  31                 my (undef, $prev_aux_data) = get_json_move($prevpos, undef, $chld_in, $chld_out);
  32                 $prev_pos_hash = $prev_aux_data->{'pos_hash'};
  33         }
  34         ($json_root_pos, $root_aux_data) = get_json_move($pos, $prev_pos_hash, $chld_in, $chld_out);
  35 }
  36
  37 my $opening = $openings{$json_root_pos->{'opening_num'}} // 'A00: Start position';
  38 my @json_moves = ($json_root_pos);
  39
  40 my $root_game;
  41 eval {
  42         if (!exists($root_aux_data->{'pgn_file_number'}) ||
  43             !exists($root_aux_data->{'pgn_start_position'})) {
  44                 die "Missing PGN position data."
  45         }
  46         my $pgntext = read_root_pgn($root_aux_data->{'pgn_file_number'}, $root_aux_data->{'pgn_start_position'});
  47         my $pgn = Chess::PGN::Parse->new(undef, $pgntext);
  48         $pgn->read_game() or die;
  49         $pgn->parse_game() or die;
  50
  51         my $tags = $pgn->tags;
  52         $root_game = {};
  53         $root_game->{'white'} = $pgn->white;
  54         $root_game->{'white_elo'} = $tags->{'WhiteElo'};
  55         $root_game->{'black'} = $pgn->black;
  56         $root_game->{'black_elo'} = $tags->{'BlackElo'};
  57         $root_game->{'event'} = $pgn->event;
  58         $root_game->{'date'} = $pgn->date;
  59         $root_game->{'result'} = $pgn->result;
  60         $root_game->{'eco'} = $pgn->eco;
  61         $root_game->{'moves'} = int(((scalar @{$pgn->moves}) + 1) / 2);
  62 };
  63
  64 # Explore one move out.
  65 for my $move (@{$root_aux_data->{'moves'}}) {
  66         my ($np, $uci_move) = $pos->make_pretty_move($move);
  67         my $json_pos;
  68         if ($includetransp) {
  69                 ($json_pos, undef) = get_json_move($np, undef, $chld_in, $chld_out);
  70         } else {
  71                 ($json_pos, undef) = get_json_move($np, $root_aux_data->{'pos_hash'}, $chld_in, $chld_out);
  72         }
  73         $json_pos->{'move'} = $move;
  74         push @json_moves, $json_pos;
  75 }
  76
  77 print $cgi->header(-type=>'application/json');
  78 print JSON::XS::encode_json({ moves => \@json_moves, opening => $opening, root_game => $root_game });
  79
  80 sub read_openings {
  81         open my $fh, "../openings.txt"
  82                 or die "../openings.txt: $!";
  83         for my $line (<$fh>) {
  84                 chomp $line;
  85                 my ($hash, $eco, $opening, $variation, $subvariation) = split /\t/, $line;
  86                 if ($variation eq '') {
  87                         $openings{$hash} = $eco . ": " . $opening;
  88                 } else {
  89                         $openings{$hash} = $eco . ": " . $opening . ": " . $variation;
  90                 }
  91         }
  92         close $fh;
  93 }
  94
  95 sub read_root_pgn {
  96         my ($pgn_file_number, $pgn_start_position) = @_;
  97         my @pgnnames;
  98         open my $pgnnamesfh, "<", "../pgnnames.txt"
  99                 or die "../pgnnames.txt: $!";
 100         while (<$pgnnamesfh>) {
 101                 chomp;
 102                 push @pgnnames, $_;
 103         }
 104         close $pgnnamesfh;
 105
 106         if ($pgn_file_number > $#pgnnames) {
 107                 die "Unknown PGN file number $pgn_file_number";
 108         }
 109
 110         my $root_pgn;
 111         open my $pgnfh, "<", "../" . $pgnnames[$pgn_file_number]
 112                 or die $pgnnames[$pgn_file_number] . ": $!";
 113         sysseek($pgnfh, $pgn_start_position, 0)
 114                 or die "Could not seek to $pgn_start_position: $!";
 115         sysread($pgnfh, $root_pgn, 32768)
 116                 or die "Could not read PGN from $pgn_start_position at $pgnnames[$pgn_file_number]: $!";
 117         close $pgnfh;
 118         $root_pgn =~ s/^.*?(\[Event )/$1/s;
 119         $root_pgn =~ s/^(.+?)\[Event .*/$1/s;
 120
 121         return $root_pgn;
 122 }
 123
 124 sub get_json_move {
 125         my ($pos, $filter_prev_pos_hash, $chld_in, $chld_out) = @_;
 126         my $bpfen_hex = unpack('H*', $pos->bitpacked_fen);
 127         my $prev_pos_hash_hex = '';
 128         if (defined($filter_prev_pos_hash)) {
 129                 $prev_pos_hash_hex .= unpack('H*', pack('S', $filter_prev_pos_hash));
 130         }
 131         print $chld_in $bpfen_hex, "\n", $prev_pos_hash_hex, "\n";
 132
 133         # Read the hash of this position.
 134         chomp (my $pos_hash = <$chld_out>);
 135
 136         chomp (my $line = <$chld_out>);
 137         if ($line eq '-') {
 138                 warn "Missing pos '" . $pos->fen . "' " . $filter_prev_pos_hash;
 139                 return ({}, {});
 140         }
 141
 142         my ($white, $draw, $black, $opening_num, $white_sum_elo, $black_sum_elo, $num_elo, $timestamp, $pgn_file_number, $pgn_start_position, @moves) = split / /, $line;
 143         my $json_pos = {
 144                 white => $white,
 145                 draw => $draw,
 146                 black => $black,
 147                 white_avg_elo => $num_elo == 0 ? undef : $white_sum_elo / $num_elo,
 148                 black_avg_elo => $num_elo == 0 ? undef : $black_sum_elo / $num_elo,
 149                 num_elo => $num_elo,
 150                 opening_num => $opening_num,
 151         };
 152         my $aux_data = {  # Only relevant for the root.
 153                 pos_hash => $pos_hash * 1,
 154                 moves => \@moves,
 155                 pgn_file_number => $pgn_file_number,
 156                 pgn_start_position => $pgn_start_position,
 157         };
 158         return ($json_pos, $aux_data);
 159 }