git.sesse.net Git - www-csrf/blob - lib/WWW/CSRF.pm

   1
   2 use strict;
   3 use warnings;
   4 use Bytes::Random::Secure;
   5 use Digest::HMAC_SHA1;
   6
   7 package WWW::CSRF;
   8 require Exporter;
   9 our @ISA = qw(Exporter);
  10 our @EXPORT_OK = qw(generate_csrf_token check_csrf_token);
  11 our $VERSION = '1.00';
  12
  13 sub generate_csrf_token {
  14         my ($id, $secret, $options) = @_;
  15
  16         my $time = $options->{'Time'} // time;
  17         my $random = $options->{'Random'};
  18
  19         my $digest = Digest::HMAC_SHA1::hmac_sha1($time . "/" . $id, $secret);
  20         my @digest_bytes = _to_byte_array($digest);
  21
  22         # Mask the token to avoid the BREACH attack.
  23         if (!defined($random) || length($random) != length($digest)) {
  24                 $random = Bytes::Random::Secure::random_bytes(scalar @digest_bytes);
  25         }
  26         my @random_bytes = _to_byte_array($random);
  27
  28         my $masked_token = "";
  29         my $mask = "";
  30         for my $i (0..$#digest_bytes) {
  31                 $masked_token .= sprintf "%02x", ($digest_bytes[$i] ^ $random_bytes[$i]);
  32                 $mask .= sprintf "%02x", $random_bytes[$i];
  33         }
  34
  35         return sprintf("%s,%s,%d", $masked_token, $mask, $time);
  36 }
  37
  38 sub check_csrf_token {
  39         my ($id, $secret, $csrf_token, $options) = @_;
  40
  41         if ($csrf_token !~ /^([0-9a-f]+),([0-9a-f]+),([0-9]+)$/) {
  42                 # Malformed token.
  43                 return 0;
  44         }
  45
  46         my $ref_time = $options->{'Time'} // time;
  47
  48         my ($masked_token, $mask, $time) = ($1, $2, $3);
  49         my $max_age = $options->{'MaxAge'};
  50         if (defined($max_age) && $ref_time - $time > $max_age) {
  51                 # Timed out.
  52                 return 0;
  53         }
  54
  55         my @masked_bytes = _to_byte_array(pack('H*', $masked_token));
  56         my @mask_bytes = _to_byte_array(pack('H*', $mask));
  57
  58         my $correct_token = Digest::HMAC_SHA1::hmac_sha1($time . '/' . $id, $secret);
  59         my @correct_bytes = _to_byte_array($correct_token);
  60
  61         if ($#masked_bytes != $#mask_bytes || $#masked_bytes != $#correct_bytes) {
  62                 # Malformed token (wrong number of characters).
  63                 return 0;
  64         }
  65
  66         # Compare in a way that should make timing attacks hard.
  67         my $mismatches = 0;
  68         for my $i (0..$#masked_bytes) {
  69                 $mismatches += $masked_bytes[$i] ^ $mask_bytes[$i] ^ $correct_bytes[$i];
  70         }
  71         return ($mismatches == 0);
  72 }
  73
  74 # Converts each byte in the given string to its numeric value,
  75 # e.g., "ABCabc" becomes (65, 66, 67, 97, 98, 99).
  76 sub _to_byte_array {
  77         return unpack("C*", $_[0]);
  78 }
  79
  80 1;