git.sesse.net Git - wloh/blob - www/index.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 no warnings qw(once);
   5 use CGI;
   6 use CGI::Carp qw( fatalsToBrowser );
   7 use DBI;
   8 use POSIX;
   9 use Devel::Peek;
  10 use HTML::Entities;
  11 use Encode;
  12 use utf8;
  13 use locale;
  14 require '../config.pm';
  15 require '../common.pm';
  16
  17 my $cgi = CGI->new;
  18
  19 my $dbh = DBI->connect($config::local_connstr, $config::local_username, $config::local_password)
  20         or die "connect: " . $DBI::errstr;
  21 $dbh->{AutoCommit} = 0;
  22 $dbh->{RaiseError} = 1;
  23
  24 my $trials = 25_000;
  25
  26 binmode STDOUT, ':utf8';
  27
  28 my %players = ();
  29 my %ratings = ();
  30 my %ratings_stddev = ();
  31 my @matches = ();
  32
  33 sub sanitize {
  34         return HTML::Entities::encode_entities(shift);
  35 }
  36
  37 sub color {
  38         my $x = shift;
  39         return int(255.0 * ($x ** (1.80)));
  40 }
  41
  42 sub get_max_season {
  43         my $dbh = shift;
  44         my $ref = $dbh->selectrow_hashref('SELECT MAX(sesong) AS max_sesong FROM fotballserier');
  45         return $ref->{'max_sesong'};
  46 }
  47
  48 sub get_divisions {
  49         my ($dbh, $season) = @_;
  50
  51         my @divisions = ();
  52
  53         my $q = $dbh->prepare('SELECT DISTINCT(divisjon) FROM fotballserier WHERE sesong=? ORDER BY divisjon');
  54         $q->execute($season);
  55
  56         while (my $ref = $q->fetchrow_hashref) {
  57                 push @divisions, $ref->{'divisjon'};
  58         }
  59
  60         return @divisions;
  61 }
  62
  63 sub get_subdivisions {
  64         my ($dbh, $season, $division) = @_;
  65
  66         my @subdivisions = ();
  67
  68         my $q = $dbh->prepare('SELECT DISTINCT(avdeling) FROM fotballserier WHERE sesong=? AND divisjon=? ORDER BY avdeling');
  69         $q->execute($season, $division);
  70
  71         while (my $ref = $q->fetchrow_hashref) {
  72                 push @subdivisions, $ref->{'avdeling'};
  73         }
  74
  75         return @subdivisions;
  76 }
  77
  78 sub print_division_selector {
  79         my ($dbh, $divisions, $subdivisions, $division, $subdivision) = @_;
  80
  81         print <<"EOF";
  82     <form method="get" action="/">
  83 EOF
  84
  85         my $max_division = $divisions->[(scalar @$divisions) - 1];
  86
  87         print <<"EOF";
  88      <p>Divisjon:
  89         <select name="divisjon" onchange="form.submit();">
  90 EOF
  91
  92         for my $d (@$divisions) {
  93                 if ($d == $division) {
  94                         print "        <option value=\"$d\" selected=\"selected\">$d</option>\n";
  95                 } else {
  96                         print "        <option value=\"$d\">$d</option>\n";
  97                 }
  98         }
  99
 100         print <<"EOF";
 101         </select>
 102         Avdeling:
 103         <select name="avdeling" onchange="form.submit();">
 104 EOF
 105
 106         for my $sd (@$subdivisions) {
 107                 if ($sd == $subdivision) {
 108                         print "        <option value=\"$sd\" selected=\"selected\">$sd</option>\n";
 109                 } else {
 110                         print "        <option value=\"$sd\">$sd</option>\n";
 111                 }
 112         }
 113
 114         print <<"EOF";
 115         </select>
 116         <input type="submit" value="Vis" />
 117       </p>
 118     </form>
 119 EOF
 120 }
 121
 122 sub get_players_and_ratings {
 123         my ($dbh, $season, $division, $subdivision) = @_;
 124
 125         my $q = $dbh->prepare('SELECT fotballdeltagere.id,fotballdeltagere.navn,rating,rating_stddev FROM fotballdeltagere JOIN fotballserier ON fotballdeltagere.serie=fotballserier.nr LEFT JOIN ratings ON fotballdeltagere.id=ratings.id WHERE sesong=? AND divisjon=? AND avdeling=?');
 126         $q->execute($season, $division, $subdivision);
 127
 128         while (my $ref = $q->fetchrow_hashref) {
 129                 my $id = $ref->{'id'};
 130                 $players{$id} = sanitize(Encode::decode_utf8($ref->{'navn'}));
 131                 $ratings{$id} = $ref->{'rating'};
 132                 $ratings_stddev{$id} = $ref->{'rating_stddev'};
 133         }
 134         $q->finish;
 135 }
 136
 137 sub get_matches {
 138         my ($dbh, $season, $division, $subdivision) = @_;
 139
 140         my @matches = ();
 141         my $q = $dbh->prepare('
 142         SELECT
 143           d1.id AS p1, d2.id AS p2, maalfor AS score1, maalmot AS score2
 144         FROM fotballresultater r
 145           JOIN fotballserier s ON r.serie=s.nr
 146           JOIN fotballdeltagere d1 ON r.lagrecno=d1.nr AND r.serie=d1.serie
 147           JOIN fotballdeltagere d2 ON r.motstander=d2.nr AND r.serie=d2.serie
 148         WHERE
 149           sesong=? AND divisjon=? AND avdeling=?
 150           AND lagrecno > motstander
 151         ');
 152         $q->execute($season, $division, $subdivision);
 153
 154         while (my $ref = $q->fetchrow_hashref) {
 155                 push @matches, [ $ref->{'p1'}, $ref->{'p2'}, $ref->{'score1'}, $ref->{'score2'} ];
 156         }
 157         $q->finish;
 158
 159         return @matches;
 160 }
 161
 162 sub get_covariance_matrix {
 163         my ($dbh, @players) = @_;
 164
 165         my $player_sql = '{' . join(',', @players ) . '}';
 166         my $q = $dbh->prepare('SELECT * FROM covariance WHERE player1=ANY(?::smallint[]) AND player2=ANY(?::smallint[])', { pg_prepare_now => 0 });
 167         $q->execute($player_sql, $player_sql);
 168
 169         my $cov = {};
 170         while (my $ref = $q->fetchrow_hashref) {
 171                 $cov->{$ref->{'player1'}}{$ref->{'player2'}} = $ref->{'cov'};
 172         }
 173
 174         return $cov;
 175 }
 176
 177 sub write_parms_to_file {
 178         my ($aux_parms, $match_stddev, $used_ratings, $used_cov) = @_;
 179
 180         POSIX::setlocale(&POSIX::LC_ALL, 'nb_NO.UTF-8');
 181
 182         my @sorted_players = sort { $players{$a} cmp $players{$b} } keys %players;
 183
 184         POSIX::setlocale(&POSIX::LC_ALL, 'C');
 185
 186         my $tmpnam = POSIX::tmpnam();
 187         open MCCALC, ">", $tmpnam
 188                 or die "$tmpnam: $!";
 189
 190         printf MCCALC "%f\n", $match_stddev;
 191         printf MCCALC "%d\n", scalar keys %players;
 192
 193         for my $id (@sorted_players) {
 194                 my $rating = $used_ratings->{$id} // 500.0;
 195                 printf MCCALC "%s %f\n", $id, $rating;
 196         }
 197
 198         # covariance matrix
 199         for my $id1 (keys %players) {
 200                 for my $id2 (keys %players) {
 201                         if ($id1 == $id2) {
 202                                 printf MCCALC "%f ", ($used_cov->{$id1}{$id2} // $aux_parms->{-3});
 203                         } else {
 204                                 printf MCCALC "%f ", ($used_cov->{$id1}{$id2} // 0.0);
 205                         }
 206                 }
 207                 printf MCCALC "\n";
 208         }
 209
 210         for my $match (@matches) {
 211                 printf MCCALC "%s %s %d %d\n", $match->[0], $match->[1], $match->[2], $match->[3];
 212         }
 213         close MCCALC;
 214
 215         POSIX::setlocale(&POSIX::LC_ALL, 'nb_NO.UTF-8');
 216
 217         return $tmpnam;
 218 }
 219
 220 my $num_tables = 0;
 221
 222 sub make_table {
 223         my ($aux_parms, $match_stddev, $lowest_division, $used_ratings, $used_cov, $division, $subdivision) = @_;
 224         ++$num_tables;
 225
 226         print <<"EOF";
 227
 228     <table class="probmatrix">
 229       <tr>
 230         <th></th>
 231 EOF
 232
 233         my $tmpnam = write_parms_to_file($aux_parms, $match_stddev, $used_ratings, $used_cov);
 234         my %prob = ();
 235
 236         open MCCALC, "$config::base_dir/mcwordfeud $trials < $tmpnam |"
 237                 or die "mccalc: $!";
 238         while (<MCCALC>) {
 239                 chomp;
 240                 my @x = split /\s+/;
 241                 my $id = $x[0];
 242                 my $player = sprintf "%s (%.0f ± %.0f)", $players{$id}, ($ratings{$id} // 500.0), ($ratings_stddev{$id} // $aux_parms->{-3});
 243                 $prob{$player} = [ @x[1..$#x] ];
 244         }
 245         close MCCALC;
 246         #unlink $tmpnam;
 247
 248         my $num_games = scalar keys %prob;
 249         for my $i (1..$num_games) {
 250                 print "        <th>$i.</th>\n";
 251         }
 252         print "        <th>NEDRYKK</th>\n" unless ($lowest_division);
 253         print "      </tr>\n";
 254
 255         my $pnum = 0;
 256         for my $player (sort { $a cmp $b } keys %prob) {
 257                 ++$pnum;
 258                 print "      <tr>\n";
 259                 print "        <th>$player</th>\n";
 260
 261                 for my $i (1..$num_games) {
 262                         my $pn = $prob{$player}->[$i - 1] / $trials;
 263
 264                         my $r = color(1.0 - $pn / 3);
 265                         my $g = color(1.0 - $pn / 3);
 266                         my $b = color(1.0);
 267
 268                         if ($i == 1) {
 269                                 ($g, $b) = ($b, $g);
 270                         } elsif ($i >= $num_games - 1 && !$lowest_division) {
 271                                 ($r, $b) = ($b, $r);
 272                         }
 273
 274                         printf "        <td style=\"background-color: rgb($r, $g, $b)\" class=\"num\"><a class=\"unmarkedlink\" href=\"javascript:var obj=document.getElementById('scenario$num_tables');var parent=obj.parentElement;parent.removeChild(obj);obj=obj.cloneNode();obj.data = '/?divisjon=$division;avdeling=$subdivision;spiller=$pnum;posisjon=$i';parent.appendChild(obj);\">%.1f%%</a></td>\n", $pn * 100.0;
 275                 }
 276
 277                 unless ($lowest_division) {
 278                         my $pn = ($prob{$player}->[$num_games - 1] + $prob{$player}->[$num_games - 2]) / $trials;
 279
 280                         my $r = color(1.0);
 281                         my $g = color(1.0 - $pn / 3);
 282                         my $b = color(1.0 - $pn / 3);
 283                         printf "        <td style=\"background-color: rgb($r, $g, $b)\" class=\"num\">%.1f%%</td>\n", $pn * 100.0;
 284                 }
 285                 print "      </tr>\n";
 286         }
 287
 288         print << "EOF";
 289     </table>
 290
 291     <p class="scenario"><object id="scenario$num_tables" data="" type="text/html"></object></p>
 292 EOF
 293 }
 294
 295 sub find_avg_rating {
 296         my ($ratings) = shift;
 297
 298         my $sum_rating = 0.0;
 299         for my $r (values %$ratings) {
 300                 $sum_rating += $r;
 301         }
 302         return $sum_rating / scalar keys %ratings;
 303 }
 304
 305 sub get_auxillary_parameters {
 306         my $q = $dbh->prepare('SELECT * FROM ratings WHERE id < 0');
 307         $q->execute;
 308
 309         my $aux_parms = {};
 310         while (my $ref = $q->fetchrow_hashref) {
 311                 $aux_parms->{$ref->{'id'}} = $ref->{'rating'};
 312         }
 313         return $aux_parms;
 314 }
 315
 316 sub print_header {
 317         my ($cgi, $title) = @_;
 318         print $cgi->header(-type=>'text/html; charset=utf-8', -expires=>'now');
 319         print <<"EOF";
 320 <?xml version="1.0" encoding="UTF-8" ?>
 321 <!DOCTYPE
 322   html PUBLIC "-//W3C//DTD XHTML 1.1//EN"
 323   "http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd">
 324 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="no">
 325   <head>
 326     <title>$title</title>
 327     <link rel="stylesheet" href="/style" type="text/css" />
 328   </head>
 329   <body>
 330 EOF
 331 }
 332
 333 sub print_footer {
 334         print <<"EOF";
 335   </body>
 336 </html>
 337 EOF
 338 }
 339
 340 my $aux_parms = get_auxillary_parameters($dbh);
 341 my $match_stddev = $aux_parms->{-2} * sqrt(2.0);
 342
 343 my $division = $cgi->param('divisjon') // -1;
 344 my $subdivision = $cgi->param('avdeling') // -1;
 345 my $match_player = $cgi->param('spiller');
 346 my $match_position = $cgi->param('posisjon');
 347
 348 my $season = get_max_season($dbh);
 349 my @divisions = get_divisions($dbh, $season);
 350 $division = 1 if (!grep { $_ == $division } @divisions);
 351 my @subdivisions = get_subdivisions($dbh, $season, $division);
 352 $subdivision = 1 if (!grep { $_ == $subdivision } @subdivisions);
 353
 354 get_players_and_ratings($dbh, $season, $division, $subdivision);
 355 @matches = get_matches($dbh, $season, $division, $subdivision);
 356 my $cov = get_covariance_matrix($dbh, keys %players);
 357
 358 print_header($cgi, 'WLoH-plasseringsannsynlighetsberegning');
 359
 360 if (defined($match_player) && defined($match_position)) {
 361         my $tmpnam = write_parms_to_file($aux_parms, $match_stddev, \%ratings, $cov);
 362
 363         --$match_player;
 364         --$match_position;
 365
 366         my @scenario = ();
 367         open MCCALC, "$config::base_dir/mcwordfeud $trials $match_player $match_position < $tmpnam |"
 368                 or die "mccalc: $!";
 369         while (<MCCALC>) {
 370                 /(\d+) (\d+) (-?\d+)/ or next;
 371                 chomp;
 372                 push @scenario, [ $1, $2, $3 ];
 373         }
 374         close MCCALC;
 375         #unlink $tmpnam;
 376
 377         if (scalar @scenario == 0) {
 378                 # FIXME: distinguish between "all played" and "none found"
 379                 print "    <p>Fant ingen m&aring;te dette kunne skje p&aring.</p>\n";
 380         } else {
 381                 print "    <ul>\n";
 382                 for my $m (@scenario) {
 383                         printf "    <li>%s &ndash; %s: %+d</li>\n", $players{$m->[0]}, $players{$m->[1]}, $m->[2];
 384                 }
 385                 print "    </ul>\n";
 386         }
 387 } else {
 388         POSIX::setlocale(&POSIX::LC_ALL, 'nb_NO.UTF-8');
 389         printf <<"EOF", $match_stddev;
 390     <h1>WLoH-plasseringsannsynlighetsberegning</h1>
 391
 392     <p><em>Dette er et hobbyprosjekt fra tredjepart, og ikke en offisiell del av
 393       <a href="http://wordfeud.aasmul.net/">Wordfeud Leage of Honour</a>.</em></p>
 394
 395     <p>Beregningen tar ikke hensyn til ujevn spillestyrke, ting som er sagt i forumet e.l.;
 396       den antar at samtlige uspilte kamper trekkes fra en normalfordeling med standardavvik
 397       %.1f poeng. Sannsynlighetene kan summere til andre tall enn 100%% pga. avrunding.
 398       Tallene vil variere litt fra gang til gang fordi utregningen skjer ved randomisering.
 399       For scenarioeksempel, klikk i en rute.</p>
 400
 401     <p>Spillerne er sortert etter nick.</p>
 402 EOF
 403
 404         print_division_selector($dbh, \@divisions, \@subdivisions, $division, $subdivision);
 405
 406         my $max_division = $divisions[$#divisions];
 407         my $lowest_division = ($division == $max_division);
 408         make_table($aux_parms, $match_stddev, $lowest_division, {}, {}, $division, $subdivision);
 409
 410         print <<"EOF";
 411     <p style="clear: both; padding-top: 1em;">Under er en variant som tar relativ spillestyrke med i beregningen;
 412       se <a href="/rating">ratingsiden</a>.</p>
 413 EOF
 414
 415         make_table($aux_parms, $match_stddev, $lowest_division, \%ratings, $cov, $division, $subdivision);
 416
 417         my $avg_rating = find_avg_rating(\%ratings);
 418         printf "    <p style=\"clear: both; padding-top: 1em;\">Gjennomsnittlig rating i denne avdelingen er <strong>%.1f</strong>.</p>\n", $avg_rating;
 419
 420         wloh_common::output_last_sync($dbh);
 421 }
 422
 423 print_footer();