git.sesse.net Git - remoteglot-book/blob - www/opening-stats.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 use CGI;
   5 use JSON::XS;
   6 use lib '..';
   7 use Position;
   8 use IPC::Open2;
   9 use Chess::PGN::Parse;
  10
  11 our %openings = ();
  12 read_openings();
  13
  14 my $cgi = CGI->new;
  15 my ($chld_out, $chld_in);
  16 my $pid = IPC::Open2::open2($chld_out, $chld_in, "../binlookup", "../open.mtbl", "40");
  17
  18 # Root position. Basically ignore everything except the opening (and later some root game stuff).
  19 my $fen = $cgi->param('fen') // 'rnbqkbnr/pppppppp/8/8/8/8/PPPPPPPP/RNBQKBNR w KQkq - 0 1';
  20 my $pos = Position->from_fen($fen);
  21 my $hex = unpack('H*', $pos->bitpacked_fen);
  22 print $chld_in $hex, "\n";
  23 chomp (my $line = <$chld_out>);
  24
  25 my ($white, $draw, $black, $opening_num, $white_avg_elo, $black_avg_elo, $num_elo, $timestamp, $pgn_file_number, $pgn_start_position, @moves) = split / /, $line;
  26 my @json_moves = ();
  27 push @json_moves, {
  28         white => $white * 1,
  29         draw => $draw * 1,
  30         black => $black * 1,
  31         white_avg_elo => $white_avg_elo * 1,
  32         black_avg_elo => $black_avg_elo * 1,
  33         num_elo => $num_elo * 1
  34 };
  35
  36 my $opening = $openings{$opening_num} // 'A00: Start position';
  37
  38 my $root_game;
  39 eval {
  40         die "Missing PGN position data." if (!defined($pgn_file_number) || !defined($pgn_start_position));
  41         my $pgntext = read_root_pgn($pgn_file_number, $pgn_start_position);
  42         my $pgn = Chess::PGN::Parse->new(undef, $pgntext);
  43         $pgn->read_game() or die;
  44         $pgn->parse_game() or die;
  45
  46         my $tags = $pgn->tags;
  47         $root_game = {};
  48         $root_game->{'white'} = $pgn->white;
  49         $root_game->{'white_elo'} = $tags->{'WhiteElo'};
  50         $root_game->{'black'} = $pgn->black;
  51         $root_game->{'black_elo'} = $tags->{'BlackElo'};
  52         $root_game->{'event'} = $pgn->event;
  53         $root_game->{'date'} = $pgn->date;
  54         $root_game->{'result'} = $pgn->result;
  55         $root_game->{'eco'} = $pgn->eco;
  56         $root_game->{'moves'} = scalar @{$pgn->moves};
  57 };
  58
  59 # Explore one move out.
  60 for my $move (@moves) {
  61         my ($np, $uci_move) = $pos->make_pretty_move($move);
  62         my $hex = unpack('H*', $np->bitpacked_fen);
  63         print $chld_in $hex, "\n";
  64         my $line = <$chld_out>;
  65         my ($white, $draw, $black, $opening_num, $white_avg_elo, $black_avg_elo, $num_elo) = split / /, $line;
  66         push @json_moves, {
  67                 move => $move,
  68                 white => $white * 1,
  69                 draw => $draw * 1,
  70                 black => $black * 1,
  71                 white_avg_elo => $white_avg_elo * 1,
  72                 black_avg_elo => $black_avg_elo * 1,
  73                 num_elo => $num_elo * 1
  74         };
  75 }
  76
  77 print $cgi->header(-type=>'application/json');
  78 print JSON::XS::encode_json({ moves => \@json_moves, opening => $opening, root_game => $root_game });
  79
  80 sub read_openings {
  81         open my $fh, "../openings.txt"
  82                 or die "../openings.txt: $!";
  83         for my $line (<$fh>) {
  84                 chomp $line;
  85                 my ($hash, $eco, $opening, $variation, $subvariation) = split /\t/, $line;
  86                 if ($variation eq '') {
  87                         $openings{$hash} = $eco . ": " . $opening;
  88                 } else {
  89                         $openings{$hash} = $eco . ": " . $opening . ": " . $variation;
  90                 }
  91         }
  92         close $fh;
  93 }
  94
  95 sub read_root_pgn {
  96         my @pgnnames;
  97         open my $pgnnamesfh, "<", "../pgnnames.txt"
  98                 or die "../pgnnames.txt: $!";
  99         while (<$pgnnamesfh>) {
 100                 chomp;
 101                 push @pgnnames, $_;
 102         }
 103         close $pgnnamesfh;
 104
 105         if ($pgn_file_number > $#pgnnames) {
 106                 die "Unknown PGN file number $pgn_file_number";
 107         }
 108
 109         my $root_pgn;
 110         open my $pgnfh, "<", "../" . $pgnnames[$pgn_file_number]
 111                 or die $pgnnames[$pgn_file_number] . ": $!";
 112         sysseek($pgnfh, $pgn_start_position, 0)
 113                 or die "Could not seek to $pgn_start_position: $!";
 114         sysread($pgnfh, $root_pgn, 32768)
 115                 or die "Could not read PGN from $pgn_start_position at $pgnnames[$pgn_file_number]: $!";
 116         close $pgnfh;
 117         $root_pgn =~ s/^.*?(\[Event )/$1/s;
 118         $root_pgn =~ s/^(.+?)\[Event .*/$1/s;
 119
 120         return $root_pgn;
 121 }