git.sesse.net Git - remoteglot-book/blob - www/opening-stats.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 use CGI;
   5 use JSON::XS;
   6 use lib '..';
   7 use Position;
   8 use IPC::Open2;
   9 use Chess::PGN::Parse;
  10
  11 our %openings = ();
  12 read_openings();
  13
  14 my $cgi = CGI->new;
  15 my ($chld_out, $chld_in);
  16 my $pid = IPC::Open2::open2($chld_out, $chld_in, "../binlookup", "../open.mtbl", "40");
  17
  18 # Root position. Basically ignore everything except the opening (and later some root game stuff).
  19 my $fen = $cgi->param('fen') // 'rnbqkbnr/pppppppp/8/8/8/8/PPPPPPPP/RNBQKBNR w KQkq - 0 1';
  20 my $includetransp = $cgi->param('includetransp') // 1;
  21
  22 my $pos = Position->from_fen($fen);
  23 my ($json_root_pos, $root_aux_data) = get_json_move($pos, undef, $chld_in, $chld_out);
  24
  25 my $opening = $openings{$json_root_pos->{'opening_num'}} // 'A00: Start position';
  26 my @json_moves = ($json_root_pos);
  27
  28 my $root_game;
  29 eval {
  30         if (!exists($root_aux_data->{'pgn_file_number'}) ||
  31             !exists($root_aux_data->{'pgn_start_position'})) {
  32                 die "Missing PGN position data."
  33         }
  34         my $pgntext = read_root_pgn($root_aux_data->{'pgn_file_number'}, $root_aux_data->{'pgn_start_position'});
  35         my $pgn = Chess::PGN::Parse->new(undef, $pgntext);
  36         $pgn->read_game() or die;
  37         $pgn->parse_game() or die;
  38
  39         my $tags = $pgn->tags;
  40         $root_game = {};
  41         $root_game->{'white'} = $pgn->white;
  42         $root_game->{'white_elo'} = $tags->{'WhiteElo'};
  43         $root_game->{'black'} = $pgn->black;
  44         $root_game->{'black_elo'} = $tags->{'BlackElo'};
  45         $root_game->{'event'} = $pgn->event;
  46         $root_game->{'date'} = $pgn->date;
  47         $root_game->{'result'} = $pgn->result;
  48         $root_game->{'eco'} = $pgn->eco;
  49         $root_game->{'moves'} = int(((scalar @{$pgn->moves}) + 1) / 2);
  50 };
  51
  52 # Explore one move out.
  53 for my $move (@{$root_aux_data->{'moves'}}) {
  54         my ($np, $uci_move) = $pos->make_pretty_move($move);
  55         my $json_pos;
  56         if ($includetransp) {
  57                 ($json_pos, undef) = get_json_move($np, undef, $chld_in, $chld_out);
  58
  59                 # See if this move exists only due to transpositions.
  60                 my ($alt_json_pos, undef) = get_json_move($np, $root_aux_data->{'pos_hash'}, $chld_in, $chld_out);
  61                 if (!defined($alt_json_pos)) {
  62                         $json_pos->{'transpose_only'} = 1;
  63                 }
  64         } else {
  65                 ($json_pos, undef) = get_json_move($np, $root_aux_data->{'pos_hash'}, $chld_in, $chld_out);
  66         }
  67         $json_pos->{'move'} = $move;
  68         push @json_moves, $json_pos;
  69 }
  70
  71 # Get stats for the root position, for the human index.
  72 my $start_pos = Position->start_pos;
  73 my ($json_start_pos, undef) = get_json_move($start_pos, 0, $chld_in, $chld_out);
  74 my $total_games = $json_start_pos->{'white'} + $json_start_pos->{'draw'} + $json_start_pos->{'black'};
  75 my $computer_games = $json_start_pos->{'computer'} * 1;
  76
  77 print $cgi->header(-type=>'application/json');
  78 print JSON::XS::encode_json({
  79         moves => \@json_moves,
  80         opening => $opening,
  81         root_game => $root_game,
  82         total_games => $total_games,
  83         computer_games => $computer_games
  84 });
  85
  86 sub read_openings {
  87         open my $fh, "../openings.txt"
  88                 or die "../openings.txt: $!";
  89         for my $line (<$fh>) {
  90                 chomp $line;
  91                 my ($hash, $eco, $opening, $variation, $subvariation) = split /\t/, $line;
  92                 if ($variation eq '') {
  93                         $openings{$hash} = $eco . ": " . $opening;
  94                 } else {
  95                         $openings{$hash} = $eco . ": " . $opening . ": " . $variation;
  96                 }
  97         }
  98         close $fh;
  99 }
 100
 101 sub read_root_pgn {
 102         my ($pgn_file_number, $pgn_start_position) = @_;
 103         my @pgnnames;
 104         open my $pgnnamesfh, "<", "../pgnnames.txt"
 105                 or die "../pgnnames.txt: $!";
 106         while (<$pgnnamesfh>) {
 107                 chomp;
 108                 push @pgnnames, $_;
 109         }
 110         close $pgnnamesfh;
 111
 112         if ($pgn_file_number > $#pgnnames) {
 113                 die "Unknown PGN file number $pgn_file_number";
 114         }
 115
 116         my $root_pgn;
 117         open my $pgnfh, "<", "../" . $pgnnames[$pgn_file_number]
 118                 or die $pgnnames[$pgn_file_number] . ": $!";
 119         sysseek($pgnfh, $pgn_start_position, 0)
 120                 or die "Could not seek to $pgn_start_position: $!";
 121         sysread($pgnfh, $root_pgn, 32768)
 122                 or die "Could not read PGN from $pgn_start_position at $pgnnames[$pgn_file_number]: $!";
 123         close $pgnfh;
 124         $root_pgn =~ s/^.*?(\[Event )/$1/s;
 125         $root_pgn =~ s/^(.+?)\[Event .*/$1/s;
 126
 127         return $root_pgn;
 128 }
 129
 130 sub get_json_move {
 131         my ($pos, $filter_prev_pos_hash, $chld_in, $chld_out) = @_;
 132         my $bpfen_hex = unpack('H*', $pos->bitpacked_fen);
 133         my $prev_pos_hash_hex = '';
 134         if (defined($filter_prev_pos_hash)) {
 135                 $prev_pos_hash_hex .= unpack('H*', pack('S', $filter_prev_pos_hash));
 136         }
 137         print $chld_in $bpfen_hex, "\n", $prev_pos_hash_hex, "\n";
 138
 139         # Read the hash of this position.
 140         chomp (my $pos_hash = <$chld_out>);
 141
 142         chomp (my $line = <$chld_out>);
 143         if ($line eq '-') {
 144                 warn "Missing pos '" . $pos->fen . "' " . $filter_prev_pos_hash;
 145                 return (undef, undef);
 146         }
 147
 148         my ($white, $draw, $black, $computer, $opening_num, $white_sum_elo, $black_sum_elo, $num_elo, $timestamp, $pgn_file_number, $pgn_start_position, @moves) = split / /, $line;
 149         my $json_pos = {
 150                 white => $white,
 151                 draw => $draw,
 152                 black => $black,
 153                 computer => $computer,
 154                 white_avg_elo => $num_elo == 0 ? undef : $white_sum_elo / $num_elo,
 155                 black_avg_elo => $num_elo == 0 ? undef : $black_sum_elo / $num_elo,
 156                 num_elo => $num_elo,
 157                 opening_num => $opening_num,
 158         };
 159         my $aux_data = {  # Only relevant for the root.
 160                 pos_hash => $pos_hash * 1,
 161                 moves => \@moves,
 162                 pgn_file_number => $pgn_file_number,
 163                 pgn_start_position => $pgn_start_position,
 164         };
 165         return ($json_pos, $aux_data);
 166 }