git.sesse.net Git - www-csrf/blob - lib/WWW/CSRF.pm

   1
   2 use strict;
   3 use warnings;
   4 use Bytes::Random::Secure;
   5 use Digest::HMAC_SHA1;
   6
   7 package WWW::CSRF;
   8 require Exporter;
   9 our @ISA = qw(Exporter);
  10 our @EXPORT_OK = qw(generate_csrf_token check_csrf_token);
  11 our $VERSION = '1.00';
  12
  13 sub generate_csrf_token {
  14         my ($id, $secret) = @_;
  15
  16         my $time = time;
  17
  18         my $digest = Digest::HMAC_SHA1::hmac_sha1($time . "/" . $id, $secret);
  19         my @digest_bytes = _to_byte_array($digest);
  20
  21         # Mask the token to avoid the BREACH attack.
  22         my $random = Bytes::Random::Secure::random_bytes(scalar @digest_bytes);
  23         my @random_bytes = _to_byte_array($random);
  24
  25         my $masked_token = "";
  26         my $mask = "";
  27         for my $i (0..$#digest_bytes) {
  28                 $masked_token .= sprintf "%02x", ($digest_bytes[$i] ^ $random_bytes[$i]);
  29                 $mask .= sprintf "%02x", $random_bytes[$i];
  30         }
  31
  32         return sprintf("%s,%s,%d", $masked_token, $mask, $time);
  33 }
  34
  35 sub check_csrf_token {
  36         my ($id, $secret, $csrf_token, $max_age) = @_;
  37
  38         if ($csrf_token !~ /^([0-9a-f]+),([0-9a-f]+),([0-9]+)$/) {
  39                 # Malformed token.
  40                 return 0;
  41         }
  42
  43         my ($masked_token, $mask, $time) = ($1, $2, $3);
  44         if (defined($max_age) && time - $time > $max_age) {
  45                 # Timed out.
  46                 return 0;
  47         }
  48
  49         my @masked_bytes = _to_byte_array(pack('H*', $masked_token));
  50         my @mask_bytes = _to_byte_array(pack('H*', $mask));
  51
  52         my $correct_token = Digest::HMAC_SHA1::hmac_sha1($time . '/' . $id, $secret);
  53         my @correct_bytes = _to_byte_array($correct_token);
  54
  55         if ($#masked_bytes != $#mask_bytes || $#masked_bytes != $#correct_bytes) {
  56                 # Malformed token (wrong number of characters).
  57                 return 0;
  58         }
  59
  60         # Compare in a way that should make timing attacks hard.
  61         my $mismatches = 0;
  62         for my $i (0..$#masked_bytes) {
  63                 $mismatches += $masked_bytes[$i] ^ $mask_bytes[$i] ^ $correct_bytes[$i];
  64         }
  65         return ($mismatches == 0);
  66 }
  67
  68 # Converts each byte in the given string to its numeric value,
  69 # e.g., "ABCabc" becomes (65, 66, 67, 97, 98, 99).
  70 sub _to_byte_array {
  71         return unpack("C*", $_[0]);
  72 }
  73
  74 1;